meson.build

   1 project('pulseaudio', 'c', 'cpp',
   2         version : run_command(find_program('git-version-gen'), join_paths(meson.current_source_dir(), '.tarball-version')).stdout().strip(),
   3         meson_version : '>= 0.50.0',
   4         default_options : [ 'c_std=gnu11', 'cpp_std=c++11' ]
   5         )
   6
   7 pa_version_str = meson.project_version()
   8 # For tarballs, the first split will do nothing, but for builds in git, we
   9 # split out suffixes when there are commits since the last tag
  10 # (e.g.: v11.99.1-3-gad14bdb24 -> v11.99.1)
  11 version_split = pa_version_str.split('-')[0].split('.')
  12 pa_version_major = version_split[0].split('v')[0]
  13 pa_version_minor = version_split[1]
  14 if version_split.length() > 2
  15   pa_version_micro = version_split[2]
  16 else
  17   pa_version_micro = '0'
  18 endif
  19 pa_version_major_minor = pa_version_major + '.' + pa_version_minor
  20
  21 pa_api_version = 12
  22 pa_protocol_version = 35
  23
  24 # The stable ABI for client applications, for the version info x:y:z
  25 # always will hold x=z
  26 libpulse_version_info = [23, 0, 23]
  27
  28 # A simplified, synchronous, ABI-stable interface for client
  29 # applications, for the version info x:y:z always will hold x=z
  30 libpulse_simple_version_info = [1, 1, 1]
  31
  32 # The ABI-stable GLib adapter for client applications, for the version
  33 # info x:y:z always will hold x=z
  34 libpulse_mainloop_glib_version_info = [0, 6, 0]
  35
  36 libpulse_version = '@0@.@1@.@2@'.format(
  37   libpulse_version_info[0] - libpulse_version_info[2],
  38   libpulse_version_info[0],
  39   libpulse_version_info[1],
  40 )
  41
  42 libpulse_simple_version = '@0@.@1@.@2@'.format(
  43   libpulse_simple_version_info[0] - libpulse_simple_version_info[2],
  44   libpulse_simple_version_info[0],
  45   libpulse_simple_version_info[1],
  46 )
  47
  48 libpulse_mainloop_glib_version = '@0@.@1@.@2@'.format(
  49   libpulse_mainloop_glib_version_info[0] - libpulse_mainloop_glib_version_info[2],
  50   libpulse_mainloop_glib_version_info[0],
  51   libpulse_mainloop_glib_version_info[1],
  52 )
  53
  54 # Paths
  55
  56 prefix = get_option('prefix')
  57 assert(prefix.startswith('/'), 'Prefix is not absolute: "@0@"'.format(prefix))
  58
  59 bindir = join_paths(prefix, get_option('bindir'))
  60 includedir = join_paths(prefix, get_option('includedir'))
  61 libdir = join_paths(prefix, get_option('libdir'))
  62 libexecdir = join_paths(prefix, get_option('libexecdir'))
  63 mandir = join_paths(prefix, get_option('mandir'))
  64 datadir = join_paths(prefix, get_option('datadir'))
  65 localedir = join_paths(prefix, get_option('localedir'))
  66 localstatedir = join_paths(prefix, get_option('localstatedir'))
  67 sysconfdir = join_paths(prefix, get_option('sysconfdir'))
  68 privlibdir = join_paths(libdir, 'pulseaudio')
  69
  70 alsadatadir = get_option('alsadatadir')
  71 if alsadatadir == ''
  72   alsadatadir = join_paths(datadir, 'pulseaudio', 'alsa-mixer')
  73 endif
  74
  75 pkgconfigdir = join_paths(libdir, 'pkgconfig')
  76 pulselibexecdir = join_paths(libexecdir, 'pulse')
  77 pulsesysconfdir = join_paths(sysconfdir, 'pulse')
  78
  79 modlibexecdir = get_option('modlibexecdir')
  80 if modlibexecdir == ''
  81   modlibexecdir = join_paths(libdir, 'pulse-' + pa_version_major_minor, 'modules')
  82 endif
  83
  84 padsplibdir = get_option('padsplibdir')
  85 if padsplibdir == ''
  86   padsplibdir = privlibdir
  87 endif
  88
  89 pulsedsp_location = get_option('pulsedsp-location')
  90 if pulsedsp_location == ''
  91   pulsedsp_location = join_paths(prefix, padsplibdir)
  92 endif
  93
  94 systemduserunitdir = get_option('systemduserunitdir')
  95 # the default value is set below
  96
  97 udevrulesdir = get_option('udevrulesdir')
  98 if udevrulesdir == ''
  99   # absolute path, otherwise meson prepends the prefix
 100   udevrulesdir = '/lib/udev/rules.d'
 101 endif
 102
 103 vapidir = join_paths(datadir, 'vala', 'vapi')
 104
 105 bashcompletiondir = get_option('bashcompletiondir')
 106 if bashcompletiondir == ''
 107   bash_completion_dep = dependency('bash-completion', required : false)
 108   if bash_completion_dep.found()
 109     bashcompletiondir = bash_completion_dep.get_pkgconfig_variable('completionsdir')
 110   else
 111     bashcompletiondir = join_paths(datadir, 'bash-completion', 'completions')
 112   endif
 113 endif
 114
 115 zshcompletiondir = get_option('zshcompletiondir')
 116 if zshcompletiondir == ''
 117   zshcompletiondir = join_paths(datadir, 'zsh', 'site-functions')
 118 endif
 119
 120 # Configuration data
 121
 122 cc = meson.get_compiler('c')
 123
 124 cdata = configuration_data()
 125 cdata.set_quoted('PACKAGE', 'pulseaudio')
 126 cdata.set_quoted('PACKAGE_NAME', 'pulseaudio')
 127 cdata.set_quoted('PACKAGE_VERSION', pa_version_str)
 128 cdata.set_quoted('CANONICAL_HOST', target_machine.cpu_family())
 129 cdata.set('PA_MAJOR', pa_version_major)
 130 cdata.set('PA_MINOR', pa_version_minor)
 131 cdata.set('PA_API_VERSION', pa_api_version)
 132 cdata.set('PA_PROTOCOL_VERSION', pa_protocol_version)
 133 cdata.set_quoted('PA_MACHINE_ID', join_paths(sysconfdir, 'machine-id'))
 134 cdata.set_quoted('PA_MACHINE_ID_FALLBACK', join_paths(localstatedir, 'lib', 'dbus', 'machine-id'))
 135 cdata.set_quoted('PA_SRCDIR', join_paths(meson.current_source_dir(), 'src'))
 136 cdata.set_quoted('PA_BUILDDIR', meson.current_build_dir())
 137 cdata.set_quoted('PA_SOEXT', '.so')
 138 cdata.set_quoted('PA_DEFAULT_CONFIG_DIR', pulsesysconfdir)
 139 cdata.set('PA_DEFAULT_CONFIG_DIR_UNQUOTED', pulsesysconfdir)
 140 cdata.set_quoted('PA_BINARY', join_paths(bindir, 'pulseaudio'))
 141 cdata.set_quoted('PA_SYSTEM_RUNTIME_PATH', join_paths(localstatedir, 'run', 'pulse'))
 142 cdata.set_quoted('PA_SYSTEM_CONFIG_PATH', join_paths(localstatedir, 'lib', 'pulse'))
 143 cdata.set_quoted('PA_SYSTEM_STATE_PATH', join_paths(localstatedir, 'lib', 'pulse'))
 144 cdata.set_quoted('PA_DLSEARCHPATH', modlibexecdir)
 145 cdata.set_quoted('PA_SYSTEM_USER', get_option('system_user'))
 146 cdata.set_quoted('PA_SYSTEM_GROUP', get_option('system_group'))
 147 cdata.set_quoted('PA_ACCESS_GROUP', get_option('access_group'))
 148 cdata.set_quoted('PA_CFLAGS', 'Not yet supported on meson')
 149 cdata.set_quoted('PA_ALSA_PATHS_DIR', join_paths(alsadatadir, 'paths'))
 150 cdata.set_quoted('PA_ALSA_PROFILE_SETS_DIR', join_paths(alsadatadir, 'profile-sets'))
 151 cdata.set_quoted('DESKTOPFILEDIR', join_paths(datadir, 'applications'))
 152 cdata.set_quoted('PULSE_LOCALEDIR', localedir)
 153 cdata.set_quoted('GETTEXT_PACKAGE', 'pulseaudio')
 154 cdata.set('ENABLE_NLS', 1)
 155 cdata.set('top_srcdir', meson.source_root())
 156
 157 # Platform specifics
 158 # First some defaults to keep config file generation happy
 159 cdata.set('HAVE_COREAUDIO', 0)
 160 cdata.set('HAVE_WAVEOUT', 0)
 161 # FIXME: This was not tested. Maybe some flags should better be CFLAGS,
 162 # rather than ending up in the config.h file?
 163 if host_machine.system() == 'darwin'
 164   cdata.set('OS_IS_DARWIN', 1)
 165   cdata.set('_DARWIN_C_SOURCE', '200112L') # Needed to get NSIG on Mac OS
 166 elif host_machine.system() == 'windows'
 167   cdata.set('OS_IS_WIN32', 1)
 168   cdata.set('WIN32_LEAN_AND_MEAN', 1) # Needed to avoid including unnecessary headers on Windows
 169 #elif host_machine.system() == 'solaris'
 170 #  # Apparently meson has no solaris support?
 171 #  # Needed to get declarations for msg_control and msg_controllen on Solaris
 172 #  cdata.set('_XOPEN_SOURCE', 600)
 173 #  cdata.set('__EXTENSIONS__', 1)
 174 endif
 175
 176 if cc.has_type('_Bool')
 177   cdata.set('HAVE_STD_BOOL', 1)
 178 endif
 179
 180 if host_machine.cpu_family() == 'x86_64' or cc.sizeof('void *') >= 8
 181   cdata.set('HAVE_FAST_64BIT_OPERATIONS', 1)
 182 endif
 183
 184 # Headers
 185
 186 check_headers = [
 187   'arpa/inet.h',
 188   'byteswap.h',
 189   'cpuid.h',
 190   'dlfcn.h',
 191   'execinfo.h',
 192   'grp.h',
 193   'langinfo.h',
 194   'linux/sockios.h',
 195   'locale.h',
 196   'netdb.h',
 197   'netinet/in.h',
 198   'netinet/in_systm.h',
 199   'netinet/ip.h',
 200   'netinet/tcp.h',
 201   'pcreposix.h',
 202   'poll.h',
 203   'pwd.h',
 204   'regex.h',
 205   'sched.h',
 206   'stdint.h',
 207   'sys/atomic.h',
 208   'sys/capability.h',
 209   'sys/conf.h',
 210   'sys/dl.h',
 211   'sys/eventfd.h',
 212   'sys/filio.h',
 213   'sys/ioctl.h',
 214   'sys/mman.h',
 215   'sys/prctl.h',
 216   'sys/resource.h',
 217   'sys/select.h',
 218   'sys/socket.h',
 219   'sys/syscall.h',
 220   'sys/uio.h',
 221   'sys/un.h',
 222   'sys/wait.h',
 223   'syslog.h',
 224   'xlocale.h',
 225 ]
 226
 227 foreach h : check_headers
 228   if cc.has_header(h)
 229     define = 'HAVE_' + h.underscorify().to_upper()
 230     cdata.set(define, 1)
 231   endif
 232 endforeach
 233
 234 if cc.has_header('valgrind/memcheck.h', required: get_option('valgrind'))
 235   cdata.set('HAVE_VALGRIND_MEMCHECK_H', 1)
 236 endif
 237
 238 # FIXME: move this to the above set
 239 if cc.has_header('pthread.h')
 240   cdata.set('HAVE_PTHREAD', 1)
 241 endif
 242
 243 if cc.has_header_symbol('pthread.h', 'PTHREAD_PRIO_INHERIT')
 244   cdata.set('HAVE_PTHREAD_PRIO_INHERIT', 1)
 245 endif
 246
 247 # Functions
 248
 249 check_functions = [
 250   'accept4',
 251   'clock_gettime',
 252   'ctime_r',
 253   'fchmod',
 254   'fchown',
 255   'fork',
 256   'fstat',
 257   'getaddrinfo',
 258   'getgrgid_r',
 259   'getgrnam_r',
 260   'getpwnam_r',
 261   'getpwuid_r',
 262   'gettimeofday',
 263   'getuid',
 264   'lrintf',
 265   'lstat',
 266   'memfd_create',
 267   'mkfifo',
 268   'mlock',
 269   'nanosleep',
 270   'open64',
 271   'paccept',
 272   'pipe',
 273   'pipe2',
 274   'posix_fadvise',
 275   'posix_madvise',
 276   'posix_memalign',
 277   'ppoll',
 278   'readlink',
 279   'setegid',
 280   'seteuid',
 281   'setpgid',
 282   'setregid',
 283   'setresgid',
 284   'setresuid',
 285   'setreuid',
 286   'setsid',
 287   'sig2str',
 288   'sigaction',
 289   'strerror_r',
 290   'strtod_l',
 291   'strtof',
 292   'symlink',
 293   'sysconf',
 294   'uname',
 295 ]
 296
 297 foreach f : check_functions
 298   if cc.has_function(f)
 299     define = 'HAVE_' + f.underscorify().to_upper()
 300     cdata.set(define, 1)
 301   endif
 302 endforeach
 303
 304 if cc.has_header_symbol('sys/syscall.h', 'SYS_memfd_create')
 305   cdata.set('HAVE_MEMFD', 1)
 306 endif
 307
 308 if cc.has_function('dgettext')
 309   libintl_dep = []
 310 else
 311   libintl_dep = cc.find_library('intl')
 312 endif
 313
 314 # Symbols
 315
 316 if cc.has_header_symbol('signal.h', 'SIGXCPU')
 317   cdata.set('HAVE_SIGXCPU', 1)
 318 endif
 319
 320 if not cc.has_header_symbol('netinet/in.h', 'INADDR_NONE')
 321   if not cc.has_header_symbol('winsock2.h', 'INADDR_NONE')
 322     # Define INADDR_NONE if not found (Solaris)
 323     cdata.set('INADDR_NONE', '0xffffffff')
 324   endif
 325 endif
 326
 327 check_decls = [
 328   [ 'environ', 'unistd.h', '#define _GNU_SOURCE' ],
 329   [ 'SOUND_PCM_READ_RATE', 'sys/soundcard.h', '' ],
 330   [ 'SOUND_PCM_READ_CHANNELS', 'sys/soundcard.h', '' ],
 331   [ 'SOUND_PCM_READ_BITS', 'sys/soundcard.h', '' ],
 332 ]
 333
 334 foreach s : check_decls
 335   if cc.has_header_symbol(s[1], s[0], prefix : s[2])
 336     define = 'HAVE_DECL_' + s[0].to_upper()
 337     cdata.set(define, 1)
 338   endif
 339 endforeach
 340
 341 # Types
 342
 343 # FIXME: do we ever care about gid_t not being defined / smaller than an int?
 344 cdata.set('GETGROUPS_T', 'gid_t')
 345
 346 # Include paths
 347
 348 configinc = include_directories('.')
 349 topinc = include_directories('src')
 350
 351 # CFLAGS/LDFLAGS
 352
 353 pa_c_args = ['-DHAVE_CONFIG_H', '-D_GNU_SOURCE']
 354 server_c_args = ['-D__INCLUDED_FROM_PULSE_AUDIO']
 355 cdata.set('MESON_BUILD', 1)
 356
 357 # On ELF systems we don't want the libraries to be unloaded since we don't clean them up properly,
 358 # so we request the nodelete flag to be enabled.
 359 # On other systems, we don't really know how to do that, but it's welcome if somebody can tell.
 360 nodelete_link_args = ['-Wl,-z,nodelete']
 361
 362 # Code coverage
 363
 364 if get_option('gcov')
 365   add_project_arguments('--coverage', language: ['c', 'cpp'])
 366   add_project_link_arguments('--coverage', language: ['c', 'cpp'])
 367 endif
 368
 369 # Core Dependencies
 370
 371 libm_dep = cc.find_library('m', required : true)
 372
 373 thread_dep = dependency('threads')
 374 foreach f : [
 375   'pthread_getname_np',
 376   'pthread_setaffinity_np',
 377   'pthread_setname_np',
 378 ]
 379   if cc.has_function(f, dependencies : thread_dep)
 380     define = 'HAVE_' + f.underscorify().to_upper()
 381     cdata.set(define, 1)
 382   endif
 383 endforeach
 384
 385 cap_dep = cc.find_library('cap', required : false)
 386
 387 shm_dep = cc.find_library('rt', required : false)
 388 if shm_dep.found()
 389   cdata.set('HAVE_SHM_OPEN', 1)
 390 endif
 391
 392 dl_dep = cc.find_library('dl', required : false)
 393 if dl_dep.found()
 394   cdata.set('HAVE_DLADDR', 1)
 395 endif
 396
 397 have_iconv = false
 398 if cc.has_function('iconv_open')
 399   iconv_dep = dependency('', required : false)
 400   have_iconv = true
 401 else
 402   iconv_dep = cc.find_library('iconv', required : false)
 403   have_iconv = iconv_dep.found()
 404 endif
 405 if have_iconv
 406   cdata.set('HAVE_ICONV', 1)
 407   iconvconsttest = '''#include <iconv.h>
 408 size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 409 '''
 410   if cc.compiles(iconvconsttest, dependencies : iconv_dep)
 411     cdata.set('ICONV_CONST', '')
 412   else
 413     cdata.set('ICONV_CONST', 'const')
 414   endif
 415 endif
 416
 417 # Atomic operations
 418
 419 if get_option('atomic-arm-memory-barrier')
 420     cdata.set('ATOMIC_ARM_MEMORY_BARRIER_ENABLED', 1)
 421 endif
 422
 423 need_libatomic_ops = false
 424
 425 atomictest = '''void func() {
 426   volatile int atomic = 2;
 427   __sync_bool_compare_and_swap (&atomic, 2, 3);
 428 }
 429 '''
 430
 431 if cc.compiles(atomictest)
 432   cdata.set('HAVE_ATOMIC_BUILTINS', 1)
 433
 434   newatomictest = '''void func() {
 435     int c = 0;
 436     __atomic_store_n(&c, 4, __ATOMIC_SEQ_CST);
 437   }
 438   '''
 439
 440   if(cc.compiles(newatomictest))
 441     cdata.set('HAVE_ATOMIC_BUILTINS_MEMORY_MODEL', 1)
 442   endif
 443
 444 elif host_machine.cpu_family() == 'arm'
 445   if host_machine.system() == 'linux' and get_option('atomic-arm-linux-helpers')
 446     cdata.set('ATOMIC_ARM_LINUX_HELPERS', 1)
 447   else
 448     armatomictest = '''int func() {
 449       volatile int a=0;
 450       int o=0, n=1, r;
 451       asm volatile (
 452               "ldrex    %0, [%1]\n"
 453               "subs  %0, %0, %2\n"
 454               "strexeq %0, %3, [%1]\n"
 455               : "=&r" (r)
 456               : "r" (&a), "Ir" (o), "r" (n)
 457       : "cc");
 458       return (a==1 ? 0 : -1);
 459     }
 460     '''
 461
 462     if cc.compiles(armatomictest)
 463       cdata.set('ATOMIC_ARM_INLINE_ASM', 1)
 464     else
 465       need_libatomic_ops = true
 466     endif
 467   endif # arm && !linux
 468
 469 elif not ['freebsd', 'netbsd'].contains(host_machine.system())
 470   need_libatomic_ops = true
 471 endif # !atomic helpers && !arm
 472
 473 if need_libatomic_ops
 474   assert(cc.has_header('atomic_ops.h'), 'Need libatomic_ops')
 475
 476   cdata.set('AO_REQUIRE_CAS', 1)
 477
 478   if host_machine.system() != 'windows'
 479     libatomic_ops_dep = cc.find_library('atomic_ops', required : true)
 480   else
 481     libatomic_ops_dep = dependency('', required: false)
 482   endif
 483 else
 484   libatomic_ops_dep = dependency('', required: false)
 485 endif
 486
 487 # ARM checks
 488 # ARMV6 instructions we need
 489 if host_machine.cpu_family() == 'arm'
 490   armv6test = '''int func() {
 491     volatile int a = -60000, b = 0xaaaabbbb, c = 0xccccdddd;
 492     asm volatile ("ldr r0, %2 \n"
 493                   "ldr r2, %3 \n"
 494                   "ldr r3, %4 \n"
 495                   "ssat r1, #8, r0 \n"
 496                   "str r1, %0 \n"
 497                   "pkhbt r1, r3, r2, LSL #8 \n"
 498                   "str r1, %1 \n"
 499                   : "=m" (a), "=m" (b)
 500                   : "m" (a), "m" (b), "m" (c)
 501                   : "r0", "r1", "r2", "r3", "cc");
 502     return (a == -128 && b == 0xaabbdddd) ? 0 : -1;
 503   }
 504   '''
 505
 506   if cc.compiles(armv6test)
 507     cdata.set('HAVE_ARMV6', 1)
 508   endif
 509 endif
 510 # NEON checks are automatically done by the unstable-simd module
 511
 512 # FIXME: make sure it's >= 2.2
 513 ltdl_dep = cc.find_library('ltdl', required : true)
 514 # FIXME: can meson support libtool -dlopen/-dlpreopen things?
 515 #        and do we still want to support this at all?
 516 cdata.set('DISABLE_LIBTOOL_PRELOAD', 1)
 517
 518 if get_option('database') == 'tdb'
 519   database_dep = dependency('tdb')
 520 elif get_option('database') == 'gdbm'
 521   database_dep = cc.find_library('gdbm', required : true)
 522 else
 523   database_dep = dependency('', required: false)
 524 endif
 525
 526 if get_option('ipv6')
 527   cdata.set('HAVE_IPV6', 1)
 528 endif
 529
 530 if get_option('legacy-database-entry-format')
 531   cdata.set('ENABLE_LEGACY_DATABASE_ENTRY_FORMAT', 1)
 532 endif
 533
 534 if get_option('stream-restore-clear-old-devices')
 535   cdata.set('STREAM_RESTORE_CLEAR_OLD_DEVICES', 1)
 536 endif
 537
 538 if get_option('running-from-build-tree')
 539   cdata.set('HAVE_RUNNING_FROM_BUILD_TREE', 1)
 540 endif
 541
 542 alsa_dep = dependency('alsa', version : '>= 1.0.24', required : get_option('alsa'))
 543 if alsa_dep.found()
 544   cdata.set('HAVE_ALSA', 1)
 545   cdata.set('HAVE_ALSA_UCM', 1)
 546 endif
 547
 548 asyncns_dep = dependency('libasyncns', version : '>= 0.1', required : get_option('asyncns'))
 549 if asyncns_dep.found()
 550   cdata.set('HAVE_LIBASYNCNS', 1)
 551 endif
 552
 553 dbus_dep = dependency('dbus-1', version : '>= 1.4.12', required : get_option('dbus'))
 554 if dbus_dep.found()
 555   cdata.set('HAVE_DBUS', 1)
 556 endif
 557
 558 gio_dep = dependency('gio-2.0', version : '>= 2.26.0', required : get_option('gsettings'))
 559 if gio_dep.found()
 560   cdata.set('HAVE_GSETTINGS', 1)
 561 endif
 562
 563 glib_dep = dependency('glib-2.0', version : '>= 2.28.0', required: get_option('glib'))
 564 if glib_dep.found()
 565   cdata.set('HAVE_GLIB', 1)
 566 endif
 567
 568 gtk_dep = dependency('gtk+-3.0', required : get_option('gtk'))
 569 if gtk_dep.found()
 570   cdata.set('HAVE_GTK', 1)
 571 endif
 572
 573 have_orcc = false
 574 orcc_args = []
 575 orc_dep = dependency('orc-0.4', version : '>= 0.4.11', required : get_option('orc'))
 576 orcc = find_program('orcc', required : get_option('orc'))
 577 if orc_dep.found() and orcc.found()
 578   have_orcc = true
 579   orcc_args = [orcc]
 580   #orcc_args = [orcc, '--include', 'glib.h']
 581   cdata.set('HAVE_ORC', 1)
 582 else
 583   cdata.set('DISABLE_ORC', 1)
 584 endif
 585
 586 samplerate_dep = dependency('samplerate', version : '>= 0.1.0', required : get_option('samplerate'))
 587 if samplerate_dep.found()
 588   cdata.set('HAVE_LIBSAMPLERATE', 1)
 589 endif
 590
 591 sndfile_dep = dependency('sndfile', version : '>= 1.0.20')
 592
 593 soxr_dep = dependency('soxr', version : '>= 0.1.1', required : get_option('soxr'))
 594 if soxr_dep.found()
 595   cdata.set('HAVE_SOXR', 1)
 596 endif
 597
 598 libsystemd_dep = dependency('libsystemd', required : get_option('systemd'))
 599 if libsystemd_dep.found()
 600   cdata.set('HAVE_SYSTEMD_DAEMON', 1)
 601   cdata.set('HAVE_SYSTEMD_LOGIN', 1)
 602   cdata.set('HAVE_SYSTEMD_JOURNAL', 1)
 603 endif
 604 systemd_dep = dependency('systemd', required : get_option('systemd'))
 605 if systemd_dep.found() and systemduserunitdir == ''
 606   systemduserunitdir = systemd_dep.get_pkgconfig_variable('systemduserunitdir')
 607 endif
 608
 609 x11_dep = dependency('x11-xcb', required : get_option('x11'))
 610 if x11_dep.found()
 611   xcb_dep  = dependency('xcb',  required : true, version : '>= 1.6')
 612   ice_dep  = dependency('ice',  required : true)
 613   sm_dep   = dependency('sm',   required : true)
 614   xtst_dep = dependency('xtst', required : true)
 615   cdata.set('HAVE_X11', 1)
 616 endif
 617
 618 # Module dependencies
 619 if cc.has_header('sys/soundcard.h', required: get_option('oss-output'))
 620   cdata.set('HAVE_OSS_OUTPUT', 1)
 621   cdata.set('HAVE_OSS_WRAPPER', 1)
 622   cdata.set('PULSEDSP_LOCATION', pulsedsp_location)
 623 endif
 624
 625 if get_option('hal-compat')
 626   cdata.set('HAVE_HAL_COMPAT', 1)
 627 endif
 628
 629 avahi_dep = dependency('avahi-client', version : '>= 0.6.0', required : get_option('avahi'), disabler : true)
 630 if avahi_dep.found()
 631   cdata.set('HAVE_AVAHI', 1)
 632 endif
 633
 634 sbc_dep = dependency('sbc', version : '>= 1.0', required : false)
 635 if get_option('bluez5')
 636   assert(dbus_dep.found(), 'BlueZ requires D-Bus support')
 637   assert(sbc_dep.found(), 'BlueZ requires SBC support')
 638   cdata.set('HAVE_SBC', 1)
 639   cdata.set('HAVE_BLUEZ', 1)
 640   cdata.set('HAVE_BLUEZ_5', 1)
 641   if get_option('bluez5-native-headset')
 642     cdata.set('HAVE_BLUEZ_5_NATIVE_HEADSET', 1)
 643   endif
 644   if get_option('bluez5-ofono-headset')
 645     cdata.set('HAVE_BLUEZ_5_OFONO_HEADSET', 1)
 646   endif
 647 endif
 648
 649 fftw_dep = dependency('fftw3f', required : get_option('fftw'))
 650 if fftw_dep.found()
 651   cdata.set('HAVE_FFTW', 1)
 652 endif
 653
 654 jack_dep = dependency('jack', version : '>= 0.117.0', required : get_option('jack'))
 655 if jack_dep.found()
 656   cdata.set('HAVE_JACK', 1)
 657 endif
 658
 659 lirc_dep = dependency('lirc', required : get_option('lirc'))
 660 if lirc_dep.found()
 661   cdata.set('HAVE_LIRC', 1)
 662 endif
 663
 664 openssl_dep = dependency('openssl', version : '>= 0.9', required : get_option('openssl'))
 665 if openssl_dep.found()
 666   cdata.set('HAVE_OPENSSL', 1)
 667 endif
 668
 669 speex_dep = dependency('speexdsp', version : '>= 1.2', required : get_option('speex'))
 670 if speex_dep.found()
 671   cdata.set('HAVE_SPEEX', 1)
 672 endif
 673
 674 udev_dep = dependency('libudev', version : '>= 143', required : get_option('udev'))
 675 if udev_dep.found()
 676   cdata.set('HAVE_UDEV', 1)
 677 endif
 678
 679 webrtc_dep = dependency('webrtc-audio-processing', version : '>= 0.2', required : get_option('webrtc-aec'))
 680 if webrtc_dep.found()
 681   cdata.set('HAVE_WEBRTC', 1)
 682 endif
 683
 684 gst_dep = dependency('gstreamer-1.0', version : '>= 1.14', required : get_option('gstreamer'))
 685 gstapp_dep = dependency('gstreamer-app-1.0', required : get_option('gstreamer'))
 686 gstrtp_dep = dependency('gstreamer-rtp-1.0', required : get_option('gstreamer'))
 687
 688 have_gstreamer = false
 689 if gst_dep.found() and gstapp_dep.found() and gstrtp_dep.found()
 690   have_gstreamer = true
 691 endif
 692
 693 # These are required for the CMake file generation
 694 cdata.set('PA_LIBDIR', libdir)
 695 cdata.set('PA_INCDIR', includedir)
 696 if glib_dep.found()
 697   cdata.set('HAVE_GLIB20', 1) # to match the AM_CONDITIONAL for CMake file generation
 698 endif
 699
 700 # Test dependencies
 701
 702 check_dep = dependency('check', version : '>= 0.9.10', required : get_option('tests'))
 703
 704 # Subdirs
 705
 706 subdir('doxygen')
 707 subdir('po')
 708 if get_option('man')
 709   subdir('man')
 710 endif
 711 subdir('shell-completion/bash')
 712 subdir('shell-completion/zsh')
 713 subdir('src')
 714 subdir('vala')
 715
 716 # Now generate config.h from everything above
 717 configure_file(output : 'config.h', configuration : cdata)
 718
 719 # pkg-config files
 720
 721 pc_cdata = configuration_data()
 722
 723 pc_cdata.set('prefix', prefix)
 724 pc_cdata.set('exec_prefix', prefix)
 725 pc_cdata.set('libdir', libdir)
 726 pc_cdata.set('includedir', includedir)
 727 pc_cdata.set('modlibexecdir', modlibexecdir)
 728 pc_cdata.set('PACKAGE_VERSION', pa_version_str)
 729 pc_cdata.set('PA_MAJORMINOR', pa_version_major_minor)
 730 # FIXME: the line below is wrong. Currently the meson thread dep lacks documentation,
 731 # and doesn't allow introspection, ie. none of get_pkgconfig_variable() or
 732 # get_configtool_variable() work with it, so we have no way to get this flag right,
 733 # unless we do all the work ourselves. See current work in glib, also meson #553.
 734 pc_cdata.set('PTHREAD_LIBS', '-pthread')
 735
 736 pc_files = [
 737   'libpulse.pc',
 738   'libpulse-simple.pc',
 739 ]
 740
 741 if glib_dep.found()
 742   pc_files += 'libpulse-mainloop-glib.pc'
 743 endif
 744
 745 foreach file : pc_files
 746   configure_file(
 747     input : file + '.in',
 748     output : file,
 749     configuration : pc_cdata,
 750     install_dir : pkgconfigdir)
 751 endforeach
 752
 753 # CMake files
 754
 755 m4 = find_program('m4', required: true)
 756
 757 cmakedir = join_paths(libdir, 'cmake', 'PulseAudio')
 758
 759 cmake_template_file = configure_file(
 760   input : 'PulseAudioConfig.cmake.in',
 761   output : 'PulseAudioConfig.cmake.tmp',
 762   configuration: cdata,
 763 )
 764
 765 custom_target('PulseAudioConfig.cmake',
 766   input : cmake_template_file,
 767   output : 'PulseAudioConfig.cmake',
 768   capture : true,
 769   command : [m4, '@INPUT@'],
 770   build_by_default : true,
 771   install : true,
 772   install_dir : cmakedir,
 773 )
 774
 775 configure_file(
 776   input : 'PulseAudioConfigVersion.cmake.in',
 777   output : 'PulseAudioConfigVersion.cmake',
 778   configuration: cdata,
 779   install : true,
 780   install_dir : cmakedir,
 781 )
 782
 783 ############################################################
 784
 785 # Final summary
 786
 787 summary = [
 788   '',
 789   '---{ @0@ @1@ }---'.format(meson.project_name(), meson.project_version()),
 790   '',
 791   'prefix:                        @0@'.format(prefix),
 792   'bindir:                        @0@'.format(bindir),
 793   'libdir:                        @0@'.format(libdir),
 794   'libexecdir:                    @0@'.format(libexecdir),
 795   'mandir:                        @0@'.format(mandir),
 796   'datadir:                       @0@'.format(datadir),
 797   'sysconfdir:                    @0@'.format(sysconfdir),
 798   'localstatedir:                 @0@'.format(localstatedir),
 799   'modlibexecdir:                 @0@'.format(modlibexecdir),
 800   'alsadatadir:                   @0@'.format(alsadatadir),
 801   'System Runtime Path:           @0@'.format(cdata.get_unquoted('PA_SYSTEM_RUNTIME_PATH')),
 802   'System State Path:             @0@'.format(cdata.get_unquoted('PA_SYSTEM_STATE_PATH')),
 803   'System Config Path:            @0@'.format(cdata.get_unquoted('PA_SYSTEM_CONFIG_PATH')),
 804   'Bash completions directory:    @0@'.format(bashcompletiondir),
 805   'Zsh completions directory:     @0@'.format(zshcompletiondir),
 806   'Compiler:                      @0@ @1@'.format(cc.get_id(), cc.version()),
 807 #  'CFLAGS:                        @0@'.format(${CFLAGS}),
 808 #  'CPPFLAGS:                      @0@'.format(${CPPFLAGS}),
 809 #  'LIBS:                          @0@'.format(${LIBS}),
 810   '',
 811   'Enable memfd shared memory:    @0@'.format(cdata.has('HAVE_MEMFD')),
 812   'Enable X11:                    @0@'.format(x11_dep.found()),
 813   'Enable OSS Output:             @0@'.format(cdata.has('HAVE_OSS_OUTPUT')),
 814   'Enable OSS Wrapper:            @0@'.format(cdata.has('HAVE_OSS_WRAPPER')),
 815 #  'Enable EsounD:                 @0@'.format(${ENABLE_ESOUND}),
 816   'Enable Alsa:                   @0@'.format(alsa_dep.found()),
 817 #  'Enable CoreAudio:              @0@'.format(${ENABLE_COREAUDIO}),
 818 #  'Enable Solaris:                @0@'.format(${ENABLE_SOLARIS}),
 819 #  'Enable WaveOut:                @0@'.format(${ENABLE_WAVEOUT}),
 820   'Enable GLib 2:                 @0@'.format(glib_dep.found()),
 821 #  'Enable GConf:                  @0@'.format(${ENABLE_GCONF}),
 822   'Enable GSettings:              @0@'.format(gio_dep.found()),
 823   'Enable Gtk+ 3:                 @0@'.format(gtk_dep.found()),
 824   'Enable Avahi:                  @0@'.format(avahi_dep.found()),
 825   'Enable Jack:                   @0@'.format(jack_dep.found()),
 826   'Enable Async DNS:              @0@'.format(asyncns_dep.found()),
 827   'Enable LIRC:                   @0@'.format(lirc_dep.found()),
 828   'Enable D-Bus:                  @0@'.format(dbus_dep.found()),
 829   '  Enable BlueZ 5:              @0@'.format(get_option('bluez5')),
 830   '    Enable native headsets:    @0@'.format(get_option('bluez5-native-headset')),
 831   '    Enable  ofono headsets:    @0@'.format(get_option('bluez5-ofono-headset')),
 832   'Enable udev:                   @0@'.format(udev_dep.found()),
 833   '  Enable HAL->udev compat:     @0@'.format(get_option('hal-compat')),
 834   'Enable systemd:                @0@'.format(libsystemd_dep.found()),
 835 #  'Enable TCP Wrappers:           @0@'.format(${ENABLE_TCPWRAP}),
 836   'Enable libsamplerate:          @0@'.format(samplerate_dep.found()),
 837   'Enable IPv6:                   @0@'.format(get_option('ipv6')),
 838   'Enable OpenSSL (for Airtunes): @0@'.format(openssl_dep.found()),
 839   'Enable FFTW:                   @0@'.format(fftw_dep.found()),
 840   'Enable ORC:                    @0@'.format(have_orcc),
 841   'Enable GStreamer:              @0@'.format(have_gstreamer),
 842   'Enable Adrian echo canceller:  @0@'.format(get_option('adrian-aec')),
 843   'Enable Speex (resampler, AEC): @0@'.format(speex_dep.found()),
 844   'Enable SoXR (resampler):       @0@'.format(soxr_dep.found()),
 845   'Enable WebRTC echo canceller:  @0@'.format(webrtc_dep.found()),
 846   'Enable Gcov coverage:          @0@'.format(get_option('gcov')),
 847   'Enable Valgrind:               @0@'.format(cdata.has('HAVE_VALGRIND_MEMCHECK_H')),
 848   'Enable man pages:              @0@'.format(get_option('man')),
 849   'Enable unit tests:             @0@'.format(get_option('tests')),
 850   '',
 851   'Database:                      @0@'.format(get_option('database')),
 852   'Legacy Database Entry Support: @0@'.format(get_option('legacy-database-entry-format')),
 853   'module-stream-restore:',
 854   '  Clear old devices:           @0@'.format(get_option('stream-restore-clear-old-devices')),
 855   'Running from build tree:       @0@'.format(get_option('running-from-build-tree')),
 856   'System User:                   @0@'.format(cdata.get_unquoted('PA_SYSTEM_USER')),
 857   'System Group:                  @0@'.format(cdata.get_unquoted('PA_SYSTEM_GROUP')),
 858   'Access Group:                  @0@'.format(cdata.get_unquoted('PA_ACCESS_GROUP')),
 859 #  'Enable per-user EsounD socket: @0@'.format(${ENABLE_PER_USER_ESOUND_SOCKET}),
 860 #  'Force preopen:                 @0@'.format(${FORCE_PREOPEN}),
 861 #  'Preopened modules:             @0@'.format(${PREOPEN_MODS}),
 862 ]
 863
 864 message('\n    '.join(summary))
 865
 866 # Sanity checks
 867
 868 if not speex_dep.found() and not webrtc_dep.found() and not get_option('adrian-aec')
 869   error('At least one echo canceller implementation must be available!')
 870 endif
 871
 872 if samplerate_dep.found()
 873   warning('Support for libsamplerate is DEPRECATED')
 874 endif
 875
 876 if host_machine.system() != 'windows'
 877   if not dbus_dep.found()
 878     message = [
 879       'You do not have D-Bus support enabled. It is strongly recommended',
 880       'that you enable D-Bus support if your platform supports it.',
 881       'Many parts of PulseAudio use D-Bus, from ConsoleKit interaction',
 882       'to the Device Reservation Protocol to speak to JACK, Bluetooth',
 883       'support and even a native control protocol for communicating and',
 884       'controlling the PulseAudio daemon itself.',
 885     ]
 886     warning('\n' + '\n'.join(message))
 887   endif
 888   if not udev_dep.found()
 889     message = [
 890       'You do not have udev support enabled. It is strongly recommended',
 891       'that you enable udev support if your platform supports it as it is',
 892       'the primary method used to detect hardware audio devices (on Linux)',
 893       'and is thus a critical part of PulseAudio on that platform.',
 894     ]
 895     warning('\n' + '\n'.join(message))
 896   endif
 897   if not speex_dep.found()
 898     message = [
 899       'You do not have speex support enabled. It is strongly recommended',
 900       'that you enable speex support if your platform supports it as it is',
 901       'the primary method used for audio resampling and is thus a critical',
 902       'part of PulseAudio on that platform.',
 903     ]
 904     warning('\n' + '\n'.join(message))
 905   endif
 906 endif