modules/java/android_test/CMakeLists.txt

   1 ocv_check_dependencies(opencv_java ${OPENCV_MODULE_opencv_java_OPT_DEPS} ${OPENCV_MODULE_opencv_java_REQ_DEPS})
   2
   3 if(NOT OCV_DEPENDENCIES_FOUND OR NOT ANT_EXECUTABLE OR NOT ANDROID_EXECUTABLE OR NOT ANDROID_TOOLS_Pkg_Revision GREATER 13)
   4   return()
   5 endif()
   6
   7 project(opencv_test_java)
   8
   9 set(opencv_test_java_bin_dir "${CMAKE_CURRENT_BINARY_DIR}/.build")
  10
  11 # get project sources
  12 file(GLOB_RECURSE opencv_test_java_files RELATIVE "${CMAKE_CURRENT_SOURCE_DIR}" "${CMAKE_CURRENT_SOURCE_DIR}/res/*" "${CMAKE_CURRENT_SOURCE_DIR}/src/*")
  13 ocv_list_filterout(opencv_test_java_files ".svn")
  14
  15 # copy sources out from the build tree
  16 set(opencv_test_java_file_deps "")
  17 foreach(f ${opencv_test_java_files} ${ANDROID_MANIFEST_FILE} ".classpath" ".project")
  18   add_custom_command(
  19       OUTPUT "${opencv_test_java_bin_dir}/${f}"
  20       COMMAND ${CMAKE_COMMAND} -E copy "${CMAKE_CURRENT_SOURCE_DIR}/${f}" "${opencv_test_java_bin_dir}/${f}"
  21       MAIN_DEPENDENCY "${CMAKE_CURRENT_SOURCE_DIR}/${f}"
  22       COMMENT "Copying ${f}")
  23   list(APPEND opencv_test_java_file_deps "${CMAKE_CURRENT_SOURCE_DIR}/${f}" "${opencv_test_java_bin_dir}/${f}")
  24 endforeach()
  25
  26 # fix Android project
  27 set(android_proj_target_files ${ANDROID_PROJECT_FILES})
  28 ocv_list_add_prefix(android_proj_target_files "${opencv_test_java_bin_dir}/")
  29 file(RELATIVE_PATH __dep "${opencv_test_java_bin_dir}" "${OpenCV_BINARY_DIR}")
  30
  31 add_custom_command(
  32     OUTPUT ${android_proj_target_files}
  33     COMMAND ${CMAKE_COMMAND} -E remove ${android_proj_target_files}
  34     COMMAND ${ANDROID_EXECUTABLE} --silent update test-project --path "${opencv_test_java_bin_dir}" --main "${OpenCV_BINARY_DIR}"
  35     COMMAND ${ANDROID_EXECUTABLE} --silent update project --path "${opencv_test_java_bin_dir}" --library "${__dep}"
  36     MAIN_DEPENDENCY "${opencv_test_java_bin_dir}/${ANDROID_MANIFEST_FILE}"
  37     DEPENDS "${CMAKE_CURRENT_SOURCE_DIR}/${ANDROID_MANIFEST_FILE}"
  38     COMMENT "Updating Android Java API test project")
  39
  40 list(APPEND opencv_test_java_file_deps ${android_proj_target_files})
  41
  42 # build java part
  43 add_custom_command(
  44     OUTPUT "${opencv_test_java_bin_dir}/bin/OpenCVTest-debug.apk"
  45     COMMAND ${CMAKE_COMMAND} -E copy "${OpenCV_BINARY_DIR}/lib/${ANDROID_NDK_ABI_NAME}/libopencv_java.so" "${opencv_test_java_bin_dir}/libs/${ANDROID_NDK_ABI_NAME}/libopencv_java.so"
  46     COMMAND ${ANT_EXECUTABLE} -q -noinput -k debug
  47     COMMAND ${CMAKE_COMMAND} -E touch "${opencv_test_java_bin_dir}/bin/OpenCVTest-debug.apk" # needed because ant does not update the timestamp of updated apk
  48     WORKING_DIRECTORY "${opencv_test_java_bin_dir}"
  49     MAIN_DEPENDENCY "${opencv_test_java_bin_dir}/${ANDROID_MANIFEST_FILE}"
  50     DEPENDS "${JAR_FILE}.dephelper" opencv_java
  51     DEPENDS ${opencv_test_java_file_deps})
  52
  53 add_custom_target(${PROJECT_NAME} ALL SOURCES "${opencv_test_java_bin_dir}/bin/OpenCVTest-debug.apk" )
  54 add_dependencies(${PROJECT_NAME} opencv_java ${__android_project_chain})
  55 set(__android_project_chain ${PROJECT_NAME} CACHE INTERNAL "auxiliary variable used for Android progects chaining" FORCE)
  56
  57 # put the final .apk to the OpenCV's bin folder
  58 add_custom_command(TARGET ${PROJECT_NAME} POST_BUILD COMMAND ${CMAKE_COMMAND} -E copy "${opencv_test_java_bin_dir}/bin/OpenCVTest-debug.apk" "${OpenCV_BINARY_DIR}/bin/${PROJECT_NAME}.apk")
  59
  60 add_dependencies(opencv_tests ${PROJECT_NAME})
  61
  62 if(PYTHON_DEFAULT_AVAILABLE)
  63   set(CHECK_TEST_COVERAGE "${OPENCV_MODULE_opencv_java_LOCATION}/check-tests.py")
  64   add_custom_command(TARGET ${PROJECT_NAME} POST_BUILD
  65       COMMAND ${PYTHON_DEFAULT_EXECUTABLE} ${CHECK_TEST_COVERAGE} "${CMAKE_CURRENT_SOURCE_DIR}/src" "${OpenCV_BINARY_DIR}/src" > "${CMAKE_CURRENT_BINARY_DIR}/tests_coverage.log"
  66       )
  67 endif()