meson.build

   1 # Copyright © 2017-2019 Intel Corporation
   2
   3 # Permission is hereby granted, free of charge, to any person obtaining a copy
   4 # of this software and associated documentation files (the "Software"), to deal
   5 # in the Software without restriction, including without limitation the rights
   6 # to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
   7 # copies of the Software, and to permit persons to whom the Software is
   8 # furnished to do so, subject to the following conditions:
   9
  10 # The above copyright notice and this permission notice shall be included in
  11 # all copies or substantial portions of the Software.
  12
  13 # THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  14 # IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  15 # FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
  16 # AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  17 # LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
  18 # OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
  19 # SOFTWARE.
  20
  21 project(
  22   'mesa',
  23   ['c', 'cpp'],
  24   version : run_command(
  25     [find_program('python', 'python2', 'python3'), 'bin/meson_get_version.py']
  26   ).stdout(),
  27   license : 'MIT',
  28   meson_version : '>= 0.46',
  29   default_options : ['buildtype=debugoptimized', 'b_ndebug=if-release', 'c_std=c99', 'cpp_std=c++14']
  30 )
  31
  32 cc = meson.get_compiler('c')
  33 cpp = meson.get_compiler('cpp')
  34
  35 null_dep = dependency('', required : false)
  36
  37 # Arguments for the preprocessor, put these in a separate array from the C and
  38 # C++ (cpp in meson terminology) arguments since they need to be added to the
  39 # default arguments for both C and C++.
  40 pre_args = [
  41   '-D__STDC_CONSTANT_MACROS',
  42   '-D__STDC_FORMAT_MACROS',
  43   '-D__STDC_LIMIT_MACROS',
  44   '-DPACKAGE_VERSION="@0@"'.format(meson.project_version()),
  45   '-DPACKAGE_BUGREPORT="https://gitlab.freedesktop.org/mesa/mesa/issues"',
  46 ]
  47
  48 with_vulkan_icd_dir = get_option('vulkan-icd-dir')
  49 with_tests = get_option('build-tests')
  50 with_valgrind = get_option('valgrind')
  51 with_libunwind = get_option('libunwind')
  52 with_glx_read_only_text = get_option('glx-read-only-text')
  53 with_glx_direct = get_option('glx-direct')
  54 with_osmesa = get_option('osmesa')
  55 with_swr_arches = get_option('swr-arches')
  56 with_tools = get_option('tools')
  57 if with_tools.contains('all')
  58   with_tools = [
  59     'drm-shim',
  60     'etnaviv',
  61     'freedreno',
  62     'glsl',
  63     'intel',
  64     'intel-ui',
  65     'lima',
  66     'nir',
  67     'nouveau',
  68     'xvmc',
  69   ]
  70 endif
  71
  72 dri_drivers_path = get_option('dri-drivers-path')
  73 if dri_drivers_path == ''
  74   dri_drivers_path = join_paths(get_option('prefix'), get_option('libdir'), 'dri')
  75 endif
  76 dri_search_path = get_option('dri-search-path')
  77 if dri_search_path == ''
  78   dri_search_path = dri_drivers_path
  79 endif
  80
  81 with_gles1 = get_option('gles1')
  82 with_gles2 = get_option('gles2')
  83 if host_machine.system() == 'windows'
  84   if with_gles1 == 'auto'
  85     with_gles1 = 'false'
  86   endif
  87   if with_gles2 == 'auto'
  88     with_gles2 = 'false'
  89   endif
  90 endif
  91 with_opengl = get_option('opengl')
  92
  93 # Default shared glapi off for windows, on elsewhere.
  94 _sg = get_option('shared-glapi')
  95 if _sg == 'auto'
  96   with_shared_glapi = host_machine.system() != 'windows'
  97 else
  98   with_shared_glapi = _sg == 'true'
  99 endif
 100
 101 # shared-glapi is required if at least two OpenGL APIs are being built
 102 if not with_shared_glapi
 103   if ((with_gles1 == 'true' and with_gles2 == 'true') or
 104       (with_gles1 == 'true' and with_opengl) or
 105       (with_gles2 == 'true' and with_opengl))
 106     error('shared-glapi required for building two or more of OpenGL, OpenGL ES 1.x, OpenGL ES 2.x')
 107   endif
 108   with_gles1 = 'false'
 109   with_gles2 = 'false'
 110 endif
 111
 112 # We require OpenGL for OpenGL ES
 113 if not with_opengl
 114   if (with_gles1 == 'true' or with_gles2 == 'true') and not with_opengl
 115     error('building OpenGL ES without OpenGL is not supported.')
 116   endif
 117   with_gles1 = 'false'
 118   with_gles2 = 'false'
 119 endif
 120
 121 with_gles1 = with_gles1 != 'false'
 122 with_gles2 = with_gles2 != 'false'
 123 with_any_opengl = with_opengl or with_gles1 or with_gles2
 124 # Only build shared_glapi if at least one OpenGL API is enabled
 125 with_shared_glapi = with_shared_glapi and with_any_opengl
 126
 127 system_has_kms_drm = ['openbsd', 'netbsd', 'freebsd', 'gnu/kfreebsd', 'dragonfly', 'linux'].contains(host_machine.system())
 128
 129 dri_drivers = get_option('dri-drivers')
 130 if dri_drivers.contains('auto')
 131   if system_has_kms_drm
 132     # TODO: PPC, Sparc
 133     if ['x86', 'x86_64'].contains(host_machine.cpu_family())
 134       dri_drivers = ['i915', 'i965', 'r100', 'r200', 'nouveau']
 135     elif ['arm', 'aarch64'].contains(host_machine.cpu_family())
 136       dri_drivers = []
 137     else
 138       error('Unknown architecture @0@. Please pass -Ddri-drivers to set driver options. Patches gladly accepted to fix this.'.format(
 139             host_machine.cpu_family()))
 140     endif
 141   elif ['darwin', 'windows', 'cygwin', 'haiku'].contains(host_machine.system())
 142     # only swrast would make sense here, but gallium swrast is a much better default
 143     dri_drivers = []
 144   else
 145     error('Unknown OS @0@. Please pass -Ddri-drivers to set driver options. Patches gladly accepted to fix this.'.format(
 146           host_machine.system()))
 147   endif
 148 endif
 149
 150 with_dri_i915 = dri_drivers.contains('i915')
 151 with_dri_i965 = dri_drivers.contains('i965')
 152 with_dri_r100 = dri_drivers.contains('r100')
 153 with_dri_r200 = dri_drivers.contains('r200')
 154 with_dri_nouveau = dri_drivers.contains('nouveau')
 155 with_dri_swrast = dri_drivers.contains('swrast')
 156
 157 with_dri = dri_drivers.length() != 0 and dri_drivers != ['']
 158
 159 gallium_drivers = get_option('gallium-drivers')
 160 if gallium_drivers.contains('auto')
 161   if system_has_kms_drm
 162     # TODO: PPC, Sparc
 163     if ['x86', 'x86_64'].contains(host_machine.cpu_family())
 164       gallium_drivers = [
 165         'r300', 'r600', 'radeonsi', 'nouveau', 'virgl', 'svga', 'swrast'
 166       ]
 167     elif ['arm', 'aarch64'].contains(host_machine.cpu_family())
 168       gallium_drivers = [
 169         'kmsro', 'v3d', 'vc4', 'freedreno', 'etnaviv', 'nouveau',
 170         'tegra', 'virgl', 'lima', 'panfrost', 'swrast'
 171       ]
 172     else
 173       error('Unknown architecture @0@. Please pass -Dgallium-drivers to set driver options. Patches gladly accepted to fix this.'.format(
 174             host_machine.cpu_family()))
 175     endif
 176   elif ['darwin', 'windows', 'cygwin', 'haiku'].contains(host_machine.system())
 177     gallium_drivers = ['swrast']
 178   else
 179     error('Unknown OS @0@. Please pass -Dgallium-drivers to set driver options. Patches gladly accepted to fix this.'.format(
 180           host_machine.system()))
 181   endif
 182 endif
 183 with_gallium_kmsro = gallium_drivers.contains('kmsro')
 184 with_gallium_radeonsi = gallium_drivers.contains('radeonsi')
 185 with_gallium_r300 = gallium_drivers.contains('r300')
 186 with_gallium_r600 = gallium_drivers.contains('r600')
 187 with_gallium_nouveau = gallium_drivers.contains('nouveau')
 188 with_gallium_freedreno = gallium_drivers.contains('freedreno')
 189 with_gallium_softpipe = gallium_drivers.contains('swrast')
 190 with_gallium_vc4 = gallium_drivers.contains('vc4')
 191 with_gallium_v3d = gallium_drivers.contains('v3d')
 192 with_gallium_panfrost = gallium_drivers.contains('panfrost')
 193 with_gallium_etnaviv = gallium_drivers.contains('etnaviv')
 194 with_gallium_tegra = gallium_drivers.contains('tegra')
 195 with_gallium_iris = gallium_drivers.contains('iris')
 196 with_gallium_i915 = gallium_drivers.contains('i915')
 197 with_gallium_svga = gallium_drivers.contains('svga')
 198 with_gallium_virgl = gallium_drivers.contains('virgl')
 199 with_gallium_swr = gallium_drivers.contains('swr')
 200 with_gallium_lima = gallium_drivers.contains('lima')
 201
 202 if cc.get_id() == 'intel'
 203   if meson.version().version_compare('< 0.49.0')
 204     error('Meson does not have sufficient support of ICC before 0.49.0 to compile mesa')
 205   elif with_gallium_swr and meson.version().version_compare('== 0.49.0')
 206     warning('Meson as of 0.49.0 is sufficient for compiling mesa with ICC, but there are some caveats with SWR. 0.49.1 should resolve all of these')
 207   endif
 208 endif
 209
 210 with_gallium = gallium_drivers.length() != 0 and gallium_drivers != ['']
 211
 212 if with_gallium and system_has_kms_drm
 213   _glx = get_option('glx')
 214   _egl = get_option('egl')
 215   if _glx == 'dri' or _egl == 'true' or (_glx == 'disabled' and _egl != 'false')
 216     with_dri = true
 217   endif
 218 endif
 219
 220 _vulkan_drivers = get_option('vulkan-drivers')
 221 if _vulkan_drivers.contains('auto')
 222   if system_has_kms_drm
 223     if host_machine.cpu_family().startswith('x86')
 224       _vulkan_drivers = ['amd', 'intel']
 225     elif ['arm', 'aarch64'].contains(host_machine.cpu_family())
 226       _vulkan_drivers = []
 227     else
 228       error('Unknown architecture @0@. Please pass -Dvulkan-drivers to set driver options. Patches gladly accepted to fix this.'.format(
 229             host_machine.cpu_family()))
 230     endif
 231   elif ['darwin', 'windows', 'cygwin', 'haiku'].contains(host_machine.system())
 232     # No vulkan driver supports windows or macOS currently
 233     _vulkan_drivers = []
 234   else
 235     error('Unknown OS @0@. Please pass -Dvulkan-drivers to set driver options. Patches gladly accepted to fix this.'.format(
 236           host_machine.system()))
 237   endif
 238 endif
 239
 240 with_intel_vk = _vulkan_drivers.contains('intel')
 241 with_amd_vk = _vulkan_drivers.contains('amd')
 242 with_freedreno_vk = _vulkan_drivers.contains('freedreno')
 243 with_any_vk = _vulkan_drivers.length() != 0 and _vulkan_drivers != ['']
 244
 245 if with_freedreno_vk and get_option('I-love-half-baked-turnips') != true
 246   error('Cannot enable freedreno vulkan driver')
 247 endif
 248
 249 if with_dri_swrast and (with_gallium_softpipe or with_gallium_swr)
 250   error('Only one swrast provider can be built')
 251 endif
 252 if with_dri_i915 and with_gallium_i915
 253   error('Only one i915 provider can be built')
 254 endif
 255 if with_gallium_kmsro and not (with_gallium_v3d or with_gallium_vc4 or with_gallium_etnaviv or with_gallium_freedreno or with_gallium_panfrost or with_gallium_lima)
 256   error('kmsro driver requires one or more renderonly drivers (vc4, etnaviv, freedreno, panfrost, lima)')
 257 endif
 258 if with_gallium_tegra and not with_gallium_nouveau
 259   error('tegra driver requires nouveau driver')
 260 endif
 261
 262 if host_machine.system() == 'darwin'
 263   with_dri_platform = 'apple'
 264   pre_args += '-DBUILDING_MESA'
 265 elif ['windows', 'cygwin'].contains(host_machine.system())
 266   with_dri_platform = 'windows'
 267 elif system_has_kms_drm
 268   with_dri_platform = 'drm'
 269 else
 270   # FIXME: haiku doesn't use dri, and xlib doesn't use dri, probably should
 271   # assert here that one of those cases has been met.
 272   # FIXME: illumos ends up here as well
 273   with_dri_platform = 'none'
 274 endif
 275
 276 _platforms = get_option('platforms')
 277 if _platforms.contains('auto')
 278   if system_has_kms_drm
 279     _platforms = ['x11', 'wayland', 'drm', 'surfaceless']
 280   elif ['darwin', 'cygwin'].contains(host_machine.system())
 281     _platforms = ['x11', 'surfaceless']
 282   elif ['haiku'].contains(host_machine.system())
 283     _platforms = ['haiku']
 284   elif host_machine.system() == 'windows'
 285     _platforms = ['windows']
 286   else
 287     error('Unknown OS @0@. Please pass -Dplatforms to set platforms. Patches gladly accepted to fix this.'.format(
 288           host_machine.system()))
 289   endif
 290 endif
 291
 292 with_platform_android = _platforms.contains('android')
 293 with_platform_x11 = _platforms.contains('x11')
 294 with_platform_wayland = _platforms.contains('wayland')
 295 with_platform_drm = _platforms.contains('drm')
 296 with_platform_haiku = _platforms.contains('haiku')
 297 with_platform_surfaceless = _platforms.contains('surfaceless')
 298 with_platform_windows = _platforms.contains('windows')
 299
 300 with_platforms = false
 301 if _platforms.length() != 0 and _platforms != ['']
 302   # sanity check that list contains no empty strings
 303   if _platforms.contains('')
 304     error('Invalid argument list given to -Dplatforms, please fix.')
 305   endif
 306   with_platforms = true
 307   egl_native_platform = _platforms[0]
 308 endif
 309
 310 _xlib_lease = get_option('xlib-lease')
 311 if _xlib_lease == 'auto'
 312   with_xlib_lease = with_platform_x11 and with_platform_drm
 313 else
 314   with_xlib_lease = _xlib_lease == 'true'
 315 endif
 316
 317 with_glx = get_option('glx')
 318 if with_glx == 'auto'
 319   if with_dri
 320     with_glx = 'dri'
 321   elif with_platform_haiku
 322     with_glx = 'disabled'
 323   elif host_machine.system() == 'windows'
 324     with_glx = 'disabled'
 325   elif with_gallium
 326     # Even when building just gallium drivers the user probably wants dri
 327     with_glx = 'dri'
 328   elif with_platform_x11 and with_any_opengl and not with_any_vk
 329     # The automatic behavior should not be to turn on xlib based glx when
 330     # building only vulkan drivers
 331     with_glx = 'xlib'
 332   else
 333     with_glx = 'disabled'
 334   endif
 335 endif
 336 if with_glx == 'dri'
 337    if with_gallium
 338       with_dri = true
 339    endif
 340 endif
 341
 342 if not (with_dri or with_gallium or with_glx != 'disabled')
 343   with_gles1 = false
 344   with_gles2 = false
 345   with_opengl = false
 346   with_any_opengl = false
 347   with_shared_glapi = false
 348 endif
 349
 350 _gbm = get_option('gbm')
 351 if _gbm == 'auto'
 352   with_gbm = system_has_kms_drm and with_dri
 353 else
 354   with_gbm = _gbm == 'true'
 355 endif
 356 if with_gbm and not system_has_kms_drm
 357   error('GBM only supports DRM/KMS platforms')
 358 endif
 359
 360 _egl = get_option('egl')
 361 if _egl == 'auto'
 362   with_egl = (
 363     not ['darwin', 'windows'].contains(host_machine.system()) and
 364     with_dri and with_shared_glapi and with_platforms
 365   )
 366 elif _egl == 'true'
 367   if not with_dri
 368     error('EGL requires dri')
 369   elif not with_shared_glapi
 370     error('EGL requires shared-glapi')
 371   elif not with_platforms
 372     error('No platforms specified, consider -Dplatforms=drm,x11,surfaceless at least')
 373   elif not ['disabled', 'dri'].contains(with_glx)
 374     error('EGL requires dri, but a GLX is being built without dri')
 375   elif ['darwin', 'windows'].contains(host_machine.system())
 376     error('EGL is not available on Windows or MacOS')
 377   endif
 378   with_egl = true
 379 else
 380   with_egl = false
 381 endif
 382
 383 if with_egl and not (with_platform_drm or with_platform_surfaceless or with_platform_android)
 384   if with_gallium_radeonsi
 385     error('RadeonSI requires the drm, surfaceless or android platform when using EGL')
 386   endif
 387   if with_gallium_virgl
 388     error('Virgl requires the drm, surfaceless or android platform when using EGL')
 389   endif
 390 endif
 391
 392 # Android uses emutls for versions <= P/28. For USE_ELF_TLS we need ELF TLS.
 393 if not with_platform_android or get_option('platform-sdk-version') >= 29
 394   pre_args += '-DUSE_ELF_TLS'
 395 endif
 396
 397 if with_glx != 'disabled'
 398   if not (with_platform_x11 and with_any_opengl)
 399     error('Cannot build GLX support without X11 platform support and at least one OpenGL API')
 400   elif with_glx == 'gallium-xlib'
 401     if not with_gallium
 402       error('Gallium-xlib based GLX requires at least one gallium driver')
 403     elif not with_gallium_softpipe
 404       error('Gallium-xlib based GLX requires softpipe or llvmpipe.')
 405     elif with_dri
 406       error('gallium-xlib conflicts with any dri driver')
 407     endif
 408   elif with_glx == 'xlib'
 409     if with_dri
 410       error('xlib conflicts with any dri driver')
 411     endif
 412   elif with_glx == 'dri'
 413     if not with_shared_glapi
 414       error('dri based GLX requires shared-glapi')
 415     endif
 416   endif
 417 endif
 418
 419 with_glvnd = get_option('glvnd')
 420 if with_glvnd
 421   if with_platform_windows
 422     error('glvnd cannot be used on Windows')
 423   elif with_glx == 'xlib' or with_glx == 'gallium-xlib'
 424     error('Cannot build glvnd support for GLX that is not DRI based.')
 425   elif with_glx == 'disabled' and not with_egl
 426     error('glvnd requires DRI based GLX and/or EGL')
 427   endif
 428   if get_option('egl-lib-suffix') != ''
 429     error('''EGL lib suffix can't be used with libglvnd''')
 430   endif
 431 endif
 432
 433 if with_vulkan_icd_dir == ''
 434   with_vulkan_icd_dir = join_paths(get_option('datadir'), 'vulkan/icd.d')
 435 endif
 436
 437 with_dri2 = (with_dri or with_any_vk) and (with_dri_platform == 'drm' or
 438   host_machine.system() == 'gnu')
 439 _dri3 = get_option('dri3')
 440 if _dri3 == 'auto'
 441   with_dri3 = system_has_kms_drm and with_dri2
 442 else
 443   with_dri3 = _dri3 == 'true'
 444 endif
 445
 446 if with_any_vk and (with_platform_x11 and not with_dri3)
 447   error('Vulkan drivers require dri3 for X11 support')
 448 endif
 449 if with_dri
 450   if with_glx == 'disabled' and not with_egl and not with_gbm and with_osmesa != 'classic'
 451     error('building dri drivers require at least one windowing system or classic osmesa')
 452   endif
 453 endif
 454
 455 prog_pkgconfig = find_program('pkg-config')
 456
 457 _vdpau = get_option('gallium-vdpau')
 458 if not system_has_kms_drm
 459   if _vdpau == 'true'
 460     error('VDPAU state tracker can only be build on unix-like OSes.')
 461   else
 462     _vdpau = 'false'
 463   endif
 464 elif not with_platform_x11
 465   if _vdpau == 'true'
 466     error('VDPAU state tracker requires X11 support.')
 467   else
 468     _vdpau = 'false'
 469   endif
 470 elif not (with_gallium_r300 or with_gallium_r600 or with_gallium_radeonsi or
 471           with_gallium_nouveau)
 472   if _vdpau == 'true'
 473     error('VDPAU state tracker requires at least one of the following gallium drivers: r300, r600, radeonsi, nouveau.')
 474   else
 475     _vdpau = 'false'
 476   endif
 477 endif
 478 dep_vdpau = null_dep
 479 with_gallium_vdpau = false
 480 if _vdpau != 'false'
 481   dep_vdpau = dependency('vdpau', version : '>= 1.1', required : _vdpau == 'true')
 482   if dep_vdpau.found()
 483     dep_vdpau = declare_dependency(
 484       compile_args : run_command(prog_pkgconfig, ['vdpau', '--cflags']).stdout().split()
 485     )
 486     with_gallium_vdpau = true
 487   endif
 488 endif
 489
 490 if with_gallium_vdpau
 491   pre_args += '-DHAVE_ST_VDPAU'
 492 endif
 493 vdpau_drivers_path = get_option('vdpau-libs-path')
 494 if vdpau_drivers_path == ''
 495   vdpau_drivers_path = join_paths(get_option('libdir'), 'vdpau')
 496 endif
 497
 498 _xvmc = get_option('gallium-xvmc')
 499 if not system_has_kms_drm
 500   if _xvmc == 'true'
 501     error('XVMC state tracker can only be build on unix-like OSes.')
 502   else
 503     _xvmc = 'false'
 504   endif
 505 elif not with_platform_x11
 506   if _xvmc == 'true'
 507     error('XVMC state tracker requires X11 support.')
 508   else
 509     _xvmc = 'false'
 510   endif
 511 elif not (with_gallium_r600 or with_gallium_nouveau)
 512   if _xvmc == 'true'
 513     error('XVMC state tracker requires at least one of the following gallium drivers: r600, nouveau.')
 514   else
 515     _xvmc = 'false'
 516   endif
 517 endif
 518 dep_xvmc = null_dep
 519 with_gallium_xvmc = false
 520 if _xvmc != 'false'
 521   dep_xvmc = dependency('xvmc', version : '>= 1.0.6', required : _xvmc == 'true')
 522   with_gallium_xvmc = dep_xvmc.found()
 523 endif
 524
 525 xvmc_drivers_path = get_option('xvmc-libs-path')
 526 if xvmc_drivers_path == ''
 527   xvmc_drivers_path = get_option('libdir')
 528 endif
 529
 530 _omx = get_option('gallium-omx')
 531 if not system_has_kms_drm
 532   if ['auto', 'disabled'].contains(_omx)
 533     _omx = 'disabled'
 534   else
 535     error('OMX state tracker can only be built on unix-like OSes.')
 536   endif
 537 elif not (with_gallium_r600 or with_gallium_radeonsi or with_gallium_nouveau)
 538   if ['auto', 'disabled'].contains(_omx)
 539     _omx = 'disabled'
 540   else
 541     error('OMX state tracker requires at least one of the following gallium drivers: r600, radeonsi, nouveau.')
 542   endif
 543 endif
 544 with_gallium_omx = _omx
 545 dep_omx = null_dep
 546 dep_omx_other = []
 547 if ['auto', 'bellagio'].contains(_omx)
 548   dep_omx = dependency(
 549     'libomxil-bellagio', required : _omx == 'bellagio'
 550   )
 551   if dep_omx.found()
 552     with_gallium_omx = 'bellagio'
 553   endif
 554 endif
 555 if ['auto', 'tizonia'].contains(_omx)
 556   if with_dri and with_egl
 557     dep_omx = dependency(
 558       'libtizonia', version : '>= 0.10.0',
 559       required : _omx == 'tizonia',
 560     )
 561     dep_omx_other = [
 562       dependency('libtizplatform', required : _omx == 'tizonia'),
 563       dependency('tizilheaders', required : _omx == 'tizonia'),
 564     ]
 565     if dep_omx.found() and dep_omx_other[0].found() and dep_omx_other[1].found()
 566       with_gallium_omx = 'tizonia'
 567     endif
 568   elif _omx == 'tizonia'
 569     error('OMX-Tizonia state tracker requires dri and egl')
 570   endif
 571 endif
 572 if _omx == 'auto'
 573   with_gallium_omx = 'disabled'
 574 else
 575   with_gallium_omx = _omx
 576 endif
 577
 578 pre_args += [
 579   '-DENABLE_ST_OMX_BELLAGIO=' + (with_gallium_omx == 'bellagio' ? '1' : '0'),
 580   '-DENABLE_ST_OMX_TIZONIA=' + (with_gallium_omx == 'tizonia' ? '1' : '0'),
 581 ]
 582
 583
 584 omx_drivers_path = get_option('omx-libs-path')
 585
 586 if with_gallium_omx != 'disabled'
 587   # Figure out where to put the omx driver.
 588   # FIXME: this could all be vastly simplified by adding a 'defined_variable'
 589   # argument to meson's get_pkgconfig_variable method.
 590   if omx_drivers_path == ''
 591     _omx_libdir = dep_omx.get_pkgconfig_variable('libdir')
 592     _omx_drivers_dir = dep_omx.get_pkgconfig_variable('pluginsdir')
 593     if _omx_libdir == get_option('libdir')
 594       omx_drivers_path = _omx_drivers_dir
 595     else
 596       _omx_base_dir = []
 597       # This will fail on windows. Does OMX run on windows?
 598       _omx_libdir = _omx_libdir.split('/')
 599       _omx_drivers_dir = _omx_drivers_dir.split('/')
 600       foreach o : _omx_drivers_dir
 601         if not _omx_libdir.contains(o)
 602           _omx_base_dir += o
 603         endif
 604       endforeach
 605       omx_drivers_path = join_paths(get_option('libdir'), _omx_base_dir)
 606     endif
 607   endif
 608 endif
 609
 610 _va = get_option('gallium-va')
 611 if not system_has_kms_drm
 612   if _va == 'true'
 613     error('VA state tracker can only be built on unix-like OSes.')
 614   else
 615     _va = 'false'
 616   endif
 617 elif not (with_gallium_r600 or with_gallium_radeonsi or with_gallium_nouveau)
 618   if _va == 'true'
 619     error('VA state tracker requires at least one of the following gallium drivers: r600, radeonsi, nouveau.')
 620   else
 621     _va = 'false'
 622   endif
 623 endif
 624 with_gallium_va = false
 625 dep_va = null_dep
 626 if _va != 'false'
 627   dep_va = dependency('libva', version : '>= 0.38.0', required : _va == 'true')
 628   if dep_va.found()
 629     dep_va_headers = declare_dependency(
 630       compile_args : run_command(prog_pkgconfig, ['libva', '--cflags']).stdout().split()
 631     )
 632     with_gallium_va = true
 633   endif
 634 endif
 635
 636 va_drivers_path = get_option('va-libs-path')
 637 if va_drivers_path == ''
 638   va_drivers_path = join_paths(get_option('libdir'), 'dri')
 639 endif
 640
 641 _xa = get_option('gallium-xa')
 642 if not system_has_kms_drm
 643   if _xa == 'true'
 644     error('XA state tracker can only be built on unix-like OSes.')
 645   else
 646     _xa = 'false'
 647   endif
 648 elif not (with_gallium_nouveau or with_gallium_freedreno or with_gallium_i915
 649           or with_gallium_svga)
 650   if _xa == 'true'
 651     error('XA state tracker requires at least one of the following gallium drivers: nouveau, freedreno, i915, svga.')
 652   else
 653     _xa = 'false'
 654   endif
 655 endif
 656 with_gallium_xa = _xa != 'false'
 657
 658 d3d_drivers_path = get_option('d3d-drivers-path')
 659 if d3d_drivers_path == ''
 660   d3d_drivers_path = join_paths(get_option('prefix'), get_option('libdir'), 'd3d')
 661 endif
 662
 663 with_gallium_st_nine =  get_option('gallium-nine')
 664 if with_gallium_st_nine
 665   if not with_gallium_softpipe
 666     error('The nine state tracker requires gallium softpipe/llvmpipe.')
 667   elif not (with_gallium_radeonsi or with_gallium_nouveau or with_gallium_r600
 668             or with_gallium_r300 or with_gallium_svga or with_gallium_i915
 669             or with_gallium_iris)
 670     error('The nine state tracker requires at least one non-swrast gallium driver.')
 671   endif
 672   if not with_dri3
 673     error('Using nine with wine requires dri3')
 674   endif
 675 endif
 676
 677 if get_option('power8') != 'false'
 678   # on old versions of meson the cpu family would return as ppc64le on little
 679   # endian power8, this was changed in 0.48 such that the family would always
 680   # be ppc64 regardless of endianness, and then the machine.endian() value
 681   # should be checked. Since we support versions < 0.48 we need to use
 682   # startswith.
 683   if host_machine.cpu_family().startswith('ppc64') and host_machine.endian() == 'little'
 684     if cc.get_id() == 'gcc' and cc.version().version_compare('< 4.8')
 685       error('Altivec is not supported with gcc version < 4.8.')
 686     endif
 687     if cc.compiles('''
 688         #include <altivec.h>
 689         int main() {
 690           vector unsigned char r;
 691           vector unsigned int v = vec_splat_u32 (1);
 692           r = __builtin_vec_vgbbd ((vector unsigned char) v);
 693           return 0;
 694         }''',
 695         args : '-mpower8-vector',
 696         name : 'POWER8 intrinsics')
 697       pre_args += ['-D_ARCH_PWR8', '-mpower8-vector']
 698     elif get_option('power8') == 'true'
 699       error('POWER8 intrinsic support required but not found.')
 700     endif
 701   endif
 702 endif
 703
 704 _opencl = get_option('gallium-opencl')
 705 clover_cpp_std = []
 706 if _opencl != 'disabled'
 707   if not with_gallium
 708     error('OpenCL Clover implementation requires at least one gallium driver.')
 709   endif
 710
 711   dep_clc = dependency('libclc')
 712   with_gallium_opencl = true
 713   with_opencl_icd = _opencl == 'icd'
 714
 715   with_opencl_spirv = get_option('opencl-spirv')
 716   if with_opencl_spirv
 717     dep_spirv_tools = dependency('SPIRV-Tools', required : true, version : '>= 2018.0')
 718     # LLVMSPIRVLib is available at https://github.com/KhronosGroup/SPIRV-LLVM-Translator
 719     dep_llvmspirvlib = dependency('LLVMSPIRVLib', required : true, version : '>= 0.2.1')
 720   else
 721     dep_spirv_tools = null_dep
 722     dep_llvmspirvlib = null_dep
 723   endif
 724
 725   if host_machine.cpu_family().startswith('ppc') and cpp.compiles('''
 726       #if !defined(__VEC__) || !defined(__ALTIVEC__)
 727       #error "AltiVec not enabled"
 728       #endif''',
 729       name : 'Altivec')
 730     clover_cpp_std += ['cpp_std=gnu++11']
 731   endif
 732 else
 733   dep_clc = null_dep
 734   dep_spirv_tools = null_dep
 735   dep_llvmspirvlib = null_dep
 736   with_gallium_opencl = false
 737   with_opencl_icd = false
 738   with_opencl_spirv = false
 739 endif
 740
 741 gl_pkgconfig_c_flags = []
 742 if with_platform_x11
 743   if with_any_vk or with_egl or (with_glx == 'dri' and with_dri_platform == 'drm')
 744     pre_args += '-DHAVE_X11_PLATFORM'
 745   endif
 746   if with_glx == 'xlib' or with_glx == 'gallium-xlib'
 747     pre_args += '-DUSE_XSHM'
 748   else
 749     pre_args += '-DGLX_INDIRECT_RENDERING'
 750     if with_glx_direct
 751       pre_args += '-DGLX_DIRECT_RENDERING'
 752     endif
 753     if with_dri_platform == 'drm'
 754       pre_args += '-DGLX_USE_DRM'
 755     elif with_dri_platform == 'apple'
 756       pre_args += '-DGLX_USE_APPLEGL'
 757     elif with_dri_platform == 'windows'
 758       pre_args += '-DGLX_USE_WINDOWSGL'
 759     endif
 760   endif
 761 else
 762   pre_args += '-DMESA_EGL_NO_X11_HEADERS'
 763   gl_pkgconfig_c_flags += '-DMESA_EGL_NO_X11_HEADERS'
 764 endif
 765 if with_platform_drm
 766   if with_egl and not with_gbm
 767     error('EGL drm platform requires gbm')
 768   endif
 769   pre_args += '-DHAVE_DRM_PLATFORM'
 770 endif
 771 if with_platform_surfaceless
 772   pre_args += '-DHAVE_SURFACELESS_PLATFORM'
 773 endif
 774 if with_platform_android
 775   dep_android = [
 776     dependency('cutils'),
 777     dependency('hardware'),
 778     dependency('sync'),
 779   ]
 780   if get_option('platform-sdk-version') >= 26
 781     dep_android += dependency('nativewindow')
 782   endif
 783   pre_args += '-DHAVE_ANDROID_PLATFORM'
 784 endif
 785 if with_platform_haiku
 786   pre_args += '-DHAVE_HAIKU_PLATFORM'
 787 endif
 788
 789 if meson.version().version_compare('>=0.50')
 790   prog_python = import('python').find_installation('python3')
 791 else
 792   prog_python = import('python3').find_python()
 793 endif
 794 has_mako = run_command(
 795   prog_python, '-c',
 796   '''
 797 from distutils.version import StrictVersion
 798 import mako
 799 assert StrictVersion(mako.__version__) > StrictVersion("0.8.0")
 800   ''')
 801 if has_mako.returncode() != 0
 802   error('Python (3.x) mako module >= 0.8.0 required to build mesa.')
 803 endif
 804
 805 if cc.get_id() == 'gcc' and cc.version().version_compare('< 4.4.6')
 806   error('When using GCC, version 4.4.6 or later is required.')
 807 endif
 808
 809 # Support systems without ETIME (e.g. FreeBSD)
 810 if cc.get_define('ETIME', prefix : '#include <errno.h>') == ''
 811   pre_args += '-DETIME=ETIMEDOUT'
 812 endif
 813
 814 # Define DEBUG for debug builds only (debugoptimized is not included on this one)
 815 if get_option('buildtype') == 'debug'
 816   pre_args += '-DDEBUG'
 817 endif
 818
 819 with_shader_cache = false
 820 _shader_cache = get_option('shader-cache')
 821 if _shader_cache != 'false'
 822   if host_machine.system() == 'windows'
 823     if _shader_cache == 'true'
 824       error('Shader Cache does not currently work on Windows')
 825     endif
 826   else
 827     pre_args += '-DENABLE_SHADER_CACHE'
 828     with_shader_cache = true
 829   endif
 830 endif
 831 if with_amd_vk and not with_shader_cache
 832   error('Radv requires shader cache support')
 833 endif
 834
 835 # Check for GCC style builtins
 836 foreach b : ['bswap32', 'bswap64', 'clz', 'clzll', 'ctz', 'expect', 'ffs',
 837              'ffsll', 'popcount', 'popcountll', 'unreachable']
 838   if cc.has_function(b)
 839     pre_args += '-DHAVE___BUILTIN_@0@'.format(b.to_upper())
 840   endif
 841 endforeach
 842
 843 # check for GCC __attribute__
 844 foreach a : ['const', 'flatten', 'malloc', 'pure', 'unused',
 845              'warn_unused_result', 'weak',]
 846   if cc.compiles('int foo(void) __attribute__((@0@));'.format(a),
 847                  name : '__attribute__((@0@))'.format(a))
 848     pre_args += '-DHAVE_FUNC_ATTRIBUTE_@0@'.format(a.to_upper())
 849   endif
 850 endforeach
 851 if cc.compiles('int foo(const char *p, ...) __attribute__((format(printf, 1, 2)));',
 852                name : '__attribute__((format(...)))')
 853   pre_args += '-DHAVE_FUNC_ATTRIBUTE_FORMAT'
 854 endif
 855 if cc.compiles('struct __attribute__((packed)) foo { int bar; };',
 856                name : '__attribute__((packed))')
 857   pre_args += '-DHAVE_FUNC_ATTRIBUTE_PACKED'
 858 endif
 859 if cc.compiles('int *foo(void) __attribute__((returns_nonnull));',
 860                name : '__attribute__((returns_nonnull))')
 861   pre_args += '-DHAVE_FUNC_ATTRIBUTE_RETURNS_NONNULL'
 862 endif
 863 if cc.compiles('''int foo_def(void) __attribute__((visibility("default")));
 864                   int foo_hid(void) __attribute__((visibility("hidden")));
 865                   int foo_int(void) __attribute__((visibility("internal")));
 866                   int foo_pro(void) __attribute__((visibility("protected")));''',
 867                name : '__attribute__((visibility(...)))')
 868   pre_args += '-DHAVE_FUNC_ATTRIBUTE_VISIBILITY'
 869 endif
 870 if cc.compiles('int foo(void) { return 0; } int bar(void) __attribute__((alias("foo")));',
 871                name : '__attribute__((alias(...)))')
 872   pre_args += '-DHAVE_FUNC_ATTRIBUTE_ALIAS'
 873 endif
 874 if cc.compiles('int foo(void) __attribute__((__noreturn__));',
 875                name : '__attribute__((__noreturn__))')
 876   pre_args += '-DHAVE_FUNC_ATTRIBUTE_NORETURN'
 877 endif
 878 if cc.compiles('__uint128_t foo(void) { return 0; }',
 879                name : '__uint128_t')
 880   pre_args += '-DHAVE_UINT128'
 881 endif
 882
 883 # TODO: this is very incomplete
 884 if ['linux', 'cygwin', 'gnu', 'gnu/kfreebsd'].contains(host_machine.system())
 885   pre_args += '-D_GNU_SOURCE'
 886 endif
 887
 888 # Check for generic C arguments
 889 c_args = []
 890 foreach a : ['-Werror=implicit-function-declaration',
 891              '-Werror=missing-prototypes',
 892              '-Werror=return-type',
 893              '-Werror=incompatible-pointer-types',
 894              '-Werror=format',
 895              '-Wformat-security',
 896              '-fno-math-errno',
 897              '-fno-trapping-math', '-Qunused-arguments']
 898   if cc.has_argument(a)
 899     c_args += a
 900   endif
 901 endforeach
 902
 903 foreach a : ['missing-field-initializers', 'format-truncation']
 904   if cc.has_argument('-W' + a)
 905     c_args += '-Wno-' + a
 906   endif
 907 endforeach
 908
 909 c_vis_args = []
 910 if cc.has_argument('-fvisibility=hidden')
 911   c_vis_args += '-fvisibility=hidden'
 912 endif
 913
 914 # Check for generic C++ arguments
 915 cpp_args = []
 916 foreach a : ['-Werror=return-type',
 917              '-Werror=format',
 918              '-Wformat-security',
 919              '-fno-math-errno', '-fno-trapping-math',
 920              '-Qunused-arguments']
 921   if cpp.has_argument(a)
 922     cpp_args += a
 923   endif
 924 endforeach
 925
 926 # For some reason, the test for -Wno-foo always succeeds with gcc, even if the
 927 # option is not supported. Hence, check for -Wfoo instead.
 928
 929 foreach a : ['non-virtual-dtor', 'missing-field-initializers', 'format-truncation']
 930   if cpp.has_argument('-W' + a)
 931     cpp_args += '-Wno-' + a
 932   endif
 933 endforeach
 934
 935 no_override_init_args = []
 936 foreach a : ['override-init', 'initializer-overrides']
 937   if cc.has_argument('-W' + a)
 938     no_override_init_args += '-Wno-' + a
 939   endif
 940 endforeach
 941
 942 cpp_vis_args = []
 943 if cpp.has_argument('-fvisibility=hidden')
 944   cpp_vis_args += '-fvisibility=hidden'
 945 endif
 946
 947 # Check for C and C++ arguments for MSVC2013 compatibility. These are only used
 948 # in parts of the mesa code base that need to compile with old versions of
 949 # MSVC, mainly common code
 950 c_msvc_compat_args = []
 951 cpp_msvc_compat_args = []
 952 foreach a : ['-Werror=pointer-arith', '-Werror=vla']
 953   if cc.has_argument(a)
 954     c_msvc_compat_args += a
 955   endif
 956   if cpp.has_argument(a)
 957     cpp_msvc_compat_args += a
 958   endif
 959 endforeach
 960
 961 if host_machine.cpu_family().startswith('x86')
 962   pre_args += '-DUSE_SSE41'
 963   with_sse41 = true
 964   sse41_args = ['-msse4.1']
 965
 966   # GCC on x86 (not x86_64) with -msse* assumes a 16 byte aligned stack, but
 967   # that's not guaranteed
 968   if host_machine.cpu_family() == 'x86'
 969     sse41_args += '-mstackrealign'
 970   endif
 971 else
 972   with_sse41 = false
 973   sse41_args = []
 974 endif
 975
 976 # Check for GCC style atomics
 977 dep_atomic = null_dep
 978
 979 if cc.compiles('''#include <stdint.h>
 980                   int main() {
 981                     struct {
 982                       uint64_t *v;
 983                     } x;
 984                     return (int)__atomic_load_n(x.v, __ATOMIC_ACQUIRE) &
 985                            (int)__atomic_add_fetch(x.v, (uint64_t)1, __ATOMIC_ACQ_REL);
 986
 987                   }''',
 988                name : 'GCC atomic builtins')
 989   pre_args += '-DUSE_GCC_ATOMIC_BUILTINS'
 990
 991   # Not all atomic calls can be turned into lock-free instructions, in which
 992   # GCC will make calls into the libatomic library. Check whether we need to
 993   # link with -latomic.
 994   #
 995   # This can happen for 64-bit atomic operations on 32-bit architectures such
 996   # as ARM.
 997   if not cc.links('''#include <stdint.h>
 998                      int main() {
 999                        struct {
1000                          uint64_t *v;
1001                        } x;
1002                        return (int)__atomic_load_n(x.v, __ATOMIC_ACQUIRE) &
1003                               (int)__atomic_add_fetch(x.v, (uint64_t)1, __ATOMIC_ACQ_REL);
1004                      }''',
1005                   name : 'GCC atomic builtins required -latomic')
1006     dep_atomic = cc.find_library('atomic')
1007   endif
1008 endif
1009 if not cc.links('''#include <stdint.h>
1010                    uint64_t v;
1011                    int main() {
1012                      return __sync_add_and_fetch(&v, (uint64_t)1);
1013                    }''',
1014                 dependencies : dep_atomic,
1015                 name : 'GCC 64bit atomics')
1016   pre_args += '-DMISSING_64BIT_ATOMICS'
1017 endif
1018
1019 # TODO: shared/static? Is this even worth doing?
1020
1021 with_asm_arch = ''
1022 if host_machine.cpu_family() == 'x86'
1023   if system_has_kms_drm or host_machine.system() == 'gnu'
1024     with_asm_arch = 'x86'
1025     pre_args += ['-DUSE_X86_ASM', '-DUSE_MMX_ASM', '-DUSE_3DNOW_ASM',
1026                  '-DUSE_SSE_ASM']
1027
1028     if with_glx_read_only_text
1029       pre_args += ['-DGLX_X86_READONLY_TEXT']
1030     endif
1031   endif
1032 elif host_machine.cpu_family() == 'x86_64'
1033   if system_has_kms_drm
1034     with_asm_arch = 'x86_64'
1035     pre_args += ['-DUSE_X86_64_ASM']
1036   endif
1037 elif host_machine.cpu_family() == 'arm'
1038   if system_has_kms_drm
1039     with_asm_arch = 'arm'
1040     pre_args += ['-DUSE_ARM_ASM']
1041   endif
1042 elif host_machine.cpu_family() == 'aarch64'
1043   if system_has_kms_drm
1044     with_asm_arch = 'aarch64'
1045     pre_args += ['-DUSE_AARCH64_ASM']
1046   endif
1047 elif host_machine.cpu_family() == 'sparc64'
1048   if system_has_kms_drm
1049     with_asm_arch = 'sparc'
1050     pre_args += ['-DUSE_SPARC_ASM']
1051   endif
1052 elif host_machine.cpu_family().startswith('ppc64') and host_machine.endian() == 'little'
1053   if system_has_kms_drm
1054     with_asm_arch = 'ppc64le'
1055     pre_args += ['-DUSE_PPC64LE_ASM']
1056   endif
1057 endif
1058
1059 # Check for standard headers and functions
1060 if cc.has_header_symbol('sys/sysmacros.h', 'major')
1061   pre_args += '-DMAJOR_IN_SYSMACROS'
1062 elif cc.has_header_symbol('sys/mkdev.h', 'major')
1063   pre_args += '-DMAJOR_IN_MKDEV'
1064 endif
1065
1066 foreach h : ['xlocale.h', 'sys/sysctl.h', 'linux/futex.h', 'endian.h', 'dlfcn.h', 'execinfo.h', 'sys/shm.h', 'cet.h']
1067   if cc.compiles('#include <@0@>'.format(h), name : '@0@'.format(h))
1068     pre_args += '-DHAVE_@0@'.format(h.to_upper().underscorify())
1069   endif
1070 endforeach
1071
1072 foreach f : ['strtof', 'mkostemp', 'posix_memalign', 'timespec_get', 'memfd_create', 'random_r']
1073   if cc.has_function(f)
1074     pre_args += '-DHAVE_@0@'.format(f.to_upper())
1075   endif
1076 endforeach
1077
1078 if cc.has_header_symbol('errno.h', 'program_invocation_name',
1079                         args : '-D_GNU_SOURCE')
1080    pre_args += '-DHAVE_PROGRAM_INVOCATION_NAME'
1081 elif with_tools.contains('intel')
1082   error('Intel tools require the program_invocation_name variable')
1083 endif
1084
1085 # strtod locale support
1086 if cc.links('''
1087     #define _GNU_SOURCE
1088     #include <stdlib.h>
1089     #include <locale.h>
1090     #ifdef HAVE_XLOCALE_H
1091     #include <xlocale.h>
1092     #endif
1093     int main() {
1094       locale_t loc = newlocale(LC_CTYPE_MASK, "C", NULL);
1095       const char *s = "1.0";
1096       char *end;
1097       double d = strtod_l(s, end, loc);
1098       float f = strtof_l(s, end, loc);
1099       freelocale(loc);
1100       return 0;
1101     }''',
1102     args : pre_args,
1103     name : 'strtod has locale support')
1104   pre_args += '-DHAVE_STRTOD_L'
1105 endif
1106
1107 # Check for some linker flags
1108 ld_args_bsymbolic = []
1109 if cc.links('int main() { return 0; }', args : '-Wl,-Bsymbolic', name : 'Bsymbolic')
1110   ld_args_bsymbolic += '-Wl,-Bsymbolic'
1111 endif
1112 ld_args_gc_sections = []
1113 if cc.links('static char unused() { return 5; } int main() { return 0; }',
1114             args : '-Wl,--gc-sections', name : 'gc-sections')
1115   ld_args_gc_sections += '-Wl,--gc-sections'
1116 endif
1117 with_ld_version_script = false
1118 if cc.links('int main() { return 0; }',
1119             args : '-Wl,--version-script=@0@'.format(
1120               join_paths(meson.source_root(), 'build-support/conftest.map')),
1121             name : 'version-script')
1122   with_ld_version_script = true
1123 endif
1124 with_ld_dynamic_list = false
1125 if cc.links('int main() { return 0; }',
1126             args : '-Wl,--dynamic-list=@0@'.format(
1127               join_paths(meson.source_root(), 'build-support/conftest.dyn')),
1128             name : 'dynamic-list')
1129   with_ld_dynamic_list = true
1130 endif
1131 ld_args_build_id = []
1132 if build_machine.system() != 'darwin'
1133    ld_args_build_id += '-Wl,--build-id=sha1'
1134 endif
1135
1136 # check for dl support
1137 dep_dl = null_dep
1138 if host_machine.system() != 'windows'
1139   if not cc.has_function('dlopen')
1140     dep_dl = cc.find_library('dl')
1141   endif
1142   if cc.has_function('dladdr', dependencies : dep_dl)
1143     # This is really only required for megadrivers
1144     pre_args += '-DHAVE_DLADDR'
1145   endif
1146 endif
1147
1148 if cc.has_function('dl_iterate_phdr')
1149   pre_args += '-DHAVE_DL_ITERATE_PHDR'
1150 elif with_intel_vk
1151   error('Intel "Anvil" Vulkan driver requires the dl_iterate_phdr function')
1152 elif with_dri_i965 and with_shader_cache
1153   error('Intel i965 GL driver requires dl_iterate_phdr when built with shader caching.')
1154 endif
1155
1156 # Determine whether or not the rt library is needed for time functions
1157 if cc.has_function('clock_gettime')
1158   dep_clock = null_dep
1159 else
1160   dep_clock = cc.find_library('rt')
1161 endif
1162
1163 # TODO: some of these may be conditional
1164 dep_zlib = dependency('zlib', version : '>= 1.2.3', fallback : ['zlib', 'zlib_dep'])
1165 pre_args += '-DHAVE_ZLIB'
1166 dep_thread = dependency('threads')
1167 if dep_thread.found() and host_machine.system() != 'windows'
1168   pre_args += '-DHAVE_PTHREAD'
1169   if cc.has_function(
1170       'pthread_setaffinity_np',
1171       dependencies : dep_thread,
1172       prefix : '#include <pthread.h>',
1173       args : '-D_GNU_SOURCE')
1174     pre_args += '-DHAVE_PTHREAD_SETAFFINITY'
1175   endif
1176   if cc.has_function(
1177       'pthread_setaffinity_np',
1178       dependencies : dep_thread,
1179       prefix : '#include <pthread_np.h>')
1180     pre_args += '-DPTHREAD_SETAFFINITY_IN_NP_HEADER'
1181   endif
1182 endif
1183 dep_expat = dependency('expat', fallback : ['expat', 'expat_dep'])
1184 # this only exists on linux so either this is linux and it will be found, or
1185 # it's not linux and wont
1186 dep_m = cc.find_library('m', required : false)
1187
1188 # Check for libdrm. Various drivers have different libdrm version requirements,
1189 # but we always want to use the same version for all libdrm modules. That means
1190 # even if driver foo requires 2.4.0 and driver bar requires 2.4.3, if foo and
1191 # bar are both on use 2.4.3 for both of them
1192 dep_libdrm_amdgpu = null_dep
1193 dep_libdrm_radeon = null_dep
1194 dep_libdrm_nouveau = null_dep
1195 dep_libdrm_intel = null_dep
1196
1197 _drm_amdgpu_ver = '2.4.99'
1198 _drm_radeon_ver = '2.4.71'
1199 _drm_nouveau_ver = '2.4.66'
1200 _drm_intel_ver = '2.4.75'
1201 _drm_ver = '2.4.81'
1202
1203 _libdrm_checks = [
1204   ['intel', with_dri_i915 or with_gallium_i915],
1205   ['amdgpu', with_amd_vk or with_gallium_radeonsi],
1206   ['radeon', (with_gallium_radeonsi or with_dri_r100 or with_dri_r200 or
1207               with_gallium_r300 or with_gallium_r600)],
1208   ['nouveau', (with_gallium_nouveau or with_dri_nouveau)],
1209 ]
1210
1211 # VC4 only needs core libdrm support of this version, not a libdrm_vc4
1212 # library.
1213 if with_gallium_vc4
1214   _drm_ver = '2.4.89'
1215 endif
1216
1217 # etnaviv only needs core libdrm
1218 if with_gallium_etnaviv
1219   _drm_ver = '2.4.89'
1220 endif
1221
1222 # Loop over the enables versions and get the highest libdrm requirement for all
1223 # active drivers.
1224 _drm_blame = ''
1225 foreach d : _libdrm_checks
1226   ver = get_variable('_drm_@0@_ver'.format(d[0]))
1227   if d[1] and ver.version_compare('>' + _drm_ver)
1228     _drm_ver = ver
1229     _drm_blame = d[0]
1230   endif
1231 endforeach
1232 if _drm_blame != ''
1233   message('libdrm @0@ needed because @1@ has the highest requirement'.format(_drm_ver, _drm_blame))
1234 endif
1235
1236 # Then get each libdrm module
1237 foreach d : _libdrm_checks
1238   if d[1]
1239     set_variable(
1240       'dep_libdrm_' + d[0],
1241       dependency('libdrm_' + d[0], version : '>=' + _drm_ver)
1242     )
1243   endif
1244 endforeach
1245
1246 with_gallium_drisw_kms = false
1247 dep_libdrm = dependency(
1248   'libdrm', version : '>=' + _drm_ver,
1249   required : with_dri2 or with_dri3
1250 )
1251 if dep_libdrm.found()
1252   pre_args += '-DHAVE_LIBDRM'
1253   if with_dri_platform == 'drm' and with_dri
1254     with_gallium_drisw_kms = true
1255   endif
1256 endif
1257
1258 llvm_modules = ['bitwriter', 'engine', 'mcdisassembler', 'mcjit']
1259 llvm_optional_modules = []
1260 if with_amd_vk or with_gallium_radeonsi or with_gallium_r600
1261   llvm_modules += ['amdgpu', 'native', 'bitreader', 'ipo']
1262   if with_gallium_r600
1263     llvm_modules += 'asmparser'
1264   endif
1265 endif
1266 if with_gallium_opencl
1267   llvm_modules += [
1268     'all-targets', 'linker', 'coverage', 'instrumentation', 'ipo', 'irreader',
1269     'lto', 'option', 'objcarcopts', 'profiledata',
1270   ]
1271 endif
1272 if with_gallium_opencl or with_gallium_softpipe
1273   llvm_optional_modules += ['coroutines']
1274 endif
1275
1276 if with_amd_vk or with_gallium_radeonsi
1277   _llvm_version = '>= 8.0.0'
1278 elif with_gallium_swr
1279   _llvm_version = '>= 6.0.0'
1280 else
1281   _llvm_version = '>= 3.9.0'
1282 endif
1283
1284 _shared_llvm = get_option('shared-llvm')
1285
1286 _llvm = get_option('llvm')
1287 dep_llvm = null_dep
1288 with_llvm = false
1289 if _llvm != 'false'
1290   dep_llvm = dependency(
1291     'llvm',
1292     version : _llvm_version,
1293     modules : llvm_modules,
1294     optional_modules : llvm_optional_modules,
1295     required : (
1296       with_amd_vk or with_gallium_radeonsi or with_gallium_swr or
1297       with_gallium_opencl or _llvm == 'true'
1298     ),
1299     static : not _shared_llvm,
1300     method : 'config-tool',
1301   )
1302   with_llvm = dep_llvm.found()
1303 endif
1304 if with_llvm
1305   pre_args += '-DLLVM_AVAILABLE'
1306   pre_args += '-DMESA_LLVM_VERSION_STRING="@0@"'.format(dep_llvm.version())
1307
1308   # LLVM can be built without rtti, turning off rtti changes the ABI of C++
1309   # programs, so we need to build all C++ code in mesa without rtti as well to
1310   # ensure that linking works.
1311   if dep_llvm.get_configtool_variable('has-rtti') == 'NO'
1312     if with_gallium_nouveau
1313       error('The Nouveau driver requires rtti. You either need to turn off nouveau or use an LLVM built with LLVM_ENABLE_RTTI.')
1314     elif with_gallium_opencl
1315       error('The Clover OpenCL state tracker requires rtti, you need to turn off clover or use an LLVM built with LLVM_ENABLE_RTTI.')
1316     endif
1317     cpp_args += '-fno-rtti'
1318   endif
1319 elif with_amd_vk or with_gallium_radeonsi or with_gallium_swr
1320   error('The following drivers require LLVM: Radv, RadeonSI, SWR. One of these is enabled, but LLVM is disabled.')
1321 elif with_gallium_opencl
1322   error('The OpenCL "Clover" state tracker requires LLVM, but LLVM is disabled.')
1323 endif
1324
1325 if (with_amd_vk or with_gallium_radeonsi or with_gallium_opencl or
1326     (with_gallium_r600 and with_llvm))
1327   dep_elf = dependency('libelf', required : false)
1328   if not dep_elf.found()
1329     dep_elf = cc.find_library('elf')
1330   endif
1331 else
1332   dep_elf = null_dep
1333 endif
1334
1335 dep_glvnd = null_dep
1336 if with_glvnd
1337   dep_glvnd = dependency('libglvnd', version : '>= 0.2.0')
1338   pre_args += '-DUSE_LIBGLVND=1'
1339 endif
1340
1341 if with_valgrind != 'false'
1342   dep_valgrind = dependency('valgrind', required : with_valgrind == 'true')
1343   if dep_valgrind.found()
1344     pre_args += '-DHAVE_VALGRIND'
1345   endif
1346 else
1347   dep_valgrind = null_dep
1348 endif
1349
1350 # pthread stubs. Lets not and say we didn't
1351
1352 prog_bison = find_program('bison', required : with_any_opengl)
1353 prog_flex = find_program('flex', required : with_any_opengl)
1354
1355 dep_selinux = null_dep
1356 if get_option('selinux')
1357   dep_selinux = dependency('libselinux')
1358   pre_args += '-DMESA_SELINUX'
1359 endif
1360
1361 if with_libunwind != 'false'
1362   dep_unwind = dependency('libunwind', required : with_libunwind == 'true')
1363   if dep_unwind.found()
1364     pre_args += '-DHAVE_LIBUNWIND'
1365   endif
1366 else
1367   dep_unwind = null_dep
1368 endif
1369
1370 if with_osmesa != 'none'
1371   if with_osmesa == 'gallium' and not with_gallium_softpipe
1372     error('OSMesa gallium requires gallium softpipe or llvmpipe.')
1373   endif
1374   osmesa_lib_name = 'OSMesa'
1375   osmesa_bits = get_option('osmesa-bits')
1376   if osmesa_bits != '8'
1377     if with_dri or with_glx != 'disabled'
1378       error('OSMesa bits must be 8 if building glx or dir based drivers')
1379     endif
1380     osmesa_lib_name = osmesa_lib_name + osmesa_bits
1381     pre_args += [
1382       '-DCHAN_BITS=@0@'.format(osmesa_bits), '-DDEFAULT_SOFTWARE_DEPTH_BITS=31'
1383     ]
1384   endif
1385 endif
1386
1387 # TODO: symbol mangling
1388
1389 if with_platform_wayland
1390   dep_wl_scanner = dependency('wayland-scanner', native: true)
1391   prog_wl_scanner = find_program(dep_wl_scanner.get_pkgconfig_variable('wayland_scanner'))
1392   if dep_wl_scanner.version().version_compare('>= 1.15')
1393     wl_scanner_arg = 'private-code'
1394   else
1395     wl_scanner_arg = 'code'
1396   endif
1397   dep_wl_protocols = dependency('wayland-protocols', version : '>= 1.8')
1398   dep_wayland_client = dependency('wayland-client', version : '>=1.11')
1399   dep_wayland_server = dependency('wayland-server', version : '>=1.11')
1400   if with_egl
1401     dep_wayland_egl = dependency('wayland-egl-backend', version : '>= 3')
1402     dep_wayland_egl_headers = declare_dependency(
1403       compile_args : run_command(prog_pkgconfig, ['wayland-egl-backend', '--cflags']).stdout().split())
1404   endif
1405   wayland_dmabuf_xml = join_paths(
1406     dep_wl_protocols.get_pkgconfig_variable('pkgdatadir'), 'unstable',
1407     'linux-dmabuf', 'linux-dmabuf-unstable-v1.xml'
1408   )
1409   pre_args += ['-DHAVE_WAYLAND_PLATFORM', '-DWL_HIDE_DEPRECATED']
1410 endif
1411
1412 dep_x11 = null_dep
1413 dep_xext = null_dep
1414 dep_xdamage = null_dep
1415 dep_xfixes = null_dep
1416 dep_x11_xcb = null_dep
1417 dep_xcb = null_dep
1418 dep_xcb_glx = null_dep
1419 dep_xcb_dri2 = null_dep
1420 dep_xcb_dri3 = null_dep
1421 dep_dri2proto = null_dep
1422 dep_glproto = null_dep
1423 dep_xxf86vm = null_dep
1424 dep_xcb_dri3 = null_dep
1425 dep_xcb_present = null_dep
1426 dep_xcb_sync = null_dep
1427 dep_xcb_xfixes = null_dep
1428 dep_xshmfence = null_dep
1429 dep_xcb_xrandr = null_dep
1430 dep_xlib_xrandr = null_dep
1431 if with_platform_x11
1432   if with_glx == 'xlib' or with_glx == 'gallium-xlib'
1433     dep_x11 = dependency('x11')
1434     dep_xext = dependency('xext')
1435     dep_xcb = dependency('xcb')
1436   elif with_glx == 'dri'
1437     dep_x11 = dependency('x11')
1438     dep_xext = dependency('xext')
1439     dep_xdamage = dependency('xdamage', version : '>= 1.1')
1440     dep_xfixes = dependency('xfixes')
1441     dep_xcb_glx = dependency('xcb-glx', version : '>= 1.8.1')
1442   endif
1443   if (with_any_vk or with_glx == 'dri' or with_egl or
1444        (with_gallium_vdpau or with_gallium_xvmc or with_gallium_va or
1445         with_gallium_omx != 'disabled'))
1446     dep_xcb = dependency('xcb')
1447     dep_x11_xcb = dependency('x11-xcb')
1448   endif
1449   if with_any_vk or with_egl or (with_glx == 'dri' and with_dri_platform == 'drm')
1450     dep_xcb_dri2 = dependency('xcb-dri2', version : '>= 1.8')
1451
1452     if with_dri3
1453       pre_args += '-DHAVE_DRI3'
1454       dep_xcb_dri3 = dependency('xcb-dri3')
1455       dep_xcb_present = dependency('xcb-present')
1456       # until xcb-dri3 has been around long enough to make a hard-dependency:
1457       if (dep_xcb_dri3.version().version_compare('>= 1.13') and
1458           dep_xcb_present.version().version_compare('>= 1.13'))
1459         pre_args += '-DHAVE_DRI3_MODIFIERS'
1460       endif
1461       dep_xcb_sync = dependency('xcb-sync')
1462       dep_xshmfence = dependency('xshmfence', version : '>= 1.1')
1463     endif
1464   endif
1465   if with_glx == 'dri' or with_glx == 'gallium-xlib'
1466     dep_glproto = dependency('glproto', version : '>= 1.4.14')
1467   endif
1468   if with_glx == 'dri'
1469     if with_dri_platform == 'drm'
1470       dep_dri2proto = dependency('dri2proto', version : '>= 2.8')
1471       dep_xxf86vm = dependency('xxf86vm')
1472     endif
1473   endif
1474   if (with_egl or (
1475       with_gallium_vdpau or with_gallium_xvmc or with_gallium_xa or
1476       with_gallium_omx != 'disabled'))
1477     dep_xcb_xfixes = dependency('xcb-xfixes')
1478   endif
1479   if with_xlib_lease
1480     dep_xcb_xrandr = dependency('xcb-randr')
1481     dep_xlib_xrandr = dependency('xrandr', version : '>= 1.3')
1482   endif
1483 endif
1484
1485 if get_option('gallium-extra-hud')
1486   pre_args += '-DHAVE_GALLIUM_EXTRA_HUD=1'
1487 endif
1488
1489 _sensors = get_option('lmsensors')
1490 if _sensors != 'false'
1491   dep_lmsensors = cc.find_library('sensors', required : _sensors == 'true')
1492   if dep_lmsensors.found()
1493     pre_args += '-DHAVE_LIBSENSORS=1'
1494   endif
1495 else
1496   dep_lmsensors = null_dep
1497 endif
1498
1499 foreach a : pre_args
1500   add_project_arguments(a, language : ['c', 'cpp'])
1501 endforeach
1502 foreach a : c_args
1503   add_project_arguments(a, language : ['c'])
1504 endforeach
1505 foreach a : cpp_args
1506   add_project_arguments(a, language : ['cpp'])
1507 endforeach
1508
1509 gl_priv_reqs = []
1510
1511 if with_glx == 'xlib' or with_glx == 'gallium-xlib'
1512   gl_priv_reqs += ['x11', 'xext', 'xcb']
1513 elif with_glx == 'dri'
1514   gl_priv_reqs += [
1515     'x11', 'xext', 'xdamage >= 1.1', 'xfixes', 'x11-xcb', 'xcb',
1516     'xcb-glx >= 1.8.1']
1517   if with_dri_platform == 'drm'
1518     gl_priv_reqs += 'xcb-dri2 >= 1.8'
1519     gl_priv_reqs += 'xxf86vm'
1520   endif
1521 endif
1522 if dep_libdrm.found()
1523   gl_priv_reqs += 'libdrm >= 2.4.75'
1524 endif
1525
1526 gl_priv_libs = []
1527 if dep_thread.found()
1528   gl_priv_libs += ['-lpthread', '-pthread']
1529 endif
1530 if dep_m.found()
1531   gl_priv_libs += '-lm'
1532 endif
1533 if dep_dl.found()
1534   gl_priv_libs += '-ldl'
1535 endif
1536
1537 pkg = import('pkgconfig')
1538
1539 prog_nm = find_program('nm', required : false)
1540
1541 # This quirk needs to be applied to sources with functions defined in assembly
1542 # as GCC LTO drops them. See: https://bugs.freedesktop.org/show_bug.cgi?id=109391
1543 gcc_lto_quirk = (cc.get_id() == 'gcc') ? ['-fno-lto'] : []
1544
1545 subdir('include')
1546 subdir('bin')
1547 subdir('src')
1548
1549 # Meson 0.49 and earlier seems to have a bug that fails to evaluate the string-
1550 # formatting below unless the first argument is passed as a variable. This has
1551 # been fixed in Meson 0.50 and beyond, but we need to keep it like this for now
1552 # for backwards compatibility.
1553 _with_opengl_string = with_opengl ? 'yes' : 'no'
1554
1555 lines = ['',
1556   'prefix:          ' + get_option('prefix'),
1557   'libdir:          ' + get_option('libdir'),
1558   'includedir:      ' + get_option('includedir'),
1559   '',
1560   'OpenGL:          @0@ (ES1: @1@ ES2: @2@)'.format(_with_opengl_string,
1561                                                     with_gles1 ? 'yes' : 'no',
1562                                                     with_gles2 ? 'yes' : 'no'),
1563 ]
1564
1565 if with_osmesa != 'none'
1566   lines += ''
1567   suffix = ''
1568   if with_osmesa == 'gallium'
1569     suffix = '(Gallium)'
1570   endif
1571   lines += 'OSMesa:          lib' + osmesa_lib_name + suffix
1572 else
1573   lines += 'OSMesa:          no'
1574 endif
1575
1576 if with_dri
1577   lines += ''
1578   lines += 'DRI platform:    ' + with_dri_platform
1579   if dri_drivers.length() != 0 and dri_drivers != ['']
1580     lines += 'DRI drivers:     ' + ' '.join(dri_drivers)
1581   else
1582     lines += 'DRI drivers:     no'
1583   endif
1584   lines += 'DRI driver dir:  ' + dri_drivers_path
1585 endif
1586
1587 if with_glx != 'disabled'
1588   lines += ''
1589   if with_glx == 'dri'
1590     lines += 'GLX:             DRI-based'
1591   elif with_glx == 'xlib'
1592     lines += 'GLX:             Xlib-based'
1593   elif with_glx == 'gallium-xlib'
1594     lines += 'GLX:             Xlib-based (Gallium)'
1595   else
1596     lines += 'GLX:             ' + with_glx
1597   endif
1598 endif
1599
1600 lines += ''
1601 lines += 'EGL:             ' + (with_egl ? 'yes' : 'no')
1602 if with_egl
1603   egl_drivers = []
1604   if with_dri
1605     egl_drivers += 'builtin:egl_dri2'
1606   endif
1607   if with_dri3
1608     egl_drivers += 'builtin:egl_dri3'
1609   endif
1610   lines += 'EGL drivers:     ' + ' '.join(egl_drivers)
1611 endif
1612 lines += 'GBM:             ' + (with_gbm ? 'yes' : 'no')
1613 if with_platforms
1614   lines += 'EGL/Vulkan/VL platforms:   ' + ' '.join(_platforms)
1615 endif
1616
1617 lines += ''
1618 if with_any_vk
1619   lines += 'Vulkan drivers:  ' + ' '.join(_vulkan_drivers)
1620   lines += 'Vulkan ICD dir:  ' + with_vulkan_icd_dir
1621 else
1622   lines += 'Vulkan drivers:  no'
1623 endif
1624
1625 lines += ''
1626 if with_llvm
1627   lines += 'llvm:            yes'
1628   lines += 'llvm-version:    ' + dep_llvm.version()
1629 else
1630   lines += 'llvm:            no'
1631 endif
1632
1633 lines += ''
1634 if with_gallium
1635   lines += 'Gallium drivers: ' + ' '.join(gallium_drivers)
1636   gallium_st = ['mesa']
1637   if with_gallium_xa
1638     gallium_st += 'xa'
1639   endif
1640   if with_gallium_xvmc
1641     gallium_st += 'xvmc'
1642   endif
1643   if with_gallium_xvmc
1644     gallium_st += 'xvmc'
1645   endif
1646   if with_gallium_vdpau
1647     gallium_st += 'vdpau'
1648   endif
1649   if with_gallium_omx != 'disabled'
1650     gallium_st += 'omx' + with_gallium_omx
1651   endif
1652   if with_gallium_va
1653     gallium_st += 'va'
1654   endif
1655   if with_gallium_st_nine
1656     gallium_st += 'nine'
1657   endif
1658   if with_gallium_opencl
1659     gallium_st += 'clover'
1660   endif
1661   lines += 'Gallium st:      ' + ' '.join(gallium_st)
1662 else
1663   lines += 'Gallium:         no'
1664 endif
1665
1666 lines += 'HUD lmsensors:   ' + (dep_lmsensors.found() ? 'yes' : 'no')
1667
1668 lines += ''
1669 lines += 'Shared-glapi:    ' + (with_shared_glapi ? 'yes' : 'no')
1670
1671
1672 indent = '        '
1673 summary = indent + ('\n' + indent).join(lines)
1674 message('Configuration summary:\n@0@\n'.format(summary))