meta-tizen-adaptation/recipes-core/dbus/dbus-glib.inc

   1 SUMMARY = "High level language (GLib) binding for D-Bus"
   2 DESCRIPTION = "GLib bindings for the D-Bus message bus that integrate \
   3 the D-Bus library with the GLib thread abstraction and main loop."
   4 HOMEPAGE = "http://www.freedesktop.org/Software/dbus"
   5 LICENSE = "AFL-2 | GPLv2+"
   6 LIC_FILES_CHKSUM = "file://COPYING;md5=cf5b3a2f7083750d504333114e738656 \
   7                     file://dbus/dbus-glib.h;beginline=7;endline=21;md5=7755c9d7abccd5dbd25a6a974538bb3c"
   8 SECTION = "base"
   9
  10 DEPENDS = "expat glib-2.0 virtual/libintl dbus-glib-native dbus"
  11 DEPENDS_class-native = "glib-2.0-native dbus-native"
  12
  13 SRC_URI = "http://dbus.freedesktop.org/releases/dbus-glib/dbus-glib-${PV}.tar.gz \
  14            file://no-examples.patch \
  15            file://test-install-makefile.patch \
  16            file://obsolete_automake_macros.patch \
  17 "
  18
  19 inherit autotools pkgconfig gettext
  20
  21 #default disable regression tests, some unit test code in non testing code
  22 #PACKAGECONFIG_pn-${PN} = "tests" enable regression tests local.conf
  23 PACKAGECONFIG ??= ""
  24 PACKAGECONFIG[tests] = "--enable-tests,,,"
  25
  26 EXTRA_OECONF = "--with-introspect-xml=${STAGING_DATADIR_NATIVE}/dbus/dbus-bus-introspect.xml \
  27                 --with-dbus-binding-tool=${STAGING_BINDIR_NATIVE}/dbus-binding-tool"
  28 EXTRA_OECONF_class-native = "--with-introspect-xml=${STAGING_DATADIR_NATIVE}/dbus/dbus-bus-introspect.xml"
  29
  30 PACKAGES += "${PN}-bash-completion ${PN}-tests-dbg ${PN}-tests"
  31
  32 FILES_${PN} = "${libdir}/lib*${SOLIBS}"
  33 FILES_${PN}-bash-completion = "${sysconfdir}/bash_completion.d/dbus-bash-completion.sh \
  34    ${libexecdir}/dbus-bash-completion-helper"
  35 FILES_${PN}-dev += "${libdir}/dbus-1.0/include ${bindir}/dbus-glib-tool"
  36 FILES_${PN}-dev += "${bindir}/dbus-binding-tool"
  37
  38 RDEPENDS_${PN}-tests += "dbus-x11"
  39 FILES_${PN}-tests = "${datadir}/${BPN}/tests"
  40 FILES_${PN}-tests-dbg = "${datadir}/${BPN}/tests/.debug/* \
  41                          ${datadir}/${BPN}/tests/core/.debug/* \
  42                          ${datadir}/${BPN}/tests/interfaces/.debug/*"
  43
  44 BBCLASSEXTEND = "native"