mpn/arm/sub_n.asm

   1 dnl  ARM mpn_sub_n -- Subtract two limb vectors of the same length > 0 and
   2 dnl  store difference in a third limb vector.
   3 dnl  Contributed by Robert Harley.
   4
   5 dnl  Copyright 1997, 2000, 2001 Free Software Foundation, Inc.
   6
   7 dnl  This file is part of the GNU MP Library.
   8
   9 dnl  The GNU MP Library is free software; you can redistribute it and/or modify
  10 dnl  it under the terms of the GNU Lesser General Public License as published
  11 dnl  by the Free Software Foundation; either version 3 of the License, or (at
  12 dnl  your option) any later version.
  13
  14 dnl  The GNU MP Library is distributed in the hope that it will be useful, but
  15 dnl  WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  16 dnl  or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General Public
  17 dnl  License for more details.
  18
  19 dnl  You should have received a copy of the GNU Lesser General Public License
  20 dnl  along with the GNU MP Library.  If not, see http://www.gnu.org/licenses/.
  21
  22 include(`../config.m4')
  23
  24 C This code runs at 5 cycles/limb.
  25
  26 define(`rp',`r0')
  27 define(`up',`r1')
  28 define(`vp',`r2')
  29 define(`n',`r3')
  30
  31
  32 ASM_START()
  33 PROLOGUE(mpn_sub_n)
  34         stmfd   sp!, { r8, r9, lr }
  35         subs    r12, r12, r12
  36         tst     n, #1
  37         beq     L(skip1)
  38         ldr     r12, [up], #4
  39         ldr     lr, [vp], #4
  40         subs    r12, r12, lr
  41         str     r12, [rp], #4
  42 L(skip1):
  43         tst     n, #2
  44         beq     L(skip2)
  45         ldmia   up!, { r8, r9 }
  46         ldmia   vp!, { r12, lr }
  47         sbcs    r8, r8, r12
  48         sbcs    r9, r9, lr
  49         stmia   rp!, { r8, r9 }
  50 L(skip2):
  51         bics    n, n, #3
  52         beq     L(return)
  53         stmfd   sp!, { r4, r5, r6, r7 }
  54 L(sub_n_loop):
  55         ldmia   up!, { r4, r5, r6, r7 }
  56         ldmia   vp!, { r8, r9, r12, lr }
  57         sbcs    r4, r4, r8
  58         ldr     r8, [rp, #12]                   C cache allocate
  59         sbcs    r5, r5, r9
  60         sbcs    r6, r6, r12
  61         sbcs    r7, r7, lr
  62         stmia   rp!, { r4, r5, r6, r7 }
  63         sub     n, n, #4
  64         teq     n, #0
  65         bne     L(sub_n_loop)
  66         ldmfd   sp!, { r4, r5, r6, r7 }
  67 L(return):
  68         sbc     r0, r0, r0
  69         and     r0, r0, #1
  70         ldmfd   sp!, { r8, r9, pc }
  71 EPILOGUE(mpn_sub_n)