meson.build

   1 project('gst-plugins-base', 'c',
   2   version : '1.15.0.1',
   3   meson_version : '>= 0.46.0',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0].to_int()
  10 gst_version_minor = version_arr[1].to_int()
  11 gst_version_micro = version_arr[2].to_int()
  12 if version_arr.length() == 4
  13   gst_version_nano = version_arr[3].to_int()
  14 else
  15   gst_version_nano = 0
  16 endif
  17
  18 have_cxx = add_languages('cpp', required : false)
  19
  20 glib_req = '>= 2.40.0'
  21 orc_req = '>= 0.4.24'
  22 gst_req = '>= @0@.@1@.0'.format(gst_version_major, gst_version_minor)
  23
  24 api_version = '1.0'
  25 soversion = 0
  26 # maintaining compatibility with the previous libtool versioning
  27 # current = minor * 100 + micro
  28 # FIXME: should be able to convert string to int somehow so we can just do maths
  29 libversion = '@0@.@1@.0'.format(soversion, gst_version_minor * 100 + gst_version_micro)
  30
  31 plugins_install_dir = '@0@/gstreamer-1.0'.format(get_option('libdir'))
  32
  33 cc = meson.get_compiler('c')
  34
  35 if cc.get_id() == 'msvc'
  36   # Ignore several spurious warnings for things gstreamer does very commonly
  37   # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  38   # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  39   # NOTE: Only add warnings here if you are sure they're spurious
  40   add_project_arguments(
  41       '/wd4018', # implicit signed/unsigned conversion
  42       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  43       '/wd4244', # lossy type conversion (e.g. double -> int)
  44       '/wd4305', # truncating type conversion (e.g. double -> float)
  45       language : 'c')
  46   # Disable SAFESEH with MSVC for plugins and libs that use external deps that
  47   # are built with MinGW
  48   noseh_link_args = ['/SAFESEH:NO']
  49 else
  50   noseh_link_args = []
  51 endif
  52
  53 if cc.has_link_argument('-Wl,-Bsymbolic-functions')
  54   add_project_link_arguments('-Wl,-Bsymbolic-functions', language : 'c')
  55 endif
  56
  57 # Symbol visibility
  58 if cc.has_argument('-fvisibility=hidden')
  59   add_project_arguments('-fvisibility=hidden', language: 'c')
  60 endif
  61
  62 # Disable strict aliasing
  63 if cc.has_argument('-fno-strict-aliasing')
  64   add_project_arguments('-fno-strict-aliasing', language: 'c')
  65 endif
  66
  67 core_conf = configuration_data()
  68 check_headers = [
  69   ['HAVE_DLFCN_H', 'dlfcn.h'],
  70   ['HAVE_EMMINTRIN_H', 'emmintrin.h'],
  71   ['HAVE_INTTYPES_H', 'inttypes.h'],
  72   ['HAVE_MEMORY_H', 'memory.h'],
  73   ['HAVE_PROCESS_H', 'process.h'],
  74   ['HAVE_SMMINTRIN_H', 'smmintrin.h'],
  75   ['HAVE_STDINT_H', 'stdint.h'],
  76   ['HAVE_STDLIB_H', 'stdlib.h'],
  77   ['HAVE_STRINGS_H', 'strings.h'],
  78   ['HAVE_STRING_H', 'string.h'],
  79   ['HAVE_SYS_SOCKET_H', 'sys/socket.h'],
  80   ['HAVE_SYS_STAT_H', 'sys/stat.h'],
  81   ['HAVE_SYS_TYPES_H', 'sys/types.h'],
  82   ['HAVE_SYS_WAIT_H', 'sys/wait.h'],
  83   ['HAVE_UNISTD_H', 'unistd.h'],
  84   ['HAVE_WINSOCK2_H', 'winsock2.h'],
  85   ['HAVE_XMMINTRIN_H', 'xmmintrin.h'],
  86   ['HAVE_LINUX_DMA_BUF_H', 'linux/dma-buf.h'],
  87 ]
  88 foreach h : check_headers
  89   if cc.has_header(h.get(1))
  90     core_conf.set(h.get(0), 1)
  91   endif
  92 endforeach
  93
  94 check_functions = [
  95   ['HAVE_DCGETTEXT', 'dcgettext', '#include<libintl.h>'],
  96   ['HAVE_GMTIME_R', 'gmtime_r', '#include<time.h>'],
  97   ['HAVE_LRINTF', 'lrintf', '#include<math.h>'],
  98   ['HAVE_MMAP', 'mmap', '#include<sys/mman.h>'],
  99   ['HAVE_LOG2', 'log2', '#include<math.h>'],
 100 ]
 101
 102 libm = cc.find_library('m', required : false)
 103 foreach f : check_functions
 104   if cc.has_function(f.get(1), prefix : f.get(2), dependencies : libm)
 105     core_conf.set(f.get(0), 1)
 106   endif
 107 endforeach
 108
 109 core_conf.set('SIZEOF_CHAR', cc.sizeof('char'))
 110 core_conf.set('SIZEOF_INT', cc.sizeof('int'))
 111 core_conf.set('SIZEOF_LONG', cc.sizeof('long'))
 112 core_conf.set('SIZEOF_SHORT', cc.sizeof('short'))
 113 core_conf.set('SIZEOF_VOIDP', cc.sizeof('void*'))
 114
 115 if get_option('nls')
 116   core_conf.set('ENABLE_NLS', 1)
 117 endif
 118 core_conf.set_quoted('GETTEXT_PACKAGE', 'gst-plugins-base-1.0')
 119 core_conf.set_quoted('LOCALEDIR', join_paths(get_option('prefix'), get_option('localedir')))
 120 core_conf.set_quoted('PACKAGE', 'gst-plugins-base')
 121 core_conf.set_quoted('VERSION', gst_version)
 122 core_conf.set_quoted('PACKAGE_VERSION', gst_version)
 123 core_conf.set_quoted('GST_API_VERSION', api_version)
 124 core_conf.set_quoted('GST_INSTALL_PLUGINS_HELPER', 'FIXME')
 125 core_conf.set_quoted('GST_DATADIR', join_paths(get_option('prefix'), get_option('datadir')))
 126 core_conf.set_quoted('GST_LICENSE', 'LGPL')
 127
 128 warning_flags = [
 129   '-Wmissing-declarations',
 130   '-Wredundant-decls',
 131   '-Wundef',
 132   '-Wwrite-strings',
 133   '-Wformat',
 134   '-Wformat-nonliteral',
 135   '-Wformat-security',
 136   '-Winit-self',
 137   '-Wmissing-include-dirs',
 138   '-Waddress',
 139   '-Wno-multichar',
 140   '-Wvla',
 141   '-Wpointer-arith',
 142 ]
 143
 144 warning_c_flags = [
 145   '-Wmissing-prototypes',
 146   '-Wdeclaration-after-statement',
 147 ]
 148
 149 warning_cxx_flags = [
 150   '-Waggregate-return',
 151 ]
 152
 153 if have_cxx
 154   cxx = meson.get_compiler('cpp')
 155   foreach extra_arg : warning_cxx_flags
 156     if cxx.has_argument (extra_arg)
 157       add_project_arguments([extra_arg], language: 'cpp')
 158     endif
 159   endforeach
 160 endif
 161
 162 foreach extra_arg : warning_flags
 163   if cc.has_argument (extra_arg)
 164     add_project_arguments([extra_arg], language: 'c')
 165   endif
 166   if have_cxx and cxx.has_argument (extra_arg)
 167     add_project_arguments([extra_arg], language: 'cpp')
 168   endif
 169 endforeach
 170
 171 foreach extra_arg : warning_c_flags
 172   if cc.has_argument (extra_arg)
 173     add_project_arguments([extra_arg], language: 'c')
 174   endif
 175 endforeach
 176
 177 # GStreamer package name and origin url
 178 gst_package_name = get_option('package-name')
 179 if gst_package_name == ''
 180   if gst_version_nano == 0
 181     gst_package_name = 'GStreamer Base Plug-ins source release'
 182   elif gst_version_nano == 1
 183     gst_package_name = 'GStreamer Base Plug-ins git'
 184   else
 185     gst_package_name = 'GStreamer Base Plug-ins prerelease'
 186   endif
 187 endif
 188 core_conf.set_quoted('GST_PACKAGE_NAME', gst_package_name)
 189 core_conf.set_quoted('GST_PACKAGE_ORIGIN', get_option('package-origin'))
 190
 191 # FIXME: These should be configure options
 192 core_conf.set_quoted('DEFAULT_VIDEOSINK', 'autovideosink')
 193 core_conf.set_quoted('DEFAULT_AUDIOSINK', 'autoaudiosink')
 194
 195 # Set whether the audioresampling method should be detected at runtime
 196 core_conf.set('AUDIORESAMPLE_FORMAT_' + get_option('audioresample_format').to_upper(), true)
 197
 198 gst_plugins_base_args = ['-DHAVE_CONFIG_H']
 199 if get_option('default_library') == 'static'
 200   gst_plugins_base_args += ['-DGST_STATIC_COMPILATION']
 201 endif
 202
 203 # X11 checks are for sys/ and tests/
 204 x11_dep = dependency('x11', required : false)
 205 # GLib checks are for the entire project
 206 giounix_dep = dependency('gio-unix-2.0', version : glib_req, required : false)
 207 # Almost everything that uses glib also uses gobject
 208 glib_deps = [dependency('glib-2.0', version : glib_req, fallback: ['glib', 'libglib_dep']),
 209              dependency('gobject-2.0', fallback: ['glib', 'libgobject_dep'])]
 210 gio_dep = dependency('gio-2.0', fallback: ['glib', 'libgio_dep'])
 211
 212 # some of the examples want GTK+
 213 gtk_dep = dependency('gtk+-3.0', version : '>= 3.10', required : false)
 214 gtk_x11_dep = dependency('gtk+-x11-3.0', version : '>= 3.10', required : false)
 215 gtk_quartz_dep = dependency('gtk+-quartz-3.0', version : '>= 3.10', required : false)
 216 gdk_pixbuf_dep = dependency('gdk-pixbuf-2.0', required : false)
 217
 218 core_conf.set('HAVE_X', x11_dep.found())
 219 core_conf.set('HAVE_GIO_UNIX_2_0',
 220     (gio_dep.type_name() != 'pkgconfig' and host_machine.system() != 'windows')
 221     or giounix_dep.found())
 222
 223 if gio_dep.type_name() == 'pkgconfig'
 224     core_conf.set_quoted('GIO_MODULE_DIR',
 225         gio_dep.get_pkgconfig_variable('giomoduledir'))
 226     core_conf.set_quoted('GIO_LIBDIR',
 227         gio_dep.get_pkgconfig_variable('libdir'))
 228     core_conf.set_quoted('GIO_PREFIX',
 229         gio_dep.get_pkgconfig_variable('prefix'))
 230 else
 231     core_conf.set_quoted('GIO_MODULE_DIR', join_paths(get_option('prefix'),
 232       get_option('libdir'), 'gio/modules'))
 233     core_conf.set_quoted('GIO_LIBDIR', join_paths(get_option('prefix'),
 234       get_option('libdir')))
 235     core_conf.set_quoted('GIO_PREFIX', get_option('prefix'))
 236 endif
 237
 238 configinc = include_directories('.')
 239 libsinc = include_directories('gst-libs')
 240
 241 # To use the subproject make subprojects directory
 242 # and put gstreamer meson git there (symlinking is fine)
 243 gst_dep = dependency('gstreamer-1.0', version : gst_req,
 244   fallback : ['gstreamer', 'gst_dep'])
 245 gst_base_dep = dependency('gstreamer-base-1.0', version : gst_req,
 246   fallback : ['gstreamer', 'gst_base_dep'])
 247 gst_net_dep = dependency('gstreamer-net-1.0', version : gst_req,
 248   fallback : ['gstreamer', 'gst_net_dep'])
 249 if host_machine.system() != 'windows'
 250   gst_check_dep = dependency('gstreamer-check-1.0', version : gst_req,
 251     fallback : ['gstreamer', 'gst_check_dep'])
 252 endif
 253 gst_controller_dep = dependency('gstreamer-controller-1.0', version : gst_req,
 254   fallback : ['gstreamer', 'gst_controller_dep'])
 255
 256 have_orcc = false
 257 orcc_args = []
 258 if get_option('orc') != 'no'
 259   need_orc = get_option('orc') == 'yes'
 260   # Used by various libraries/elements that use Orc code
 261   orc_dep = dependency('orc-0.4', version : orc_req, required : need_orc)
 262   orcc = find_program('orcc', required : need_orc)
 263   if orc_dep.found() and orcc.found()
 264     have_orcc = true
 265     orcc_args = [orcc, '--include', 'glib.h']
 266     core_conf.set('HAVE_ORC', 1)
 267   else
 268     message('Orc Compiler not found, will use backup C code')
 269     core_conf.set('DISABLE_ORC', 1)
 270   endif
 271 else
 272   core_conf.set('DISABLE_ORC', 1)
 273 endif
 274
 275 # Used to build SSE* things in audio-resampler
 276 sse_args = '-msse'
 277 sse2_args = '-msse2'
 278 sse41_args = '-msse4.1'
 279
 280 have_sse = cc.has_argument(sse_args)
 281 have_sse2 = cc.has_argument(sse2_args)
 282 have_sse41 = cc.has_argument(sse41_args)
 283
 284 if gst_dep.type_name() == 'internal'
 285     gst_proj = subproject('gstreamer')
 286
 287     if not gst_proj.get_variable('gst_debug')
 288         message('GStreamer debug system is disabled')
 289         add_project_arguments('-Wno-unused', language: 'c')
 290     else
 291         message('GStreamer debug system is enabled')
 292     endif
 293 else
 294     # We can't check that in the case of subprojects as we won't
 295     # be able to build against an internal dependency (which is not built yet)
 296     if not cc.compiles('''
 297 #include <gst/gstconfig.h>
 298 #ifdef GST_DISABLE_GST_DEBUG
 299 #error "debugging disabled, make compiler fail"
 300 #endif''' , dependencies: gst_dep)
 301         message('GStreamer debug system is disabled')
 302         add_project_arguments('-Wno-unused', language: 'c')
 303     else
 304         message('GStreamer debug system is enabled')
 305     endif
 306 endif
 307
 308 gir = find_program('g-ir-scanner', required : false)
 309 gnome = import('gnome')
 310 build_gir = gir.found() and not meson.is_cross_build() and get_option('introspection')
 311 gir_init_section = [ '--add-init-section=extern void gst_init(gint*,gchar**);' + \
 312     'g_setenv("GST_REGISTRY_DISABLE", "yes", TRUE);' + \
 313     'g_setenv("GST_REGISTRY_1.0", "@0@", TRUE);'.format(meson.current_build_dir() + '/gir_empty_registry.reg') + \
 314     'g_setenv("GST_PLUGIN_PATH_1_0", "", TRUE);' + \
 315     'g_setenv("GST_PLUGIN_SYSTEM_PATH_1_0", "", TRUE);' + \
 316     'gst_init(NULL,NULL);' ]
 317
 318 pkgconfig = import('pkgconfig')
 319 plugins_pkgconfig_install_dir = join_paths(plugins_install_dir, 'pkgconfig')
 320 if get_option('default_library') == 'shared'
 321   # If we don't build static plugins there is no need to generate pc files
 322   plugins_pkgconfig_install_dir = disabler()
 323 endif
 324
 325 subdir('gst-libs')
 326 subdir('gst')
 327 subdir('ext')
 328 subdir('sys')
 329 subdir('tools')
 330 subdir('tests')
 331 subdir('pkgconfig')
 332
 333 # xgettext is optional (on Windows for instance)
 334 if get_option('nls') and find_program('xgettext', required : false).found()
 335   subdir('po')
 336 endif
 337
 338 if build_machine.system() == 'windows'
 339   message('Disabling gtk-doc while building on Windows')
 340 elif not get_option('gtkdoc')
 341   message('gtk-doc is disabled via options')
 342 else
 343   if find_program('gtkdoc-scan', required : false).found()
 344     subdir('docs')
 345   else
 346     message('Not building documentation as gtk-doc was not found')
 347   endif
 348 endif
 349
 350 # Use core_conf after all subdirs have set values
 351 configure_file(output : 'config.h', configuration : core_conf)
 352
 353 python3 = import('python3').find_python()
 354 run_command(python3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')