meson.build

   1 project('pulseaudio', 'c', 'cpp',
   2         version : run_command(find_program('git-version-gen'), join_paths(meson.current_source_dir(), '.tarball-version')).stdout().strip(),
   3         meson_version : '>= 0.50.0',
   4         default_options : [ 'c_std=gnu11', 'cpp_std=c++11' ]
   5         )
   6
   7 pa_version_str = meson.project_version()
   8 # For tarballs, the first split will do nothing, but for builds in git, we
   9 # split out suffixes when there are commits since the last tag
  10 # (e.g.: v11.99.1-3-gad14bdb24 -> v11.99.1)
  11 version_split = pa_version_str.split('-')[0].split('.')
  12 pa_version_major = version_split[0].split('v')[0]
  13 pa_version_minor = version_split[1]
  14 if version_split.length() > 2
  15   pa_version_micro = version_split[2]
  16 else
  17   pa_version_micro = '0'
  18 endif
  19 pa_version_major_minor = pa_version_major + '.' + pa_version_minor
  20
  21 pa_api_version = 12
  22 pa_protocol_version = 33
  23
  24 apiversion = '1.0'
  25 soversion = 0
  26 # FIXME: this doesn't actually do what we want it to
  27 # maintaining compatibility with the previous libtool versioning
  28 # current = minor * 100 + micro
  29 libversion = '@0@.@1@.0'.format(soversion, pa_version_minor.to_int() * 100 + pa_version_micro.to_int())
  30
  31 # A simplified, synchronous, ABI-stable interface for client applications.
  32 # For the version x:y:z always will hold y=z.
  33 libpulse_simple_version = '1.1.1'
  34
  35 # The ABI-stable GLib adapter for client applications.
  36 # For the version x:y:z always will hold y=z.
  37 libpulse_mainloop_glib_version = '0.5.0'
  38
  39 # Paths
  40
  41 prefix = get_option('prefix')
  42 assert(prefix.startswith('/'), 'Prefix is not absolute: "@0@"'.format(prefix))
  43
  44 bindir = join_paths(prefix, get_option('bindir'))
  45 libdir = join_paths(prefix, get_option('libdir'))
  46 libexecdir = join_paths(prefix, get_option('libexecdir'))
  47 datadir = join_paths(prefix, get_option('datadir'))
  48 localstatedir = join_paths(prefix, get_option('localstatedir'))
  49 sysconfdir = join_paths(prefix, get_option('sysconfdir'))
  50 privlibdir = join_paths(get_option('libdir'), 'pulseaudio')
  51 alsadatadir = join_paths(datadir, 'pulseaudio', 'alsa-mixer')
  52
  53 pulselibexecdir = join_paths(libexecdir, 'pulse')
  54 pulsesysconfdir = join_paths(sysconfdir, 'pulse')
  55
  56 modlibexecdir = get_option('modlibexecdir')
  57 if modlibexecdir == ''
  58   modlibexecdir = join_paths(libdir, 'pulse-' + pa_version_major_minor, 'modules')
  59 endif
  60
  61 pulsedspdir = get_option('pulsedspdir')
  62 if pulsedspdir == ''
  63   join_paths(libdir, 'pulseaudio')
  64 endif
  65
  66 # Configuration data
  67
  68 cc = meson.get_compiler('c')
  69
  70 cdata = configuration_data()
  71 cdata.set_quoted('PACKAGE', 'pulseaudio')
  72 cdata.set_quoted('PACKAGE_NAME', 'pulseaudio')
  73 cdata.set_quoted('PACKAGE_VERSION', pa_version_str)
  74 cdata.set_quoted('CANONICAL_HOST', host_machine.cpu())
  75 cdata.set('PA_MAJOR', pa_version_major)
  76 cdata.set('PA_MINOR', pa_version_minor)
  77 cdata.set('PA_API_VERSION', pa_api_version)
  78 cdata.set('PA_PROTOCOL_VERSION', pa_protocol_version)
  79 cdata.set_quoted('PA_MACHINE_ID', join_paths(sysconfdir, 'machine-id'))
  80 cdata.set_quoted('PA_MACHINE_ID_FALLBACK', join_paths(localstatedir, 'lib', 'dbus', 'machine-id'))
  81 cdata.set_quoted('PA_SRCDIR', join_paths(meson.current_source_dir(), 'src'))
  82 cdata.set_quoted('PA_BUILDDIR', meson.current_build_dir())
  83 cdata.set_quoted('PA_SOEXT', '.so')
  84 cdata.set_quoted('PA_DEFAULT_CONFIG_DIR', pulsesysconfdir)
  85 cdata.set_quoted('PA_BINARY', join_paths(bindir, 'pulseaudio'))
  86 cdata.set_quoted('PA_SYSTEM_RUNTIME_PATH', join_paths(localstatedir, 'run', 'pulse'))
  87 cdata.set_quoted('PA_SYSTEM_CONFIG_PATH', join_paths(localstatedir, 'lib', 'pulse'))
  88 cdata.set_quoted('PA_SYSTEM_STATE_PATH', join_paths(localstatedir, 'lib', 'pulse'))
  89 cdata.set_quoted('PA_DLSEARCHPATH', modlibexecdir)
  90 cdata.set_quoted('PA_SYSTEM_USER', get_option('system_user'))
  91 cdata.set_quoted('PA_SYSTEM_GROUP', get_option('system_group'))
  92 cdata.set_quoted('PA_ACCESS_GROUP', get_option('access_group'))
  93 cdata.set_quoted('PA_CFLAGS', 'Not yet supported on meson')
  94 cdata.set_quoted('PA_ALSA_PATHS_DIR', join_paths(alsadatadir, 'paths'))
  95 cdata.set_quoted('PA_ALSA_PROFILE_SETS_DIR', join_paths(alsadatadir, 'profile-sets'))
  96 cdata.set_quoted('DESKTOPFILEDIR', join_paths(datadir, 'applications'))
  97
  98 # Platform specifics
  99 # First some defaults to keep config file generation happy
 100 cdata.set('HAVE_COREAUDIO', 0)
 101 cdata.set('HAVE_WAVEOUT', 0)
 102 # FIXME: This was not tested. Maybe some flags should better be CFLAGS,
 103 # rather than ending up in the config.h file?
 104 if host_machine.system() == 'darwin'
 105   cdata.set('OS_IS_DARWIN', 1)
 106   cdata.set('_DARWIN_C_SOURCE', '200112L') # Needed to get NSIG on Mac OS
 107 elif host_machine.system() == 'windows'
 108   cdata.set('OS_IS_WIN32', 1)
 109   cdata.set('WIN32_LEAN_AND_MEAN', 1) # Needed to avoid including unnecessary headers on Windows
 110 #elif host_machine.system() == 'solaris'
 111 #  # Apparently meson has no solaris support?
 112 #  # Needed to get declarations for msg_control and msg_controllen on Solaris
 113 #  cdata.set('_XOPEN_SOURCE', 600)
 114 #  cdata.set('__EXTENSIONS__', 1)
 115 endif
 116
 117 # Headers
 118
 119 check_headers = [
 120   'arpa/inet.h',
 121   'cpuid.h',
 122   'execinfo.h',
 123   'grp.h',
 124   'langinfo.h',
 125   'locale.h',
 126   'netdb.h',
 127   'netinet/in.h',
 128   'netinet/in_systm.h',
 129   'netinet/ip.h',
 130   'netinet/tcp.h',
 131   'pcreposix.h',
 132   'poll.h',
 133   'pwd.h',
 134   'regex.h',
 135   'sched.h',
 136   'sys/capability.h',
 137   'sys/eventfd.h',
 138   'sys/ioctl.h',
 139   'sys/mman.h',
 140   'sys/prctl.h',
 141   'sys/resource.h',
 142   'sys/select.h',
 143   'sys/socket.h',
 144   'sys/un.h',
 145   'sys/wait.h',
 146   'valgrind/memcheck.h',
 147   'xlocale.h',
 148 ]
 149
 150 foreach h : check_headers
 151   if cc.has_header(h)
 152     define = 'HAVE_' + h.underscorify().to_upper()
 153     cdata.set(define, 1)
 154   endif
 155 endforeach
 156
 157 # FIXME: move this to the above set
 158 if cc.has_header('pthread.h')
 159   cdata.set('HAVE_PTHREAD', 1)
 160 endif
 161
 162 # Functions
 163
 164 check_functions = [
 165   'accept4',
 166   'clock_gettime',
 167   'fchmod',
 168   'fchown',
 169   'fork',
 170   'fstat',
 171   'getaddrinfo',
 172   'getgrgid_r',
 173   'getpwnam_r',
 174   'gettimeofday',
 175   'getuid',
 176   'lstat',
 177   'memfd_create',
 178   'mkfifo',
 179   'mlock',
 180   'nanosleep',
 181   'paccept',
 182   'pipe',
 183   'pipe2',
 184   'posix_madvise',
 185   'readlink',
 186   'setegid',
 187   'seteuid',
 188   'setregid',
 189   'setreuid',
 190   'setresgid',
 191   'setresuid',
 192   'setsid',
 193   'sig2str',
 194   'sigaction',
 195   'strtod_l',
 196   'symlink',
 197   'sysconf',
 198   'uname',
 199 ]
 200
 201 foreach f : check_functions
 202   if cc.has_function(f)
 203     define = 'HAVE_' + f.underscorify().to_upper()
 204     cdata.set(define, 1)
 205   endif
 206 endforeach
 207
 208 if cc.has_function('SYS_memfd_create', prefix : '#include <sys/syscall.h>')
 209   cdata.set('HAVE_MEMFD', 1)
 210 endif
 211
 212 # Symbols
 213
 214 if cc.has_header_symbol('signal.h', 'SIGXCPU')
 215   cdata.set('HAVE_SIGXCPU', 1)
 216 endif
 217
 218 if not cc.has_header_symbol('netinet/in.h', 'INADDR_NONE')
 219   if not cc.has_header_symbol('winsock2.h', 'INADDR_NONE')
 220     # Define INADDR_NONE if not found (Solaris)
 221     cdata.set('INADDR_NONE', '0xffffffff')
 222   endif
 223 endif
 224
 225 # Types
 226
 227 # FIXME: do we ever care about gid_t not being defined / smaller than an int?
 228 cdata.set('GETGROUPS_T', 'gid_t')
 229
 230 # Include paths
 231
 232 configinc = include_directories('.')
 233 topinc = include_directories('src')
 234
 235 # CFLAGS
 236
 237 pa_c_args = ['-DHAVE_CONFIG_H', '-D_GNU_SOURCE']
 238 server_c_args = ['-D__INCLUDED_FROM_PULSE_AUDIO']
 239 cdata.set('MESON_BUILD', 1)
 240
 241 # Core Dependencies
 242
 243 libm_dep = cc.find_library('m', required : true)
 244 thread_dep = dependency('threads')
 245 cap_dep = cc.find_library('cap', required : false)
 246
 247 shm_dep = cc.find_library('rt', required : false)
 248 if shm_dep.found()
 249   cdata.set('HAVE_SHM_OPEN', 1)
 250 endif
 251
 252 atomictest = '''void func() {
 253   volatile int atomic = 2;
 254   __sync_bool_compare_and_swap (&atomic, 2, 3);
 255 }
 256 '''
 257 if cc.compiles(atomictest)
 258   cdata.set('HAVE_ATOMIC_BUILTINS', true)
 259 else
 260   # FIXME: check if we need libatomic_ops
 261 endif
 262
 263 # FIXME: make sure it's >= 2.2
 264 ltdl_dep = cc.find_library('ltdl', required : true)
 265 # FIXME: can meson support libtool -dlopen/-dlpreopen things?
 266 #        and do we still want to support this at all?
 267 cdata.set('DISABLE_LIBTOOL_PRELOAD', 1)
 268
 269 if get_option('database') == 'tdb'
 270   database_dep = dependency('tdb')
 271 elif get_option('database') == 'gdbm'
 272   database_dep = cc.find_library('gdbm', required : true)
 273 else
 274   database_dep = dependency('', required: false)
 275 endif
 276
 277 if get_option('ipv6')
 278   cdata.set('HAVE_IPV6', 1)
 279 endif
 280
 281 if get_option('legacy-database-entry-format')
 282   cdata.set('ENABLE_LEGACY_DATABASE_ENTRY_FORMAT', 1)
 283 endif
 284
 285 alsa_dep = dependency('alsa', version : '>= 1.0.24', required : get_option('alsa'))
 286 if alsa_dep.found()
 287   cdata.set('HAVE_ALSA', 1)
 288   cdata.set('HAVE_ALSA_UCM', 1)
 289 endif
 290
 291 asyncns_dep = dependency('libasyncns', version : '>= 0.1', required : get_option('asyncns'))
 292 if asyncns_dep.found()
 293   cdata.set('HAVE_LIBASYNCNS', 1)
 294 endif
 295
 296 dbus_dep = dependency('dbus-1', version : '>= 1.4.12', required : get_option('dbus'))
 297 if dbus_dep.found()
 298   cdata.set('HAVE_DBUS', 1)
 299 endif
 300
 301 gio_dep = dependency('gio-2.0', version : '>= 2.26.0', required : get_option('gsettings'))
 302 if gio_dep.found()
 303   cdata.set('HAVE_GSETTINGS', 1)
 304 endif
 305
 306 glib_dep = dependency('glib-2.0', version : '>= 2.4.0', required: get_option('glib'))
 307 if glib_dep.found()
 308   cdata.set('HAVE_GLIB', 1)
 309 endif
 310
 311 gtk_dep = dependency('gtk+-3.0', required : get_option('gtk'))
 312 if gtk_dep.found()
 313   cdata.set('HAVE_GTK', 1)
 314 endif
 315
 316 samplerate_dep = dependency('samplerate', version : '>= 0.1.0', required : get_option('samplerate'))
 317 if samplerate_dep.found()
 318   cdata.set('HAVE_LIBSAMPLERATE', 1)
 319 endif
 320
 321 sndfile_dep = dependency('sndfile', version : '>= 1.0.20')
 322
 323 soxr_dep = dependency('soxr', version : '>= 0.1.1', required : get_option('soxr'))
 324 if soxr_dep.found()
 325   cdata.set('HAVE_SOXR', 1)
 326 endif
 327
 328 systemd_dep = dependency('libsystemd', required : get_option('systemd'))
 329 if systemd_dep.found()
 330   cdata.set('HAVE_SYSTEMD_DAEMON', 1)
 331   cdata.set('HAVE_SYSTEMD_LOGIN', 1)
 332   cdata.set('HAVE_SYSTEMD_JOURNAL', 1)
 333 endif
 334
 335 x11_dep = dependency('x11-xcb', required : get_option('x11'))
 336 if x11_dep.found()
 337   xcb_dep  = dependency('xcb',  required : true, version : '>= 1.6')
 338   ice_dep  = dependency('ice',  required : true)
 339   sm_dep   = dependency('sm',   required : true)
 340   xtst_dep = dependency('xtst', required : true)
 341   cdata.set('HAVE_X11', 1)
 342 endif
 343
 344 # FIXME: support ORC
 345 cdata.set('DISABLE_ORC', 1)
 346
 347 # Module dependencies
 348
 349 if cc.has_header('sys/soundcard.h')
 350   cdata.set('HAVE_OSS_OUTPUT', 1)
 351   cdata.set('HAVE_OSS_WRAPPER', 1)
 352   cdata.set_quoted('PULSEDSP_LOCATION', pulsedspdir)
 353 endif
 354
 355 if get_option('hal-compat')
 356   cdata.set('HAVE_HAL_COMPAT', 1)
 357 endif
 358
 359 avahi_dep = dependency('avahi-client', version : '>= 0.6.0', required : get_option('avahi'), disabler : true)
 360 if avahi_dep.found()
 361   cdata.set('HAVE_AVAHI', 1)
 362 endif
 363
 364 bluez_dep = dependency('bluez', version : '>= 5.0', required : get_option('bluez5'))
 365 sbc_dep = dependency('sbc', version : '>= 1.0', required : false)
 366 if bluez_dep.found()
 367   assert(dbus_dep.found(), 'BlueZ requires D-Bus support')
 368   assert(sbc_dep.found(), 'BlueZ requires SBC support')
 369   cdata.set('HAVE_SBC', 1)
 370   cdata.set('HAVE_BLUEZ', 1)
 371   cdata.set('HAVE_BLUEZ_5', 1)
 372   if get_option('bluez5-native-headset')
 373     cdata.set('HAVE_BLUEZ_5_NATIVE_HEADSET', 1)
 374   endif
 375   if get_option('bluez5-ofono-headset')
 376     cdata.set('HAVE_BLUEZ_5_OFONO_HEADSET', 1)
 377   endif
 378 endif
 379
 380 fftw_dep = dependency('fftw3f', required : get_option('fftw'))
 381 if fftw_dep.found()
 382   cdata.set('HAVE_FFTW', 1)
 383 endif
 384
 385 jack_dep = dependency('jack', version : '>= 0.117.0', required : get_option('jack'))
 386 if jack_dep.found()
 387   cdata.set('HAVE_JACK', 1)
 388 endif
 389
 390 lirc_dep = dependency('lirc', required : get_option('lirc'))
 391 if lirc_dep.found()
 392   cdata.set('HAVE_LIRC', 1)
 393 endif
 394
 395 openssl_dep = dependency('openssl', version : '>= 0.9', required : get_option('openssl'))
 396 if openssl_dep.found()
 397   cdata.set('HAVE_OPENSSL', 1)
 398 endif
 399
 400 speex_dep = dependency('speexdsp', version : '>= 1.2', required : get_option('speex'))
 401 if speex_dep.found()
 402   cdata.set('HAVE_SPEEX', 1)
 403 endif
 404
 405 udev_dep = dependency('libudev', version : '>= 143', required : get_option('udev'))
 406 if udev_dep.found()
 407   cdata.set('HAVE_UDEV', 1)
 408 endif
 409
 410 webrtc_dep = dependency('webrtc-audio-processing', version : '>= 0.2', required : get_option('webrtc-aec'))
 411 if webrtc_dep.found()
 412   cdata.set('HAVE_WEBRTC', 1)
 413 endif
 414
 415 # Test dependencies
 416
 417 check_dep = dependency('check', version : '>= 0.9.10', required : get_option('tests'))
 418
 419 # Now generate config.h from everything above
 420 configure_file(output : 'config.h', configuration : cdata)
 421
 422 subdir('man')
 423 subdir('src')
 424
 425 ############################################################
 426
 427 # Final summary
 428
 429 summary = [
 430   '',
 431   '---{ @0@ @1@ }---'.format(meson.project_name(), meson.project_version()),
 432   '',
 433   'prefix:                        @0@'.format(prefix),
 434   'bindir:                        @0@'.format(bindir),
 435   'libdir:                        @0@'.format(libdir),
 436   'libexecdir:                    @0@'.format(libexecdir),
 437   'datadir:                       @0@'.format(datadir),
 438   'sysconfdir:                    @0@'.format(sysconfdir),
 439   'localstatedir:                 @0@'.format(localstatedir),
 440   'modlibexecdir:                 @0@'.format(modlibexecdir),
 441   'System Runtime Path:           @0@'.format(cdata.get_unquoted('PA_SYSTEM_RUNTIME_PATH')),
 442   'System State Path:             @0@'.format(cdata.get_unquoted('PA_SYSTEM_STATE_PATH')),
 443   'System Config Path:            @0@'.format(cdata.get_unquoted('PA_SYSTEM_CONFIG_PATH')),
 444 #  'Zsh completions directory:     @0@'.format(${zshcompletiondir}),
 445 #  'Bash completions directory:    @0@'.format(${bashcompletiondir}),
 446   'Compiler:                      @0@ @1@'.format(cc.get_id(), cc.version()),
 447 #  'CFLAGS:                        @0@'.format(${CFLAGS}),
 448 #  'CPPFLAGS:                      @0@'.format(${CPPFLAGS}),
 449 #  'LIBS:                          @0@'.format(${LIBS}),
 450   '',
 451   'Enable memfd shared memory:    @0@'.format(cdata.has('HAVE_MEMFD')),
 452   'Enable X11:                    @0@'.format(x11_dep.found()),
 453 #  'Enable OSS Output:             @0@'.format(${ENABLE_OSS_OUTPUT}),
 454 #  'Enable OSS Wrapper:            @0@'.format(${ENABLE_OSS_WRAPPER}),
 455 #  'Enable EsounD:                 @0@'.format(${ENABLE_ESOUND}),
 456   'Enable Alsa:                   @0@'.format(alsa_dep.found()),
 457 #  'Enable CoreAudio:              @0@'.format(${ENABLE_COREAUDIO}),
 458 #  'Enable Solaris:                @0@'.format(${ENABLE_SOLARIS}),
 459 #  'Enable WaveOut:                @0@'.format(${ENABLE_WAVEOUT}),
 460   'Enable GLib 2:                 @0@'.format(glib_dep.found()),
 461 #  'Enable GConf:                  @0@'.format(${ENABLE_GCONF}),
 462   'Enable GSettings:              @0@'.format(gio_dep.found()),
 463   'Enable Gtk+ 3:                 @0@'.format(gtk_dep.found()),
 464   'Enable Avahi:                  @0@'.format(avahi_dep.found()),
 465   'Enable Jack:                   @0@'.format(jack_dep.found()),
 466   'Enable Async DNS:              @0@'.format(asyncns_dep.found()),
 467   'Enable LIRC:                   @0@'.format(lirc_dep.found()),
 468   'Enable D-Bus:                  @0@'.format(dbus_dep.found()),
 469   '  Enable BlueZ 5:              @0@'.format(bluez_dep.found()),
 470   '    Enable native headsets:    @0@'.format(get_option('bluez5-native-headset')),
 471   '    Enable  ofono headsets:    @0@'.format(get_option('bluez5-ofono-headset')),
 472   'Enable udev:                   @0@'.format(udev_dep.found()),
 473   '  Enable HAL->udev compat:     @0@'.format(get_option('hal-compat')),
 474   'Enable systemd:                @0@'.format(systemd_dep.found()),
 475 #  'Enable TCP Wrappers:           @0@'.format(${ENABLE_TCPWRAP}),
 476   'Enable libsamplerate:          @0@'.format(samplerate_dep.found()),
 477   'Enable IPv6:                   @0@'.format(get_option('ipv6')),
 478   'Enable OpenSSL (for Airtunes): @0@'.format(openssl_dep.found()),
 479   'Enable FFTW:                   @0@'.format(fftw_dep.found()),
 480 #  'Enable orc:                    @0@'.format(${ENABLE_ORC}),
 481   'Enable Adrian echo canceller:  @0@'.format(get_option('adrian-aec')),
 482   'Enable Speex (resampler, AEC): @0@'.format(speex_dep.found()),
 483   'Enable SoXR (resampler):       @0@'.format(soxr_dep.found()),
 484   'Enable WebRTC echo canceller:  @0@'.format(webrtc_dep.found()),
 485 #  'Enable gcov coverage:          @0@'.format(${ENABLE_GCOV}),
 486   'Enable unit tests:             @0@'.format(get_option('tests')),
 487   '',
 488   'Database:                      @0@'.format(get_option('database')),
 489   'Legacy Database Entry Support: @0@'.format(get_option('legacy-database-entry-format')),
 490   'System User:                   @0@'.format(cdata.get_unquoted('PA_SYSTEM_USER')),
 491   'System Group:                  @0@'.format(cdata.get_unquoted('PA_SYSTEM_GROUP')),
 492   'Access Group:                  @0@'.format(cdata.get_unquoted('PA_ACCESS_GROUP')),
 493 #  'Enable per-user EsounD socket: @0@'.format(${ENABLE_PER_USER_ESOUND_SOCKET}),
 494 #  'Force preopen:                 @0@'.format(${FORCE_PREOPEN}),
 495 #  'Preopened modules:             @0@'.format(${PREOPEN_MODS}),
 496 ]
 497
 498 message('\n    '.join(summary))
 499
 500 # Sanity checks
 501
 502 if not speex_dep.found() and not webrtc_dep.found() and not get_option('adrian-aec')
 503   error('At least one echo canceller implementation must be available!')
 504 endif
 505
 506 if samplerate_dep.found()
 507   warning('Support for libsamplerate is DEPRECATED')
 508 endif
 509
 510 if host_machine.system() != 'windows'
 511   if not dbus_dep.found()
 512     message = [
 513       'You do not have D-Bus support enabled. It is strongly recommended',
 514       'that you enable D-Bus support if your platform supports it.',
 515       'Many parts of PulseAudio use D-Bus, from ConsoleKit interaction',
 516       'to the Device Reservation Protocol to speak to JACK, Bluetooth',
 517       'support and even a native control protocol for communicating and',
 518       'controlling the PulseAudio daemon itself.',
 519     ]
 520     warning('\n' + '\n'.join(message))
 521   endif
 522   if not udev_dep.found()
 523     message = [
 524       'You do not have udev support enabled. It is strongly recommended',
 525       'that you enable udev support if your platform supports it as it is',
 526       'the primary method used to detect hardware audio devices (on Linux)',
 527       'and is thus a critical part of PulseAudio on that platform.',
 528     ]
 529     warning('\n' + '\n'.join(message))
 530   endif
 531   if not speex_dep.found()
 532     message = [
 533       'You do not have speex support enabled. It is strongly recommended',
 534       'that you enable speex support if your platform supports it as it is',
 535       'the primary method used for audio resampling and is thus a critical',
 536       'part of PulseAudio on that platform.',
 537     ]
 538     warning('\n' + '\n'.join(message))
 539   endif
 540 endif