modules/dnn/CMakeLists.txt

   1 if(WINRT)
   2   ocv_module_disable(dnn)
   3 endif()
   4
   5 if(NOT HAVE_PROTOBUF)
   6   ocv_module_disable(opencv_dnn)
   7 endif()
   8
   9 set(the_description "Deep neural network module. It allows to load models from different frameworks and to make forward pass")
  10
  11 ocv_add_dispatched_file_force_all("layers/layers_common" AVX AVX2 AVX512_SKX)
  12
  13 ocv_add_module(dnn opencv_core opencv_imgproc WRAP python java js)
  14
  15 ocv_option(OPENCV_DNN_OPENCL "Build with OpenCL support" HAVE_OPENCL AND NOT APPLE)
  16
  17 if(OPENCV_DNN_OPENCL AND HAVE_OPENCL)
  18   add_definitions(-DCV_OCL4DNN=1)
  19 endif()
  20
  21 ocv_option(OPENCV_DNN_CUDA "Build with CUDA support" HAVE_CUDA AND HAVE_CUBLAS AND HAVE_CUDNN)
  22
  23 if(OPENCV_DNN_CUDA AND HAVE_CUDA AND HAVE_CUBLAS AND HAVE_CUDNN)
  24   add_definitions(-DCV_CUDA4DNN=1)
  25 endif()
  26
  27 ocv_cmake_hook_append(INIT_MODULE_SOURCES_opencv_dnn "${CMAKE_CURRENT_LIST_DIR}/cmake/hooks/INIT_MODULE_SOURCES_opencv_dnn.cmake")
  28
  29 if(MSVC)
  30   add_definitions( -D_CRT_SECURE_NO_WARNINGS=1 )
  31   ocv_warnings_disable(CMAKE_CXX_FLAGS /wd4244 /wd4267 /wd4018 /wd4355 /wd4800 /wd4251 /wd4996 /wd4146
  32                                        /wd4305 /wd4127 /wd4100 /wd4512 /wd4125 /wd4389 /wd4510 /wd4610
  33                                        /wd4702 /wd4456 /wd4457 /wd4065 /wd4310 /wd4661 /wd4506
  34   )
  35 else()
  36   ocv_warnings_disable(CMAKE_CXX_FLAGS -Wno-deprecated -Wmissing-prototypes -Wmissing-declarations -Wshadow
  37                                        -Wunused-parameter -Wsign-compare
  38   )
  39 endif()
  40 if(HAVE_CUDA)
  41   ocv_warnings_disable(CMAKE_CXX_FLAGS -Wundef)
  42 endif()
  43 if(NOT HAVE_CXX11)
  44   ocv_warnings_disable(CMAKE_CXX_FLAGS -Wno-undef)  # LANG_CXX11 from protobuf files
  45 endif()
  46
  47 if(APPLE_FRAMEWORK)
  48   ocv_warnings_disable(CMAKE_CXX_FLAGS -Wshorten-64-to-32)
  49 endif()
  50
  51 if(ANDROID)
  52   add_definitions(-DDISABLE_POSIX_MEMALIGN -DTH_DISABLE_HEAP_TRACKING)
  53 endif()
  54
  55 if(NOT BUILD_PROTOBUF)
  56   add_definitions(-DOPENCV_DNN_EXTERNAL_PROTOBUF=1)
  57 endif()
  58
  59 add_definitions(-DHAVE_PROTOBUF=1)
  60
  61 #suppress warnings in autogenerated caffe.pb.* files
  62 ocv_warnings_disable(CMAKE_CXX_FLAGS
  63     /wd4125 /wd4267 /wd4127 /wd4244 /wd4512 /wd4702
  64     /wd4456 /wd4510 /wd4610 /wd4800
  65     /wd4701 /wd4703                    # potentially uninitialized local/pointer variable 'value' used
  66     /wd4505                            # unreferenced local function has been removed
  67     -wd858 -wd2196
  68     -Winvalid-offsetof                 # Apple Clang (attr_value.pb.cc)
  69 )
  70
  71 if(PROTOBUF_UPDATE_FILES)
  72   file(GLOB proto_files "${CMAKE_CURRENT_LIST_DIR}/src/tensorflow/*.proto" "${CMAKE_CURRENT_LIST_DIR}/src/caffe/opencv-caffe.proto" "${CMAKE_CURRENT_LIST_DIR}/src/onnx/opencv-onnx.proto")
  73   set(PROTOBUF_GENERATE_CPP_APPEND_PATH ON) # required for tensorflow
  74   protobuf_generate_cpp(fw_srcs fw_hdrs ${proto_files})
  75 else()
  76   file(GLOB fw_srcs "${CMAKE_CURRENT_LIST_DIR}/misc/tensorflow/*.cc" "${CMAKE_CURRENT_LIST_DIR}/misc/caffe/opencv-caffe.pb.cc" "${CMAKE_CURRENT_LIST_DIR}/misc/onnx/opencv-onnx.pb.cc")
  77   file(GLOB fw_hdrs "${CMAKE_CURRENT_LIST_DIR}/misc/tensorflow/*.h" "${CMAKE_CURRENT_LIST_DIR}/misc/caffe/opencv-caffe.pb.h" "${CMAKE_CURRENT_LIST_DIR}/misc/onnx/opencv-onnx.pb.h")
  78   set(fw_inc "${CMAKE_CURRENT_LIST_DIR}/misc/caffe" "${CMAKE_CURRENT_LIST_DIR}/misc/tensorflow" "${CMAKE_CURRENT_LIST_DIR}/misc/onnx")
  79 endif()
  80
  81 set(include_dirs ${fw_inc})
  82 set(sources_options "")
  83 set(libs libprotobuf ${LAPACK_LIBRARIES})
  84
  85 if(OPENCV_DNN_OPENCL AND HAVE_OPENCL)
  86   list(APPEND include_dirs ${OPENCL_INCLUDE_DIRS})
  87 else()
  88   set(sources_options EXCLUDE_OPENCL)
  89 endif()
  90
  91 if(OPENCV_DNN_CUDA AND HAVE_CUDA AND HAVE_CUBLAS AND HAVE_CUDNN)
  92   list(APPEND include_dirs ${CUDA_TOOLKIT_INCLUDE} ${CUDNN_INCLUDE_DIRS})
  93 else()
  94   set(sources_options ${sources_options} EXCLUDE_CUDA)
  95 endif()
  96
  97 ocv_module_include_directories(${include_dirs})
  98 if(CMAKE_CXX_COMPILER_ID STREQUAL "GNU")
  99   ocv_append_source_files_cxx_compiler_options(fw_srcs "-Wno-suggest-override")  # GCC
 100 elseif(CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
 101   ocv_append_source_files_cxx_compiler_options(fw_srcs "-Wno-inconsistent-missing-override")  # Clang
 102 endif()
 103 ocv_glob_module_sources(${sources_options} SOURCES ${fw_srcs})
 104 ocv_create_module(${libs} ${INF_ENGINE_TARGET})
 105 ocv_add_samples()
 106 ocv_add_accuracy_tests(${INF_ENGINE_TARGET})
 107
 108 set(perf_path "${CMAKE_CURRENT_LIST_DIR}/perf")
 109 file(GLOB_RECURSE perf_srcs "${perf_path}/*.cpp")
 110 file(GLOB_RECURSE perf_hdrs "${perf_path}/*.hpp" "${perf_path}/*.h")
 111 ocv_add_perf_tests(${INF_ENGINE_TARGET}
 112     FILES test_common "${CMAKE_CURRENT_LIST_DIR}/test/test_common.hpp" "${CMAKE_CURRENT_LIST_DIR}/test/test_common.impl.hpp"
 113     FILES Src ${perf_srcs}
 114     FILES Include ${perf_hdrs}
 115 )
 116
 117 ocv_option(${the_module}_PERF_CAFFE "Add performance tests of Caffe framework" OFF)
 118 ocv_option(${the_module}_PERF_CLCAFFE "Add performance tests of clCaffe framework" OFF)
 119 if(BUILD_PERF_TESTS)
 120   if (${the_module}_PERF_CAFFE)
 121     find_package(Caffe QUIET)
 122     if (Caffe_FOUND)
 123       add_definitions(-DHAVE_CAFFE=1)
 124       ocv_target_link_libraries(opencv_perf_dnn caffe)
 125     endif()
 126   elseif(${the_module}_PERF_CLCAFFE)
 127     find_package(Caffe QUIET)
 128     if (Caffe_FOUND)
 129       add_definitions(-DHAVE_CLCAFFE=1)
 130       ocv_target_link_libraries(opencv_perf_dnn caffe)
 131     endif()
 132   endif()
 133 endif()