meson.build

   1 project('pulseaudio', 'c', 'cpp',
   2         version : run_command(find_program('git-version-gen'), join_paths(meson.current_source_dir(), '.tarball-version')).stdout().strip(),
   3         meson_version : '>= 0.50.0',
   4         default_options : [ 'c_std=gnu11', 'cpp_std=c++11' ]
   5         )
   6
   7 meson.add_dist_script('scripts/save-tarball-version.sh', meson.project_version())
   8
   9 pa_version_str = meson.project_version()
  10 # For tarballs, the first split will do nothing, but for builds in git, we
  11 # split out suffixes when there are commits since the last tag
  12 # (e.g.: v11.99.1-3-gad14bdb24 -> v11.99.1)
  13 version_split = pa_version_str.split('-')[0].split('.')
  14 pa_version_major = version_split[0].split('v')[0]
  15 pa_version_minor = version_split[1]
  16 if version_split.length() > 2
  17   pa_version_micro = version_split[2]
  18 else
  19   pa_version_micro = '0'
  20 endif
  21 pa_version_major_minor = pa_version_major + '.' + pa_version_minor
  22
  23 pa_api_version = 12
  24 pa_protocol_version = 35
  25
  26 # The stable ABI for client applications, for the version info x:y:z
  27 # always will hold x=z
  28 libpulse_version_info = [24, 0, 24]
  29
  30 # A simplified, synchronous, ABI-stable interface for client
  31 # applications, for the version info x:y:z always will hold x=z
  32 libpulse_simple_version_info = [1, 1, 1]
  33
  34 # The ABI-stable GLib adapter for client applications, for the version
  35 # info x:y:z always will hold x=z
  36 libpulse_mainloop_glib_version_info = [0, 6, 0]
  37
  38 libpulse_version = '@0@.@1@.@2@'.format(
  39   libpulse_version_info[0] - libpulse_version_info[2],
  40   libpulse_version_info[0],
  41   libpulse_version_info[1],
  42 )
  43
  44 libpulse_simple_version = '@0@.@1@.@2@'.format(
  45   libpulse_simple_version_info[0] - libpulse_simple_version_info[2],
  46   libpulse_simple_version_info[0],
  47   libpulse_simple_version_info[1],
  48 )
  49
  50 libpulse_mainloop_glib_version = '@0@.@1@.@2@'.format(
  51   libpulse_mainloop_glib_version_info[0] - libpulse_mainloop_glib_version_info[2],
  52   libpulse_mainloop_glib_version_info[0],
  53   libpulse_mainloop_glib_version_info[1],
  54 )
  55
  56 # Paths
  57
  58 prefix = get_option('prefix')
  59 assert(prefix.startswith('/'), 'Prefix is not absolute: "@0@"'.format(prefix))
  60
  61 bindir = join_paths(prefix, get_option('bindir'))
  62 includedir = join_paths(prefix, get_option('includedir'))
  63 libdir = join_paths(prefix, get_option('libdir'))
  64 libexecdir = join_paths(prefix, get_option('libexecdir'))
  65 mandir = join_paths(prefix, get_option('mandir'))
  66 datadir = join_paths(prefix, get_option('datadir'))
  67 localedir = join_paths(prefix, get_option('localedir'))
  68 localstatedir = join_paths(prefix, get_option('localstatedir'))
  69 sysconfdir = join_paths(prefix, get_option('sysconfdir'))
  70 privlibdir = join_paths(libdir, 'pulseaudio')
  71
  72 if host_machine.system() == 'windows'
  73   # Windows only supports loading libraries from the same dir as the executable
  74   privlibdir = bindir
  75 endif
  76
  77 alsadatadir = get_option('alsadatadir')
  78 if alsadatadir == ''
  79   alsadatadir = join_paths(datadir, 'pulseaudio', 'alsa-mixer')
  80 endif
  81
  82 pkgconfigdir = join_paths(libdir, 'pkgconfig')
  83 pulselibexecdir = join_paths(libexecdir, 'pulse')
  84 pulsesysconfdir = join_paths(sysconfdir, 'pulse')
  85
  86 modlibexecdir = get_option('modlibexecdir')
  87 if modlibexecdir == ''
  88   modlibexecdir = join_paths(libdir, 'pulse-' + pa_version_major_minor, 'modules')
  89 endif
  90
  91 padsplibdir = get_option('padsplibdir')
  92 if padsplibdir == ''
  93   padsplibdir = privlibdir
  94 endif
  95
  96 pulsedsp_location = get_option('pulsedsp-location')
  97 if pulsedsp_location == ''
  98   pulsedsp_location = join_paths(prefix, padsplibdir)
  99 endif
 100
 101 systemduserunitdir = get_option('systemduserunitdir')
 102 # the default value is set below
 103
 104 udevrulesdir = get_option('udevrulesdir')
 105 if udevrulesdir == ''
 106   # absolute path, otherwise meson prepends the prefix
 107   udevrulesdir = '/lib/udev/rules.d'
 108 endif
 109
 110 vapidir = join_paths(datadir, 'vala', 'vapi')
 111
 112 bashcompletiondir = get_option('bashcompletiondir')
 113 if bashcompletiondir == ''
 114   bash_completion_dep = dependency('bash-completion', required : false)
 115   if bash_completion_dep.found()
 116     bashcompletiondir = bash_completion_dep.get_pkgconfig_variable('completionsdir')
 117   else
 118     bashcompletiondir = join_paths(datadir, 'bash-completion', 'completions')
 119   endif
 120 endif
 121
 122 zshcompletiondir = get_option('zshcompletiondir')
 123 if zshcompletiondir == ''
 124   zshcompletiondir = join_paths(datadir, 'zsh', 'site-functions')
 125 endif
 126
 127 # Configuration data
 128
 129 cc = meson.get_compiler('c')
 130
 131 cdata = configuration_data()
 132 cdata.set_quoted('PACKAGE', 'pulseaudio')
 133 cdata.set_quoted('PACKAGE_NAME', 'pulseaudio')
 134 cdata.set_quoted('PACKAGE_VERSION', pa_version_str)
 135 cdata.set('PA_MAJOR', pa_version_major)
 136 cdata.set('PA_MINOR', pa_version_minor)
 137 cdata.set('PA_API_VERSION', pa_api_version)
 138 cdata.set('PA_PROTOCOL_VERSION', pa_protocol_version)
 139 cdata.set_quoted('PA_MACHINE_ID', join_paths(sysconfdir, 'machine-id'))
 140 cdata.set_quoted('PA_MACHINE_ID_FALLBACK', join_paths(localstatedir, 'lib', 'dbus', 'machine-id'))
 141 cdata.set_quoted('PA_SRCDIR', join_paths(meson.current_source_dir(), 'src'))
 142 cdata.set_quoted('PA_BUILDDIR', meson.current_build_dir())
 143 cdata.set_quoted('PA_SOEXT', '.so')
 144 cdata.set_quoted('PA_DEFAULT_CONFIG_DIR', pulsesysconfdir)
 145 cdata.set('PA_DEFAULT_CONFIG_DIR_UNQUOTED', pulsesysconfdir)
 146 cdata.set_quoted('PA_BINARY', join_paths(bindir, 'pulseaudio'))
 147 cdata.set_quoted('PA_SYSTEM_RUNTIME_PATH', join_paths(localstatedir, 'run', 'pulse'))
 148 cdata.set_quoted('PA_SYSTEM_CONFIG_PATH', join_paths(localstatedir, 'lib', 'pulse'))
 149 cdata.set_quoted('PA_SYSTEM_STATE_PATH', join_paths(localstatedir, 'lib', 'pulse'))
 150 cdata.set_quoted('PA_DLSEARCHPATH', modlibexecdir)
 151 cdata.set_quoted('PA_SYSTEM_USER', get_option('system_user'))
 152 cdata.set_quoted('PA_SYSTEM_GROUP', get_option('system_group'))
 153 cdata.set_quoted('PA_ACCESS_GROUP', get_option('access_group'))
 154 cdata.set_quoted('PA_CFLAGS', 'Not yet supported on meson')
 155 cdata.set_quoted('PA_ALSA_PATHS_DIR', join_paths(alsadatadir, 'paths'))
 156 cdata.set_quoted('PA_ALSA_PROFILE_SETS_DIR', join_paths(alsadatadir, 'profile-sets'))
 157 cdata.set_quoted('DESKTOPFILEDIR', join_paths(datadir, 'applications'))
 158 cdata.set_quoted('PULSE_LOCALEDIR', localedir)
 159 cdata.set_quoted('GETTEXT_PACKAGE', 'pulseaudio')
 160 cdata.set('ENABLE_NLS', 1)
 161 cdata.set('top_srcdir', meson.source_root())
 162
 163 # Platform specifics
 164 # First some defaults to keep config file generation happy
 165 cdata.set('HAVE_COREAUDIO', 0)
 166 cdata.set('HAVE_WAVEOUT', 0)
 167 cdata.set('OS_IS_FREEBSD', 0)
 168
 169 platform_socket_dep = []
 170 platform_dep = []
 171
 172 # FIXME: This was not tested. Maybe some flags should better be CFLAGS,
 173 # rather than ending up in the config.h file?
 174 if host_machine.system() == 'darwin'
 175   cdata.set('OS_IS_DARWIN', 1)
 176   cdata.set('_DARWIN_C_SOURCE', '200112L') # Needed to get NSIG on Mac OS
 177 elif host_machine.system() == 'windows'
 178   cdata.set('OS_IS_WIN32', 1)
 179   cdata.set('HAVE_WINDOWS_H', 1)
 180   cdata.set('HAVE_WAVEOUT', 1)
 181   cdata.set('HAVE_WINSOCK2_H', 1)
 182   cdata.set('HAVE_WS2TCPIP_H', 1)
 183   cdata.set('WIN32_LEAN_AND_MEAN', 1) # Needed to avoid including unnecessary headers on Windows
 184   cdata.set('gid_t', 'int')
 185   cdata.set('uid_t', 'int')
 186   ws2_32_dep = meson.get_compiler('c').find_library('ws2_32')
 187   winsock_dep = meson.get_compiler('c').find_library('wsock32')
 188   ole32_dep = meson.get_compiler('c').find_library('ole32')
 189   ssp_dep = meson.get_compiler('c').find_library('ssp')
 190   pcreposix_dep = meson.get_compiler('c').find_library('pcreposix')
 191   platform_socket_dep = [ws2_32_dep, winsock_dep]
 192   platform_dep = [ole32_dep, ssp_dep, pcreposix_dep]
 193 elif host_machine.system() == 'freebsd'
 194   cdata.set('OS_IS_FREEBSD', 1)
 195 #elif host_machine.system() == 'solaris'
 196 #  # Apparently meson has no solaris support?
 197 #  # Needed to get declarations for msg_control and msg_controllen on Solaris
 198 #  cdata.set('_XOPEN_SOURCE', 600)
 199 #  cdata.set('__EXTENSIONS__', 1)
 200 endif
 201
 202 if cc.has_type('_Bool')
 203   cdata.set('HAVE_STD_BOOL', 1)
 204 endif
 205
 206 if host_machine.cpu_family() == 'x86_64' or cc.sizeof('void *') >= 8
 207   cdata.set('HAVE_FAST_64BIT_OPERATIONS', 1)
 208 endif
 209
 210 # Headers
 211
 212 check_headers = [
 213   'arpa/inet.h',
 214   'byteswap.h',
 215   'cpuid.h',
 216   'dlfcn.h',
 217   'execinfo.h',
 218   'grp.h',
 219   'langinfo.h',
 220   'linux/sockios.h',
 221   'locale.h',
 222   'netdb.h',
 223   'netinet/in.h',
 224   'netinet/in_systm.h',
 225   'netinet/ip.h',
 226   'netinet/tcp.h',
 227   'pcreposix.h',
 228   'poll.h',
 229   'pwd.h',
 230   'regex.h',
 231   'sched.h',
 232   'stdint.h',
 233   'sys/atomic.h',
 234   'sys/capability.h',
 235   'sys/conf.h',
 236   'sys/dl.h',
 237   'sys/eventfd.h',
 238   'sys/filio.h',
 239   'sys/ioctl.h',
 240   'sys/mman.h',
 241   'sys/prctl.h',
 242   'sys/resource.h',
 243   'sys/select.h',
 244   'sys/socket.h',
 245   'sys/syscall.h',
 246   'sys/uio.h',
 247   'sys/un.h',
 248   'sys/wait.h',
 249   'syslog.h',
 250   'xlocale.h',
 251 ]
 252
 253 foreach h : check_headers
 254   if cc.has_header(h)
 255     define = 'HAVE_' + h.underscorify().to_upper()
 256     cdata.set(define, 1)
 257   endif
 258 endforeach
 259
 260 if cc.has_header('valgrind/memcheck.h', required: get_option('valgrind'))
 261   cdata.set('HAVE_VALGRIND_MEMCHECK_H', 1)
 262 endif
 263
 264 # FIXME: move this to the above set
 265 if host_machine.system() != 'windows'
 266   if cc.has_header('pthread.h')
 267     cdata.set('HAVE_PTHREAD', 1)
 268   endif
 269 endif
 270
 271 if cc.has_header_symbol('pthread.h', 'PTHREAD_PRIO_INHERIT')
 272   cdata.set('HAVE_PTHREAD_PRIO_INHERIT', 1)
 273 endif
 274
 275 # Functions
 276
 277 check_functions = [
 278   'accept4',
 279   'clock_gettime',
 280   'ctime_r',
 281   'fchmod',
 282   'fchown',
 283   'fork',
 284   'fstat',
 285   'getaddrinfo',
 286   'getgrgid_r',
 287   'getgrnam_r',
 288   'getpwnam_r',
 289   'getpwuid_r',
 290   'gettimeofday',
 291   'getuid',
 292   'lrintf',
 293   'lstat',
 294   'memfd_create',
 295   'mkfifo',
 296   'mlock',
 297   'nanosleep',
 298   'open64',
 299   'paccept',
 300   'pipe',
 301   'pipe2',
 302   'posix_fadvise',
 303   'posix_madvise',
 304   'posix_memalign',
 305   'ppoll',
 306   'readlink',
 307   'setegid',
 308   'seteuid',
 309   'setpgid',
 310   'setregid',
 311   'setresgid',
 312   'setresuid',
 313   'setreuid',
 314   'setsid',
 315   'sig2str',
 316   'sigaction',
 317   'strerror_r',
 318   'strtod_l',
 319   'strtof',
 320   'symlink',
 321   'sysconf',
 322   'uname',
 323 ]
 324
 325 foreach f : check_functions
 326   if cc.has_function(f)
 327     define = 'HAVE_' + f.underscorify().to_upper()
 328
 329     if f == 'posix_memalign' and host_machine.system() == 'windows'
 330       message('Win32/mingw32 does not properly define posix_memalign.')
 331     elif f == 'fork' and host_machine.system() == 'windows'
 332       # __builtin_fork is defined and compiles properly, but calling __builtin_fork() does not.
 333       # This causes Meson to think that Windows has a fork() which causes a link error...
 334       message('Win32/mingw32 does not properly define fork.')
 335     else
 336       cdata.set(define, 1)
 337     endif
 338   endif
 339 endforeach
 340
 341 if cc.has_header_symbol('sys/syscall.h', 'SYS_memfd_create') \
 342   or cc.has_function('memfd_create')
 343   cdata.set('HAVE_MEMFD', 1)
 344 endif
 345
 346 if cc.has_function('dgettext')
 347   if host_machine.system() != 'windows'
 348     libintl_dep = []
 349   else
 350     libintl_dep = cc.find_library('intl')
 351   endif
 352 else
 353   libintl_dep = cc.find_library('intl')
 354 endif
 355
 356 # Symbols
 357
 358 if cc.has_header_symbol('signal.h', 'SIGXCPU')
 359   cdata.set('HAVE_SIGXCPU', 1)
 360 endif
 361
 362 if not cc.has_header_symbol('netinet/in.h', 'INADDR_NONE')
 363   if not cc.has_header_symbol('winsock2.h', 'INADDR_NONE')
 364     # Define INADDR_NONE if not found (Solaris)
 365     cdata.set('INADDR_NONE', '0xffffffff')
 366   endif
 367 endif
 368
 369 check_decls = [
 370   [ 'environ', 'unistd.h', '#define _GNU_SOURCE' ],
 371   [ 'SOUND_PCM_READ_RATE', 'sys/soundcard.h', '' ],
 372   [ 'SOUND_PCM_READ_CHANNELS', 'sys/soundcard.h', '' ],
 373   [ 'SOUND_PCM_READ_BITS', 'sys/soundcard.h', '' ],
 374 ]
 375
 376 foreach s : check_decls
 377   if cc.has_header_symbol(s[1], s[0], prefix : s[2])
 378     define = 'HAVE_DECL_' + s[0].to_upper()
 379     cdata.set(define, 1)
 380   endif
 381 endforeach
 382
 383 # Types
 384
 385 # FIXME: do we ever care about gid_t not being defined / smaller than an int?
 386 cdata.set('GETGROUPS_T', 'gid_t')
 387
 388 # Include paths
 389
 390 configinc = include_directories('.')
 391 topinc = include_directories('src')
 392
 393 # CFLAGS/LDFLAGS
 394
 395 pa_c_args = ['-DHAVE_CONFIG_H', '-D_GNU_SOURCE']
 396 server_c_args = ['-D__INCLUDED_FROM_PULSE_AUDIO']
 397 cdata.set('MESON_BUILD', 1)
 398
 399 # On ELF systems we don't want the libraries to be unloaded since we don't clean them up properly,
 400 # so we request the nodelete flag to be enabled.
 401 # On other systems, we don't really know how to do that, but it's welcome if somebody can tell.
 402 # Windows doesn't support this flag.
 403 if host_machine.system() != 'windows'
 404   nodelete_link_args = ['-Wl,-z,nodelete']
 405 else
 406   nodelete_link_args = []
 407 endif
 408
 409 # Code coverage
 410
 411 if get_option('gcov')
 412   add_project_arguments('--coverage', language: ['c', 'cpp'])
 413   add_project_link_arguments('--coverage', language: ['c', 'cpp'])
 414 endif
 415
 416 # Core Dependencies
 417
 418 libm_dep = cc.find_library('m', required : true)
 419
 420 thread_dep = dependency('threads')
 421 foreach f : [
 422   'pthread_getname_np',
 423   'pthread_setaffinity_np',
 424   'pthread_setname_np',
 425 ]
 426   if cc.has_function(f, dependencies : thread_dep)
 427     define = 'HAVE_' + f.underscorify().to_upper()
 428     cdata.set(define, 1)
 429   endif
 430 endforeach
 431
 432 cap_dep = cc.find_library('cap', required : false)
 433
 434 shm_dep = cc.find_library('rt', required : false)
 435 if cc.has_function('shm_open', dependencies : shm_dep)
 436   cdata.set('HAVE_SHM_OPEN', 1)
 437 endif
 438
 439 dl_dep = cc.find_library('dl', required : false)
 440 if cc.has_function('dladdr', dependencies : dl_dep)
 441   cdata.set('HAVE_DLADDR', 1)
 442 endif
 443
 444 have_iconv = false
 445 if cc.has_function('iconv_open')
 446   iconv_dep = dependency('', required : false)
 447   have_iconv = true
 448   # tell the libiconv header to pretend to be libc iconv
 449   cdata.set('LIBICONV_PLUG', 1)
 450 else
 451   iconv_dep = cc.find_library('iconv', required : false)
 452   have_iconv = iconv_dep.found()
 453 endif
 454 if have_iconv
 455   cdata.set('HAVE_ICONV', 1)
 456   iconvconsttest = '''#include <iconv.h>
 457 size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 458 '''
 459   if cc.compiles(iconvconsttest, dependencies : iconv_dep)
 460     cdata.set('ICONV_CONST', '')
 461   else
 462     cdata.set('ICONV_CONST', 'const')
 463   endif
 464 endif
 465
 466 # Used for backtraces on BSD
 467 execinfo_dep = cc.find_library('execinfo', required : false)
 468
 469 # Atomic operations
 470
 471 if get_option('atomic-arm-memory-barrier')
 472     cdata.set('ATOMIC_ARM_MEMORY_BARRIER_ENABLED', 1)
 473 endif
 474
 475 need_libatomic_ops = false
 476
 477 atomictest = '''void func() {
 478   volatile int atomic = 2;
 479   __sync_bool_compare_and_swap (&atomic, 2, 3);
 480 }
 481 '''
 482
 483 if cc.compiles(atomictest)
 484   cdata.set('HAVE_ATOMIC_BUILTINS', 1)
 485
 486   newatomictest = '''void func() {
 487     int c = 0;
 488     __atomic_store_n(&c, 4, __ATOMIC_SEQ_CST);
 489   }
 490   '''
 491
 492   if(cc.compiles(newatomictest))
 493     cdata.set('HAVE_ATOMIC_BUILTINS_MEMORY_MODEL', 1)
 494   endif
 495
 496 elif host_machine.cpu_family() == 'arm'
 497   if host_machine.system() == 'linux' and get_option('atomic-arm-linux-helpers')
 498     cdata.set('ATOMIC_ARM_LINUX_HELPERS', 1)
 499   else
 500     armatomictest = '''int func() {
 501       volatile int a=0;
 502       int o=0, n=1, r;
 503       asm volatile (
 504               "ldrex    %0, [%1]\n"
 505               "subs  %0, %0, %2\n"
 506               "strexeq %0, %3, [%1]\n"
 507               : "=&r" (r)
 508               : "r" (&a), "Ir" (o), "r" (n)
 509       : "cc");
 510       return (a==1 ? 0 : -1);
 511     }
 512     '''
 513
 514     if cc.compiles(armatomictest)
 515       cdata.set('ATOMIC_ARM_INLINE_ASM', 1)
 516     else
 517       need_libatomic_ops = true
 518     endif
 519   endif # arm && !linux
 520
 521 elif not ['freebsd', 'netbsd'].contains(host_machine.system())
 522   need_libatomic_ops = true
 523 endif # !atomic helpers && !arm
 524
 525 if need_libatomic_ops
 526   assert(cc.has_header('atomic_ops.h'), 'Need libatomic_ops')
 527
 528   cdata.set('AO_REQUIRE_CAS', 1)
 529
 530   if host_machine.system() != 'windows'
 531     libatomic_ops_dep = cc.find_library('atomic_ops', required : true)
 532   else
 533     libatomic_ops_dep = dependency('', required: false)
 534   endif
 535 else
 536   libatomic_ops_dep = dependency('', required: false)
 537 endif
 538
 539 # ARM checks
 540 # ARMV6 instructions we need
 541 if host_machine.cpu_family() == 'arm'
 542   armv6test = '''int func() {
 543     volatile int a = -60000, b = 0xaaaabbbb, c = 0xccccdddd;
 544     asm volatile ("ldr r0, %2 \n"
 545                   "ldr r2, %3 \n"
 546                   "ldr r3, %4 \n"
 547                   "ssat r1, #8, r0 \n"
 548                   "str r1, %0 \n"
 549                   "pkhbt r1, r3, r2, LSL #8 \n"
 550                   "str r1, %1 \n"
 551                   : "=m" (a), "=m" (b)
 552                   : "m" (a), "m" (b), "m" (c)
 553                   : "r0", "r1", "r2", "r3", "cc");
 554     return (a == -128 && b == 0xaabbdddd) ? 0 : -1;
 555   }
 556   '''
 557
 558   if cc.compiles(armv6test)
 559     cdata.set('HAVE_ARMV6', 1)
 560   endif
 561 endif
 562 # NEON checks are automatically done by the unstable-simd module
 563
 564 if get_option('daemon')
 565   # FIXME: make sure it's >= 2.2
 566   ltdl_dep = cc.find_library('ltdl', required : true)
 567 endif
 568
 569 # FIXME: can meson support libtool -dlopen/-dlpreopen things?
 570 #        and do we still want to support this at all?
 571 cdata.set('DISABLE_LIBTOOL_PRELOAD', 1)
 572
 573 if get_option('database') == 'tdb'
 574   database_dep = dependency('tdb')
 575 elif get_option('database') == 'gdbm'
 576   database_dep = cc.find_library('gdbm', required : true)
 577 else
 578   database_dep = dependency('', required: false)
 579 endif
 580
 581 if get_option('ipv6')
 582   cdata.set('HAVE_IPV6', 1)
 583 endif
 584
 585 if get_option('legacy-database-entry-format')
 586   cdata.set('ENABLE_LEGACY_DATABASE_ENTRY_FORMAT', 1)
 587 endif
 588
 589 if get_option('stream-restore-clear-old-devices')
 590   cdata.set('STREAM_RESTORE_CLEAR_OLD_DEVICES', 1)
 591 endif
 592
 593 if get_option('running-from-build-tree')
 594   cdata.set('HAVE_RUNNING_FROM_BUILD_TREE', 1)
 595 endif
 596
 597 alsa_dep = dependency('alsa', version : '>= 1.0.24', required : get_option('alsa'))
 598 if alsa_dep.found()
 599   cdata.set('HAVE_ALSA', 1)
 600   cdata.set('HAVE_ALSA_UCM', 1)
 601 endif
 602
 603 asyncns_dep = dependency('libasyncns', version : '>= 0.1', required : get_option('asyncns'))
 604 if asyncns_dep.found()
 605   cdata.set('HAVE_LIBASYNCNS', 1)
 606 endif
 607
 608 dbus_dep = dependency('dbus-1', version : '>= 1.4.12', required : get_option('dbus'))
 609 if dbus_dep.found()
 610   cdata.set('HAVE_DBUS', 1)
 611 endif
 612
 613 gio_dep = dependency('gio-2.0', version : '>= 2.26.0', required : get_option('gsettings'))
 614 if gio_dep.found()
 615   cdata.set('HAVE_GSETTINGS', 1)
 616 endif
 617
 618 glib_dep = dependency('glib-2.0', version : '>= 2.28.0', required: get_option('glib'))
 619 if glib_dep.found()
 620   cdata.set('HAVE_GLIB', 1)
 621 endif
 622
 623 gtk_dep = dependency('gtk+-3.0', required : get_option('gtk'))
 624 if gtk_dep.found()
 625   cdata.set('HAVE_GTK', 1)
 626 endif
 627
 628 have_orcc = false
 629 orcc_args = []
 630 orc_dep = dependency('orc-0.4', version : '>= 0.4.11', required : get_option('orc'))
 631 orcc = find_program('orcc', required : get_option('orc'))
 632 if orc_dep.found() and orcc.found()
 633   have_orcc = true
 634   orcc_args = [orcc]
 635   #orcc_args = [orcc, '--include', 'glib.h']
 636   cdata.set('HAVE_ORC', 1)
 637 else
 638   cdata.set('DISABLE_ORC', 1)
 639 endif
 640
 641 samplerate_dep = dependency('samplerate', version : '>= 0.1.0', required : get_option('samplerate'))
 642 if samplerate_dep.found()
 643   cdata.set('HAVE_LIBSAMPLERATE', 1)
 644 endif
 645
 646 sndfile_dep = dependency('sndfile', version : '>= 1.0.20')
 647
 648 soxr_dep = dependency('soxr', version : '>= 0.1.1', required : get_option('soxr'))
 649 if soxr_dep.found()
 650   cdata.set('HAVE_SOXR', 1)
 651 endif
 652
 653 libsystemd_dep = dependency('libsystemd', required : get_option('systemd'))
 654 if libsystemd_dep.found()
 655   cdata.set('HAVE_SYSTEMD_DAEMON', 1)
 656   cdata.set('HAVE_SYSTEMD_LOGIN', 1)
 657   cdata.set('HAVE_SYSTEMD_JOURNAL', 1)
 658 endif
 659 systemd_dep = dependency('systemd', required : get_option('systemd'))
 660 if systemd_dep.found() and systemduserunitdir == ''
 661   systemduserunitdir = systemd_dep.get_pkgconfig_variable('systemduserunitdir')
 662 endif
 663
 664 libelogind_dep = dependency('libelogind', required : get_option('elogind'))
 665 if libelogind_dep.found()
 666   cdata.set('HAVE_SYSTEMD_LOGIN', 1)
 667 endif
 668
 669 tcpwrap_dep = cc.find_library('wrap', required: get_option('tcpwrap'))
 670 if cc.has_header('tcpd.h') and cc.has_function('hosts_access', dependencies : tcpwrap_dep)
 671   cdata.set('HAVE_LIBWRAP', 1)
 672 endif
 673
 674 x11_dep = dependency('x11-xcb', required : get_option('x11'))
 675 if x11_dep.found()
 676   xcb_dep  = dependency('xcb',  required : true, version : '>= 1.6')
 677   ice_dep  = dependency('ice',  required : true)
 678   sm_dep   = dependency('sm',   required : true)
 679   xtst_dep = dependency('xtst', required : true)
 680   cdata.set('HAVE_X11', 1)
 681   if cc.has_function('XSetIOErrorExitHandler', dependencies: x11_dep)
 682     cdata.set('HAVE_XSETIOERROREXITHANDLER', 1)
 683   endif
 684 endif
 685
 686 # Module dependencies
 687 if cc.has_header('sys/soundcard.h', required: get_option('oss-output'))
 688   cdata.set('HAVE_OSS_OUTPUT', 1)
 689   cdata.set('HAVE_OSS_WRAPPER', 1)
 690   cdata.set('PULSEDSP_LOCATION', pulsedsp_location)
 691 endif
 692
 693 if get_option('hal-compat')
 694   cdata.set('HAVE_HAL_COMPAT', 1)
 695 endif
 696
 697 avahi_dep = dependency('avahi-client', version : '>= 0.6.0', required : get_option('avahi'), disabler : true)
 698 if avahi_dep.found()
 699   cdata.set('HAVE_AVAHI', 1)
 700 endif
 701
 702 sbc_dep = dependency('sbc', version : '>= 1.0', required : false)
 703
 704 if get_option('bluez5')
 705   assert(dbus_dep.found(), 'BlueZ requires D-Bus support')
 706   assert(sbc_dep.found(), 'BlueZ requires SBC support')
 707   cdata.set('HAVE_SBC', 1)
 708   cdata.set('HAVE_BLUEZ', 1)
 709   cdata.set('HAVE_BLUEZ_5', 1)
 710   if get_option('bluez5-native-headset')
 711     cdata.set('HAVE_BLUEZ_5_NATIVE_HEADSET', 1)
 712   endif
 713   if get_option('bluez5-ofono-headset')
 714     cdata.set('HAVE_BLUEZ_5_OFONO_HEADSET', 1)
 715   endif
 716 endif
 717
 718 fftw_dep = dependency('fftw3f', required : get_option('fftw'))
 719 if fftw_dep.found()
 720   cdata.set('HAVE_FFTW', 1)
 721 endif
 722
 723 jack_dep = dependency('jack', version : '>= 0.117.0', required : get_option('jack'))
 724 if jack_dep.found()
 725   cdata.set('HAVE_JACK', 1)
 726 endif
 727
 728 lirc_dep = dependency('lirc', required : get_option('lirc'))
 729 if lirc_dep.found()
 730   cdata.set('HAVE_LIRC', 1)
 731 endif
 732
 733 openssl_dep = dependency('openssl', version : '>= 0.9', required : get_option('openssl'))
 734 if openssl_dep.found()
 735   cdata.set('HAVE_OPENSSL', 1)
 736 endif
 737
 738 speex_dep = dependency('speexdsp', version : '>= 1.2', required : get_option('speex'))
 739 if speex_dep.found()
 740   cdata.set('HAVE_SPEEX', 1)
 741 endif
 742
 743 udev_dep = dependency('libudev', version : '>= 143', required : get_option('udev'))
 744 if udev_dep.found()
 745   cdata.set('HAVE_UDEV', 1)
 746 endif
 747
 748 webrtc_dep = dependency('webrtc-audio-processing', version : '>= 0.2', required : get_option('webrtc-aec'))
 749 if webrtc_dep.found()
 750   cdata.set('HAVE_WEBRTC', 1)
 751 endif
 752
 753 gst_dep = dependency('gstreamer-1.0', version : '>= 1.14', required : get_option('gstreamer'))
 754 gstapp_dep = dependency('gstreamer-app-1.0', required : get_option('gstreamer'))
 755 gstrtp_dep = dependency('gstreamer-rtp-1.0', required : get_option('gstreamer'))
 756
 757 have_gstreamer = false
 758 if gst_dep.found() and gstapp_dep.found() and gstrtp_dep.found()
 759   have_gstreamer = true
 760 endif
 761
 762 bluez5_gst_dep = dependency('gstreamer-1.0', version : '>= 1.14', required : get_option('bluez5-gstreamer'))
 763 bluez5_gstapp_dep = dependency('gstreamer-app-1.0', required : get_option('bluez5-gstreamer'))
 764 have_bluez5_gstreamer = false
 765 if bluez5_gst_dep.found() and bluez5_gstapp_dep.found()
 766   have_bluez5_gstreamer = true
 767   cdata.set('HAVE_GSTLDAC', 1)
 768   cdata.set('HAVE_GSTAPTX', 1)
 769 endif
 770
 771 # These are required for the CMake file generation
 772 cdata.set('PA_LIBDIR', libdir)
 773 cdata.set('PA_INCDIR', includedir)
 774 if glib_dep.found()
 775   cdata.set('HAVE_GLIB20', 1) # to match the AM_CONDITIONAL for CMake file generation
 776 endif
 777
 778 # Test dependencies
 779
 780 check_dep = dependency('check', version : '>= 0.9.10', required : get_option('tests'))
 781
 782 # Subdirs
 783
 784 if get_option('doxygen')
 785   subdir('doxygen')
 786 endif
 787 subdir('po')
 788 if get_option('man')
 789   subdir('man')
 790 endif
 791 subdir('shell-completion/bash')
 792 subdir('shell-completion/zsh')
 793 subdir('src')
 794 subdir('vala')
 795
 796 # Now generate config.h from everything above
 797 configure_file(output : 'config.h', configuration : cdata)
 798
 799 # pkg-config files
 800
 801 pc_cdata = configuration_data()
 802
 803 pc_cdata.set('prefix', prefix)
 804 pc_cdata.set('exec_prefix', prefix)
 805 pc_cdata.set('libdir', libdir)
 806 pc_cdata.set('includedir', includedir)
 807 pc_cdata.set('modlibexecdir', modlibexecdir)
 808 pc_cdata.set('PACKAGE_VERSION', pa_version_str)
 809 pc_cdata.set('PA_MAJORMINOR', pa_version_major_minor)
 810 # FIXME: the line below is wrong. Currently the meson thread dep lacks documentation,
 811 # and doesn't allow introspection, ie. none of get_pkgconfig_variable() or
 812 # get_configtool_variable() work with it, so we have no way to get this flag right,
 813 # unless we do all the work ourselves. See current work in glib, also meson #553.
 814 pc_cdata.set('PTHREAD_LIBS', '-pthread')
 815
 816 pc_files = [
 817   'libpulse.pc',
 818   'libpulse-simple.pc',
 819 ]
 820
 821 if glib_dep.found()
 822   pc_files += 'libpulse-mainloop-glib.pc'
 823 endif
 824
 825 foreach file : pc_files
 826   configure_file(
 827     input : file + '.in',
 828     output : file,
 829     configuration : pc_cdata,
 830     install_dir : pkgconfigdir)
 831 endforeach
 832
 833 # CMake files
 834
 835 m4 = find_program('m4', required: true)
 836
 837 cmakedir = join_paths(libdir, 'cmake', 'PulseAudio')
 838
 839 cmake_template_file = configure_file(
 840   input : 'PulseAudioConfig.cmake.in',
 841   output : 'PulseAudioConfig.cmake.tmp',
 842   configuration: cdata,
 843 )
 844
 845 custom_target('PulseAudioConfig.cmake',
 846   input : cmake_template_file,
 847   output : 'PulseAudioConfig.cmake',
 848   capture : true,
 849   command : [m4, '@INPUT@'],
 850   build_by_default : true,
 851   install : true,
 852   install_dir : cmakedir,
 853 )
 854
 855 configure_file(
 856   input : 'PulseAudioConfigVersion.cmake.in',
 857   output : 'PulseAudioConfigVersion.cmake',
 858   configuration: cdata,
 859   install : true,
 860   install_dir : cmakedir,
 861 )
 862
 863 ############################################################
 864
 865 # Final summary
 866
 867 summary = [
 868   '',
 869   '---{ @0@ @1@ }---'.format(meson.project_name(), meson.project_version()),
 870   '',
 871   'prefix:                        @0@'.format(prefix),
 872   'bindir:                        @0@'.format(bindir),
 873   'libdir:                        @0@'.format(libdir),
 874   'libexecdir:                    @0@'.format(libexecdir),
 875   'mandir:                        @0@'.format(mandir),
 876   'datadir:                       @0@'.format(datadir),
 877   'sysconfdir:                    @0@'.format(sysconfdir),
 878   'localstatedir:                 @0@'.format(localstatedir),
 879   'modlibexecdir:                 @0@'.format(modlibexecdir),
 880   'alsadatadir:                   @0@'.format(alsadatadir),
 881   'System Runtime Path:           @0@'.format(cdata.get_unquoted('PA_SYSTEM_RUNTIME_PATH')),
 882   'System State Path:             @0@'.format(cdata.get_unquoted('PA_SYSTEM_STATE_PATH')),
 883   'System Config Path:            @0@'.format(cdata.get_unquoted('PA_SYSTEM_CONFIG_PATH')),
 884   'Bash completions directory:    @0@'.format(bashcompletiondir),
 885   'Zsh completions directory:     @0@'.format(zshcompletiondir),
 886   'Compiler:                      @0@ @1@'.format(cc.get_id(), cc.version()),
 887 #  'CFLAGS:                        @0@'.format(${CFLAGS}),
 888 #  'CPPFLAGS:                      @0@'.format(${CPPFLAGS}),
 889 #  'LIBS:                          @0@'.format(${LIBS}),
 890   '',
 891   'Enable pulseaudio daemon:      @0@'.format(get_option('daemon')),
 892   '',
 893   'Enable memfd shared memory:    @0@'.format(cdata.has('HAVE_MEMFD')),
 894   'Enable X11:                    @0@'.format(x11_dep.found()),
 895   '  Safe X11 I/O errors:         @0@'.format(cdata.has('HAVE_XSETIOERROREXITHANDLER')),
 896   'Enable OSS Output:             @0@'.format(cdata.has('HAVE_OSS_OUTPUT')),
 897   'Enable OSS Wrapper:            @0@'.format(cdata.has('HAVE_OSS_WRAPPER')),
 898 #  'Enable EsounD:                 @0@'.format(${ENABLE_ESOUND}),
 899   'Enable Alsa:                   @0@'.format(alsa_dep.found()),
 900 #  'Enable CoreAudio:              @0@'.format(${ENABLE_COREAUDIO}),
 901 #  'Enable Solaris:                @0@'.format(${ENABLE_SOLARIS}),
 902 #  'Enable WaveOut:                @0@'.format(${ENABLE_WAVEOUT}),
 903   'Enable GLib 2:                 @0@'.format(glib_dep.found()),
 904   'Enable GSettings:              @0@'.format(gio_dep.found()),
 905   'Enable Gtk+ 3:                 @0@'.format(gtk_dep.found()),
 906   'Enable Avahi:                  @0@'.format(avahi_dep.found()),
 907   'Enable Jack:                   @0@'.format(jack_dep.found()),
 908   'Enable Async DNS:              @0@'.format(asyncns_dep.found()),
 909   'Enable LIRC:                   @0@'.format(lirc_dep.found()),
 910   'Enable D-Bus:                  @0@'.format(dbus_dep.found()),
 911   '  Enable BlueZ 5:              @0@'.format(get_option('bluez5')),
 912   '    Enable native headsets:    @0@'.format(get_option('bluez5-native-headset')),
 913   '    Enable  ofono headsets:    @0@'.format(get_option('bluez5-ofono-headset')),
 914   '    Enable GStreamer based codecs: @0@'.format(have_bluez5_gstreamer),
 915   'Enable udev:                   @0@'.format(udev_dep.found()),
 916   '  Enable HAL->udev compat:     @0@'.format(get_option('hal-compat')),
 917   'Enable systemd:                @0@'.format(libsystemd_dep.found()),
 918   'Enable elogind:                @0@'.format(libelogind_dep.found()),
 919   'Enable TCP Wrappers:           @0@'.format(tcpwrap_dep.found()),
 920   'Enable libsamplerate:          @0@'.format(samplerate_dep.found()),
 921   'Enable IPv6:                   @0@'.format(get_option('ipv6')),
 922   'Enable OpenSSL (for Airtunes): @0@'.format(openssl_dep.found()),
 923   'Enable FFTW:                   @0@'.format(fftw_dep.found()),
 924   'Enable ORC:                    @0@'.format(have_orcc),
 925   'Enable GStreamer:              @0@'.format(have_gstreamer),
 926   'Enable Adrian echo canceller:  @0@'.format(get_option('adrian-aec')),
 927   'Enable Speex (resampler, AEC): @0@'.format(speex_dep.found()),
 928   'Enable SoXR (resampler):       @0@'.format(soxr_dep.found()),
 929   'Enable WebRTC echo canceller:  @0@'.format(webrtc_dep.found()),
 930   'Enable Gcov coverage:          @0@'.format(get_option('gcov')),
 931   'Enable Valgrind:               @0@'.format(cdata.has('HAVE_VALGRIND_MEMCHECK_H')),
 932   'Enable man pages:              @0@'.format(get_option('man')),
 933   'Enable unit tests:             @0@'.format(get_option('tests')),
 934   '',
 935   'Database:                      @0@'.format(get_option('database')),
 936   'Legacy Database Entry Support: @0@'.format(get_option('legacy-database-entry-format')),
 937   'module-stream-restore:',
 938   '  Clear old devices:           @0@'.format(get_option('stream-restore-clear-old-devices')),
 939   'Running from build tree:       @0@'.format(get_option('running-from-build-tree')),
 940   'System User:                   @0@'.format(cdata.get_unquoted('PA_SYSTEM_USER')),
 941   'System Group:                  @0@'.format(cdata.get_unquoted('PA_SYSTEM_GROUP')),
 942   'Access Group:                  @0@'.format(cdata.get_unquoted('PA_ACCESS_GROUP')),
 943 #  'Enable per-user EsounD socket: @0@'.format(${ENABLE_PER_USER_ESOUND_SOCKET}),
 944 #  'Force preopen:                 @0@'.format(${FORCE_PREOPEN}),
 945 #  'Preopened modules:             @0@'.format(${PREOPEN_MODS}),
 946 ]
 947
 948 message('\n    '.join(summary))
 949
 950 # Sanity checks
 951
 952 if not speex_dep.found() and not webrtc_dep.found() and not get_option('adrian-aec')
 953   error('At least one echo canceller implementation must be available!')
 954 endif
 955
 956 if samplerate_dep.found()
 957   warning('Support for libsamplerate is DEPRECATED')
 958 endif
 959
 960 if host_machine.system() != 'windows'
 961   if not dbus_dep.found()
 962     message = [
 963       'You do not have D-Bus support enabled. It is strongly recommended',
 964       'that you enable D-Bus support if your platform supports it.',
 965       'Many parts of PulseAudio use D-Bus, from ConsoleKit interaction',
 966       'to the Device Reservation Protocol to speak to JACK, Bluetooth',
 967       'support and even a native control protocol for communicating and',
 968       'controlling the PulseAudio daemon itself.',
 969     ]
 970     warning('\n' + '\n'.join(message))
 971   endif
 972   if host_machine.system() == 'linux' and not udev_dep.found()
 973     message = [
 974       'You do not have udev support enabled. It is strongly recommended',
 975       'that you enable udev support if your platform supports it as it is',
 976       'the primary method used to detect hardware audio devices (on Linux)',
 977       'and is thus a critical part of PulseAudio on that platform.',
 978     ]
 979     warning('\n' + '\n'.join(message))
 980   endif
 981   if not speex_dep.found()
 982     message = [
 983       'You do not have speex support enabled. It is strongly recommended',
 984       'that you enable speex support if your platform supports it as it is',
 985       'the primary method used for audio resampling and is thus a critical',
 986       'part of PulseAudio on that platform.',
 987     ]
 988     warning('\n' + '\n'.join(message))
 989   endif
 990 endif