meson.build

   1 project('gst-plugins-base', 'c',
   2   version : '1.13.0.1',
   3   meson_version : '>= 0.36.0',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0]
  10 gst_version_minor = version_arr[1]
  11 gst_version_micro = version_arr[2]
  12 if version_arr.length() == 4
  13   gst_version_nano = version_arr[3]
  14 else
  15   gst_version_nano = 0
  16 endif
  17
  18 have_cxx = add_languages('cpp', required : false)
  19
  20 glib_req = '>= 2.40.0'
  21 orc_req = '>= 0.4.24'
  22 gst_req = '>= @0@.@1@.0'.format(gst_version_major, gst_version_minor)
  23
  24 api_version = '1.0'
  25 soversion = 0
  26 # maintaining compatibility with the previous libtool versioning
  27 # current = minor * 100 + micro
  28 # FIXME: should be able to convert string to int somehow so we can just do maths
  29 libversion = '@0@.@1@.0'.format(soversion, gst_version_minor.to_int() * 100 + gst_version_micro.to_int())
  30
  31 plugins_install_dir = '@0@/gstreamer-1.0'.format(get_option('libdir'))
  32
  33 cc = meson.get_compiler('c')
  34
  35 if cc.get_id() == 'msvc'
  36   # Ignore several spurious warnings for things gstreamer does very commonly
  37   # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  38   # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  39   # NOTE: Only add warnings here if you are sure they're spurious
  40   add_project_arguments(
  41       '/wd4018', # implicit signed/unsigned conversion
  42       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  43       '/wd4244', # lossy type conversion (e.g. double -> int)
  44       '/wd4305', # truncating type conversion (e.g. double -> float)
  45       language : 'c')
  46   # Disable SAFESEH with MSVC for plugins and libs that use external deps that
  47   # are built with MinGW
  48   noseh_link_args = ['/SAFESEH:NO']
  49 else
  50   noseh_link_args = []
  51 endif
  52
  53 # Symbol visibility
  54 if cc.has_argument('-fvisibility=hidden')
  55   add_project_arguments('-fvisibility=hidden', language: 'c')
  56 endif
  57
  58 core_conf = configuration_data()
  59 check_headers = [
  60   ['HAVE_DLFCN_H', 'dlfcn.h'],
  61   ['HAVE_EMMINTRIN_H', 'emmintrin.h'],
  62   ['HAVE_INTTYPES_H', 'inttypes.h'],
  63   ['HAVE_MEMORY_H', 'memory.h'],
  64   ['HAVE_PROCESS_H', 'process.h'],
  65   ['HAVE_SMMINTRIN_H', 'smmintrin.h'],
  66   ['HAVE_STDINT_H', 'stdint.h'],
  67   ['HAVE_STDLIB_H', 'stdlib.h'],
  68   ['HAVE_STRINGS_H', 'strings.h'],
  69   ['HAVE_STRING_H', 'string.h'],
  70   ['HAVE_SYS_SOCKET_H', 'sys/socket.h'],
  71   ['HAVE_SYS_STAT_H', 'sys/stat.h'],
  72   ['HAVE_SYS_TYPES_H', 'sys/types.h'],
  73   ['HAVE_SYS_WAIT_H', 'sys/wait.h'],
  74   ['HAVE_UNISTD_H', 'unistd.h'],
  75   ['HAVE_WINSOCK2_H', 'winsock2.h'],
  76   ['HAVE_XMMINTRIN_H', 'xmmintrin.h'],
  77 ]
  78 foreach h : check_headers
  79   if cc.has_header(h.get(1))
  80     core_conf.set(h.get(0), 1)
  81   endif
  82 endforeach
  83
  84 check_functions = [
  85   ['HAVE_DCGETTEXT', 'dcgettext', '#include<libintl.h>'],
  86   ['HAVE_GMTIME_R', 'gmtime_r', '#include<time.h>'],
  87   ['HAVE_LRINTF', 'lrintf', '#include<math.h>'],
  88   ['HAVE_MMAP', 'mmap', '#include<sys/mman.h>'],
  89   ['HAVE_LOG2', 'log2', '#include<math.h>'],
  90 ]
  91
  92 libm = cc.find_library('m', required : false)
  93 foreach f : check_functions
  94   if cc.has_function(f.get(1), prefix : f.get(2), dependencies : libm)
  95     core_conf.set(f.get(0), 1)
  96   endif
  97 endforeach
  98
  99 core_conf.set('SIZEOF_CHAR', cc.sizeof('char'))
 100 core_conf.set('SIZEOF_INT', cc.sizeof('int'))
 101 core_conf.set('SIZEOF_LONG', cc.sizeof('long'))
 102 core_conf.set('SIZEOF_SHORT', cc.sizeof('short'))
 103 core_conf.set('SIZEOF_VOIDP', cc.sizeof('void*'))
 104
 105 core_conf.set('GETTEXT_PACKAGE', '"gst-plugins-base-1.0"')
 106 core_conf.set('PACKAGE', '"gst-plugins-base"')
 107 core_conf.set('VERSION', '"@0@"'.format(gst_version))
 108 core_conf.set('PACKAGE_VERSION', '"@0@"'.format(gst_version))
 109 core_conf.set('GST_API_VERSION', '"@0@"'.format(api_version))
 110 core_conf.set('GST_INSTALL_PLUGINS_HELPER', '"/FIXME"')
 111 core_conf.set('GST_DATADIR', '"/FIXME"')
 112 core_conf.set('GST_LICENSE', '"LGPL"')
 113
 114 # GStreamer package name and origin url
 115 gst_package_name = get_option('with-package-name')
 116 if gst_package_name == ''
 117   if gst_version_nano == 0
 118     gst_package_name = 'GStreamer Base Plug-ins source release'
 119   elif gst_version_nano == 1
 120     gst_package_name = 'GStreamer Base Plug-ins git'
 121   else
 122     gst_package_name = 'GStreamer Base Plug-ins prerelease'
 123   endif
 124 endif
 125 core_conf.set_quoted('GST_PACKAGE_NAME', gst_package_name)
 126 core_conf.set_quoted('GST_PACKAGE_ORIGIN', get_option('with-package-origin'))
 127
 128 # FIXME: These should be configure options
 129 core_conf.set('DEFAULT_VIDEOSINK', '"autovideosink"')
 130 core_conf.set('DEFAULT_AUDIOSINK', '"autoaudiosink"')
 131
 132 # Set whether the audioresampling method should be detected at runtime
 133 core_conf.set('AUDIORESAMPLE_FORMAT_' + get_option('audioresample_format').to_upper(), true)
 134
 135 gst_plugins_base_args = ['-DHAVE_CONFIG_H']
 136 if get_option('default_library') == 'static'
 137   gst_plugins_base_args += ['-DGST_STATIC_COMPILATION']
 138 endif
 139
 140 # X11 checks are for sys/ and tests/
 141 x11_dep = dependency('x11', required : false)
 142 # GLib checks are for the entire project
 143 giounix_dep = dependency('gio-unix-2.0', version : glib_req, required : false)
 144 # Almost everything that uses glib also uses gobject
 145 glib_deps = [dependency('glib-2.0', version : glib_req, fallback: ['glib', 'libglib_dep']),
 146              dependency('gobject-2.0', fallback: ['glib', 'libgobject_dep'])]
 147 gio_dep = dependency('gio-2.0', fallback: ['glib', 'libgio_dep'])
 148
 149 core_conf.set('HAVE_X', x11_dep.found())
 150 core_conf.set('HAVE_GIO_UNIX_2_0',
 151     (gio_dep.type_name() != 'pkgconfig' and host_machine.system() != 'windows')
 152     or giounix_dep.found())
 153
 154 if gio_dep.type_name() == 'pkgconfig'
 155     core_conf.set_quoted('GIO_MODULE_DIR',
 156         gio_dep.get_pkgconfig_variable('giomoduledir'))
 157     core_conf.set_quoted('GIO_LIBDIR',
 158         gio_dep.get_pkgconfig_variable('libdir'))
 159     core_conf.set_quoted('GIO_PREFIX',
 160         gio_dep.get_pkgconfig_variable('prefix'))
 161 else
 162     core_conf.set_quoted('GIO_MODULE_DIR', join_paths(get_option('prefix'),
 163       get_option('libdir'), 'gio/modules'))
 164     core_conf.set_quoted('GIO_LIBDIR', join_paths(get_option('prefix'),
 165       get_option('libdir')))
 166     core_conf.set_quoted('GIO_PREFIX', get_option('prefix'))
 167 endif
 168
 169 configinc = include_directories('.')
 170 libsinc = include_directories('gst-libs')
 171
 172 # To use the subproject make subprojects directory
 173 # and put gstreamer meson git there (symlinking is fine)
 174 gst_dep = dependency('gstreamer-1.0', version : gst_req,
 175   fallback : ['gstreamer', 'gst_dep'])
 176 gst_base_dep = dependency('gstreamer-base-1.0', version : gst_req,
 177   fallback : ['gstreamer', 'gst_base_dep'])
 178 gst_net_dep = dependency('gstreamer-net-1.0', version : gst_req,
 179   fallback : ['gstreamer', 'gst_net_dep'])
 180 if host_machine.system() != 'windows'
 181   gst_check_dep = dependency('gstreamer-check-1.0', version : gst_req,
 182     fallback : ['gstreamer', 'gst_check_dep'])
 183 endif
 184 gst_controller_dep = dependency('gstreamer-controller-1.0', version : gst_req,
 185   fallback : ['gstreamer', 'gst_controller_dep'])
 186
 187 # Used by the *_mkenum.py helper scripts
 188 glib_mkenums = find_program('glib-mkenums')
 189
 190 have_orcc = false
 191 orcc_args = []
 192 if get_option('use_orc') != 'no'
 193   need_orc = get_option('use_orc') == 'yes'
 194   # Used by various libraries/elements that use Orc code
 195   orc_dep = dependency('orc-0.4', version : orc_req, required : need_orc)
 196   orcc = find_program('orcc', required : need_orc)
 197   if orc_dep.found() and orcc.found()
 198     have_orcc = true
 199     orcc_args = [orcc, '--include', 'glib.h']
 200     core_conf.set('HAVE_ORC', 1)
 201   else
 202     message('Orc Compiler not found, will use backup C code')
 203     core_conf.set('DISABLE_ORC', 1)
 204   endif
 205 else
 206   core_conf.set('DISABLE_ORC', 1)
 207 endif
 208
 209 # Used to build SSE* things in audio-resampler
 210 sse_args = '-msse'
 211 sse2_args = '-msse2'
 212 sse41_args = '-msse4.1'
 213
 214 have_sse = cc.has_argument(sse_args)
 215 have_sse2 = cc.has_argument(sse2_args)
 216 have_sse41 = cc.has_argument(sse41_args)
 217
 218 # FIXME: Meson should have a way for portably adding -fPIC when needed for use
 219 # with static libraries that are linked into shared libraries. Or, it should
 220 # add it by default with an option to turn it off if needed.
 221 pic_args = ['-fPIC']
 222 if host_machine.system() == 'windows'
 223   pic_args = []
 224 endif
 225
 226 if gst_dep.type_name() == 'internal'
 227     gst_proj = subproject('gstreamer')
 228
 229     if gst_proj.get_variable('disable_gst_debug')
 230         message('GStreamer debug system is disabled')
 231         add_project_arguments('-Wno-unused', language: 'c')
 232     else
 233         message('GStreamer debug system is enabled')
 234     endif
 235 else
 236     # We can't check that in the case of subprojects as we won't
 237     # be able to build against an internal dependency (which is not built yet)
 238     if not cc.compiles('''
 239 #include <gst/gstconfig.h>
 240 #ifdef GST_DISABLE_GST_DEBUG
 241 #error "debugging disabled, make compiler fail"
 242 #endif''' , dependencies: gst_dep)
 243         message('GStreamer debug system is disabled')
 244         add_project_arguments('-Wno-unused', language: 'c')
 245     else
 246         message('GStreamer debug system is enabled')
 247     endif
 248 endif
 249
 250 gir = find_program('g-ir-scanner', required : false)
 251 gnome = import('gnome')
 252 build_gir = gir.found() and not meson.is_cross_build() and not get_option('disable_introspection')
 253 gir_init_section = [ '--add-init-section=extern void gst_init(gint*,gchar**);' + \
 254     'g_setenv("GST_REGISTRY_DISABLE", "yes", TRUE);' + \
 255     'g_setenv("GST_REGISTRY_1.0", "@0@", TRUE);'.format(meson.current_build_dir() + '/gir_empty_registry.reg') + \
 256     'g_setenv("GST_PLUGIN_PATH_1_0", "", TRUE);' + \
 257     'g_setenv("GST_PLUGIN_SYSTEM_PATH_1_0", "", TRUE);' + \
 258     'gst_init(NULL,NULL);' ]
 259
 260 subdir('gst-libs')
 261 subdir('gst')
 262 subdir('ext')
 263 subdir('sys')
 264 subdir('tools')
 265 subdir('tests')
 266 subdir('pkgconfig')
 267 subdir('po')
 268
 269 if build_machine.system() == 'windows'
 270   message('Disabling gtk-doc while building on Windows')
 271 elif get_option('disable_gtkdoc')
 272   message('gtk-doc is disabled via options')
 273 else
 274   if find_program('gtkdoc-scan', required : false).found()
 275     subdir('docs')
 276   else
 277     message('Not building documentation as gtk-doc was not found')
 278   endif
 279 endif
 280
 281 # Use core_conf after all subdirs have set values
 282 configure_file(output : 'config.h', configuration : core_conf)
 283
 284 python3 = import('python3').find_python()
 285 run_command(python3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')