modules/ts/CMakeLists.txt

   1 set(the_description "The ts module")
   2
   3 if(NOT BUILD_opencv_ts AND NOT BUILD_TESTS AND NOT BUILD_PERF_TESTS)
   4   ocv_module_disable(ts)
   5 endif()
   6
   7 set(OPENCV_MODULE_TYPE STATIC)
   8 set(OPENCV_MODULE_IS_PART_OF_WORLD FALSE)
   9
  10 if(WINRT)
  11   # WINRT doesn't have access to environment variables
  12   # so adding corresponding macros during CMake run
  13   add_env_definitions(OPENCV_TEST_DATA_PATH)
  14   add_env_definitions(OPENCV_PERF_VALIDATION_DIR)
  15 endif()
  16
  17 ocv_warnings_disable(CMAKE_CXX_FLAGS -Wundef)
  18 if(ARM AND CV_GCC AND CMAKE_CXX_COMPILER_VERSION VERSION_GREATER 7.0)
  19   # suppress warnings from GCC only on 7.1 and later
  20   ocv_warnings_disable(CMAKE_CXX_FLAGS -Wno-psabi)
  21 endif()
  22
  23 ocv_add_module(ts INTERNAL opencv_core opencv_imgproc opencv_imgcodecs opencv_videoio opencv_highgui)
  24
  25 ocv_glob_module_sources()
  26 ocv_module_include_directories()
  27 ocv_create_module()
  28
  29 # generate config file
  30 set(OPENCV_TESTS_CONFIG_FILE "${CMAKE_BINARY_DIR}/opencv_tests_config.hpp")
  31 set(OPENCV_TESTS_CONFIG_STR "")
  32 if(CMAKE_INSTALL_PREFIX)
  33   set(OPENCV_TESTS_CONFIG_STR "${OPENCV_TESTS_CONFIG_STR}
  34 #define OPENCV_INSTALL_PREFIX \"${CMAKE_INSTALL_PREFIX}\"
  35 ")
  36 endif()
  37 if(OPENCV_TEST_DATA_INSTALL_PATH)
  38   set(OPENCV_TESTS_CONFIG_STR "${OPENCV_TESTS_CONFIG_STR}
  39 #define OPENCV_TEST_DATA_INSTALL_PATH \"${OPENCV_TEST_DATA_INSTALL_PATH}\"
  40 ")
  41 endif()
  42 if(EXISTS "${OPENCV_TESTS_CONFIG_FILE}")
  43   file(READ "${OPENCV_TESTS_CONFIG_FILE}" __content)
  44 endif()
  45 if(NOT OPENCV_TESTS_CONFIG_STR STREQUAL "${__content}")
  46   file(WRITE "${OPENCV_TESTS_CONFIG_FILE}" "${OPENCV_TESTS_CONFIG_STR}")
  47 endif()