meta-openembedded/meta-networking/recipes-support/tcpdump/tcpdump_4.6.1.bb

   1 SUMMARY = "A sophisticated network protocol analyzer"
   2 HOMEPAGE = "http://www.tcpdump.org/"
   3 LICENSE = "BSD"
   4 LIC_FILES_CHKSUM = "file://LICENSE;md5=1d4b0366557951c84a94fabe3529f867"
   5 SECTION = "console/network"
   6 DEPENDS = "libpcap"
   7
   8 SRC_URI = " \
   9     http://www.tcpdump.org/release/${BP}.tar.gz \
  10     file://configure.patch \
  11     file://unnecessary-to-check-libpcap.patch \
  12     file://tcpdump-configure-dlpi.patch \
  13     file://tcpdump-cross-getaddrinfo.patch \
  14     file://add-ptest.patch \
  15     file://run-ptest \
  16 "
  17 SRC_URI[md5sum] = "dab267ec30216a069747d10314079ec7"
  18 SRC_URI[sha256sum] = "4c88c2a9aeb4047074f344fc9b2b6577b219972d359e192f6d12ccf983a13fd7"
  19 export LIBS=" -lpcap"
  20
  21 inherit autotools-brokensep ptest
  22 CACHED_CONFIGUREVARS = "ac_cv_linux_vers=${ac_cv_linux_vers=2}"
  23
  24 PACKAGECONFIG ??= "openssl ipv6"
  25 PACKAGECONFIG[openssl] = "--with-crypto=yes, --without-openssl --without-crypto, openssl"
  26 PACKAGECONFIG[ipv6] = "--enable-ipv6, --disable-ipv6,"
  27
  28 EXTRA_AUTORECONF += " -I m4"
  29
  30 do_configure_prepend() {
  31     mkdir -p ${S}/m4
  32     if [ -f aclocal.m4 ]; then
  33         mv aclocal.m4 ${S}/m4
  34     fi
  35     # AC_CHECK_LIB(dlpi.. was looking to host /lib
  36     sed -i 's:-L/lib::g' ./configure.in
  37 }
  38 do_configure_append() {
  39     sed -i 's:-L/usr/lib::' ./Makefile
  40     sed -i 's:-Wl,-rpath,${STAGING_LIBDIR}::' ./Makefile
  41     sed -i 's:-I/usr/include::' ./Makefile
  42 }
  43
  44 do_install_append() {
  45     # tcpdump 4.0.0 installs a copy to /usr/sbin/tcpdump.4.0.0
  46     rm -f ${D}${sbindir}/tcpdump.${PV}
  47 }
  48
  49 do_compile_ptest() {
  50         oe_runmake buildtest-TESTS
  51 }