meson.build

   1 project('gst-plugins-base', 'c',
   2   version : '1.19.0.1',
   3   meson_version : '>= 0.54',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0].to_int()
  10 gst_version_minor = version_arr[1].to_int()
  11 gst_version_micro = version_arr[2].to_int()
  12 if version_arr.length() == 4
  13   gst_version_nano = version_arr[3].to_int()
  14 else
  15   gst_version_nano = 0
  16 endif
  17 gst_version_is_dev = gst_version_minor % 2 == 1 and gst_version_micro < 90
  18
  19 host_system = host_machine.system()
  20
  21 have_cxx = add_languages('cpp', native: false, required: false)
  22
  23 if host_system in ['ios', 'darwin']
  24   have_objc = add_languages('objc', native: false)
  25 else
  26   have_objc = false
  27 endif
  28
  29 glib_req = '>= 2.44.0'
  30 orc_req = '>= 0.4.24'
  31 gst_req = '>= @0@.@1@.0'.format(gst_version_major, gst_version_minor)
  32
  33 api_version = '1.0'
  34 soversion = 0
  35 # maintaining compatibility with the previous libtool versioning
  36 # current = minor * 100 + micro
  37 curversion = gst_version_minor * 100 + gst_version_micro
  38 libversion = '@0@.@1@.0'.format(soversion, curversion)
  39 osxversion = curversion + 1
  40
  41 plugins_install_dir = join_paths(get_option('libdir'), 'gstreamer-1.0')
  42 plugins = []
  43
  44 cc = meson.get_compiler('c')
  45
  46 if cc.get_id() == 'msvc'
  47   # Ignore several spurious warnings for things gstreamer does very commonly
  48   # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  49   # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  50   # NOTE: Only add warnings here if you are sure they're spurious
  51   add_project_arguments(
  52       '/wd4018', # implicit signed/unsigned conversion
  53       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  54       '/wd4244', # lossy type conversion (e.g. double -> int)
  55       '/wd4305', # truncating type conversion (e.g. double -> float)
  56       cc.get_supported_arguments(['/utf-8']), # set the input encoding to utf-8
  57       language : 'c')
  58   # Disable SAFESEH with MSVC for plugins and libs that use external deps that
  59   # are built with MinGW
  60   noseh_link_args = ['/SAFESEH:NO']
  61 else
  62   noseh_link_args = []
  63 endif
  64
  65 if cc.has_link_argument('-Wl,-Bsymbolic-functions')
  66   add_project_link_arguments('-Wl,-Bsymbolic-functions', language : 'c')
  67 endif
  68
  69 core_conf = configuration_data()
  70
  71 # Symbol visibility
  72 if cc.get_id() == 'msvc'
  73   export_define = '__declspec(dllexport) extern'
  74 elif cc.has_argument('-fvisibility=hidden')
  75   add_project_arguments('-fvisibility=hidden', language: 'c')
  76   if have_objc
  77     add_project_arguments('-fvisibility=hidden', language: 'objc')
  78   endif
  79   export_define = 'extern __attribute__ ((visibility ("default")))'
  80 else
  81   export_define = 'extern'
  82 endif
  83
  84 # Passing this through the command line would be too messy
  85 core_conf.set('GST_API_EXPORT', export_define)
  86
  87 # Disable strict aliasing
  88 if cc.has_argument('-fno-strict-aliasing')
  89   add_project_arguments('-fno-strict-aliasing', language: 'c')
  90 endif
  91
  92 # Define G_DISABLE_DEPRECATED for development versions
  93 if gst_version_is_dev
  94   message('Disabling deprecated GLib API')
  95   add_project_arguments('-DG_DISABLE_DEPRECATED', language: 'c')
  96 endif
  97
  98 cast_checks = get_option('gobject-cast-checks')
  99 if cast_checks.disabled() or (cast_checks.auto() and not gst_version_is_dev)
 100   message('Disabling GLib cast checks')
 101   add_project_arguments('-DG_DISABLE_CAST_CHECKS', language: 'c')
 102 endif
 103
 104 glib_asserts = get_option('glib-asserts')
 105 if glib_asserts.disabled() or (glib_asserts.auto() and not gst_version_is_dev)
 106   message('Disabling GLib asserts')
 107   add_project_arguments('-DG_DISABLE_ASSERT', language: 'c')
 108 endif
 109
 110 glib_checks = get_option('glib-checks')
 111 if glib_checks.disabled() or (glib_checks.auto() and not gst_version_is_dev)
 112   message('Disabling GLib checks')
 113   add_project_arguments('-DG_DISABLE_CHECKS', language: 'c')
 114 endif
 115
 116 # These are only needed/used by the ABI tests from core
 117 host_defines = [
 118   [ 'x86', 'HAVE_CPU_I386' ],
 119   [ 'x86_64', 'HAVE_CPU_X86_64' ],
 120   [ 'arm', 'HAVE_CPU_ARM' ],
 121   [ 'aarch64', 'HAVE_CPU_AARCH64' ],
 122   [ 'mips', 'HAVE_CPU_MIPS' ],
 123   [ 'powerpc', 'HAVE_CPU_PPC' ],
 124   [ 'powerpc64', 'HAVE_CPU_PPC64' ],
 125   [ 'alpha', 'HAVE_CPU_ALPHA' ],
 126   [ 'sparc', 'HAVE_CPU_SPARC' ],
 127   [ 'ia64', 'HAVE_CPU_IA64' ],
 128   [ 'hppa', 'HAVE_CPU_HPPA' ],
 129   [ 'm68k', 'HAVE_CPU_M68K' ],
 130   [ 's390', 'HAVE_CPU_S390' ],
 131 ]
 132 foreach h : host_defines
 133   if h.get(0) == host_machine.cpu()
 134     core_conf.set(h.get(1), 1)
 135   endif
 136 endforeach
 137 # FIXME: should really be called HOST_CPU or such
 138 core_conf.set_quoted('TARGET_CPU', host_machine.cpu())
 139
 140 check_headers = [
 141   ['HAVE_DLFCN_H', 'dlfcn.h'],
 142   ['HAVE_EMMINTRIN_H', 'emmintrin.h'],
 143   ['HAVE_INTTYPES_H', 'inttypes.h'],
 144   ['HAVE_MEMORY_H', 'memory.h'],
 145   ['HAVE_NETINET_IN_H', 'netinet/in.h'],
 146   ['HAVE_NETINET_TCP_H', 'netinet/tcp.h'],
 147   ['HAVE_PROCESS_H', 'process.h'],
 148   ['HAVE_SMMINTRIN_H', 'smmintrin.h'],
 149   ['HAVE_STDINT_H', 'stdint.h'],
 150   ['HAVE_STRINGS_H', 'strings.h'],
 151   ['HAVE_STRING_H', 'string.h'],
 152   ['HAVE_SYS_SOCKET_H', 'sys/socket.h'],
 153   ['HAVE_SYS_STAT_H', 'sys/stat.h'],
 154   ['HAVE_SYS_TYPES_H', 'sys/types.h'],
 155   ['HAVE_SYS_WAIT_H', 'sys/wait.h'],
 156   ['HAVE_UNISTD_H', 'unistd.h'],
 157   ['HAVE_WINSOCK2_H', 'winsock2.h'],
 158   ['HAVE_XMMINTRIN_H', 'xmmintrin.h'],
 159   ['HAVE_LINUX_DMA_BUF_H', 'linux/dma-buf.h'],
 160 ]
 161 foreach h : check_headers
 162   if cc.has_header(h.get(1))
 163     core_conf.set(h.get(0), 1)
 164   endif
 165 endforeach
 166
 167 check_functions = [
 168   ['HAVE_DCGETTEXT', 'dcgettext', '#include<libintl.h>'],
 169   ['HAVE_GMTIME_R', 'gmtime_r', '#include<time.h>'],
 170   ['HAVE_LOCALTIME_R', 'localtime_r', '#include<time.h>'],
 171   ['HAVE_LRINTF', 'lrintf', '#include<math.h>'],
 172   ['HAVE_MMAP', 'mmap', '#include<sys/mman.h>'],
 173   ['HAVE_LOG2', 'log2', '#include<math.h>'],
 174 ]
 175
 176 libm = cc.find_library('m', required : false)
 177 foreach f : check_functions
 178   if cc.has_function(f.get(1), prefix : f.get(2), dependencies : libm)
 179     core_conf.set(f.get(0), 1)
 180   endif
 181 endforeach
 182
 183 core_conf.set('SIZEOF_CHAR', cc.sizeof('char'))
 184 core_conf.set('SIZEOF_INT', cc.sizeof('int'))
 185 core_conf.set('SIZEOF_LONG', cc.sizeof('long'))
 186 core_conf.set('SIZEOF_SHORT', cc.sizeof('short'))
 187 core_conf.set('SIZEOF_VOIDP', cc.sizeof('void*'))
 188
 189 core_conf.set_quoted('GETTEXT_PACKAGE', 'gst-plugins-base-1.0')
 190 core_conf.set_quoted('LOCALEDIR', join_paths(get_option('prefix'), get_option('localedir')))
 191 core_conf.set_quoted('PACKAGE', 'gst-plugins-base')
 192 core_conf.set_quoted('VERSION', gst_version)
 193 core_conf.set_quoted('PACKAGE_VERSION', gst_version)
 194 core_conf.set_quoted('GST_API_VERSION', api_version)
 195 core_conf.set_quoted('GST_DATADIR', join_paths(get_option('prefix'), get_option('datadir')))
 196 core_conf.set_quoted('GST_LICENSE', 'LGPL')
 197
 198 install_plugins_helper = get_option('install_plugins_helper')
 199 if install_plugins_helper == ''
 200   install_plugins_helper = join_paths(get_option('prefix'),
 201                                       get_option('libexecdir'),
 202                                       'gst-install-plugins-helper')
 203 endif
 204 core_conf.set_quoted('GST_INSTALL_PLUGINS_HELPER', install_plugins_helper)
 205
 206 warning_flags = [
 207   '-Wmissing-declarations',
 208   '-Wredundant-decls',
 209   '-Wundef',
 210   '-Wwrite-strings',
 211   '-Wformat',
 212   '-Wformat-nonliteral',
 213   '-Wformat-security',
 214   '-Winit-self',
 215   '-Wmissing-include-dirs',
 216   '-Waddress',
 217   '-Wno-multichar',
 218   '-Wvla',
 219   '-Wpointer-arith',
 220 ]
 221
 222 warning_c_flags = [
 223   '-Wmissing-prototypes',
 224   '-Wdeclaration-after-statement',
 225 ]
 226
 227 warning_cxx_flags = [
 228   '-Waggregate-return',
 229 ]
 230
 231 if have_cxx
 232   cxx = meson.get_compiler('cpp')
 233   foreach extra_arg : warning_cxx_flags
 234     if cxx.has_argument (extra_arg)
 235       add_project_arguments([extra_arg], language: 'cpp')
 236     endif
 237   endforeach
 238 endif
 239
 240 foreach extra_arg : warning_flags
 241   if cc.has_argument (extra_arg)
 242     add_project_arguments([extra_arg], language: 'c')
 243   endif
 244   if have_cxx and cxx.has_argument (extra_arg)
 245     add_project_arguments([extra_arg], language: 'cpp')
 246   endif
 247 endforeach
 248
 249 foreach extra_arg : warning_c_flags
 250   if cc.has_argument (extra_arg)
 251     add_project_arguments([extra_arg], language: 'c')
 252   endif
 253 endforeach
 254
 255 # GStreamer package name and origin url
 256 gst_package_name = get_option('package-name')
 257 if gst_package_name == ''
 258   if gst_version_nano == 0
 259     gst_package_name = 'GStreamer Base Plug-ins source release'
 260   elif gst_version_nano == 1
 261     gst_package_name = 'GStreamer Base Plug-ins git'
 262   else
 263     gst_package_name = 'GStreamer Base Plug-ins prerelease'
 264   endif
 265 endif
 266 core_conf.set_quoted('GST_PACKAGE_NAME', gst_package_name)
 267 core_conf.set_quoted('GST_PACKAGE_ORIGIN', get_option('package-origin'))
 268
 269 # FIXME: These should be configure options
 270 core_conf.set_quoted('DEFAULT_VIDEOSINK', 'autovideosink')
 271 core_conf.set_quoted('DEFAULT_AUDIOSINK', 'autoaudiosink')
 272
 273 # Set whether the audioresampling method should be detected at runtime
 274 core_conf.set('AUDIORESAMPLE_FORMAT_' + get_option('audioresample_format').to_upper(), true)
 275
 276 gst_plugins_base_args = ['-DHAVE_CONFIG_H']
 277 if get_option('default_library') == 'static'
 278   gst_plugins_base_args += ['-DGST_STATIC_COMPILATION']
 279 endif
 280
 281 # X11 checks are for sys/ and tests/
 282 x11_dep = dependency('x11', required : get_option('x11'))
 283 # GLib checks are for the entire project
 284 # Almost everything that uses glib also uses gobject
 285 glib_deps = [dependency('glib-2.0', version : glib_req, fallback: ['glib', 'libglib_dep']),
 286              dependency('gobject-2.0', fallback: ['glib', 'libgobject_dep'])]
 287 # GIO is used by the GIO plugin, and by the TCP, SDP, and RTSP plugins
 288 gio_dep = dependency('gio-2.0', fallback: ['glib', 'libgio_dep'])
 289 giounix_dep = dependency('', required: false)
 290 if host_system != 'windows'
 291   giounix_dep = dependency('gio-unix-2.0', version : glib_req,
 292                            fallback: ['glib', 'libgiounix_dep'])
 293 endif
 294 gmodule_dep = dependency('gmodule-no-export-2.0',
 295                          fallback: ['glib', 'libgmodule_dep'])
 296
 297 # some of the examples can use gdk-pixbuf and GTK+3
 298 gdk_pixbuf_dep = dependency('gdk-pixbuf-2.0', required : get_option('examples'))
 299 gtk_dep = dependency('gtk+-3.0', version : '>= 3.10', required : get_option('examples'))
 300 # TODO: https://github.com/mesonbuild/meson/issues/3941
 301 if not get_option('x11').disabled()
 302   gtk_x11_dep = dependency('gtk+-x11-3.0', version : '>= 3.10', required : get_option('examples'))
 303 else
 304   gtk_x11_dep = dependency('', required : false)
 305 endif
 306 # gtk+ quartz backend is only available on macOS
 307 if host_system == 'darwin'
 308   gtk_quartz_dep = dependency('gtk+-quartz-3.0', version : '>= 3.10', required : get_option('examples'))
 309 else
 310   gtk_quartz_dep = dependency('', required : false)
 311 endif
 312
 313 core_conf.set('HAVE_X11', x11_dep.found())
 314 core_conf.set('HAVE_GIO_UNIX_2_0', giounix_dep.found())
 315
 316 if gio_dep.type_name() == 'pkgconfig'
 317     core_conf.set_quoted('GIO_MODULE_DIR',
 318         gio_dep.get_pkgconfig_variable('giomoduledir'))
 319     core_conf.set_quoted('GIO_LIBDIR',
 320         gio_dep.get_pkgconfig_variable('libdir'))
 321     core_conf.set_quoted('GIO_PREFIX',
 322         gio_dep.get_pkgconfig_variable('prefix'))
 323 else
 324     core_conf.set_quoted('GIO_MODULE_DIR', join_paths(get_option('prefix'),
 325       get_option('libdir'), 'gio/modules'))
 326     core_conf.set_quoted('GIO_LIBDIR', join_paths(get_option('prefix'),
 327       get_option('libdir')))
 328     core_conf.set_quoted('GIO_PREFIX', join_paths(get_option('prefix')))
 329 endif
 330
 331 configinc = include_directories('.')
 332 libsinc = include_directories('gst-libs')
 333
 334 # To use the subproject make subprojects directory
 335 # and put gstreamer meson git there (symlinking is fine)
 336 gst_dep = dependency('gstreamer-1.0', version : gst_req,
 337   fallback : ['gstreamer', 'gst_dep'])
 338 gst_base_dep = dependency('gstreamer-base-1.0', version : gst_req,
 339   fallback : ['gstreamer', 'gst_base_dep'])
 340 gst_net_dep = dependency('gstreamer-net-1.0', version : gst_req,
 341   fallback : ['gstreamer', 'gst_net_dep'])
 342 gst_check_dep = dependency('gstreamer-check-1.0', version : gst_req,
 343   required : get_option('tests'),
 344   fallback : ['gstreamer', 'gst_check_dep'])
 345 gst_controller_dep = dependency('gstreamer-controller-1.0', version : gst_req,
 346   fallback : ['gstreamer', 'gst_controller_dep'])
 347
 348 have_orcc = false
 349 orcc_args = []
 350 orc_targets = []
 351 # Used by various libraries/elements that use Orc code
 352 orc_dep = dependency('orc-0.4', version : orc_req, required : get_option('orc'),
 353     fallback : ['orc', 'orc_dep'])
 354 orcc = find_program('orcc', required : get_option('orc'))
 355 if orc_dep.found() and orcc.found()
 356   have_orcc = true
 357   orcc_args = [orcc, '--include', 'glib.h']
 358   core_conf.set('HAVE_ORC', 1)
 359 else
 360   message('Orc Compiler not found or disabled, will use backup C code')
 361   core_conf.set('DISABLE_ORC', 1)
 362 endif
 363
 364 # Used to build SSE* things in audio-resampler
 365 sse_args = '-msse'
 366 sse2_args = '-msse2'
 367 sse41_args = '-msse4.1'
 368
 369 have_sse = cc.has_argument(sse_args)
 370 have_sse2 = cc.has_argument(sse2_args)
 371 have_sse41 = cc.has_argument(sse41_args)
 372
 373 if host_machine.cpu_family() == 'arm'
 374   if cc.compiles('''
 375 #include <arm_neon.h>
 376 int32x4_t testfunc(int16_t *a, int16_t *b) {
 377   asm volatile ("vmull.s16 q0, d0, d0" : : : "q0");
 378   return vmull_s16(vld1_s16(a), vld1_s16(b));
 379 }
 380 ''', name : 'NEON support')
 381     core_conf.set('HAVE_ARM_NEON', true)
 382   endif
 383 endif
 384
 385 if gst_dep.type_name() == 'internal'
 386     gst_proj = subproject('gstreamer')
 387
 388     if not gst_proj.get_variable('gst_debug')
 389         message('GStreamer debug system is disabled')
 390         add_project_arguments('-Wno-unused', language: 'c')
 391     else
 392         message('GStreamer debug system is enabled')
 393     endif
 394 else
 395     # We can't check that in the case of subprojects as we won't
 396     # be able to build against an internal dependency (which is not built yet)
 397     if not cc.compiles('''
 398 #include <gst/gstconfig.h>
 399 #ifdef GST_DISABLE_GST_DEBUG
 400 #error "debugging disabled, make compiler fail"
 401 #endif''' , dependencies: gst_dep)
 402         message('GStreamer debug system is disabled')
 403         add_project_arguments('-Wno-unused', language: 'c')
 404     else
 405         message('GStreamer debug system is enabled')
 406     endif
 407 endif
 408
 409 if cc.has_member('struct tcp_info', '__tcpi_reordering', prefix: '#include <netinet/tcp.h>')
 410   core_conf.set('HAVE_BSD_TCP_INFO', true)
 411 endif
 412
 413 if cc.has_member('struct tcp_info', 'tcpi_reordering', prefix: '#include <netinet/tcp.h>')
 414   core_conf.set('HAVE_LINUX_TCP_INFO', true)
 415 endif
 416
 417 gir = find_program('g-ir-scanner', required : get_option('introspection'))
 418 gnome = import('gnome')
 419 build_gir = gir.found() and (not meson.is_cross_build() or get_option('introspection').enabled())
 420 gir_init_section = [ '--add-init-section=extern void gst_init(gint*,gchar**);' + \
 421     'g_setenv("GST_REGISTRY_DISABLE", "yes", TRUE);' + \
 422     'g_setenv("GST_REGISTRY_1.0", "@0@", TRUE);'.format(meson.current_build_dir() + '/gir_empty_registry.reg') + \
 423     'g_setenv("GST_PLUGIN_PATH_1_0", "", TRUE);' + \
 424     'g_setenv("GST_PLUGIN_SYSTEM_PATH_1_0", "", TRUE);' + \
 425     'gst_init(NULL,NULL);', '--quiet']
 426
 427 pkgconfig = import('pkgconfig')
 428 plugins_pkgconfig_install_dir = join_paths(plugins_install_dir, 'pkgconfig')
 429 if get_option('default_library') == 'shared'
 430   # If we don't build static plugins there is no need to generate pc files
 431   plugins_pkgconfig_install_dir = disabler()
 432 endif
 433
 434 python3 = import('python').find_installation()
 435 subdir('gst-libs')
 436 subdir('gst')
 437 subdir('ext')
 438 subdir('sys')
 439 if not get_option('tools').disabled()
 440   subdir('tools')
 441 endif
 442 subdir('tests')
 443 subdir('pkgconfig')
 444 # xgettext is optional (on Windows for instance)
 445 if find_program('xgettext', required : get_option('nls')).found()
 446   core_conf.set('ENABLE_NLS', 1)
 447   subdir('po')
 448 endif
 449 subdir('docs')
 450 subdir('scripts')
 451
 452 if have_orcc
 453   update_orc_dist_files = find_program('scripts/update-orc-dist-files.py')
 454
 455   orc_update_targets = []
 456   foreach t : orc_targets
 457     orc_name = t.get('name')
 458     orc_file = t.get('orc-source')
 459     header = t.get('header')
 460     source = t.get('source')
 461     # alias_target() only works with build targets, so can't use run_target() here
 462     orc_update_targets += [
 463       custom_target('update-orc-@0@'.format(orc_name),
 464         input: [header, source],
 465         command: [update_orc_dist_files, orc_file, header, source],
 466         output: ['@0@-dist.c'.format(orc_name)]) # not entirely true
 467     ]
 468   endforeach
 469
 470   if meson.version().version_compare('>= 0.52')
 471     update_orc_dist_target = alias_target('update-orc-dist', orc_update_targets)
 472   endif
 473 endif
 474
 475 # Set release date
 476 if gst_version_nano == 0
 477   extract_release_date = find_program('scripts/extract-release-date-from-doap-file.py')
 478   run_result = run_command(extract_release_date, gst_version, files('gst-plugins-base.doap'))
 479   if run_result.returncode() == 0
 480     release_date = run_result.stdout().strip()
 481     core_conf.set_quoted('GST_PACKAGE_RELEASE_DATETIME', release_date)
 482     message('Package release date: ' + release_date)
 483   else
 484     # Error out if our release can't be found in the .doap file
 485     error(run_result.stderr())
 486   endif
 487 endif
 488
 489 # Use core_conf after all subdirs have set values
 490 configure_file(output : 'config.h', configuration : core_conf)
 491
 492 run_command(python3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')
 493
 494 if meson.version().version_compare('>= 0.54')
 495   plugin_names = []
 496   foreach plugin: plugins
 497     # FIXME: Use str.subtring() when we can depend on Meson 0.56
 498     split = plugin.name().split('gst')
 499     if split.length() == 2
 500       plugin_names += [split[1]]
 501     else
 502       warning('Need substring API in meson >= 0.56 to properly parse plugin name: ' + plugin.name())
 503       plugin_names += [plugin.name()]
 504     endif
 505   endforeach
 506   summary({'Plugins':plugin_names}, list_sep: ', ')
 507 endif