meson.build

   1 project('gst-plugins-base', 'c',
   2   version : '1.18.0',
   3   meson_version : '>= 0.48',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0].to_int()
  10 gst_version_minor = version_arr[1].to_int()
  11 gst_version_micro = version_arr[2].to_int()
  12 if version_arr.length() == 4
  13   gst_version_nano = version_arr[3].to_int()
  14 else
  15   gst_version_nano = 0
  16 endif
  17 gst_version_is_dev = gst_version_minor % 2 == 1 and gst_version_micro < 90
  18
  19 host_system = host_machine.system()
  20
  21 have_cxx = add_languages('cpp', native: false, required: false)
  22
  23 if host_system in ['ios', 'darwin']
  24   have_objc = add_languages('objc', native: false)
  25 else
  26   have_objc = false
  27 endif
  28
  29 glib_req = '>= 2.44.0'
  30 orc_req = '>= 0.4.24'
  31 gst_req = '>= @0@.@1@.0'.format(gst_version_major, gst_version_minor)
  32
  33 api_version = '1.0'
  34 soversion = 0
  35 # maintaining compatibility with the previous libtool versioning
  36 # current = minor * 100 + micro
  37 curversion = gst_version_minor * 100 + gst_version_micro
  38 libversion = '@0@.@1@.0'.format(soversion, curversion)
  39 osxversion = curversion + 1
  40
  41 plugins_install_dir = join_paths(get_option('libdir'), 'gstreamer-1.0')
  42 plugins = []
  43
  44 cc = meson.get_compiler('c')
  45
  46 if cc.get_id() == 'msvc'
  47   # Ignore several spurious warnings for things gstreamer does very commonly
  48   # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  49   # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  50   # NOTE: Only add warnings here if you are sure they're spurious
  51   add_project_arguments(
  52       '/wd4018', # implicit signed/unsigned conversion
  53       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  54       '/wd4244', # lossy type conversion (e.g. double -> int)
  55       '/wd4305', # truncating type conversion (e.g. double -> float)
  56       cc.get_supported_arguments(['/utf-8']), # set the input encoding to utf-8
  57       language : 'c')
  58   # Disable SAFESEH with MSVC for plugins and libs that use external deps that
  59   # are built with MinGW
  60   noseh_link_args = ['/SAFESEH:NO']
  61 else
  62   noseh_link_args = []
  63 endif
  64
  65 if cc.has_link_argument('-Wl,-Bsymbolic-functions')
  66   add_project_link_arguments('-Wl,-Bsymbolic-functions', language : 'c')
  67 endif
  68
  69 core_conf = configuration_data()
  70
  71 # Symbol visibility
  72 if cc.get_id() == 'msvc'
  73   export_define = '__declspec(dllexport) extern'
  74 elif cc.has_argument('-fvisibility=hidden')
  75   add_project_arguments('-fvisibility=hidden', language: 'c')
  76   if have_objc
  77     add_project_arguments('-fvisibility=hidden', language: 'objc')
  78   endif
  79   export_define = 'extern __attribute__ ((visibility ("default")))'
  80 else
  81   export_define = 'extern'
  82 endif
  83
  84 # Passing this through the command line would be too messy
  85 core_conf.set('GST_API_EXPORT', export_define)
  86
  87 # Disable strict aliasing
  88 if cc.has_argument('-fno-strict-aliasing')
  89   add_project_arguments('-fno-strict-aliasing', language: 'c')
  90 endif
  91
  92 # Define G_DISABLE_DEPRECATED for development versions
  93 if gst_version_is_dev
  94   message('Disabling deprecated GLib API')
  95   add_project_arguments('-DG_DISABLE_DEPRECATED', language: 'c')
  96 endif
  97
  98 cast_checks = get_option('gobject-cast-checks')
  99 if cast_checks.disabled() or (cast_checks.auto() and not gst_version_is_dev)
 100   message('Disabling GLib cast checks')
 101   add_project_arguments('-DG_DISABLE_CAST_CHECKS', language: 'c')
 102 endif
 103
 104 glib_asserts = get_option('glib-asserts')
 105 if glib_asserts.disabled() or (glib_asserts.auto() and not gst_version_is_dev)
 106   message('Disabling GLib asserts')
 107   add_project_arguments('-DG_DISABLE_ASSERT', language: 'c')
 108 endif
 109
 110 glib_checks = get_option('glib-checks')
 111 if glib_checks.disabled() or (glib_checks.auto() and not gst_version_is_dev)
 112   message('Disabling GLib checks')
 113   add_project_arguments('-DG_DISABLE_CHECKS', language: 'c')
 114 endif
 115
 116 check_headers = [
 117   ['HAVE_DLFCN_H', 'dlfcn.h'],
 118   ['HAVE_EMMINTRIN_H', 'emmintrin.h'],
 119   ['HAVE_INTTYPES_H', 'inttypes.h'],
 120   ['HAVE_MEMORY_H', 'memory.h'],
 121   ['HAVE_NETINET_IN_H', 'netinet/in.h'],
 122   ['HAVE_NETINET_TCP_H', 'netinet/tcp.h'],
 123   ['HAVE_PROCESS_H', 'process.h'],
 124   ['HAVE_SMMINTRIN_H', 'smmintrin.h'],
 125   ['HAVE_STDINT_H', 'stdint.h'],
 126   ['HAVE_STRINGS_H', 'strings.h'],
 127   ['HAVE_STRING_H', 'string.h'],
 128   ['HAVE_SYS_SOCKET_H', 'sys/socket.h'],
 129   ['HAVE_SYS_STAT_H', 'sys/stat.h'],
 130   ['HAVE_SYS_TYPES_H', 'sys/types.h'],
 131   ['HAVE_SYS_WAIT_H', 'sys/wait.h'],
 132   ['HAVE_UNISTD_H', 'unistd.h'],
 133   ['HAVE_WINSOCK2_H', 'winsock2.h'],
 134   ['HAVE_XMMINTRIN_H', 'xmmintrin.h'],
 135   ['HAVE_LINUX_DMA_BUF_H', 'linux/dma-buf.h'],
 136 ]
 137 foreach h : check_headers
 138   if cc.has_header(h.get(1))
 139     core_conf.set(h.get(0), 1)
 140   endif
 141 endforeach
 142
 143 check_functions = [
 144   ['HAVE_DCGETTEXT', 'dcgettext', '#include<libintl.h>'],
 145   ['HAVE_GMTIME_R', 'gmtime_r', '#include<time.h>'],
 146   ['HAVE_LOCALTIME_R', 'localtime_r', '#include<time.h>'],
 147   ['HAVE_LRINTF', 'lrintf', '#include<math.h>'],
 148   ['HAVE_MMAP', 'mmap', '#include<sys/mman.h>'],
 149   ['HAVE_LOG2', 'log2', '#include<math.h>'],
 150 ]
 151
 152 libm = cc.find_library('m', required : false)
 153 foreach f : check_functions
 154   if cc.has_function(f.get(1), prefix : f.get(2), dependencies : libm)
 155     core_conf.set(f.get(0), 1)
 156   endif
 157 endforeach
 158
 159 core_conf.set('SIZEOF_CHAR', cc.sizeof('char'))
 160 core_conf.set('SIZEOF_INT', cc.sizeof('int'))
 161 core_conf.set('SIZEOF_LONG', cc.sizeof('long'))
 162 core_conf.set('SIZEOF_SHORT', cc.sizeof('short'))
 163 core_conf.set('SIZEOF_VOIDP', cc.sizeof('void*'))
 164
 165 core_conf.set_quoted('GETTEXT_PACKAGE', 'gst-plugins-base-1.0')
 166 core_conf.set_quoted('LOCALEDIR', join_paths(get_option('prefix'), get_option('localedir')))
 167 core_conf.set_quoted('PACKAGE', 'gst-plugins-base')
 168 core_conf.set_quoted('VERSION', gst_version)
 169 core_conf.set_quoted('PACKAGE_VERSION', gst_version)
 170 core_conf.set_quoted('GST_API_VERSION', api_version)
 171 core_conf.set_quoted('GST_DATADIR', join_paths(get_option('prefix'), get_option('datadir')))
 172 core_conf.set_quoted('GST_LICENSE', 'LGPL')
 173
 174 install_plugins_helper = get_option('install_plugins_helper')
 175 if install_plugins_helper == ''
 176   install_plugins_helper = join_paths(get_option('prefix'),
 177                                       get_option('libexecdir'),
 178                                       'gst-install-plugins-helper')
 179 endif
 180 core_conf.set_quoted('GST_INSTALL_PLUGINS_HELPER', install_plugins_helper)
 181
 182 warning_flags = [
 183   '-Wmissing-declarations',
 184   '-Wredundant-decls',
 185   '-Wundef',
 186   '-Wwrite-strings',
 187   '-Wformat',
 188   '-Wformat-nonliteral',
 189   '-Wformat-security',
 190   '-Winit-self',
 191   '-Wmissing-include-dirs',
 192   '-Waddress',
 193   '-Wno-multichar',
 194   '-Wvla',
 195   '-Wpointer-arith',
 196 ]
 197
 198 warning_c_flags = [
 199   '-Wmissing-prototypes',
 200   '-Wdeclaration-after-statement',
 201 ]
 202
 203 warning_cxx_flags = [
 204   '-Waggregate-return',
 205 ]
 206
 207 if have_cxx
 208   cxx = meson.get_compiler('cpp')
 209   foreach extra_arg : warning_cxx_flags
 210     if cxx.has_argument (extra_arg)
 211       add_project_arguments([extra_arg], language: 'cpp')
 212     endif
 213   endforeach
 214 endif
 215
 216 foreach extra_arg : warning_flags
 217   if cc.has_argument (extra_arg)
 218     add_project_arguments([extra_arg], language: 'c')
 219   endif
 220   if have_cxx and cxx.has_argument (extra_arg)
 221     add_project_arguments([extra_arg], language: 'cpp')
 222   endif
 223 endforeach
 224
 225 foreach extra_arg : warning_c_flags
 226   if cc.has_argument (extra_arg)
 227     add_project_arguments([extra_arg], language: 'c')
 228   endif
 229 endforeach
 230
 231 # GStreamer package name and origin url
 232 gst_package_name = get_option('package-name')
 233 if gst_package_name == ''
 234   if gst_version_nano == 0
 235     gst_package_name = 'GStreamer Base Plug-ins source release'
 236   elif gst_version_nano == 1
 237     gst_package_name = 'GStreamer Base Plug-ins git'
 238   else
 239     gst_package_name = 'GStreamer Base Plug-ins prerelease'
 240   endif
 241 endif
 242 core_conf.set_quoted('GST_PACKAGE_NAME', gst_package_name)
 243 core_conf.set_quoted('GST_PACKAGE_ORIGIN', get_option('package-origin'))
 244
 245 # FIXME: These should be configure options
 246 core_conf.set_quoted('DEFAULT_VIDEOSINK', 'autovideosink')
 247 core_conf.set_quoted('DEFAULT_AUDIOSINK', 'autoaudiosink')
 248
 249 # Set whether the audioresampling method should be detected at runtime
 250 core_conf.set('AUDIORESAMPLE_FORMAT_' + get_option('audioresample_format').to_upper(), true)
 251
 252 gst_plugins_base_args = ['-DHAVE_CONFIG_H']
 253 if get_option('default_library') == 'static'
 254   gst_plugins_base_args += ['-DGST_STATIC_COMPILATION']
 255 endif
 256
 257 # X11 checks are for sys/ and tests/
 258 x11_dep = dependency('x11', required : get_option('x11'))
 259 # GLib checks are for the entire project
 260 # Almost everything that uses glib also uses gobject
 261 glib_deps = [dependency('glib-2.0', version : glib_req, fallback: ['glib', 'libglib_dep']),
 262              dependency('gobject-2.0', fallback: ['glib', 'libgobject_dep'])]
 263 # GIO is used by the GIO plugin, and by the TCP, SDP, and RTSP plugins
 264 gio_dep = dependency('gio-2.0', fallback: ['glib', 'libgio_dep'])
 265 giounix_dep = dependency('', required: false)
 266 if host_system != 'windows'
 267   giounix_dep = dependency('gio-unix-2.0', version : glib_req,
 268                            fallback: ['glib', 'libgiounix_dep'])
 269 endif
 270 gmodule_dep = dependency('gmodule-no-export-2.0',
 271                          fallback: ['glib', 'libgmodule_dep'])
 272
 273 # some of the examples can use gdk-pixbuf and GTK+3
 274 gdk_pixbuf_dep = dependency('gdk-pixbuf-2.0', required : get_option('examples'))
 275 gtk_dep = dependency('gtk+-3.0', version : '>= 3.10', required : get_option('examples'))
 276 # TODO: https://github.com/mesonbuild/meson/issues/3941
 277 if not get_option('x11').disabled()
 278   gtk_x11_dep = dependency('gtk+-x11-3.0', version : '>= 3.10', required : get_option('examples'))
 279 else
 280   gtk_x11_dep = dependency('', required : false)
 281 endif
 282 # gtk+ quartz backend is only available on macOS
 283 if host_system == 'darwin'
 284   gtk_quartz_dep = dependency('gtk+-quartz-3.0', version : '>= 3.10', required : get_option('examples'))
 285 else
 286   gtk_quartz_dep = dependency('', required : false)
 287 endif
 288
 289 core_conf.set('HAVE_X11', x11_dep.found())
 290 core_conf.set('HAVE_GIO_UNIX_2_0', giounix_dep.found())
 291
 292 if gio_dep.type_name() == 'pkgconfig'
 293     core_conf.set_quoted('GIO_MODULE_DIR',
 294         gio_dep.get_pkgconfig_variable('giomoduledir'))
 295     core_conf.set_quoted('GIO_LIBDIR',
 296         gio_dep.get_pkgconfig_variable('libdir'))
 297     core_conf.set_quoted('GIO_PREFIX',
 298         gio_dep.get_pkgconfig_variable('prefix'))
 299 else
 300     core_conf.set_quoted('GIO_MODULE_DIR', join_paths(get_option('prefix'),
 301       get_option('libdir'), 'gio/modules'))
 302     core_conf.set_quoted('GIO_LIBDIR', join_paths(get_option('prefix'),
 303       get_option('libdir')))
 304     core_conf.set_quoted('GIO_PREFIX', get_option('prefix'))
 305 endif
 306
 307 configinc = include_directories('.')
 308 libsinc = include_directories('gst-libs')
 309
 310 # To use the subproject make subprojects directory
 311 # and put gstreamer meson git there (symlinking is fine)
 312 gst_dep = dependency('gstreamer-1.0', version : gst_req,
 313   fallback : ['gstreamer', 'gst_dep'])
 314 gst_base_dep = dependency('gstreamer-base-1.0', version : gst_req,
 315   fallback : ['gstreamer', 'gst_base_dep'])
 316 gst_net_dep = dependency('gstreamer-net-1.0', version : gst_req,
 317   fallback : ['gstreamer', 'gst_net_dep'])
 318 gst_check_dep = dependency('gstreamer-check-1.0', version : gst_req,
 319   required : get_option('tests'),
 320   fallback : ['gstreamer', 'gst_check_dep'])
 321 gst_controller_dep = dependency('gstreamer-controller-1.0', version : gst_req,
 322   fallback : ['gstreamer', 'gst_controller_dep'])
 323
 324 have_orcc = false
 325 orcc_args = []
 326 orc_targets = []
 327 # Used by various libraries/elements that use Orc code
 328 orc_dep = dependency('orc-0.4', version : orc_req, required : get_option('orc'),
 329     fallback : ['orc', 'orc_dep'])
 330 orcc = find_program('orcc', required : get_option('orc'))
 331 if orc_dep.found() and orcc.found()
 332   have_orcc = true
 333   orcc_args = [orcc, '--include', 'glib.h']
 334   core_conf.set('HAVE_ORC', 1)
 335 else
 336   message('Orc Compiler not found or disabled, will use backup C code')
 337   core_conf.set('DISABLE_ORC', 1)
 338 endif
 339
 340 # Used to build SSE* things in audio-resampler
 341 sse_args = '-msse'
 342 sse2_args = '-msse2'
 343 sse41_args = '-msse4.1'
 344
 345 have_sse = cc.has_argument(sse_args)
 346 have_sse2 = cc.has_argument(sse2_args)
 347 have_sse41 = cc.has_argument(sse41_args)
 348
 349 if host_machine.cpu_family() == 'arm'
 350   if cc.compiles('''
 351 #include <arm_neon.h>
 352 int32x4_t testfunc(int16_t *a, int16_t *b) {
 353   asm volatile ("vmull.s16 q0, d0, d0" : : : "q0");
 354   return vmull_s16(vld1_s16(a), vld1_s16(b));
 355 }
 356 ''', name : 'NEON support')
 357     core_conf.set('HAVE_ARM_NEON', true)
 358   endif
 359 endif
 360
 361 if gst_dep.type_name() == 'internal'
 362     gst_proj = subproject('gstreamer')
 363
 364     if not gst_proj.get_variable('gst_debug')
 365         message('GStreamer debug system is disabled')
 366         add_project_arguments('-Wno-unused', language: 'c')
 367     else
 368         message('GStreamer debug system is enabled')
 369     endif
 370 else
 371     # We can't check that in the case of subprojects as we won't
 372     # be able to build against an internal dependency (which is not built yet)
 373     if not cc.compiles('''
 374 #include <gst/gstconfig.h>
 375 #ifdef GST_DISABLE_GST_DEBUG
 376 #error "debugging disabled, make compiler fail"
 377 #endif''' , dependencies: gst_dep)
 378         message('GStreamer debug system is disabled')
 379         add_project_arguments('-Wno-unused', language: 'c')
 380     else
 381         message('GStreamer debug system is enabled')
 382     endif
 383 endif
 384
 385 if cc.has_member('struct tcp_info', '__tcpi_reordering', prefix: '#include <netinet/tcp.h>')
 386   core_conf.set('HAVE_BSD_TCP_INFO', true)
 387 endif
 388
 389 if cc.has_member('struct tcp_info', 'tcpi_reordering', prefix: '#include <netinet/tcp.h>')
 390   core_conf.set('HAVE_LINUX_TCP_INFO', true)
 391 endif
 392
 393 gir = find_program('g-ir-scanner', required : get_option('introspection'))
 394 gnome = import('gnome')
 395 build_gir = gir.found() and (not meson.is_cross_build() or get_option('introspection').enabled())
 396 gir_init_section = [ '--add-init-section=extern void gst_init(gint*,gchar**);' + \
 397     'g_setenv("GST_REGISTRY_DISABLE", "yes", TRUE);' + \
 398     'g_setenv("GST_REGISTRY_1.0", "@0@", TRUE);'.format(meson.current_build_dir() + '/gir_empty_registry.reg') + \
 399     'g_setenv("GST_PLUGIN_PATH_1_0", "", TRUE);' + \
 400     'g_setenv("GST_PLUGIN_SYSTEM_PATH_1_0", "", TRUE);' + \
 401     'gst_init(NULL,NULL);', '--quiet']
 402
 403 pkgconfig = import('pkgconfig')
 404 plugins_pkgconfig_install_dir = join_paths(plugins_install_dir, 'pkgconfig')
 405 if get_option('default_library') == 'shared'
 406   # If we don't build static plugins there is no need to generate pc files
 407   plugins_pkgconfig_install_dir = disabler()
 408 endif
 409
 410 python3 = import('python').find_installation()
 411 subdir('gst-libs')
 412 subdir('gst')
 413 subdir('ext')
 414 subdir('sys')
 415 if not get_option('tools').disabled()
 416   subdir('tools')
 417 endif
 418 subdir('tests')
 419 subdir('pkgconfig')
 420 # xgettext is optional (on Windows for instance)
 421 if find_program('xgettext', required : get_option('nls')).found()
 422   core_conf.set('ENABLE_NLS', 1)
 423   subdir('po')
 424 endif
 425 subdir('docs')
 426 subdir('scripts')
 427
 428 if have_orcc
 429   update_orc_dist_files = find_program('scripts/update-orc-dist-files.py')
 430
 431   orc_update_targets = []
 432   foreach t : orc_targets
 433     orc_name = t.get('name')
 434     orc_file = t.get('orc-source')
 435     header = t.get('header')
 436     source = t.get('source')
 437     # alias_target() only works with build targets, so can't use run_target() here
 438     orc_update_targets += [
 439       custom_target('update-orc-@0@'.format(orc_name),
 440         input: [header, source],
 441         command: [update_orc_dist_files, orc_file, header, source],
 442         output: ['@0@-dist.c'.format(orc_name)]) # not entirely true
 443     ]
 444   endforeach
 445
 446   if meson.version().version_compare('>= 0.52')
 447     update_orc_dist_target = alias_target('update-orc-dist', orc_update_targets)
 448   endif
 449 endif
 450
 451 # Set release date
 452 if gst_version_nano == 0
 453   extract_release_date = find_program('scripts/extract-release-date-from-doap-file.py')
 454   run_result = run_command(extract_release_date, gst_version, files('gst-plugins-base.doap'))
 455   if run_result.returncode() == 0
 456     release_date = run_result.stdout().strip()
 457     core_conf.set_quoted('GST_PACKAGE_RELEASE_DATETIME', release_date)
 458     message('Package release date: ' + release_date)
 459   else
 460     # Error out if our release can't be found in the .doap file
 461     error(run_result.stderr())
 462   endif
 463 endif
 464
 465 # Use core_conf after all subdirs have set values
 466 configure_file(output : 'config.h', configuration : core_conf)
 467
 468 run_command(python3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')
 469
 470 if meson.version().version_compare('>= 0.54')
 471   plugin_names = []
 472   foreach plugin: plugins
 473     # FIXME: Use str.subtring() when we can depend on Meson 0.56
 474     split = plugin.name().split('gst')
 475     if split.length() == 2
 476       plugin_names += [split[1]]
 477     else
 478       warning('Need substring API in meson >= 0.56 to properly parse plugin name: ' + plugin.name())
 479       plugin_names += [plugin.name()]
 480     endif
 481   endforeach
 482   summary({'Plugins':plugin_names}, list_sep: ', ')
 483 endif