modules/dnn/CMakeLists.txt

   1 if(WINRT)
   2   ocv_module_disable(dnn)
   3 endif()
   4
   5 if(NOT HAVE_PROTOBUF)
   6   ocv_module_disable(opencv_dnn)
   7 endif()
   8
   9 set(the_description "Deep neural network module. It allows to load models from different frameworks and to make forward pass")
  10
  11 ocv_add_dispatched_file_force_all("layers/layers_common" AVX AVX2 AVX512_SKX)
  12
  13 ocv_add_module(dnn opencv_core opencv_imgproc WRAP python java js)
  14
  15 ocv_option(OPENCV_DNN_OPENCL "Build with OpenCL support" HAVE_OPENCL AND NOT APPLE)
  16
  17 if(OPENCV_DNN_OPENCL AND HAVE_OPENCL)
  18   add_definitions(-DCV_OCL4DNN=1)
  19 else()
  20   ocv_cmake_hook_append(INIT_MODULE_SOURCES_opencv_dnn "${CMAKE_CURRENT_LIST_DIR}/cmake/hooks/INIT_MODULE_SOURCES_opencv_dnn.cmake")
  21 endif()
  22
  23 if(MSVC)
  24   add_definitions( -D_CRT_SECURE_NO_WARNINGS=1 )
  25   ocv_warnings_disable(CMAKE_CXX_FLAGS /wd4244 /wd4267 /wd4018 /wd4355 /wd4800 /wd4251 /wd4996 /wd4146
  26                                        /wd4305 /wd4127 /wd4100 /wd4512 /wd4125 /wd4389 /wd4510 /wd4610
  27                                        /wd4702 /wd4456 /wd4457 /wd4065 /wd4310 /wd4661 /wd4506
  28   )
  29 else()
  30   ocv_warnings_disable(CMAKE_CXX_FLAGS -Wno-deprecated -Wmissing-prototypes -Wmissing-declarations -Wshadow
  31                                        -Wunused-parameter -Wsign-compare
  32   )
  33 endif()
  34 if(HAVE_CUDA)
  35   ocv_warnings_disable(CMAKE_CXX_FLAGS -Wundef)
  36 endif()
  37 if(NOT HAVE_CXX11)
  38   ocv_warnings_disable(CMAKE_CXX_FLAGS -Wno-undef)  # LANG_CXX11 from protobuf files
  39 endif()
  40
  41 if(APPLE_FRAMEWORK)
  42   ocv_warnings_disable(CMAKE_CXX_FLAGS -Wshorten-64-to-32)
  43 endif()
  44
  45 if(ANDROID)
  46   add_definitions(-DDISABLE_POSIX_MEMALIGN -DTH_DISABLE_HEAP_TRACKING)
  47 endif()
  48
  49 if(NOT BUILD_PROTOBUF)
  50   add_definitions(-DOPENCV_DNN_EXTERNAL_PROTOBUF=1)
  51 endif()
  52
  53 add_definitions(-DHAVE_PROTOBUF=1)
  54
  55 #suppress warnings in autogenerated caffe.pb.* files
  56 ocv_warnings_disable(CMAKE_CXX_FLAGS
  57     /wd4125 /wd4267 /wd4127 /wd4244 /wd4512 /wd4702
  58     /wd4456 /wd4510 /wd4610 /wd4800
  59     /wd4701 /wd4703                    # potentially uninitialized local/pointer variable 'value' used
  60     /wd4505                            # unreferenced local function has been removed
  61     -wd858 -wd2196
  62     -Winvalid-offsetof                 # Apple Clang (attr_value.pb.cc)
  63 )
  64
  65 if(PROTOBUF_UPDATE_FILES)
  66   file(GLOB proto_files "${CMAKE_CURRENT_LIST_DIR}/src/tensorflow/*.proto" "${CMAKE_CURRENT_LIST_DIR}/src/caffe/opencv-caffe.proto" "${CMAKE_CURRENT_LIST_DIR}/src/onnx/opencv-onnx.proto")
  67   set(PROTOBUF_GENERATE_CPP_APPEND_PATH ON) # required for tensorflow
  68   protobuf_generate_cpp(fw_srcs fw_hdrs ${proto_files})
  69 else()
  70   file(GLOB fw_srcs "${CMAKE_CURRENT_LIST_DIR}/misc/tensorflow/*.cc" "${CMAKE_CURRENT_LIST_DIR}/misc/caffe/opencv-caffe.pb.cc" "${CMAKE_CURRENT_LIST_DIR}/misc/onnx/opencv-onnx.pb.cc")
  71   file(GLOB fw_hdrs "${CMAKE_CURRENT_LIST_DIR}/misc/tensorflow/*.h" "${CMAKE_CURRENT_LIST_DIR}/misc/caffe/opencv-caffe.pb.h" "${CMAKE_CURRENT_LIST_DIR}/misc/onnx/opencv-onnx.pb.h")
  72   set(fw_inc "${CMAKE_CURRENT_LIST_DIR}/misc/caffe" "${CMAKE_CURRENT_LIST_DIR}/misc/tensorflow" "${CMAKE_CURRENT_LIST_DIR}/misc/onnx")
  73 endif()
  74
  75 set(include_dirs ${fw_inc})
  76 set(sources_options "")
  77
  78 set(libs libprotobuf ${LAPACK_LIBRARIES})
  79 if(OPENCV_DNN_OPENCL AND HAVE_OPENCL)
  80   list(APPEND include_dirs ${OPENCL_INCLUDE_DIRS})
  81 else()
  82   set(sources_options EXCLUDE_OPENCL)
  83 endif()
  84
  85 ocv_module_include_directories(${include_dirs})
  86 if(CMAKE_CXX_COMPILER_ID STREQUAL "GNU")
  87   ocv_append_source_files_cxx_compiler_options(fw_srcs "-Wno-suggest-override")  # GCC
  88 elseif(CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
  89   ocv_append_source_files_cxx_compiler_options(fw_srcs "-Wno-inconsistent-missing-override")  # Clang
  90 endif()
  91
  92 set(dnn_runtime_libs "")
  93 if(INF_ENGINE_TARGET)
  94   list(APPEND dnn_runtime_libs ${INF_ENGINE_TARGET})
  95 endif()
  96 if(HAVE_NGRAPH)
  97   add_definitions(-DHAVE_DNN_NGRAPH)
  98   list(APPEND dnn_runtime_libs ngraph::ngraph)
  99 endif()
 100
 101 ocv_glob_module_sources(${sources_options} SOURCES ${fw_srcs})
 102 ocv_create_module(${libs} ${dnn_runtime_libs})
 103 ocv_add_samples()
 104 ocv_add_accuracy_tests(${dnn_runtime_libs})
 105
 106 set(perf_path "${CMAKE_CURRENT_LIST_DIR}/perf")
 107 file(GLOB_RECURSE perf_srcs "${perf_path}/*.cpp")
 108 file(GLOB_RECURSE perf_hdrs "${perf_path}/*.hpp" "${perf_path}/*.h")
 109 ocv_add_perf_tests(${INF_ENGINE_TARGET}
 110     FILES test_common "${CMAKE_CURRENT_LIST_DIR}/test/test_common.hpp" "${CMAKE_CURRENT_LIST_DIR}/test/test_common.impl.hpp"
 111     FILES Src ${perf_srcs}
 112     FILES Include ${perf_hdrs}
 113 )
 114
 115 ocv_option(${the_module}_PERF_CAFFE "Add performance tests of Caffe framework" OFF)
 116 ocv_option(${the_module}_PERF_CLCAFFE "Add performance tests of clCaffe framework" OFF)
 117 if(BUILD_PERF_TESTS)
 118   if (${the_module}_PERF_CAFFE)
 119     find_package(Caffe QUIET)
 120     if (Caffe_FOUND)
 121       add_definitions(-DHAVE_CAFFE=1)
 122       ocv_target_link_libraries(opencv_perf_dnn caffe)
 123     endif()
 124   elseif(${the_module}_PERF_CLCAFFE)
 125     find_package(Caffe QUIET)
 126     if (Caffe_FOUND)
 127       add_definitions(-DHAVE_CLCAFFE=1)
 128       ocv_target_link_libraries(opencv_perf_dnn caffe)
 129     endif()
 130   endif()
 131 endif()