meta-tizen-adaptation/meta/recipes-graphics/wayland/wayland_1.6.0.bb

   1 SUMMARY = "Wayland, a protocol between a compositor and clients"
   2 DESCRIPTION = "Wayland is a protocol for a compositor to talk to its clients \
   3 as well as a C library implementation of that protocol. The compositor can be \
   4 a standalone display server running on Linux kernel modesetting and evdev \
   5 input devices, an X application, or a wayland client itself. The clients can \
   6 be traditional applications, X servers (rootless or fullscreen) or other \
   7 display servers."
   8 HOMEPAGE = "http://wayland.freedesktop.org"
   9 LICENSE = "MIT"
  10 LIC_FILES_CHKSUM = "file://COPYING;md5=1d4476a7d98dd5691c53d4d43a510c72 \
  11                     file://src/wayland-server.c;endline=21;md5=079ae21dbf98ada52ec23744851b0a5c"
  12
  13 SRC_URI = "http://wayland.freedesktop.org/releases/${BPN}-${PV}.tar.xz"
  14 SRC_URI[md5sum] = "d34c141c975084e4fb668e77b38f840e"
  15 SRC_URI[sha256sum] = "a7d5102dcf53d08c059d24bc62de491d7cd482070abeb6737a20d0d86ba6fc7f"
  16 SRC_URI_append_class-native = " \
  17     file://disable-macro-checks-not-used-for-scanner.patch \
  18     "
  19 EXTRA_OECONF_class-native = "--disable-documentation --enable-scanner"
  20
  21 inherit autotools pkgconfig
  22
  23 # We need wayland-native for the wayland-scanner utility
  24 BBCLASSEXTEND = "native"
  25
  26 DEPENDS_class-native = "expat-native libffi-native"
  27 DEPENDS = "expat libffi wayland-native"
  28
  29 EXTRA_OECONF = "--disable-documentation --disable-scanner"
  30
  31 # Wayland installs a M4 macro for other projects to use, which uses the target
  32 # pkg-config to find files.  Replace pkg-config with pkg-config-native.
  33 do_install_append_class-native() {
  34   sed -e 's,PKG_CHECK_MODULES(.*),,g' \
  35       -e 's,$PKG_CONFIG,pkg-config-native,g' \
  36       -i ${D}/${datadir}/aclocal/wayland-scanner.m4
  37 }
  38
  39 sysroot_stage_all_append_class-target () {
  40         cp ${STAGING_DATADIR_NATIVE}/aclocal/wayland-scanner.m4 ${SYSROOT_DESTDIR}/${datadir}/aclocal/
  41 }