meson.build

   1 project('gst-plugins-base', 'c',
   2   version : '1.17.0.1',
   3   meson_version : '>= 0.48',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0].to_int()
  10 gst_version_minor = version_arr[1].to_int()
  11 gst_version_micro = version_arr[2].to_int()
  12 if version_arr.length() == 4
  13   gst_version_nano = version_arr[3].to_int()
  14 else
  15   gst_version_nano = 0
  16 endif
  17 gst_version_is_dev = gst_version_minor % 2 == 1 and gst_version_micro < 90
  18
  19 have_cxx = add_languages('cpp', required : false)
  20 have_objc = add_languages('objc', required : false)
  21
  22 glib_req = '>= 2.44.0'
  23 orc_req = '>= 0.4.24'
  24 gst_req = '>= @0@.@1@.0'.format(gst_version_major, gst_version_minor)
  25
  26 api_version = '1.0'
  27 soversion = 0
  28 # maintaining compatibility with the previous libtool versioning
  29 # current = minor * 100 + micro
  30 curversion = gst_version_minor * 100 + gst_version_micro
  31 libversion = '@0@.@1@.0'.format(soversion, curversion)
  32 osxversion = curversion + 1
  33
  34 plugins_install_dir = join_paths(get_option('libdir'), 'gstreamer-1.0')
  35 plugins = []
  36
  37 cc = meson.get_compiler('c')
  38 host_system = host_machine.system()
  39
  40 if cc.get_id() == 'msvc'
  41   # Ignore several spurious warnings for things gstreamer does very commonly
  42   # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  43   # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  44   # NOTE: Only add warnings here if you are sure they're spurious
  45   add_project_arguments(
  46       '/wd4018', # implicit signed/unsigned conversion
  47       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  48       '/wd4244', # lossy type conversion (e.g. double -> int)
  49       '/wd4305', # truncating type conversion (e.g. double -> float)
  50       cc.get_supported_arguments(['/utf-8']), # set the input encoding to utf-8
  51       language : 'c')
  52   # Disable SAFESEH with MSVC for plugins and libs that use external deps that
  53   # are built with MinGW
  54   noseh_link_args = ['/SAFESEH:NO']
  55 else
  56   noseh_link_args = []
  57 endif
  58
  59 if cc.has_link_argument('-Wl,-Bsymbolic-functions')
  60   add_project_link_arguments('-Wl,-Bsymbolic-functions', language : 'c')
  61 endif
  62
  63 core_conf = configuration_data()
  64
  65 # Symbol visibility
  66 if cc.get_id() == 'msvc'
  67   export_define = '__declspec(dllexport) extern'
  68 elif cc.has_argument('-fvisibility=hidden')
  69   add_project_arguments('-fvisibility=hidden', language: 'c')
  70   if have_objc
  71     add_project_arguments('-fvisibility=hidden', language: 'objc')
  72   endif
  73   export_define = 'extern __attribute__ ((visibility ("default")))'
  74 else
  75   export_define = 'extern'
  76 endif
  77
  78 # Passing this through the command line would be too messy
  79 core_conf.set('GST_API_EXPORT', export_define)
  80
  81 # Disable strict aliasing
  82 if cc.has_argument('-fno-strict-aliasing')
  83   add_project_arguments('-fno-strict-aliasing', language: 'c')
  84 endif
  85
  86 # Define G_DISABLE_DEPRECATED for development versions
  87 if gst_version_is_dev
  88   message('Disabling deprecated GLib API')
  89   add_project_arguments('-DG_DISABLE_DEPRECATED', language: 'c')
  90 endif
  91
  92 cast_checks = get_option('gobject-cast-checks')
  93 if cast_checks.disabled() or (cast_checks.auto() and not gst_version_is_dev)
  94   message('Disabling GLib cast checks')
  95   add_project_arguments('-DG_DISABLE_CAST_CHECKS', language: 'c')
  96 endif
  97
  98 glib_asserts = get_option('glib-asserts')
  99 if glib_asserts.disabled() or (glib_asserts.auto() and not gst_version_is_dev)
 100   message('Disabling GLib asserts')
 101   add_project_arguments('-DG_DISABLE_ASSERT', language: 'c')
 102 endif
 103
 104 glib_checks = get_option('glib-checks')
 105 if glib_checks.disabled() or (glib_checks.auto() and not gst_version_is_dev)
 106   message('Disabling GLib checks')
 107   add_project_arguments('-DG_DISABLE_CHECKS', language: 'c')
 108 endif
 109
 110 check_headers = [
 111   ['HAVE_DLFCN_H', 'dlfcn.h'],
 112   ['HAVE_EMMINTRIN_H', 'emmintrin.h'],
 113   ['HAVE_INTTYPES_H', 'inttypes.h'],
 114   ['HAVE_MEMORY_H', 'memory.h'],
 115   ['HAVE_NETINET_IN_H', 'netinet/in.h'],
 116   ['HAVE_NETINET_TCP_H', 'netinet/tcp.h'],
 117   ['HAVE_PROCESS_H', 'process.h'],
 118   ['HAVE_SMMINTRIN_H', 'smmintrin.h'],
 119   ['HAVE_STDINT_H', 'stdint.h'],
 120   ['HAVE_STRINGS_H', 'strings.h'],
 121   ['HAVE_STRING_H', 'string.h'],
 122   ['HAVE_SYS_SOCKET_H', 'sys/socket.h'],
 123   ['HAVE_SYS_STAT_H', 'sys/stat.h'],
 124   ['HAVE_SYS_TYPES_H', 'sys/types.h'],
 125   ['HAVE_SYS_WAIT_H', 'sys/wait.h'],
 126   ['HAVE_UNISTD_H', 'unistd.h'],
 127   ['HAVE_WINSOCK2_H', 'winsock2.h'],
 128   ['HAVE_XMMINTRIN_H', 'xmmintrin.h'],
 129   ['HAVE_LINUX_DMA_BUF_H', 'linux/dma-buf.h'],
 130 ]
 131 foreach h : check_headers
 132   if cc.has_header(h.get(1))
 133     core_conf.set(h.get(0), 1)
 134   endif
 135 endforeach
 136
 137 check_functions = [
 138   ['HAVE_DCGETTEXT', 'dcgettext', '#include<libintl.h>'],
 139   ['HAVE_GMTIME_R', 'gmtime_r', '#include<time.h>'],
 140   ['HAVE_LOCALTIME_R', 'localtime_r', '#include<time.h>'],
 141   ['HAVE_LRINTF', 'lrintf', '#include<math.h>'],
 142   ['HAVE_MMAP', 'mmap', '#include<sys/mman.h>'],
 143   ['HAVE_LOG2', 'log2', '#include<math.h>'],
 144 ]
 145
 146 libm = cc.find_library('m', required : false)
 147 foreach f : check_functions
 148   if cc.has_function(f.get(1), prefix : f.get(2), dependencies : libm)
 149     core_conf.set(f.get(0), 1)
 150   endif
 151 endforeach
 152
 153 core_conf.set('SIZEOF_CHAR', cc.sizeof('char'))
 154 core_conf.set('SIZEOF_INT', cc.sizeof('int'))
 155 core_conf.set('SIZEOF_LONG', cc.sizeof('long'))
 156 core_conf.set('SIZEOF_SHORT', cc.sizeof('short'))
 157 core_conf.set('SIZEOF_VOIDP', cc.sizeof('void*'))
 158
 159 core_conf.set_quoted('GETTEXT_PACKAGE', 'gst-plugins-base-1.0')
 160 core_conf.set_quoted('LOCALEDIR', join_paths(get_option('prefix'), get_option('localedir')))
 161 core_conf.set_quoted('PACKAGE', 'gst-plugins-base')
 162 core_conf.set_quoted('VERSION', gst_version)
 163 core_conf.set_quoted('PACKAGE_VERSION', gst_version)
 164 core_conf.set_quoted('GST_API_VERSION', api_version)
 165 core_conf.set_quoted('GST_DATADIR', join_paths(get_option('prefix'), get_option('datadir')))
 166 core_conf.set_quoted('GST_LICENSE', 'LGPL')
 167
 168 install_plugins_helper = get_option('install_plugins_helper')
 169 if install_plugins_helper == ''
 170   install_plugins_helper = join_paths(get_option('prefix'),
 171                                       get_option('libexecdir'),
 172                                       'gst-install-plugins-helper')
 173 endif
 174 core_conf.set_quoted('GST_INSTALL_PLUGINS_HELPER', install_plugins_helper)
 175
 176 warning_flags = [
 177   '-Wmissing-declarations',
 178   '-Wredundant-decls',
 179   '-Wundef',
 180   '-Wwrite-strings',
 181   '-Wformat',
 182   '-Wformat-nonliteral',
 183   '-Wformat-security',
 184   '-Winit-self',
 185   '-Wmissing-include-dirs',
 186   '-Waddress',
 187   '-Wno-multichar',
 188   '-Wvla',
 189   '-Wpointer-arith',
 190 ]
 191
 192 warning_c_flags = [
 193   '-Wmissing-prototypes',
 194   '-Wdeclaration-after-statement',
 195 ]
 196
 197 warning_cxx_flags = [
 198   '-Waggregate-return',
 199 ]
 200
 201 if have_cxx
 202   cxx = meson.get_compiler('cpp')
 203   foreach extra_arg : warning_cxx_flags
 204     if cxx.has_argument (extra_arg)
 205       add_project_arguments([extra_arg], language: 'cpp')
 206     endif
 207   endforeach
 208 endif
 209
 210 foreach extra_arg : warning_flags
 211   if cc.has_argument (extra_arg)
 212     add_project_arguments([extra_arg], language: 'c')
 213   endif
 214   if have_cxx and cxx.has_argument (extra_arg)
 215     add_project_arguments([extra_arg], language: 'cpp')
 216   endif
 217 endforeach
 218
 219 foreach extra_arg : warning_c_flags
 220   if cc.has_argument (extra_arg)
 221     add_project_arguments([extra_arg], language: 'c')
 222   endif
 223 endforeach
 224
 225 # GStreamer package name and origin url
 226 gst_package_name = get_option('package-name')
 227 if gst_package_name == ''
 228   if gst_version_nano == 0
 229     gst_package_name = 'GStreamer Base Plug-ins source release'
 230   elif gst_version_nano == 1
 231     gst_package_name = 'GStreamer Base Plug-ins git'
 232   else
 233     gst_package_name = 'GStreamer Base Plug-ins prerelease'
 234   endif
 235 endif
 236 core_conf.set_quoted('GST_PACKAGE_NAME', gst_package_name)
 237 core_conf.set_quoted('GST_PACKAGE_ORIGIN', get_option('package-origin'))
 238
 239 # FIXME: These should be configure options
 240 core_conf.set_quoted('DEFAULT_VIDEOSINK', 'autovideosink')
 241 core_conf.set_quoted('DEFAULT_AUDIOSINK', 'autoaudiosink')
 242
 243 # Set whether the audioresampling method should be detected at runtime
 244 core_conf.set('AUDIORESAMPLE_FORMAT_' + get_option('audioresample_format').to_upper(), true)
 245
 246 gst_plugins_base_args = ['-DHAVE_CONFIG_H']
 247 if get_option('default_library') == 'static'
 248   gst_plugins_base_args += ['-DGST_STATIC_COMPILATION']
 249 endif
 250
 251 # X11 checks are for sys/ and tests/
 252 x11_dep = dependency('x11', required : get_option('x11'))
 253 # GLib checks are for the entire project
 254 # Almost everything that uses glib also uses gobject
 255 glib_deps = [dependency('glib-2.0', version : glib_req, fallback: ['glib', 'libglib_dep']),
 256              dependency('gobject-2.0', fallback: ['glib', 'libgobject_dep'])]
 257 # GIO is used by the GIO plugin, and by the TCP, SDP, and RTSP plugins
 258 gio_dep = dependency('gio-2.0', fallback: ['glib', 'libgio_dep'])
 259 giounix_dep = dependency('', required: false)
 260 if host_system != 'windows'
 261   giounix_dep = dependency('gio-unix-2.0', version : glib_req,
 262                            fallback: ['glib', 'libgiounix_dep'])
 263 endif
 264 gmodule_dep = dependency('gmodule-no-export-2.0',
 265                          fallback: ['glib', 'libgmodule_dep'])
 266
 267 # some of the examples can use gdk-pixbuf and GTK+3
 268 gdk_pixbuf_dep = dependency('gdk-pixbuf-2.0', required : get_option('examples'))
 269 gtk_dep = dependency('gtk+-3.0', version : '>= 3.10', required : get_option('examples'))
 270 # TODO: https://github.com/mesonbuild/meson/issues/3941
 271 if not get_option('x11').disabled()
 272   gtk_x11_dep = dependency('gtk+-x11-3.0', version : '>= 3.10', required : get_option('examples'))
 273 else
 274   gtk_x11_dep = dependency('', required : false)
 275 endif
 276 # gtk+ quartz backend is only available on macOS
 277 if host_system == 'darwin'
 278   gtk_quartz_dep = dependency('gtk+-quartz-3.0', version : '>= 3.10', required : get_option('examples'))
 279 else
 280   gtk_quartz_dep = dependency('', required : false)
 281 endif
 282
 283 core_conf.set('HAVE_X11', x11_dep.found())
 284 core_conf.set('HAVE_GIO_UNIX_2_0', giounix_dep.found())
 285
 286 if gio_dep.type_name() == 'pkgconfig'
 287     core_conf.set_quoted('GIO_MODULE_DIR',
 288         gio_dep.get_pkgconfig_variable('giomoduledir'))
 289     core_conf.set_quoted('GIO_LIBDIR',
 290         gio_dep.get_pkgconfig_variable('libdir'))
 291     core_conf.set_quoted('GIO_PREFIX',
 292         gio_dep.get_pkgconfig_variable('prefix'))
 293 else
 294     core_conf.set_quoted('GIO_MODULE_DIR', join_paths(get_option('prefix'),
 295       get_option('libdir'), 'gio/modules'))
 296     core_conf.set_quoted('GIO_LIBDIR', join_paths(get_option('prefix'),
 297       get_option('libdir')))
 298     core_conf.set_quoted('GIO_PREFIX', get_option('prefix'))
 299 endif
 300
 301 configinc = include_directories('.')
 302 libsinc = include_directories('gst-libs')
 303
 304 # To use the subproject make subprojects directory
 305 # and put gstreamer meson git there (symlinking is fine)
 306 gst_dep = dependency('gstreamer-1.0', version : gst_req,
 307   fallback : ['gstreamer', 'gst_dep'])
 308 gst_base_dep = dependency('gstreamer-base-1.0', version : gst_req,
 309   fallback : ['gstreamer', 'gst_base_dep'])
 310 gst_net_dep = dependency('gstreamer-net-1.0', version : gst_req,
 311   fallback : ['gstreamer', 'gst_net_dep'])
 312 gst_check_dep = dependency('gstreamer-check-1.0', version : gst_req,
 313   required : get_option('tests'),
 314   fallback : ['gstreamer', 'gst_check_dep'])
 315 gst_controller_dep = dependency('gstreamer-controller-1.0', version : gst_req,
 316   fallback : ['gstreamer', 'gst_controller_dep'])
 317
 318 have_orcc = false
 319 orcc_args = []
 320 # Used by various libraries/elements that use Orc code
 321 orc_dep = dependency('orc-0.4', version : orc_req, required : get_option('orc'),
 322     fallback : ['orc', 'orc_dep'])
 323 orcc = find_program('orcc', required : get_option('orc'))
 324 if orc_dep.found() and orcc.found()
 325   have_orcc = true
 326   orcc_args = [orcc, '--include', 'glib.h']
 327   core_conf.set('HAVE_ORC', 1)
 328 else
 329   message('Orc Compiler not found or disabled, will use backup C code')
 330   core_conf.set('DISABLE_ORC', 1)
 331 endif
 332
 333 # Used to build SSE* things in audio-resampler
 334 sse_args = '-msse'
 335 sse2_args = '-msse2'
 336 sse41_args = '-msse4.1'
 337
 338 have_sse = cc.has_argument(sse_args)
 339 have_sse2 = cc.has_argument(sse2_args)
 340 have_sse41 = cc.has_argument(sse41_args)
 341
 342 if host_machine.cpu_family() == 'arm'
 343   if cc.compiles('''
 344 #include <arm_neon.h>
 345 int32x4_t testfunc(int16_t *a, int16_t *b) {
 346   asm volatile ("vmull.s16 q0, d0, d0" : : : "q0");
 347   return vmull_s16(vld1_s16(a), vld1_s16(b));
 348 }
 349 ''', name : 'NEON support')
 350     core_conf.set('HAVE_ARM_NEON', true)
 351   endif
 352 endif
 353
 354 if gst_dep.type_name() == 'internal'
 355     gst_proj = subproject('gstreamer')
 356
 357     if not gst_proj.get_variable('gst_debug')
 358         message('GStreamer debug system is disabled')
 359         add_project_arguments('-Wno-unused', language: 'c')
 360     else
 361         message('GStreamer debug system is enabled')
 362     endif
 363 else
 364     # We can't check that in the case of subprojects as we won't
 365     # be able to build against an internal dependency (which is not built yet)
 366     if not cc.compiles('''
 367 #include <gst/gstconfig.h>
 368 #ifdef GST_DISABLE_GST_DEBUG
 369 #error "debugging disabled, make compiler fail"
 370 #endif''' , dependencies: gst_dep)
 371         message('GStreamer debug system is disabled')
 372         add_project_arguments('-Wno-unused', language: 'c')
 373     else
 374         message('GStreamer debug system is enabled')
 375     endif
 376 endif
 377
 378 if cc.has_member('struct tcp_info', '__tcpi_reordering', prefix: '#include <netinet/tcp.h>')
 379   core_conf.set('HAVE_BSD_TCP_INFO', true)
 380 endif
 381
 382 if cc.has_member('struct tcp_info', 'tcpi_reordering', prefix: '#include <netinet/tcp.h>')
 383   core_conf.set('HAVE_LINUX_TCP_INFO', true)
 384 endif
 385
 386 gir = find_program('g-ir-scanner', required : get_option('introspection'))
 387 gnome = import('gnome')
 388 build_gir = gir.found() and (not meson.is_cross_build() or get_option('introspection').enabled())
 389 gir_init_section = [ '--add-init-section=extern void gst_init(gint*,gchar**);' + \
 390     'g_setenv("GST_REGISTRY_DISABLE", "yes", TRUE);' + \
 391     'g_setenv("GST_REGISTRY_1.0", "@0@", TRUE);'.format(meson.current_build_dir() + '/gir_empty_registry.reg') + \
 392     'g_setenv("GST_PLUGIN_PATH_1_0", "", TRUE);' + \
 393     'g_setenv("GST_PLUGIN_SYSTEM_PATH_1_0", "", TRUE);' + \
 394     'gst_init(NULL,NULL);', '--quiet']
 395
 396 pkgconfig = import('pkgconfig')
 397 plugins_pkgconfig_install_dir = join_paths(plugins_install_dir, 'pkgconfig')
 398 if get_option('default_library') == 'shared'
 399   # If we don't build static plugins there is no need to generate pc files
 400   plugins_pkgconfig_install_dir = disabler()
 401 endif
 402
 403 python3 = import('python').find_installation()
 404 subdir('gst-libs')
 405 subdir('gst')
 406 subdir('ext')
 407 subdir('sys')
 408 if not get_option('tools').disabled()
 409   subdir('tools')
 410 endif
 411 subdir('tests')
 412 subdir('pkgconfig')
 413 # xgettext is optional (on Windows for instance)
 414 if find_program('xgettext', required : get_option('nls')).found()
 415   core_conf.set('ENABLE_NLS', 1)
 416   subdir('po')
 417 endif
 418 subdir('docs')
 419
 420 # Use core_conf after all subdirs have set values
 421 configure_file(output : 'config.h', configuration : core_conf)
 422
 423 run_command(python3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')