meson.build

   1 project('nntrainer', 'c', 'cpp',
   2   version: '0.0.1',
   3   license: ['apache-2.0'],
   4   meson_version: '>=0.50.0',
   5   default_options: [
   6     'werror=true',
   7     'warning_level=1',
   8     'c_std=gnu89',
   9     'cpp_std=c++14'
  10   ]
  11 )
  12 add_project_arguments('-DMIN_CPP_VERSION=201402', language:['c','cpp'])
  13
  14 cc = meson.get_compiler('c')
  15 cxx = meson.get_compiler('cpp')
  16 build_platform = ''
  17
  18 if get_option('enable-tizen')
  19   # Pass __TIZEN__ to the compiler
  20   build_platform = 'tizen'
  21   add_project_arguments('-D__TIZEN__=1', language:['c','cpp'])
  22
  23   if get_option('enable-tizen-feature-check')
  24     add_project_arguments('-D__FEATURE_CHECK_SUPPORT__', language: ['c', 'cpp'])
  25   endif
  26 endif
  27
  28 warning_flags = [
  29   '-Wredundant-decls',
  30   '-Wwrite-strings',
  31   '-Wformat',
  32   '-Wformat-nonliteral',
  33   '-Wformat-security',
  34   '-Winit-self',
  35   '-Waddress',
  36   '-Wno-multichar',
  37   '-Wvla',
  38   '-Wpointer-arith',
  39   '-Wno-error=varargs',
  40   '-O2',
  41   '-ftree-vectorize'
  42 ]
  43
  44 warning_c_flags = [
  45   '-Wmissing-declarations',
  46   '-Wmissing-include-dirs',
  47   '-Wmissing-prototypes',
  48   '-Wnested-externs',
  49   '-Waggregate-return',
  50   '-Wold-style-definition',
  51   '-Wdeclaration-after-statement',
  52   '-Wno-error=varargs'
  53 ]
  54
  55 foreach extra_arg : warning_flags
  56   if cc.has_argument (extra_arg)
  57     add_project_arguments([extra_arg], language: 'c')
  58   endif
  59   if cxx.has_argument (extra_arg)
  60     add_project_arguments([extra_arg], language: 'cpp')
  61   endif
  62 endforeach
  63
  64 foreach extra_arg : warning_c_flags
  65   if cc.has_argument (extra_arg)
  66     add_project_arguments([extra_arg], language: 'c')
  67   endif
  68 endforeach
  69
  70 # Set install path
  71 nntrainer_prefix = get_option('prefix')
  72 nntrainer_libdir = join_paths(nntrainer_prefix, get_option('libdir'))
  73 nntrainer_bindir = join_paths(nntrainer_prefix, get_option('bindir'))
  74 nntrainer_includedir = join_paths(nntrainer_prefix, get_option('includedir'))
  75 nntrainer_inidir = get_option('sysconfdir')
  76 application_install_dir = join_paths(nntrainer_bindir, 'applications')
  77
  78 # Set default configuration
  79 nntrainer_conf = configuration_data()
  80 nntrainer_conf.set('VERSION', meson.project_version())
  81 nntrainer_conf.set('PREFIX', nntrainer_prefix)
  82 nntrainer_conf.set('EXEC_PREFIX', nntrainer_bindir)
  83 nntrainer_conf.set('LIB_INSTALL_DIR', nntrainer_libdir)
  84 nntrainer_conf.set('INCLUDE_INSTALL_DIR', nntrainer_includedir)
  85
  86 dummy_dep = dependency('', required: false)
  87
  88 blas_dep = dummy_dep
  89 # Dependencies
  90 if get_option('enable-cublas')
  91    add_project_arguments('-DUSE_CUBLAS=1', language:['c','cpp'])
  92 endif
  93
  94 if get_option('enable-blas')
  95   add_project_arguments('-DUSE_BLAS=1', language:['c','cpp'])
  96   if build_platform == 'tizen'
  97     blas_dep = dependency('openblas')
  98   else
  99     blas_dep = dependency('blas-openblas')
 100   endif
 101 endif
 102
 103 if get_option('enable-profile')
 104   add_project_arguments('-DPROFILE=1', language:['c', 'cpp'])
 105 endif
 106
 107 if get_option('use_gym')
 108    add_project_arguments('-DUSE_GYM=1', language:['c','cpp'])
 109 endif
 110
 111 if get_option('enable-logging')
 112    add_project_arguments('-D__LOGGING__=1', language:['c','cpp'])
 113 endif
 114
 115 if get_option('enable-test')
 116   add_project_arguments('-DENABLE_TEST=1', language:['c','cpp'])
 117 endif
 118
 119 libm_dep = cxx.find_library('m') # cmath library
 120 libdl_dep = cxx.find_library('dl') # DL library
 121 thread_dep = dependency('threads') # pthread for tensorflow-lite
 122 iniparser_dep = dependency('iniparser', required : false) # iniparser
 123 if not iniparser_dep.found()
 124   message('falling back to find libiniparser library and header files')
 125   libiniparser_dep = cxx.find_library('iniparser')
 126   if libiniparser_dep.found() and cxx.has_header('iniparser.h', \
 127         args : '-I/usr/include/iniparser')
 128     iniparser_dep = declare_dependency (dependencies : libiniparser_dep,
 129       compile_args : '-I/usr/include/iniparser')
 130   endif
 131 endif
 132
 133 nnstreamer_capi_dep = dependency('capi-nnstreamer', required:false)
 134 if get_option('enable-nnstreamer-backbone')
 135   add_project_arguments('-DENABLE_NNSTREAMER_BACKBONE=1', language:['c','cpp'])
 136 endif
 137
 138 tflite_dep = dependency('tensorflow-lite', required: false)
 139 if get_option('enable-tflite-backbone')
 140   add_project_arguments('-DENABLE_TFLITE_BACKBONE=1', language:['c','cpp'])
 141 endif
 142
 143 jsoncpp_dep = dependency('jsoncpp') # jsoncpp
 144 libcurl_dep = dependency('libcurl')
 145 gtest_dep = dependency('gtest', required: false)
 146
 147 # Install .pc
 148 configure_file(input: 'nntrainer.pc.in', output: 'nntrainer.pc',
 149   install_dir: join_paths(nntrainer_libdir, 'pkgconfig'),
 150   configuration: nntrainer_conf
 151 )
 152
 153 # Build nntrainer
 154 subdir('nntrainer')
 155
 156 # Build api
 157 subdir('api')
 158
 159 if get_option('enable-app')
 160   if not tflite_dep.found()
 161     error('Tensorflow-Lite dependency not found')
 162   endif
 163   subdir('Applications')
 164 endif
 165
 166 if get_option('enable-test')
 167    subdir('test')
 168 endif
 169
 170 if get_option('enable-nnstreamer-tensor-filter')
 171    nnstreamer_dep = dependency('nnstreamer', required: true)
 172    subdir('nnstreamer/tensor_filter')
 173 endif
 174
 175 if get_option('enable-android')
 176
 177   ndk_build = find_program('ndk-build', required : true)
 178   jni_root = meson.current_source_dir() / 'jni'
 179   jni_build_root = meson.build_root() / 'jni'
 180
 181   ndk_args = {
 182     'NDK_PROJECT_PATH': jni_root,
 183     'APP_BUILD_SCRIPT': jni_root / 'Android.mk',
 184     'NDK_APPLICATION_MK': jni_root / 'Application.mk',
 185     'NDK_LIBS_OUT': jni_build_root / 'libs',
 186     'NDK_OUT': jni_build_root / 'objs',
 187   }
 188
 189   num_threads = run_command('grep', '-c', '^processor', '/proc/cpuinfo').stdout().strip()
 190   message('num processor are: ' + num_threads)
 191
 192   thread_opt_flag = '-j' + num_threads
 193
 194   ndk_additional_flags = [thread_opt_flag]
 195
 196   ndk_build_command = [ndk_build]
 197   foreach key, val : ndk_args
 198     ndk_build_command += '@0@=@1@'.format(key, val)
 199   endforeach
 200   ndk_build_command += ndk_additional_flags
 201
 202   android_build_target = custom_target('android',
 203     output: 'jni',
 204     build_by_default: true,
 205     command: ndk_build_command
 206   )
 207
 208 endif