modules/java/test/CMakeLists.txt

   1 # list of modules covered with tests
   2 set(tested_modules opencv_calib3d opencv_core opencv_features2d opencv_highgui opencv_imgproc opencv_objdetect opencv_photo opencv_video)
   3
   4 # opencv_ml is broken
   5 #list(APPEND tested_modules opencv_ml)
   6
   7 ocv_check_dependencies(opencv_java ${tested_modules})
   8
   9 if(NOT OCV_DEPENDENCIES_FOUND)
  10   return()
  11 endif()
  12
  13 project(opencv_test_java)
  14
  15 set(opencv_test_java_bin_dir "${CMAKE_CURRENT_BINARY_DIR}/.build")
  16 set(android_source_dir "${CMAKE_CURRENT_SOURCE_DIR}/../android_test")
  17 set(java_source_dir ${CMAKE_CURRENT_SOURCE_DIR})
  18
  19 # make sure the build directory exists
  20 file(MAKE_DIRECTORY "${opencv_test_java_bin_dir}")
  21
  22 # get project sources
  23 file(GLOB_RECURSE opencv_test_java_files RELATIVE "${android_source_dir}" "${android_source_dir}/res/*" "${android_source_dir}/src/*.java")
  24 # These are the files that need to be updated for pure Java.
  25 ocv_list_filterout(opencv_test_java_files "OpenCVTest(Case|Runner).java")
  26 # These files aren't for desktop Java.
  27 ocv_list_filterout(opencv_test_java_files "/android/")
  28 # opencv_ml is broken
  29 ocv_list_filterout(opencv_test_java_files "/ml/")
  30
  31 # These are files updated for pure Java.
  32 file(GLOB_RECURSE modified_files RELATIVE "${java_source_dir}" "${java_source_dir}/src/*")
  33
  34 # These are extra jars needed to run the tests.
  35 file(GLOB_RECURSE lib_files RELATIVE "${java_source_dir}" "${java_source_dir}/lib/*.jar")
  36
  37 # copy sources out from the build tree
  38 set(opencv_test_java_file_deps "")
  39 foreach(f ${opencv_test_java_files})
  40   add_custom_command(OUTPUT "${opencv_test_java_bin_dir}/${f}"
  41                      COMMAND ${CMAKE_COMMAND} -E copy "${android_source_dir}/${f}" "${opencv_test_java_bin_dir}/${f}"
  42                      DEPENDS "${android_source_dir}/${f}"
  43                      COMMENT "Copying ${f}"
  44                     )
  45   list(APPEND opencv_test_java_file_deps "${android_source_dir}/${f}" "${opencv_test_java_bin_dir}/${f}")
  46 endforeach()
  47
  48 # Overwrite select Android sources with Java-specific sources.
  49 # Also, copy over the libs we'll need for testing.
  50 foreach(f ${modified_files} ${lib_files})
  51   add_custom_command(OUTPUT "${opencv_test_java_bin_dir}/${f}"
  52                      COMMAND ${CMAKE_COMMAND} -E copy "${java_source_dir}/${f}" "${opencv_test_java_bin_dir}/${f}"
  53                      DEPENDS "${java_source_dir}/${f}"
  54                      COMMENT "Copying ${f}"
  55                     )
  56   list(APPEND opencv_test_java_file_deps "${java_source_dir}/${f}" "${opencv_test_java_bin_dir}/${f}")
  57 endforeach()
  58
  59 # Copy the OpenCV jar after it has been generated.
  60 add_custom_command(OUTPUT "${opencv_test_java_bin_dir}/bin/${JAR_NAME}"
  61                    COMMAND ${CMAKE_COMMAND} -E copy "${JAR_FILE}" "${opencv_test_java_bin_dir}/bin/${JAR_NAME}"
  62                    DEPENDS "${JAR_FILE}"
  63                    COMMENT "Copying the OpenCV jar"
  64                   )
  65
  66 add_custom_command(OUTPUT "${opencv_test_java_bin_dir}/build.xml"
  67                    COMMAND ${CMAKE_COMMAND} -E copy "${CMAKE_CURRENT_SOURCE_DIR}/build.xml" "${opencv_test_java_bin_dir}/build.xml"
  68                    DEPENDS "${CMAKE_CURRENT_SOURCE_DIR}/build.xml"
  69                    COMMENT "Copying build.xml"
  70                   )
  71
  72 add_custom_command(OUTPUT "${opencv_test_java_bin_dir}/build/jar/opencv-test.jar"
  73                    COMMAND "${ANT_EXECUTABLE}" build
  74                    WORKING_DIRECTORY "${opencv_test_java_bin_dir}"
  75                    DEPENDS ${opencv_test_java_file_deps} "${opencv_test_java_bin_dir}/build.xml" "${CMAKE_CURRENT_SOURCE_DIR}/build.xml" "${JAR_FILE}" "${opencv_test_java_bin_dir}/bin/${JAR_NAME}"
  76                    COMMENT "Build Java tests"
  77                   )
  78
  79 # Not add_custom_command because generator expressions aren't supported in
  80 # OUTPUT file names, and we need to generate different files for different
  81 # configurations.
  82 add_custom_target(${PROJECT_NAME}_properties
  83                   COMMAND "${CMAKE_COMMAND}" -E echo "opencv.lib.path = $<TARGET_FILE_DIR:${the_module}>"
  84                     > "${opencv_test_java_bin_dir}/ant-$<CONFIGURATION>.properties"
  85                   VERBATIM
  86                  )
  87
  88 add_custom_target(${PROJECT_NAME} ALL
  89                   DEPENDS ${the_module} ${PROJECT_NAME}_properties
  90                   SOURCES "${opencv_test_java_bin_dir}/build/jar/opencv-test.jar"
  91                  )
  92
  93 if(ENABLE_SOLUTION_FOLDERS)
  94   set_target_properties(${PROJECT_NAME} PROPERTIES FOLDER "tests accuracy")
  95 endif()