modules/dnn/CMakeLists.txt

   1 if(WINRT)
   2   ocv_module_disable(dnn)
   3 endif()
   4
   5 if(NOT HAVE_PROTOBUF)
   6   ocv_module_disable(opencv_dnn)
   7 endif()
   8
   9 set(the_description "Deep neural network module. It allows to load models from different frameworks and to make forward pass")
  10
  11 ocv_add_dispatched_file_force_all("layers/layers_common" AVX AVX2 AVX512_SKX)
  12
  13 ocv_add_module(dnn opencv_core opencv_imgproc WRAP python matlab java js)
  14
  15 ocv_option(OPENCV_DNN_OPENCL "Build with OpenCL support" HAVE_OPENCL AND NOT APPLE)
  16
  17 if(OPENCV_DNN_OPENCL AND HAVE_OPENCL)
  18   add_definitions(-DCV_OCL4DNN=1)
  19 else()
  20   ocv_cmake_hook_append(INIT_MODULE_SOURCES_opencv_dnn "${CMAKE_CURRENT_LIST_DIR}/cmake/hooks/INIT_MODULE_SOURCES_opencv_dnn.cmake")
  21 endif()
  22
  23 ocv_warnings_disable(CMAKE_CXX_FLAGS -Wno-shadow -Wno-parentheses -Wmaybe-uninitialized -Wsign-promo
  24                                      -Wmissing-declarations -Wmissing-prototypes
  25 )
  26 ocv_warnings_disable(CMAKE_CXX_FLAGS /wd4701 /wd4100)
  27
  28 if(MSVC)
  29   add_definitions( -D_CRT_SECURE_NO_WARNINGS=1 )
  30   ocv_warnings_disable(CMAKE_CXX_FLAGS /wd4244 /wd4267 /wd4018 /wd4355 /wd4800 /wd4251 /wd4996 /wd4146
  31                                        /wd4305 /wd4127 /wd4100 /wd4512 /wd4125 /wd4389 /wd4510 /wd4610
  32                                        /wd4702 /wd4456 /wd4457 /wd4065 /wd4310 /wd4661 /wd4506
  33   )
  34 else()
  35   ocv_warnings_disable(CMAKE_CXX_FLAGS -Wno-deprecated -Wmissing-prototypes -Wmissing-declarations -Wshadow
  36                                        -Wunused-parameter -Wunused-local-typedefs -Wsign-compare -Wsign-promo
  37                                        -Wundef -Wtautological-undefined-compare -Wignored-qualifiers -Wextra
  38                                        -Wunused-function -Wunused-const-variable -Wdeprecated-declarations
  39                                        -Werror=non-virtual-dtor
  40   )
  41 endif()
  42
  43 if(APPLE_FRAMEWORK)
  44   ocv_warnings_disable(CMAKE_CXX_FLAGS -Wshorten-64-to-32)
  45 endif()
  46
  47 if(ANDROID)
  48   add_definitions(-DDISABLE_POSIX_MEMALIGN -DTH_DISABLE_HEAP_TRACKING)
  49 endif()
  50
  51 if(NOT BUILD_PROTOBUF)
  52   add_definitions(-DOPENCV_DNN_EXTERNAL_PROTOBUF=1)
  53 endif()
  54
  55 add_definitions(-DHAVE_PROTOBUF=1)
  56
  57 #suppress warnings in autogenerated caffe.pb.* files
  58 ocv_warnings_disable(CMAKE_CXX_FLAGS
  59     -Wunused-parameter -Wundef -Wignored-qualifiers -Wno-enum-compare
  60     -Wdeprecated-declarations
  61     /wd4125 /wd4267 /wd4127 /wd4244 /wd4512 /wd4702
  62     /wd4456 /wd4510 /wd4610 /wd4800
  63     /wd4701 /wd4703                    # potentially uninitialized local/pointer variable 'value' used
  64     /wd4505                            # unreferenced local function has been removed
  65     -wd858 -wd2196
  66     -Winvalid-offsetof                 # Apple Clang (attr_value.pb.cc)
  67 )
  68
  69 if(PROTOBUF_UPDATE_FILES)
  70   file(GLOB proto_files "${CMAKE_CURRENT_LIST_DIR}/src/tensorflow/*.proto" "${CMAKE_CURRENT_LIST_DIR}/src/caffe/opencv-caffe.proto")
  71   set(PROTOBUF_GENERATE_CPP_APPEND_PATH ON) # required for tensorflow
  72   protobuf_generate_cpp(fw_srcs fw_hdrs ${proto_files})
  73 else()
  74   file(GLOB fw_srcs "${CMAKE_CURRENT_LIST_DIR}/misc/tensorflow/*.cc" "${CMAKE_CURRENT_LIST_DIR}/misc/caffe/opencv-caffe.pb.cc")
  75   file(GLOB fw_hdrs "${CMAKE_CURRENT_LIST_DIR}/misc/tensorflow/*.h" "${CMAKE_CURRENT_LIST_DIR}/misc/caffe/opencv-caffe.pb.h")
  76   set(fw_inc "${CMAKE_CURRENT_LIST_DIR}/misc/caffe" "${CMAKE_CURRENT_LIST_DIR}/misc/tensorflow")
  77 endif()
  78
  79 set(include_dirs ${fw_inc})
  80 set(sources_options "")
  81 set(libs libprotobuf ${LAPACK_LIBRARIES})
  82 if(OPENCV_DNN_OPENCL AND HAVE_OPENCL)
  83   list(APPEND include_dirs ${OPENCL_INCLUDE_DIRS})
  84 else()
  85   set(sources_options EXCLUDE_OPENCL)
  86 endif()
  87
  88 if(HAVE_INF_ENGINE)
  89   add_definitions(-DHAVE_INF_ENGINE=1)
  90   list(APPEND include_dirs ${INF_ENGINE_INCLUDE_DIRS})
  91   list(APPEND libs ${INF_ENGINE_LIBRARIES})
  92 endif()
  93
  94 ocv_module_include_directories(${include_dirs})
  95 if(CMAKE_CXX_COMPILER_ID STREQUAL "GNU")
  96   ocv_append_source_files_cxx_compiler_options(fw_srcs "-Wno-suggest-override")  # GCC
  97 elseif(CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
  98   ocv_append_source_files_cxx_compiler_options(fw_srcs "-Wno-inconsistent-missing-override")  # Clang
  99 endif()
 100 ocv_glob_module_sources(${sources_options} SOURCES ${fw_srcs})
 101 ocv_create_module(${libs})
 102 ocv_add_samples()
 103 ocv_add_accuracy_tests()
 104 ocv_add_perf_tests()
 105
 106 ocv_option(${the_module}_PERF_CAFFE "Add performance tests of Caffe framework" OFF)
 107 ocv_option(${the_module}_PERF_CLCAFFE "Add performance tests of clCaffe framework" OFF)
 108 if(BUILD_PERF_TESTS)
 109   if (${the_module}_PERF_CAFFE)
 110     find_package(Caffe QUIET)
 111     if (Caffe_FOUND)
 112       add_definitions(-DHAVE_CAFFE=1)
 113       ocv_target_link_libraries(opencv_perf_dnn caffe)
 114     endif()
 115   elseif(${the_module}_PERF_CLCAFFE)
 116     find_package(Caffe QUIET)
 117     if (Caffe_FOUND)
 118       add_definitions(-DHAVE_CLCAFFE=1)
 119       ocv_target_link_libraries(opencv_perf_dnn caffe)
 120     endif()
 121   endif()
 122 endif()
 123
 124 # Test Intel's Inference Engine models
 125 if(HAVE_INF_ENGINE AND TARGET opencv_test_dnn)
 126   ocv_target_include_directories(opencv_test_dnn PRIVATE ${INF_ENGINE_INCLUDE_DIRS})
 127   ocv_target_link_libraries(opencv_test_dnn LINK_PRIVATE ${INF_ENGINE_LIBRARIES})
 128 endif()