modules/python/CMakeLists.txt

   1 # ----------------------------------------------------------------------------
   2 #  CMake file for python support
   3 # ----------------------------------------------------------------------------
   4
   5 if(WIN32 AND CMAKE_BUILD_TYPE STREQUAL "Debug")
   6   ocv_module_disable(python)
   7 endif()
   8
   9 if(ANDROID OR IOS OR NOT PYTHONLIBS_FOUND OR NOT PYTHON_NUMPY_INCLUDE_DIRS)
  10   ocv_module_disable(python)
  11 endif()
  12
  13 set(the_description "The python bindings")
  14 ocv_add_module(python BINDINGS opencv_core opencv_flann opencv_imgproc opencv_video opencv_ml opencv_features2d opencv_highgui opencv_calib3d opencv_photo opencv_objdetect opencv_contrib opencv_legacy opencv_softcascade OPTIONAL opencv_nonfree)
  15
  16 ocv_module_include_directories(
  17     "${PYTHON_INCLUDE_PATH}"
  18     ${PYTHON_NUMPY_INCLUDE_DIRS}
  19     "${CMAKE_CURRENT_SOURCE_DIR}/src2"
  20     )
  21
  22 set(opencv_hdrs
  23     "${OPENCV_MODULE_opencv_core_LOCATION}/include/opencv2/core.hpp"
  24     "${OPENCV_MODULE_opencv_core_LOCATION}/include/opencv2/core/base.hpp"
  25     "${OPENCV_MODULE_opencv_core_LOCATION}/include/opencv2/core/types.hpp"
  26     "${OPENCV_MODULE_opencv_core_LOCATION}/include/opencv2/core/persistence.hpp"
  27     "${OPENCV_MODULE_opencv_core_LOCATION}/include/opencv2/core/utility.hpp"
  28     "${OPENCV_MODULE_opencv_core_LOCATION}/include/opencv2/core/ocl.hpp"
  29     "${OPENCV_MODULE_opencv_flann_LOCATION}/include/opencv2/flann/miniflann.hpp"
  30     "${OPENCV_MODULE_opencv_imgproc_LOCATION}/include/opencv2/imgproc.hpp"
  31     "${OPENCV_MODULE_opencv_video_LOCATION}/include/opencv2/video/background_segm.hpp"
  32     "${OPENCV_MODULE_opencv_video_LOCATION}/include/opencv2/video/tracking.hpp"
  33     "${OPENCV_MODULE_opencv_photo_LOCATION}/include/opencv2/photo.hpp"
  34     "${OPENCV_MODULE_opencv_highgui_LOCATION}/include/opencv2/highgui.hpp"
  35     "${OPENCV_MODULE_opencv_ml_LOCATION}/include/opencv2/ml.hpp"
  36     "${OPENCV_MODULE_opencv_features2d_LOCATION}/include/opencv2/features2d.hpp"
  37     "${OPENCV_MODULE_opencv_calib3d_LOCATION}/include/opencv2/calib3d.hpp"
  38     "${OPENCV_MODULE_opencv_objdetect_LOCATION}/include/opencv2/objdetect.hpp"
  39     "${OPENCV_MODULE_opencv_softcascade_LOCATION}/include/opencv2/softcascade.hpp"
  40     "${OPENCV_MODULE_opencv_contrib_LOCATION}/include/opencv2/contrib.hpp")
  41
  42 if(HAVE_opencv_nonfree)
  43   list(APPEND opencv_hdrs     "${OPENCV_MODULE_opencv_nonfree_LOCATION}/include/opencv2/nonfree/features2d.hpp"
  44                               "${OPENCV_MODULE_opencv_nonfree_LOCATION}/include/opencv2/nonfree.hpp")
  45 endif()
  46
  47 set(cv2_generated_hdrs
  48     "${CMAKE_CURRENT_BINARY_DIR}/pyopencv_generated_include.h"
  49     "${CMAKE_CURRENT_BINARY_DIR}/pyopencv_generated_funcs.h"
  50     "${CMAKE_CURRENT_BINARY_DIR}/pyopencv_generated_func_tab.h"
  51     "${CMAKE_CURRENT_BINARY_DIR}/pyopencv_generated_types.h"
  52     "${CMAKE_CURRENT_BINARY_DIR}/pyopencv_generated_type_reg.h"
  53     "${CMAKE_CURRENT_BINARY_DIR}/pyopencv_generated_const_reg.h")
  54
  55 add_custom_command(
  56    OUTPUT ${cv2_generated_hdrs}
  57    COMMAND ${PYTHON_EXECUTABLE} "${CMAKE_CURRENT_SOURCE_DIR}/src2/gen2.py" ${CMAKE_CURRENT_BINARY_DIR} ${opencv_hdrs}
  58    DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/src2/gen2.py
  59    DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/src2/hdr_parser.py
  60    DEPENDS ${opencv_hdrs})
  61
  62 add_library(${the_module} SHARED src2/cv2.cpp ${cv2_generated_hdrs})
  63 set_target_properties(${the_module} PROPERTIES COMPILE_DEFINITIONS OPENCV_NOSTL)
  64
  65 if(PYTHON_DEBUG_LIBRARIES AND NOT PYTHON_LIBRARIES MATCHES "optimized.*debug")
  66   target_link_libraries(${the_module} debug ${PYTHON_DEBUG_LIBRARIES} optimized ${PYTHON_LIBRARIES})
  67 else()
  68   target_link_libraries(${the_module} ${PYTHON_LIBRARIES})
  69 endif()
  70 target_link_libraries(${the_module} ${OPENCV_MODULE_${the_module}_DEPS})
  71
  72 execute_process(COMMAND ${PYTHON_EXECUTABLE} -c "import distutils.sysconfig; print(distutils.sysconfig.get_config_var('SO'))"
  73                 RESULT_VARIABLE PYTHON_CVPY_PROCESS
  74                 OUTPUT_VARIABLE CVPY_SUFFIX
  75                 OUTPUT_STRIP_TRAILING_WHITESPACE)
  76
  77 set_target_properties(${the_module} PROPERTIES
  78                       PREFIX ""
  79                       OUTPUT_NAME cv2
  80                       SUFFIX ${CVPY_SUFFIX})
  81
  82 if(ENABLE_SOLUTION_FOLDERS)
  83   set_target_properties(${the_module} PROPERTIES FOLDER "bindings")
  84 endif()
  85
  86 if(MSVC)
  87     add_definitions(-DCVAPI_EXPORTS)
  88 endif()
  89
  90 if(CMAKE_COMPILER_IS_GNUCXX AND NOT ENABLE_NOISY_WARNINGS)
  91   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wno-unused-function")
  92 endif()
  93
  94 if(MSVC AND NOT ENABLE_NOISY_WARNINGS)
  95   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /wd4100") #unreferenced formal parameter
  96   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /wd4127") #conditional expression is constant
  97   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /wd4505") #unreferenced local function has been removed
  98   string(REPLACE "/W4" "/W3" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
  99 endif()
 100
 101 if(MSVC AND NOT BUILD_SHARED_LIBS)
 102   set_target_properties(${the_module} PROPERTIES LINK_FLAGS "/NODEFAULTLIB:atlthunk.lib /NODEFAULTLIB:atlsd.lib /DEBUG")
 103 endif()
 104
 105 if(MSVC AND NOT PYTHON_DEBUG_LIBRARIES)
 106   set(PYTHON_INSTALL_CONFIGURATIONS CONFIGURATIONS Release)
 107 else()
 108   set(PYTHON_INSTALL_CONFIGURATIONS "")
 109 endif()
 110
 111 if(WIN32)
 112   set(PYTHON_INSTALL_ARCHIVE "")
 113 else()
 114   set(PYTHON_INSTALL_ARCHIVE ARCHIVE DESTINATION ${PYTHON_PACKAGES_PATH} COMPONENT python)
 115 endif()
 116
 117 if(NOT INSTALL_CREATE_DISTRIB)
 118   install(TARGETS ${the_module}
 119           ${PYTHON_INSTALL_CONFIGURATIONS}
 120           RUNTIME DESTINATION ${PYTHON_PACKAGES_PATH} COMPONENT python
 121           LIBRARY DESTINATION ${PYTHON_PACKAGES_PATH} COMPONENT python
 122           ${PYTHON_INSTALL_ARCHIVE}
 123           )
 124 else()
 125   if(DEFINED PYTHON_VERSION_MAJOR)
 126     set(__ver "${PYTHON_VERSION_MAJOR}.${PYTHON_VERSION_MINOR}")
 127   else()
 128     set(__ver "unknown")
 129   endif()
 130   install(TARGETS ${the_module}
 131           CONFIGURATIONS Release
 132           RUNTIME DESTINATION python/${__ver}/${OpenCV_ARCH} COMPONENT python
 133           LIBRARY DESTINATION python/${__ver}/${OpenCV_ARCH} COMPONENT python
 134           )
 135 endif()