meson.build

   1 # Copyright © 2017-2019 Intel Corporation
   2
   3 # Permission is hereby granted, free of charge, to any person obtaining a copy
   4 # of this software and associated documentation files (the "Software"), to deal
   5 # in the Software without restriction, including without limitation the rights
   6 # to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
   7 # copies of the Software, and to permit persons to whom the Software is
   8 # furnished to do so, subject to the following conditions:
   9
  10 # The above copyright notice and this permission notice shall be included in
  11 # all copies or substantial portions of the Software.
  12
  13 # THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  14 # IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  15 # FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
  16 # AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  17 # LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
  18 # OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
  19 # SOFTWARE.
  20
  21 project(
  22   'mesa',
  23   ['c', 'cpp'],
  24   version : run_command(
  25     [find_program('python', 'python2', 'python3'), 'bin/meson_get_version.py']
  26   ).stdout(),
  27   license : 'MIT',
  28   meson_version : '>= 0.46',
  29   default_options : ['buildtype=debugoptimized', 'b_ndebug=if-release', 'c_std=c99', 'cpp_std=c++14']
  30 )
  31
  32 cc = meson.get_compiler('c')
  33 cpp = meson.get_compiler('cpp')
  34
  35 null_dep = dependency('', required : false)
  36
  37 # Arguments for the preprocessor, put these in a separate array from the C and
  38 # C++ (cpp in meson terminology) arguments since they need to be added to the
  39 # default arguments for both C and C++.
  40 pre_args = [
  41   '-D__STDC_CONSTANT_MACROS',
  42   '-D__STDC_FORMAT_MACROS',
  43   '-D__STDC_LIMIT_MACROS',
  44   '-DPACKAGE_VERSION="@0@"'.format(meson.project_version()),
  45   '-DPACKAGE_BUGREPORT="https://gitlab.freedesktop.org/mesa/mesa/issues"',
  46 ]
  47
  48 with_vulkan_icd_dir = get_option('vulkan-icd-dir')
  49 with_tests = get_option('build-tests')
  50 with_valgrind = get_option('valgrind')
  51 with_libunwind = get_option('libunwind')
  52 with_glx_read_only_text = get_option('glx-read-only-text')
  53 with_glx_direct = get_option('glx-direct')
  54 with_osmesa = get_option('osmesa')
  55 with_swr_arches = get_option('swr-arches')
  56 with_tools = get_option('tools')
  57 if with_tools.contains('all')
  58   with_tools = [
  59     'drm-shim',
  60     'etnaviv',
  61     'freedreno',
  62     'glsl',
  63     'intel',
  64     'intel-ui',
  65     'lima',
  66     'nir',
  67     'nouveau',
  68     'xvmc',
  69   ]
  70 endif
  71
  72 dri_drivers_path = get_option('dri-drivers-path')
  73 if dri_drivers_path == ''
  74   dri_drivers_path = join_paths(get_option('prefix'), get_option('libdir'), 'dri')
  75 endif
  76 dri_search_path = get_option('dri-search-path')
  77 if dri_search_path == ''
  78   dri_search_path = dri_drivers_path
  79 endif
  80
  81 with_gles1 = get_option('gles1')
  82 with_gles2 = get_option('gles2')
  83 if host_machine.system() == 'windows'
  84   if with_gles1 == 'auto'
  85     with_gles1 = 'false'
  86   endif
  87   if with_gles2 == 'auto'
  88     with_gles2 = 'false'
  89   endif
  90 endif
  91 with_opengl = get_option('opengl')
  92
  93 # Default shared glapi off for windows, on elsewhere.
  94 _sg = get_option('shared-glapi')
  95 if _sg == 'auto'
  96   with_shared_glapi = host_machine.system() != 'windows'
  97 else
  98   with_shared_glapi = _sg == 'true'
  99 endif
 100
 101 # shared-glapi is required if at least two OpenGL APIs are being built
 102 if not with_shared_glapi
 103   if ((with_gles1 == 'true' and with_gles2 == 'true') or
 104       (with_gles1 == 'true' and with_opengl) or
 105       (with_gles2 == 'true' and with_opengl))
 106     error('shared-glapi required for building two or more of OpenGL, OpenGL ES 1.x, OpenGL ES 2.x')
 107   endif
 108   with_gles1 = 'false'
 109   with_gles2 = 'false'
 110 endif
 111
 112 # We require OpenGL for OpenGL ES
 113 if not with_opengl
 114   if (with_gles1 == 'true' or with_gles2 == 'true') and not with_opengl
 115     error('building OpenGL ES without OpenGL is not supported.')
 116   endif
 117   with_gles1 = 'false'
 118   with_gles2 = 'false'
 119 endif
 120
 121 with_gles1 = with_gles1 != 'false'
 122 with_gles2 = with_gles2 != 'false'
 123 with_any_opengl = with_opengl or with_gles1 or with_gles2
 124 # Only build shared_glapi if at least one OpenGL API is enabled
 125 with_shared_glapi = with_shared_glapi and with_any_opengl
 126
 127 system_has_kms_drm = ['openbsd', 'netbsd', 'freebsd', 'gnu/kfreebsd', 'dragonfly', 'linux'].contains(host_machine.system())
 128
 129 dri_drivers = get_option('dri-drivers')
 130 if dri_drivers.contains('auto')
 131   if system_has_kms_drm
 132     # TODO: PPC, Sparc
 133     if ['x86', 'x86_64'].contains(host_machine.cpu_family())
 134       dri_drivers = ['i915', 'i965', 'r100', 'r200', 'nouveau']
 135     elif ['arm', 'aarch64'].contains(host_machine.cpu_family())
 136       dri_drivers = []
 137     else
 138       error('Unknown architecture @0@. Please pass -Ddri-drivers to set driver options. Patches gladly accepted to fix this.'.format(
 139             host_machine.cpu_family()))
 140     endif
 141   elif ['darwin', 'windows', 'cygwin', 'haiku'].contains(host_machine.system())
 142     # only swrast would make sense here, but gallium swrast is a much better default
 143     dri_drivers = []
 144   else
 145     error('Unknown OS @0@. Please pass -Ddri-drivers to set driver options. Patches gladly accepted to fix this.'.format(
 146           host_machine.system()))
 147   endif
 148 endif
 149
 150 with_dri_i915 = dri_drivers.contains('i915')
 151 with_dri_i965 = dri_drivers.contains('i965')
 152 with_dri_r100 = dri_drivers.contains('r100')
 153 with_dri_r200 = dri_drivers.contains('r200')
 154 with_dri_nouveau = dri_drivers.contains('nouveau')
 155 with_dri_swrast = dri_drivers.contains('swrast')
 156
 157 with_dri = dri_drivers.length() != 0 and dri_drivers != ['']
 158
 159 gallium_drivers = get_option('gallium-drivers')
 160 if gallium_drivers.contains('auto')
 161   if system_has_kms_drm
 162     # TODO: PPC, Sparc
 163     if ['x86', 'x86_64'].contains(host_machine.cpu_family())
 164       gallium_drivers = [
 165         'r300', 'r600', 'radeonsi', 'nouveau', 'virgl', 'svga', 'swrast'
 166       ]
 167     elif ['arm', 'aarch64'].contains(host_machine.cpu_family())
 168       gallium_drivers = [
 169         'kmsro', 'v3d', 'vc4', 'freedreno', 'etnaviv', 'nouveau',
 170         'tegra', 'virgl', 'lima', 'panfrost', 'swrast'
 171       ]
 172     else
 173       error('Unknown architecture @0@. Please pass -Dgallium-drivers to set driver options. Patches gladly accepted to fix this.'.format(
 174             host_machine.cpu_family()))
 175     endif
 176   elif ['darwin', 'windows', 'cygwin', 'haiku'].contains(host_machine.system())
 177     gallium_drivers = ['swrast']
 178   else
 179     error('Unknown OS @0@. Please pass -Dgallium-drivers to set driver options. Patches gladly accepted to fix this.'.format(
 180           host_machine.system()))
 181   endif
 182 endif
 183 with_gallium_kmsro = gallium_drivers.contains('kmsro')
 184 with_gallium_radeonsi = gallium_drivers.contains('radeonsi')
 185 with_gallium_r300 = gallium_drivers.contains('r300')
 186 with_gallium_r600 = gallium_drivers.contains('r600')
 187 with_gallium_nouveau = gallium_drivers.contains('nouveau')
 188 with_gallium_freedreno = gallium_drivers.contains('freedreno')
 189 with_gallium_softpipe = gallium_drivers.contains('swrast')
 190 with_gallium_vc4 = gallium_drivers.contains('vc4')
 191 with_gallium_v3d = gallium_drivers.contains('v3d')
 192 with_gallium_panfrost = gallium_drivers.contains('panfrost')
 193 with_gallium_etnaviv = gallium_drivers.contains('etnaviv')
 194 with_gallium_tegra = gallium_drivers.contains('tegra')
 195 with_gallium_iris = gallium_drivers.contains('iris')
 196 with_gallium_i915 = gallium_drivers.contains('i915')
 197 with_gallium_svga = gallium_drivers.contains('svga')
 198 with_gallium_virgl = gallium_drivers.contains('virgl')
 199 with_gallium_swr = gallium_drivers.contains('swr')
 200 with_gallium_lima = gallium_drivers.contains('lima')
 201
 202 if cc.get_id() == 'intel'
 203   if meson.version().version_compare('< 0.49.0')
 204     error('Meson does not have sufficient support of ICC before 0.49.0 to compile mesa')
 205   elif with_gallium_swr and meson.version().version_compare('== 0.49.0')
 206     warning('Meson as of 0.49.0 is sufficient for compiling mesa with ICC, but there are some caveats with SWR. 0.49.1 should resolve all of these')
 207   endif
 208 endif
 209
 210 with_gallium = gallium_drivers.length() != 0 and gallium_drivers != ['']
 211
 212 if with_gallium and system_has_kms_drm
 213   _glx = get_option('glx')
 214   _egl = get_option('egl')
 215   if _glx == 'dri' or _egl == 'true' or (_glx == 'disabled' and _egl != 'false')
 216     with_dri = true
 217   endif
 218 endif
 219
 220 _vulkan_drivers = get_option('vulkan-drivers')
 221 if _vulkan_drivers.contains('auto')
 222   if system_has_kms_drm
 223     if host_machine.cpu_family().startswith('x86')
 224       _vulkan_drivers = ['amd', 'intel']
 225     elif ['arm', 'aarch64'].contains(host_machine.cpu_family())
 226       _vulkan_drivers = []
 227     else
 228       error('Unknown architecture @0@. Please pass -Dvulkan-drivers to set driver options. Patches gladly accepted to fix this.'.format(
 229             host_machine.cpu_family()))
 230     endif
 231   elif ['darwin', 'windows', 'cygwin', 'haiku'].contains(host_machine.system())
 232     # No vulkan driver supports windows or macOS currently
 233     _vulkan_drivers = []
 234   else
 235     error('Unknown OS @0@. Please pass -Dvulkan-drivers to set driver options. Patches gladly accepted to fix this.'.format(
 236           host_machine.system()))
 237   endif
 238 endif
 239
 240 with_intel_vk = _vulkan_drivers.contains('intel')
 241 with_amd_vk = _vulkan_drivers.contains('amd')
 242 with_freedreno_vk = _vulkan_drivers.contains('freedreno')
 243 with_any_vk = _vulkan_drivers.length() != 0 and _vulkan_drivers != ['']
 244
 245 if with_freedreno_vk and get_option('I-love-half-baked-turnips') != true
 246   error('Cannot enable freedreno vulkan driver')
 247 endif
 248
 249 if with_dri_swrast and (with_gallium_softpipe or with_gallium_swr)
 250   error('Only one swrast provider can be built')
 251 endif
 252 if with_dri_i915 and with_gallium_i915
 253   error('Only one i915 provider can be built')
 254 endif
 255 if with_gallium_kmsro and not (with_gallium_v3d or with_gallium_vc4 or with_gallium_etnaviv or with_gallium_freedreno or with_gallium_panfrost or with_gallium_lima)
 256   error('kmsro driver requires one or more renderonly drivers (vc4, etnaviv, freedreno, panfrost, lima)')
 257 endif
 258 if with_gallium_tegra and not with_gallium_nouveau
 259   error('tegra driver requires nouveau driver')
 260 endif
 261
 262 if host_machine.system() == 'darwin'
 263   with_dri_platform = 'apple'
 264   pre_args += '-DBUILDING_MESA'
 265 elif ['windows', 'cygwin'].contains(host_machine.system())
 266   with_dri_platform = 'windows'
 267 elif system_has_kms_drm
 268   with_dri_platform = 'drm'
 269 else
 270   # FIXME: haiku doesn't use dri, and xlib doesn't use dri, probably should
 271   # assert here that one of those cases has been met.
 272   # FIXME: illumos ends up here as well
 273   with_dri_platform = 'none'
 274 endif
 275
 276 _platforms = get_option('platforms')
 277 if _platforms.contains('auto')
 278   if system_has_kms_drm
 279     _platforms = ['x11', 'wayland', 'drm', 'surfaceless']
 280   elif ['darwin', 'cygwin'].contains(host_machine.system())
 281     _platforms = ['x11', 'surfaceless']
 282   elif ['haiku'].contains(host_machine.system())
 283     _platforms = ['haiku']
 284   elif host_machine.system() == 'windows'
 285     _platforms = ['windows']
 286   else
 287     error('Unknown OS @0@. Please pass -Dplatforms to set platforms. Patches gladly accepted to fix this.'.format(
 288           host_machine.system()))
 289   endif
 290 endif
 291
 292 with_platform_android = _platforms.contains('android')
 293 with_platform_x11 = _platforms.contains('x11')
 294 with_platform_wayland = _platforms.contains('wayland')
 295 with_platform_drm = _platforms.contains('drm')
 296 with_platform_haiku = _platforms.contains('haiku')
 297 with_platform_surfaceless = _platforms.contains('surfaceless')
 298 with_platform_windows = _platforms.contains('windows')
 299
 300 with_platforms = false
 301 if _platforms.length() != 0 and _platforms != ['']
 302   # sanity check that list contains no empty strings
 303   if _platforms.contains('')
 304     error('Invalid argument list given to -Dplatforms, please fix.')
 305   endif
 306   with_platforms = true
 307   egl_native_platform = _platforms[0]
 308 endif
 309
 310 _xlib_lease = get_option('xlib-lease')
 311 if _xlib_lease == 'auto'
 312   with_xlib_lease = with_platform_x11 and with_platform_drm
 313 else
 314   with_xlib_lease = _xlib_lease == 'true'
 315 endif
 316
 317 with_glx = get_option('glx')
 318 if with_glx == 'auto'
 319   if with_dri
 320     with_glx = 'dri'
 321   elif with_platform_haiku
 322     with_glx = 'disabled'
 323   elif host_machine.system() == 'windows'
 324     with_glx = 'disabled'
 325   elif with_gallium
 326     # Even when building just gallium drivers the user probably wants dri
 327     with_glx = 'dri'
 328   elif with_platform_x11 and with_any_opengl and not with_any_vk
 329     # The automatic behavior should not be to turn on xlib based glx when
 330     # building only vulkan drivers
 331     with_glx = 'xlib'
 332   else
 333     with_glx = 'disabled'
 334   endif
 335 endif
 336 if with_glx == 'dri'
 337    if with_gallium
 338       with_dri = true
 339    endif
 340 endif
 341
 342 if not (with_dri or with_gallium or with_glx != 'disabled')
 343   with_gles1 = false
 344   with_gles2 = false
 345   with_opengl = false
 346   with_any_opengl = false
 347   with_shared_glapi = false
 348 endif
 349
 350 _gbm = get_option('gbm')
 351 if _gbm == 'auto'
 352   with_gbm = system_has_kms_drm and with_dri
 353 else
 354   with_gbm = _gbm == 'true'
 355 endif
 356 if with_gbm and not system_has_kms_drm
 357   error('GBM only supports DRM/KMS platforms')
 358 endif
 359
 360 _egl = get_option('egl')
 361 if _egl == 'auto'
 362   with_egl = (
 363     not ['darwin', 'windows'].contains(host_machine.system()) and
 364     with_dri and with_shared_glapi and with_platforms
 365   )
 366 elif _egl == 'true'
 367   if not with_dri
 368     error('EGL requires dri')
 369   elif not with_shared_glapi
 370     error('EGL requires shared-glapi')
 371   elif not with_platforms
 372     error('No platforms specified, consider -Dplatforms=drm,x11,surfaceless at least')
 373   elif not ['disabled', 'dri'].contains(with_glx)
 374     error('EGL requires dri, but a GLX is being built without dri')
 375   elif ['darwin', 'windows'].contains(host_machine.system())
 376     error('EGL is not available on Windows or MacOS')
 377   endif
 378   with_egl = true
 379 else
 380   with_egl = false
 381 endif
 382
 383 if with_egl and not (with_platform_drm or with_platform_surfaceless or with_platform_android)
 384   if with_gallium_radeonsi
 385     error('RadeonSI requires the drm, surfaceless or android platform when using EGL')
 386   endif
 387   if with_gallium_virgl
 388     error('Virgl requires the drm, surfaceless or android platform when using EGL')
 389   endif
 390 endif
 391
 392 # Android uses emutls for versions <= P/28. For USE_ELF_TLS we need ELF TLS.
 393 if not with_platform_android or get_option('platform-sdk-version') >= 29
 394   pre_args += '-DUSE_ELF_TLS'
 395 endif
 396
 397 if with_glx != 'disabled'
 398   if not (with_platform_x11 and with_any_opengl)
 399     error('Cannot build GLX support without X11 platform support and at least one OpenGL API')
 400   elif with_glx == 'gallium-xlib'
 401     if not with_gallium
 402       error('Gallium-xlib based GLX requires at least one gallium driver')
 403     elif not with_gallium_softpipe
 404       error('Gallium-xlib based GLX requires softpipe or llvmpipe.')
 405     elif with_dri
 406       error('gallium-xlib conflicts with any dri driver')
 407     endif
 408   elif with_glx == 'xlib'
 409     if with_dri
 410       error('xlib conflicts with any dri driver')
 411     endif
 412   elif with_glx == 'dri'
 413     if not with_shared_glapi
 414       error('dri based GLX requires shared-glapi')
 415     endif
 416   endif
 417 endif
 418
 419 with_glvnd = get_option('glvnd')
 420 if with_glvnd
 421   if with_platform_windows
 422     error('glvnd cannot be used on Windows')
 423   elif with_glx == 'xlib' or with_glx == 'gallium-xlib'
 424     error('Cannot build glvnd support for GLX that is not DRI based.')
 425   elif with_glx == 'disabled' and not with_egl
 426     error('glvnd requires DRI based GLX and/or EGL')
 427   endif
 428   if get_option('egl-lib-suffix') != ''
 429     error('''EGL lib suffix can't be used with libglvnd''')
 430   endif
 431 endif
 432
 433 if with_vulkan_icd_dir == ''
 434   with_vulkan_icd_dir = join_paths(get_option('datadir'), 'vulkan/icd.d')
 435 endif
 436
 437 with_dri2 = (with_dri or with_any_vk) and (with_dri_platform == 'drm' or
 438   host_machine.system() == 'gnu')
 439 _dri3 = get_option('dri3')
 440 if _dri3 == 'auto'
 441   with_dri3 = system_has_kms_drm and with_dri2
 442 else
 443   with_dri3 = _dri3 == 'true'
 444 endif
 445
 446 if with_any_vk and (with_platform_x11 and not with_dri3)
 447   error('Vulkan drivers require dri3 for X11 support')
 448 endif
 449 if with_dri
 450   if with_glx == 'disabled' and not with_egl and not with_gbm and with_osmesa != 'classic'
 451     error('building dri drivers require at least one windowing system or classic osmesa')
 452   endif
 453 endif
 454
 455 prog_pkgconfig = find_program('pkg-config')
 456
 457 _vdpau = get_option('gallium-vdpau')
 458 if not system_has_kms_drm
 459   if _vdpau == 'true'
 460     error('VDPAU state tracker can only be build on unix-like OSes.')
 461   else
 462     _vdpau = 'false'
 463   endif
 464 elif not with_platform_x11
 465   if _vdpau == 'true'
 466     error('VDPAU state tracker requires X11 support.')
 467   else
 468     _vdpau = 'false'
 469   endif
 470 elif not (with_gallium_r300 or with_gallium_r600 or with_gallium_radeonsi or
 471           with_gallium_nouveau)
 472   if _vdpau == 'true'
 473     error('VDPAU state tracker requires at least one of the following gallium drivers: r300, r600, radeonsi, nouveau.')
 474   else
 475     _vdpau = 'false'
 476   endif
 477 endif
 478 dep_vdpau = null_dep
 479 with_gallium_vdpau = false
 480 if _vdpau != 'false'
 481   dep_vdpau = dependency('vdpau', version : '>= 1.1', required : _vdpau == 'true')
 482   if dep_vdpau.found()
 483     dep_vdpau = declare_dependency(
 484       compile_args : run_command(prog_pkgconfig, ['vdpau', '--cflags']).stdout().split()
 485     )
 486     with_gallium_vdpau = true
 487   endif
 488 endif
 489
 490 if with_gallium_vdpau
 491   pre_args += '-DHAVE_ST_VDPAU'
 492 endif
 493 vdpau_drivers_path = get_option('vdpau-libs-path')
 494 if vdpau_drivers_path == ''
 495   vdpau_drivers_path = join_paths(get_option('libdir'), 'vdpau')
 496 endif
 497
 498 _xvmc = get_option('gallium-xvmc')
 499 if not system_has_kms_drm
 500   if _xvmc == 'true'
 501     error('XVMC state tracker can only be build on unix-like OSes.')
 502   else
 503     _xvmc = 'false'
 504   endif
 505 elif not with_platform_x11
 506   if _xvmc == 'true'
 507     error('XVMC state tracker requires X11 support.')
 508   else
 509     _xvmc = 'false'
 510   endif
 511 elif not (with_gallium_r600 or with_gallium_nouveau)
 512   if _xvmc == 'true'
 513     error('XVMC state tracker requires at least one of the following gallium drivers: r600, nouveau.')
 514   else
 515     _xvmc = 'false'
 516   endif
 517 endif
 518 dep_xvmc = null_dep
 519 dep_xv = null_dep
 520 with_gallium_xvmc = false
 521 if _xvmc != 'false'
 522   dep_xvmc = dependency('xvmc', version : '>= 1.0.6', required : _xvmc == 'true')
 523   dep_xv = dependency('xv', required : _xvmc == 'true')
 524   with_gallium_xvmc = dep_xvmc.found() and dep_xv.found()
 525 endif
 526
 527 xvmc_drivers_path = get_option('xvmc-libs-path')
 528 if xvmc_drivers_path == ''
 529   xvmc_drivers_path = get_option('libdir')
 530 endif
 531
 532 _omx = get_option('gallium-omx')
 533 if not system_has_kms_drm
 534   if ['auto', 'disabled'].contains(_omx)
 535     _omx = 'disabled'
 536   else
 537     error('OMX state tracker can only be built on unix-like OSes.')
 538   endif
 539 elif not (with_gallium_r600 or with_gallium_radeonsi or with_gallium_nouveau)
 540   if ['auto', 'disabled'].contains(_omx)
 541     _omx = 'disabled'
 542   else
 543     error('OMX state tracker requires at least one of the following gallium drivers: r600, radeonsi, nouveau.')
 544   endif
 545 endif
 546 with_gallium_omx = _omx
 547 dep_omx = null_dep
 548 dep_omx_other = []
 549 if ['auto', 'bellagio'].contains(_omx)
 550   dep_omx = dependency(
 551     'libomxil-bellagio', required : _omx == 'bellagio'
 552   )
 553   if dep_omx.found()
 554     with_gallium_omx = 'bellagio'
 555   endif
 556 endif
 557 if ['auto', 'tizonia'].contains(_omx)
 558   if with_dri and with_egl
 559     dep_omx = dependency(
 560       'libtizonia', version : '>= 0.10.0',
 561       required : _omx == 'tizonia',
 562     )
 563     dep_omx_other = [
 564       dependency('libtizplatform', required : _omx == 'tizonia'),
 565       dependency('tizilheaders', required : _omx == 'tizonia'),
 566     ]
 567     if dep_omx.found() and dep_omx_other[0].found() and dep_omx_other[1].found()
 568       with_gallium_omx = 'tizonia'
 569     endif
 570   elif _omx == 'tizonia'
 571     error('OMX-Tizonia state tracker requires dri and egl')
 572   endif
 573 endif
 574 if _omx == 'auto'
 575   with_gallium_omx = 'disabled'
 576 else
 577   with_gallium_omx = _omx
 578 endif
 579
 580 pre_args += [
 581   '-DENABLE_ST_OMX_BELLAGIO=' + (with_gallium_omx == 'bellagio' ? '1' : '0'),
 582   '-DENABLE_ST_OMX_TIZONIA=' + (with_gallium_omx == 'tizonia' ? '1' : '0'),
 583 ]
 584
 585
 586 omx_drivers_path = get_option('omx-libs-path')
 587
 588 if with_gallium_omx != 'disabled'
 589   # Figure out where to put the omx driver.
 590   # FIXME: this could all be vastly simplified by adding a 'defined_variable'
 591   # argument to meson's get_pkgconfig_variable method.
 592   if omx_drivers_path == ''
 593     _omx_libdir = dep_omx.get_pkgconfig_variable('libdir')
 594     _omx_drivers_dir = dep_omx.get_pkgconfig_variable('pluginsdir')
 595     if _omx_libdir == get_option('libdir')
 596       omx_drivers_path = _omx_drivers_dir
 597     else
 598       _omx_base_dir = []
 599       # This will fail on windows. Does OMX run on windows?
 600       _omx_libdir = _omx_libdir.split('/')
 601       _omx_drivers_dir = _omx_drivers_dir.split('/')
 602       foreach o : _omx_drivers_dir
 603         if not _omx_libdir.contains(o)
 604           _omx_base_dir += o
 605         endif
 606       endforeach
 607       omx_drivers_path = join_paths(get_option('libdir'), _omx_base_dir)
 608     endif
 609   endif
 610 endif
 611
 612 _va = get_option('gallium-va')
 613 if not system_has_kms_drm
 614   if _va == 'true'
 615     error('VA state tracker can only be built on unix-like OSes.')
 616   else
 617     _va = 'false'
 618   endif
 619 elif not (with_gallium_r600 or with_gallium_radeonsi or with_gallium_nouveau)
 620   if _va == 'true'
 621     error('VA state tracker requires at least one of the following gallium drivers: r600, radeonsi, nouveau.')
 622   else
 623     _va = 'false'
 624   endif
 625 endif
 626 with_gallium_va = false
 627 dep_va = null_dep
 628 if _va != 'false'
 629   dep_va = dependency('libva', version : '>= 0.38.0', required : _va == 'true')
 630   if dep_va.found()
 631     dep_va_headers = declare_dependency(
 632       compile_args : run_command(prog_pkgconfig, ['libva', '--cflags']).stdout().split()
 633     )
 634     with_gallium_va = true
 635   endif
 636 endif
 637
 638 va_drivers_path = get_option('va-libs-path')
 639 if va_drivers_path == ''
 640   va_drivers_path = join_paths(get_option('libdir'), 'dri')
 641 endif
 642
 643 _xa = get_option('gallium-xa')
 644 if not system_has_kms_drm
 645   if _xa == 'true'
 646     error('XA state tracker can only be built on unix-like OSes.')
 647   else
 648     _xa = 'false'
 649   endif
 650 elif not (with_gallium_nouveau or with_gallium_freedreno or with_gallium_i915
 651           or with_gallium_svga)
 652   if _xa == 'true'
 653     error('XA state tracker requires at least one of the following gallium drivers: nouveau, freedreno, i915, svga.')
 654   else
 655     _xa = 'false'
 656   endif
 657 endif
 658 with_gallium_xa = _xa != 'false'
 659
 660 d3d_drivers_path = get_option('d3d-drivers-path')
 661 if d3d_drivers_path == ''
 662   d3d_drivers_path = join_paths(get_option('prefix'), get_option('libdir'), 'd3d')
 663 endif
 664
 665 with_gallium_st_nine =  get_option('gallium-nine')
 666 if with_gallium_st_nine
 667   if not with_gallium_softpipe
 668     error('The nine state tracker requires gallium softpipe/llvmpipe.')
 669   elif not (with_gallium_radeonsi or with_gallium_nouveau or with_gallium_r600
 670             or with_gallium_r300 or with_gallium_svga or with_gallium_i915
 671             or with_gallium_iris)
 672     error('The nine state tracker requires at least one non-swrast gallium driver.')
 673   endif
 674   if not with_dri3
 675     error('Using nine with wine requires dri3')
 676   endif
 677 endif
 678
 679 if get_option('power8') != 'false'
 680   # on old versions of meson the cpu family would return as ppc64le on little
 681   # endian power8, this was changed in 0.48 such that the family would always
 682   # be ppc64 regardless of endianness, and then the machine.endian() value
 683   # should be checked. Since we support versions < 0.48 we need to use
 684   # startswith.
 685   if host_machine.cpu_family().startswith('ppc64') and host_machine.endian() == 'little'
 686     if cc.get_id() == 'gcc' and cc.version().version_compare('< 4.8')
 687       error('Altivec is not supported with gcc version < 4.8.')
 688     endif
 689     if cc.compiles('''
 690         #include <altivec.h>
 691         int main() {
 692           vector unsigned char r;
 693           vector unsigned int v = vec_splat_u32 (1);
 694           r = __builtin_vec_vgbbd ((vector unsigned char) v);
 695           return 0;
 696         }''',
 697         args : '-mpower8-vector',
 698         name : 'POWER8 intrinsics')
 699       pre_args += ['-D_ARCH_PWR8', '-mpower8-vector']
 700     elif get_option('power8') == 'true'
 701       error('POWER8 intrinsic support required but not found.')
 702     endif
 703   endif
 704 endif
 705
 706 _opencl = get_option('gallium-opencl')
 707 clover_cpp_std = []
 708 if _opencl != 'disabled'
 709   if not with_gallium
 710     error('OpenCL Clover implementation requires at least one gallium driver.')
 711   endif
 712
 713   dep_clc = dependency('libclc')
 714   with_gallium_opencl = true
 715   with_opencl_icd = _opencl == 'icd'
 716
 717   with_opencl_spirv = get_option('opencl-spirv')
 718   if with_opencl_spirv
 719     dep_spirv_tools = dependency('SPIRV-Tools', required : true, version : '>= 2018.0')
 720     # LLVMSPIRVLib is available at https://github.com/KhronosGroup/SPIRV-LLVM-Translator
 721     dep_llvmspirvlib = dependency('LLVMSPIRVLib', required : true, version : '>= 0.2.1')
 722   else
 723     dep_spirv_tools = null_dep
 724     dep_llvmspirvlib = null_dep
 725   endif
 726
 727   if host_machine.cpu_family().startswith('ppc') and cpp.compiles('''
 728       #if !defined(__VEC__) || !defined(__ALTIVEC__)
 729       #error "AltiVec not enabled"
 730       #endif''',
 731       name : 'Altivec')
 732     clover_cpp_std += ['cpp_std=gnu++11']
 733   endif
 734 else
 735   dep_clc = null_dep
 736   dep_spirv_tools = null_dep
 737   dep_llvmspirvlib = null_dep
 738   with_gallium_opencl = false
 739   with_opencl_icd = false
 740   with_opencl_spirv = false
 741 endif
 742
 743 gl_pkgconfig_c_flags = []
 744 if with_platform_x11
 745   if with_any_vk or with_egl or (with_glx == 'dri' and with_dri_platform == 'drm')
 746     pre_args += '-DHAVE_X11_PLATFORM'
 747   endif
 748   if with_glx == 'xlib' or with_glx == 'gallium-xlib'
 749     pre_args += '-DUSE_XSHM'
 750   else
 751     pre_args += '-DGLX_INDIRECT_RENDERING'
 752     if with_glx_direct
 753       pre_args += '-DGLX_DIRECT_RENDERING'
 754     endif
 755     if with_dri_platform == 'drm'
 756       pre_args += '-DGLX_USE_DRM'
 757     elif with_dri_platform == 'apple'
 758       pre_args += '-DGLX_USE_APPLEGL'
 759     elif with_dri_platform == 'windows'
 760       pre_args += '-DGLX_USE_WINDOWSGL'
 761     endif
 762   endif
 763 else
 764   pre_args += '-DMESA_EGL_NO_X11_HEADERS'
 765   gl_pkgconfig_c_flags += '-DMESA_EGL_NO_X11_HEADERS'
 766 endif
 767 if with_platform_drm
 768   if with_egl and not with_gbm
 769     error('EGL drm platform requires gbm')
 770   endif
 771   pre_args += '-DHAVE_DRM_PLATFORM'
 772 endif
 773 if with_platform_surfaceless
 774   pre_args += '-DHAVE_SURFACELESS_PLATFORM'
 775 endif
 776 if with_platform_android
 777   dep_android = [
 778     dependency('cutils'),
 779     dependency('hardware'),
 780     dependency('sync'),
 781   ]
 782   if get_option('platform-sdk-version') >= 26
 783     dep_android += dependency('nativewindow')
 784   endif
 785   pre_args += '-DHAVE_ANDROID_PLATFORM'
 786 endif
 787 if with_platform_haiku
 788   pre_args += '-DHAVE_HAIKU_PLATFORM'
 789 endif
 790
 791 if meson.version().version_compare('>=0.50')
 792   prog_python = import('python').find_installation('python3')
 793 else
 794   prog_python = import('python3').find_python()
 795 endif
 796 has_mako = run_command(
 797   prog_python, '-c',
 798   '''
 799 from distutils.version import StrictVersion
 800 import mako
 801 assert StrictVersion(mako.__version__) > StrictVersion("0.8.0")
 802   ''')
 803 if has_mako.returncode() != 0
 804   error('Python (3.x) mako module >= 0.8.0 required to build mesa.')
 805 endif
 806
 807 if cc.get_id() == 'gcc' and cc.version().version_compare('< 4.4.6')
 808   error('When using GCC, version 4.4.6 or later is required.')
 809 endif
 810
 811 # Support systems without ETIME (e.g. FreeBSD)
 812 if cc.get_define('ETIME', prefix : '#include <errno.h>') == ''
 813   pre_args += '-DETIME=ETIMEDOUT'
 814 endif
 815
 816 # Define DEBUG for debug builds only (debugoptimized is not included on this one)
 817 if get_option('buildtype') == 'debug'
 818   pre_args += '-DDEBUG'
 819 endif
 820
 821 with_shader_cache = false
 822 _shader_cache = get_option('shader-cache')
 823 if _shader_cache != 'false'
 824   if host_machine.system() == 'windows'
 825     if _shader_cache == 'true'
 826       error('Shader Cache does not currently work on Windows')
 827     endif
 828   else
 829     pre_args += '-DENABLE_SHADER_CACHE'
 830     with_shader_cache = true
 831   endif
 832 endif
 833 if with_amd_vk and not with_shader_cache
 834   error('Radv requires shader cache support')
 835 endif
 836
 837 # Check for GCC style builtins
 838 foreach b : ['bswap32', 'bswap64', 'clz', 'clzll', 'ctz', 'expect', 'ffs',
 839              'ffsll', 'popcount', 'popcountll', 'unreachable']
 840   if cc.has_function(b)
 841     pre_args += '-DHAVE___BUILTIN_@0@'.format(b.to_upper())
 842   endif
 843 endforeach
 844
 845 # check for GCC __attribute__
 846 foreach a : ['const', 'flatten', 'malloc', 'pure', 'unused',
 847              'warn_unused_result', 'weak',]
 848   if cc.compiles('int foo(void) __attribute__((@0@));'.format(a),
 849                  name : '__attribute__((@0@))'.format(a))
 850     pre_args += '-DHAVE_FUNC_ATTRIBUTE_@0@'.format(a.to_upper())
 851   endif
 852 endforeach
 853 if cc.compiles('int foo(const char *p, ...) __attribute__((format(printf, 1, 2)));',
 854                name : '__attribute__((format(...)))')
 855   pre_args += '-DHAVE_FUNC_ATTRIBUTE_FORMAT'
 856 endif
 857 if cc.compiles('struct __attribute__((packed)) foo { int bar; };',
 858                name : '__attribute__((packed))')
 859   pre_args += '-DHAVE_FUNC_ATTRIBUTE_PACKED'
 860 endif
 861 if cc.compiles('int *foo(void) __attribute__((returns_nonnull));',
 862                name : '__attribute__((returns_nonnull))')
 863   pre_args += '-DHAVE_FUNC_ATTRIBUTE_RETURNS_NONNULL'
 864 endif
 865 if cc.compiles('''int foo_def(void) __attribute__((visibility("default")));
 866                   int foo_hid(void) __attribute__((visibility("hidden")));
 867                   int foo_int(void) __attribute__((visibility("internal")));
 868                   int foo_pro(void) __attribute__((visibility("protected")));''',
 869                name : '__attribute__((visibility(...)))')
 870   pre_args += '-DHAVE_FUNC_ATTRIBUTE_VISIBILITY'
 871 endif
 872 if cc.compiles('int foo(void) { return 0; } int bar(void) __attribute__((alias("foo")));',
 873                name : '__attribute__((alias(...)))')
 874   pre_args += '-DHAVE_FUNC_ATTRIBUTE_ALIAS'
 875 endif
 876 if cc.compiles('int foo(void) __attribute__((__noreturn__));',
 877                name : '__attribute__((__noreturn__))')
 878   pre_args += '-DHAVE_FUNC_ATTRIBUTE_NORETURN'
 879 endif
 880 if cc.compiles('__uint128_t foo(void) { return 0; }',
 881                name : '__uint128_t')
 882   pre_args += '-DHAVE_UINT128'
 883 endif
 884
 885 # TODO: this is very incomplete
 886 if ['linux', 'cygwin', 'gnu', 'gnu/kfreebsd'].contains(host_machine.system())
 887   pre_args += '-D_GNU_SOURCE'
 888 endif
 889
 890 # Check for generic C arguments
 891 c_args = []
 892 foreach a : ['-Werror=implicit-function-declaration',
 893              '-Werror=missing-prototypes',
 894              '-Werror=return-type',
 895              '-Werror=incompatible-pointer-types',
 896              '-Werror=format',
 897              '-Wformat-security',
 898              '-Wno-missing-field-initializers',
 899              '-Wno-format-truncation',
 900              '-fno-math-errno',
 901              '-fno-trapping-math',
 902              '-Qunused-arguments']
 903   if cc.has_argument(a)
 904     c_args += a
 905   endif
 906 endforeach
 907
 908 c_vis_args = []
 909 if cc.has_argument('-fvisibility=hidden')
 910   c_vis_args += '-fvisibility=hidden'
 911 endif
 912
 913 # Check for generic C++ arguments
 914 cpp_args = []
 915 foreach a : ['-Werror=return-type',
 916              '-Werror=format',
 917              '-Wformat-security',
 918              '-Wno-non-virtual-dtor',
 919              '-Wno-missing-field-initializers',
 920              '-Wno-format-truncation',
 921              '-fno-math-errno',
 922              '-fno-trapping-math',
 923              '-Qunused-arguments']
 924   if cpp.has_argument(a)
 925     cpp_args += a
 926   endif
 927 endforeach
 928
 929 no_override_init_args = []
 930 foreach a : ['-Wno-override-init',
 931              '-Wno-initializer-overrides']
 932   if cc.has_argument(a)
 933     no_override_init_args += a
 934   endif
 935 endforeach
 936
 937 cpp_vis_args = []
 938 if cpp.has_argument('-fvisibility=hidden')
 939   cpp_vis_args += '-fvisibility=hidden'
 940 endif
 941
 942 # Check for C and C++ arguments for MSVC2013 compatibility. These are only used
 943 # in parts of the mesa code base that need to compile with old versions of
 944 # MSVC, mainly common code
 945 c_msvc_compat_args = []
 946 cpp_msvc_compat_args = []
 947 foreach a : ['-Werror=pointer-arith', '-Werror=vla']
 948   if cc.has_argument(a)
 949     c_msvc_compat_args += a
 950   endif
 951   if cpp.has_argument(a)
 952     cpp_msvc_compat_args += a
 953   endif
 954 endforeach
 955
 956 if host_machine.cpu_family().startswith('x86')
 957   pre_args += '-DUSE_SSE41'
 958   with_sse41 = true
 959   sse41_args = ['-msse4.1']
 960
 961   # GCC on x86 (not x86_64) with -msse* assumes a 16 byte aligned stack, but
 962   # that's not guaranteed
 963   if host_machine.cpu_family() == 'x86'
 964     sse41_args += '-mstackrealign'
 965   endif
 966 else
 967   with_sse41 = false
 968   sse41_args = []
 969 endif
 970
 971 # Check for GCC style atomics
 972 dep_atomic = null_dep
 973
 974 if cc.compiles('''#include <stdint.h>
 975                   int main() {
 976                     struct {
 977                       uint64_t *v;
 978                     } x;
 979                     return (int)__atomic_load_n(x.v, __ATOMIC_ACQUIRE) &
 980                            (int)__atomic_add_fetch(x.v, (uint64_t)1, __ATOMIC_ACQ_REL);
 981
 982                   }''',
 983                name : 'GCC atomic builtins')
 984   pre_args += '-DUSE_GCC_ATOMIC_BUILTINS'
 985
 986   # Not all atomic calls can be turned into lock-free instructions, in which
 987   # GCC will make calls into the libatomic library. Check whether we need to
 988   # link with -latomic.
 989   #
 990   # This can happen for 64-bit atomic operations on 32-bit architectures such
 991   # as ARM.
 992   if not cc.links('''#include <stdint.h>
 993                      int main() {
 994                        struct {
 995                          uint64_t *v;
 996                        } x;
 997                        return (int)__atomic_load_n(x.v, __ATOMIC_ACQUIRE) &
 998                               (int)__atomic_add_fetch(x.v, (uint64_t)1, __ATOMIC_ACQ_REL);
 999                      }''',
1000                   name : 'GCC atomic builtins required -latomic')
1001     dep_atomic = cc.find_library('atomic')
1002   endif
1003 endif
1004 if not cc.links('''#include <stdint.h>
1005                    uint64_t v;
1006                    int main() {
1007                      return __sync_add_and_fetch(&v, (uint64_t)1);
1008                    }''',
1009                 dependencies : dep_atomic,
1010                 name : 'GCC 64bit atomics')
1011   pre_args += '-DMISSING_64BIT_ATOMICS'
1012 endif
1013
1014 # TODO: shared/static? Is this even worth doing?
1015
1016 with_asm_arch = ''
1017 if host_machine.cpu_family() == 'x86'
1018   if system_has_kms_drm or host_machine.system() == 'gnu'
1019     with_asm_arch = 'x86'
1020     pre_args += ['-DUSE_X86_ASM', '-DUSE_MMX_ASM', '-DUSE_3DNOW_ASM',
1021                  '-DUSE_SSE_ASM']
1022
1023     if with_glx_read_only_text
1024       pre_args += ['-DGLX_X86_READONLY_TEXT']
1025     endif
1026   endif
1027 elif host_machine.cpu_family() == 'x86_64'
1028   if system_has_kms_drm
1029     with_asm_arch = 'x86_64'
1030     pre_args += ['-DUSE_X86_64_ASM']
1031   endif
1032 elif host_machine.cpu_family() == 'arm'
1033   if system_has_kms_drm
1034     with_asm_arch = 'arm'
1035     pre_args += ['-DUSE_ARM_ASM']
1036   endif
1037 elif host_machine.cpu_family() == 'aarch64'
1038   if system_has_kms_drm
1039     with_asm_arch = 'aarch64'
1040     pre_args += ['-DUSE_AARCH64_ASM']
1041   endif
1042 elif host_machine.cpu_family() == 'sparc64'
1043   if system_has_kms_drm
1044     with_asm_arch = 'sparc'
1045     pre_args += ['-DUSE_SPARC_ASM']
1046   endif
1047 elif host_machine.cpu_family().startswith('ppc64') and host_machine.endian() == 'little'
1048   if system_has_kms_drm
1049     with_asm_arch = 'ppc64le'
1050     pre_args += ['-DUSE_PPC64LE_ASM']
1051   endif
1052 endif
1053
1054 # Check for standard headers and functions
1055 if cc.has_header_symbol('sys/sysmacros.h', 'major')
1056   pre_args += '-DMAJOR_IN_SYSMACROS'
1057 elif cc.has_header_symbol('sys/mkdev.h', 'major')
1058   pre_args += '-DMAJOR_IN_MKDEV'
1059 endif
1060
1061 foreach h : ['xlocale.h', 'sys/sysctl.h', 'linux/futex.h', 'endian.h', 'dlfcn.h', 'execinfo.h', 'sys/shm.h', 'cet.h']
1062   if cc.compiles('#include <@0@>'.format(h), name : '@0@'.format(h))
1063     pre_args += '-DHAVE_@0@'.format(h.to_upper().underscorify())
1064   endif
1065 endforeach
1066
1067 foreach f : ['strtof', 'mkostemp', 'posix_memalign', 'timespec_get', 'memfd_create', 'random_r']
1068   if cc.has_function(f)
1069     pre_args += '-DHAVE_@0@'.format(f.to_upper())
1070   endif
1071 endforeach
1072
1073 if cc.has_header_symbol('errno.h', 'program_invocation_name',
1074                         args : '-D_GNU_SOURCE')
1075    pre_args += '-DHAVE_PROGRAM_INVOCATION_NAME'
1076 elif with_tools.contains('intel')
1077   error('Intel tools require the program_invocation_name variable')
1078 endif
1079
1080 # strtod locale support
1081 if cc.links('''
1082     #define _GNU_SOURCE
1083     #include <stdlib.h>
1084     #include <locale.h>
1085     #ifdef HAVE_XLOCALE_H
1086     #include <xlocale.h>
1087     #endif
1088     int main() {
1089       locale_t loc = newlocale(LC_CTYPE_MASK, "C", NULL);
1090       const char *s = "1.0";
1091       char *end;
1092       double d = strtod_l(s, end, loc);
1093       float f = strtof_l(s, end, loc);
1094       freelocale(loc);
1095       return 0;
1096     }''',
1097     args : pre_args,
1098     name : 'strtod has locale support')
1099   pre_args += '-DHAVE_STRTOD_L'
1100 endif
1101
1102 # Check for some linker flags
1103 ld_args_bsymbolic = []
1104 if cc.links('int main() { return 0; }', args : '-Wl,-Bsymbolic', name : 'Bsymbolic')
1105   ld_args_bsymbolic += '-Wl,-Bsymbolic'
1106 endif
1107 ld_args_gc_sections = []
1108 if cc.links('static char unused() { return 5; } int main() { return 0; }',
1109             args : '-Wl,--gc-sections', name : 'gc-sections')
1110   ld_args_gc_sections += '-Wl,--gc-sections'
1111 endif
1112 with_ld_version_script = false
1113 if cc.links('int main() { return 0; }',
1114             args : '-Wl,--version-script=@0@'.format(
1115               join_paths(meson.source_root(), 'build-support/conftest.map')),
1116             name : 'version-script')
1117   with_ld_version_script = true
1118 endif
1119 with_ld_dynamic_list = false
1120 if cc.links('int main() { return 0; }',
1121             args : '-Wl,--dynamic-list=@0@'.format(
1122               join_paths(meson.source_root(), 'build-support/conftest.dyn')),
1123             name : 'dynamic-list')
1124   with_ld_dynamic_list = true
1125 endif
1126
1127 ld_args_build_id = cc.get_supported_link_arguments('-Wl,--build-id=sha1')
1128
1129 # check for dl support
1130 dep_dl = null_dep
1131 if host_machine.system() != 'windows'
1132   if not cc.has_function('dlopen')
1133     dep_dl = cc.find_library('dl')
1134   endif
1135   if cc.has_function('dladdr', dependencies : dep_dl)
1136     # This is really only required for megadrivers
1137     pre_args += '-DHAVE_DLADDR'
1138   endif
1139 endif
1140
1141 if cc.has_function('dl_iterate_phdr')
1142   pre_args += '-DHAVE_DL_ITERATE_PHDR'
1143 elif with_intel_vk
1144   error('Intel "Anvil" Vulkan driver requires the dl_iterate_phdr function')
1145 elif with_dri_i965 and with_shader_cache
1146   error('Intel i965 GL driver requires dl_iterate_phdr when built with shader caching.')
1147 endif
1148
1149 # Determine whether or not the rt library is needed for time functions
1150 if cc.has_function('clock_gettime')
1151   dep_clock = null_dep
1152 else
1153   dep_clock = cc.find_library('rt')
1154 endif
1155
1156 # TODO: some of these may be conditional
1157 dep_zlib = dependency('zlib', version : '>= 1.2.3', fallback : ['zlib', 'zlib_dep'])
1158 pre_args += '-DHAVE_ZLIB'
1159 dep_thread = dependency('threads')
1160 if dep_thread.found() and host_machine.system() != 'windows'
1161   pre_args += '-DHAVE_PTHREAD'
1162   if cc.has_function(
1163       'pthread_setaffinity_np',
1164       dependencies : dep_thread,
1165       prefix : '#include <pthread.h>',
1166       args : '-D_GNU_SOURCE')
1167     pre_args += '-DHAVE_PTHREAD_SETAFFINITY'
1168   endif
1169   if cc.has_function(
1170       'pthread_setaffinity_np',
1171       dependencies : dep_thread,
1172       prefix : '#include <pthread_np.h>')
1173     pre_args += '-DPTHREAD_SETAFFINITY_IN_NP_HEADER'
1174   endif
1175 endif
1176 dep_expat = dependency('expat', fallback : ['expat', 'expat_dep'])
1177 # this only exists on linux so either this is linux and it will be found, or
1178 # it's not linux and wont
1179 dep_m = cc.find_library('m', required : false)
1180
1181 # Check for libdrm. Various drivers have different libdrm version requirements,
1182 # but we always want to use the same version for all libdrm modules. That means
1183 # even if driver foo requires 2.4.0 and driver bar requires 2.4.3, if foo and
1184 # bar are both on use 2.4.3 for both of them
1185 dep_libdrm_amdgpu = null_dep
1186 dep_libdrm_radeon = null_dep
1187 dep_libdrm_nouveau = null_dep
1188 dep_libdrm_intel = null_dep
1189
1190 _drm_amdgpu_ver = '2.4.99'
1191 _drm_radeon_ver = '2.4.71'
1192 _drm_nouveau_ver = '2.4.66'
1193 _drm_intel_ver = '2.4.75'
1194 _drm_ver = '2.4.81'
1195
1196 _libdrm_checks = [
1197   ['intel', with_dri_i915 or with_gallium_i915],
1198   ['amdgpu', with_amd_vk or with_gallium_radeonsi],
1199   ['radeon', (with_gallium_radeonsi or with_dri_r100 or with_dri_r200 or
1200               with_gallium_r300 or with_gallium_r600)],
1201   ['nouveau', (with_gallium_nouveau or with_dri_nouveau)],
1202 ]
1203
1204 # VC4 only needs core libdrm support of this version, not a libdrm_vc4
1205 # library.
1206 if with_gallium_vc4
1207   _drm_ver = '2.4.89'
1208 endif
1209
1210 # etnaviv only needs core libdrm
1211 if with_gallium_etnaviv
1212   _drm_ver = '2.4.89'
1213 endif
1214
1215 # Loop over the enables versions and get the highest libdrm requirement for all
1216 # active drivers.
1217 _drm_blame = ''
1218 foreach d : _libdrm_checks
1219   ver = get_variable('_drm_@0@_ver'.format(d[0]))
1220   if d[1] and ver.version_compare('>' + _drm_ver)
1221     _drm_ver = ver
1222     _drm_blame = d[0]
1223   endif
1224 endforeach
1225 if _drm_blame != ''
1226   message('libdrm @0@ needed because @1@ has the highest requirement'.format(_drm_ver, _drm_blame))
1227 endif
1228
1229 # Then get each libdrm module
1230 foreach d : _libdrm_checks
1231   if d[1]
1232     set_variable(
1233       'dep_libdrm_' + d[0],
1234       dependency('libdrm_' + d[0], version : '>=' + _drm_ver)
1235     )
1236   endif
1237 endforeach
1238
1239 with_gallium_drisw_kms = false
1240 dep_libdrm = dependency(
1241   'libdrm', version : '>=' + _drm_ver,
1242   required : with_dri2 or with_dri3
1243 )
1244 if dep_libdrm.found()
1245   pre_args += '-DHAVE_LIBDRM'
1246   if with_dri_platform == 'drm' and with_dri
1247     with_gallium_drisw_kms = true
1248   endif
1249 endif
1250
1251 llvm_modules = ['bitwriter', 'engine', 'mcdisassembler', 'mcjit']
1252 llvm_optional_modules = []
1253 if with_amd_vk or with_gallium_radeonsi or with_gallium_r600
1254   llvm_modules += ['amdgpu', 'native', 'bitreader', 'ipo']
1255   if with_gallium_r600
1256     llvm_modules += 'asmparser'
1257   endif
1258 endif
1259 if with_gallium_opencl
1260   llvm_modules += [
1261     'all-targets', 'linker', 'coverage', 'instrumentation', 'ipo', 'irreader',
1262     'lto', 'option', 'objcarcopts', 'profiledata',
1263   ]
1264 endif
1265 if with_gallium_opencl or with_gallium_softpipe
1266   llvm_optional_modules += ['coroutines']
1267 endif
1268
1269 if with_amd_vk or with_gallium_radeonsi
1270   _llvm_version = '>= 8.0.0'
1271 elif with_gallium_swr
1272   _llvm_version = '>= 6.0.0'
1273 else
1274   _llvm_version = '>= 3.9.0'
1275 endif
1276
1277 _shared_llvm = get_option('shared-llvm')
1278
1279 _llvm = get_option('llvm')
1280 dep_llvm = null_dep
1281 with_llvm = false
1282 if _llvm != 'false'
1283   dep_llvm = dependency(
1284     'llvm',
1285     version : _llvm_version,
1286     modules : llvm_modules,
1287     optional_modules : llvm_optional_modules,
1288     required : (
1289       with_amd_vk or with_gallium_radeonsi or with_gallium_swr or
1290       with_gallium_opencl or _llvm == 'true'
1291     ),
1292     static : not _shared_llvm,
1293     method : 'config-tool',
1294   )
1295   with_llvm = dep_llvm.found()
1296 endif
1297 if with_llvm
1298   pre_args += '-DLLVM_AVAILABLE'
1299   pre_args += '-DMESA_LLVM_VERSION_STRING="@0@"'.format(dep_llvm.version())
1300
1301   # LLVM can be built without rtti, turning off rtti changes the ABI of C++
1302   # programs, so we need to build all C++ code in mesa without rtti as well to
1303   # ensure that linking works.
1304   if dep_llvm.get_configtool_variable('has-rtti') == 'NO'
1305     if with_gallium_nouveau
1306       error('The Nouveau driver requires rtti. You either need to turn off nouveau or use an LLVM built with LLVM_ENABLE_RTTI.')
1307     elif with_gallium_opencl
1308       error('The Clover OpenCL state tracker requires rtti, you need to turn off clover or use an LLVM built with LLVM_ENABLE_RTTI.')
1309     endif
1310     cpp_args += '-fno-rtti'
1311   endif
1312 elif with_amd_vk or with_gallium_radeonsi or with_gallium_swr
1313   error('The following drivers require LLVM: Radv, RadeonSI, SWR. One of these is enabled, but LLVM is disabled.')
1314 elif with_gallium_opencl
1315   error('The OpenCL "Clover" state tracker requires LLVM, but LLVM is disabled.')
1316 endif
1317
1318 if (with_amd_vk or with_gallium_radeonsi or with_gallium_opencl or
1319     (with_gallium_r600 and with_llvm))
1320   dep_elf = dependency('libelf', required : false)
1321   if not dep_elf.found()
1322     dep_elf = cc.find_library('elf')
1323   endif
1324 else
1325   dep_elf = null_dep
1326 endif
1327
1328 dep_glvnd = null_dep
1329 glvnd_missing_pc_files = false
1330 if with_glvnd
1331   dep_glvnd = dependency('libglvnd', version : '>= 0.2.0')
1332   # GLVND until commit 0dfaea2bcb7cdcc785f9 ("Add pkg-config files for EGL, GL,
1333   # GLES, and GLX.") was missing its pkg-config files, forcing every vendor to
1334   # provide them and the distro maintainers to resolve the conflict.
1335   glvnd_missing_pc_files = dep_glvnd.version().version_compare('< 1.2.0')
1336   pre_args += '-DUSE_LIBGLVND=1'
1337 endif
1338
1339 if with_valgrind != 'false'
1340   dep_valgrind = dependency('valgrind', required : with_valgrind == 'true')
1341   if dep_valgrind.found()
1342     pre_args += '-DHAVE_VALGRIND'
1343   endif
1344 else
1345   dep_valgrind = null_dep
1346 endif
1347
1348 # pthread stubs. Lets not and say we didn't
1349
1350 prog_bison = find_program('bison', required : with_any_opengl)
1351 prog_flex = find_program('flex', required : with_any_opengl)
1352
1353 dep_selinux = null_dep
1354 if get_option('selinux')
1355   dep_selinux = dependency('libselinux')
1356   pre_args += '-DMESA_SELINUX'
1357 endif
1358
1359 if with_libunwind != 'false'
1360   dep_unwind = dependency('libunwind', required : with_libunwind == 'true')
1361   if dep_unwind.found()
1362     pre_args += '-DHAVE_LIBUNWIND'
1363   endif
1364 else
1365   dep_unwind = null_dep
1366 endif
1367
1368 if with_osmesa != 'none'
1369   if with_osmesa == 'gallium' and not with_gallium_softpipe
1370     error('OSMesa gallium requires gallium softpipe or llvmpipe.')
1371   endif
1372   osmesa_lib_name = 'OSMesa'
1373   osmesa_bits = get_option('osmesa-bits')
1374   if osmesa_bits != '8'
1375     if with_dri or with_glx != 'disabled'
1376       error('OSMesa bits must be 8 if building glx or dir based drivers')
1377     endif
1378     osmesa_lib_name = osmesa_lib_name + osmesa_bits
1379     pre_args += [
1380       '-DCHAN_BITS=@0@'.format(osmesa_bits), '-DDEFAULT_SOFTWARE_DEPTH_BITS=31'
1381     ]
1382   endif
1383 endif
1384
1385 # TODO: symbol mangling
1386
1387 if with_platform_wayland
1388   dep_wl_scanner = dependency('wayland-scanner', native: true)
1389   prog_wl_scanner = find_program(dep_wl_scanner.get_pkgconfig_variable('wayland_scanner'))
1390   if dep_wl_scanner.version().version_compare('>= 1.15')
1391     wl_scanner_arg = 'private-code'
1392   else
1393     wl_scanner_arg = 'code'
1394   endif
1395   dep_wl_protocols = dependency('wayland-protocols', version : '>= 1.8')
1396   dep_wayland_client = dependency('wayland-client', version : '>=1.11')
1397   dep_wayland_server = dependency('wayland-server', version : '>=1.11')
1398   if with_egl
1399     dep_wayland_egl = dependency('wayland-egl-backend', version : '>= 3')
1400     dep_wayland_egl_headers = declare_dependency(
1401       compile_args : run_command(prog_pkgconfig, ['wayland-egl-backend', '--cflags']).stdout().split())
1402   endif
1403   wayland_dmabuf_xml = join_paths(
1404     dep_wl_protocols.get_pkgconfig_variable('pkgdatadir'), 'unstable',
1405     'linux-dmabuf', 'linux-dmabuf-unstable-v1.xml'
1406   )
1407   pre_args += ['-DHAVE_WAYLAND_PLATFORM', '-DWL_HIDE_DEPRECATED']
1408 endif
1409
1410 dep_x11 = null_dep
1411 dep_xext = null_dep
1412 dep_xdamage = null_dep
1413 dep_xfixes = null_dep
1414 dep_x11_xcb = null_dep
1415 dep_xcb = null_dep
1416 dep_xcb_glx = null_dep
1417 dep_xcb_dri2 = null_dep
1418 dep_xcb_dri3 = null_dep
1419 dep_dri2proto = null_dep
1420 dep_glproto = null_dep
1421 dep_xxf86vm = null_dep
1422 dep_xcb_dri3 = null_dep
1423 dep_xcb_present = null_dep
1424 dep_xcb_sync = null_dep
1425 dep_xcb_xfixes = null_dep
1426 dep_xshmfence = null_dep
1427 dep_xcb_xrandr = null_dep
1428 dep_xlib_xrandr = null_dep
1429 if with_platform_x11
1430   if with_glx == 'xlib' or with_glx == 'gallium-xlib'
1431     dep_x11 = dependency('x11')
1432     dep_xext = dependency('xext')
1433     dep_xcb = dependency('xcb')
1434   elif with_glx == 'dri'
1435     dep_x11 = dependency('x11')
1436     dep_xext = dependency('xext')
1437     dep_xdamage = dependency('xdamage', version : '>= 1.1')
1438     dep_xfixes = dependency('xfixes')
1439     dep_xcb_glx = dependency('xcb-glx', version : '>= 1.8.1')
1440   endif
1441   if (with_any_vk or with_glx == 'dri' or with_egl or
1442        (with_gallium_vdpau or with_gallium_xvmc or with_gallium_va or
1443         with_gallium_omx != 'disabled'))
1444     dep_xcb = dependency('xcb')
1445     dep_x11_xcb = dependency('x11-xcb')
1446     if not dep_libdrm.found()
1447       error('libdrm required for gallium video statetrackers when using x11')
1448     endif
1449   endif
1450   if with_any_vk or with_egl or (with_glx == 'dri' and with_dri_platform == 'drm')
1451     dep_xcb_dri2 = dependency('xcb-dri2', version : '>= 1.8')
1452
1453     if with_dri3
1454       pre_args += '-DHAVE_DRI3'
1455       dep_xcb_dri3 = dependency('xcb-dri3')
1456       dep_xcb_present = dependency('xcb-present')
1457       # until xcb-dri3 has been around long enough to make a hard-dependency:
1458       if (dep_xcb_dri3.version().version_compare('>= 1.13') and
1459           dep_xcb_present.version().version_compare('>= 1.13'))
1460         pre_args += '-DHAVE_DRI3_MODIFIERS'
1461       endif
1462       dep_xcb_sync = dependency('xcb-sync')
1463       dep_xshmfence = dependency('xshmfence', version : '>= 1.1')
1464     endif
1465   endif
1466   if with_glx == 'dri' or with_glx == 'gallium-xlib'
1467     dep_glproto = dependency('glproto', version : '>= 1.4.14')
1468   endif
1469   if with_glx == 'dri'
1470     if with_dri_platform == 'drm'
1471       dep_dri2proto = dependency('dri2proto', version : '>= 2.8')
1472       dep_xxf86vm = dependency('xxf86vm')
1473     endif
1474   endif
1475   if (with_egl or (
1476       with_gallium_vdpau or with_gallium_xvmc or with_gallium_xa or
1477       with_gallium_omx != 'disabled'))
1478     dep_xcb_xfixes = dependency('xcb-xfixes')
1479   endif
1480   if with_xlib_lease
1481     dep_xcb_xrandr = dependency('xcb-randr')
1482     dep_xlib_xrandr = dependency('xrandr', version : '>= 1.3')
1483   endif
1484 endif
1485
1486 if get_option('gallium-extra-hud')
1487   pre_args += '-DHAVE_GALLIUM_EXTRA_HUD=1'
1488 endif
1489
1490 _sensors = get_option('lmsensors')
1491 if _sensors != 'false'
1492   dep_lmsensors = cc.find_library('sensors', required : _sensors == 'true')
1493   if dep_lmsensors.found()
1494     pre_args += '-DHAVE_LIBSENSORS=1'
1495   endif
1496 else
1497   dep_lmsensors = null_dep
1498 endif
1499
1500 foreach a : pre_args
1501   add_project_arguments(a, language : ['c', 'cpp'])
1502 endforeach
1503 foreach a : c_args
1504   add_project_arguments(a, language : ['c'])
1505 endforeach
1506 foreach a : cpp_args
1507   add_project_arguments(a, language : ['cpp'])
1508 endforeach
1509
1510 gl_priv_reqs = []
1511
1512 if with_glx == 'xlib' or with_glx == 'gallium-xlib'
1513   gl_priv_reqs += ['x11', 'xext', 'xcb']
1514 elif with_glx == 'dri'
1515   gl_priv_reqs += [
1516     'x11', 'xext', 'xdamage >= 1.1', 'xfixes', 'x11-xcb', 'xcb',
1517     'xcb-glx >= 1.8.1']
1518   if with_dri_platform == 'drm'
1519     gl_priv_reqs += 'xcb-dri2 >= 1.8'
1520     gl_priv_reqs += 'xxf86vm'
1521   endif
1522 endif
1523 if dep_libdrm.found()
1524   gl_priv_reqs += 'libdrm >= 2.4.75'
1525 endif
1526
1527 gl_priv_libs = []
1528 if dep_thread.found()
1529   gl_priv_libs += ['-lpthread', '-pthread']
1530 endif
1531 if dep_m.found()
1532   gl_priv_libs += '-lm'
1533 endif
1534 if dep_dl.found()
1535   gl_priv_libs += '-ldl'
1536 endif
1537
1538 pkg = import('pkgconfig')
1539
1540 prog_nm = find_program('nm', required : false)
1541
1542 # This quirk needs to be applied to sources with functions defined in assembly
1543 # as GCC LTO drops them. See: https://bugs.freedesktop.org/show_bug.cgi?id=109391
1544 gcc_lto_quirk = (cc.get_id() == 'gcc') ? ['-fno-lto'] : []
1545
1546 subdir('include')
1547 subdir('bin')
1548 subdir('src')
1549
1550 # Meson 0.49 and earlier seems to have a bug that fails to evaluate the string-
1551 # formatting below unless the first argument is passed as a variable. This has
1552 # been fixed in Meson 0.50 and beyond, but we need to keep it like this for now
1553 # for backwards compatibility.
1554 _with_opengl_string = with_opengl ? 'yes' : 'no'
1555
1556 lines = ['',
1557   'prefix:          ' + get_option('prefix'),
1558   'libdir:          ' + get_option('libdir'),
1559   'includedir:      ' + get_option('includedir'),
1560   '',
1561   'OpenGL:          @0@ (ES1: @1@ ES2: @2@)'.format(_with_opengl_string,
1562                                                     with_gles1 ? 'yes' : 'no',
1563                                                     with_gles2 ? 'yes' : 'no'),
1564 ]
1565
1566 if with_osmesa != 'none'
1567   lines += ''
1568   suffix = ''
1569   if with_osmesa == 'gallium'
1570     suffix = '(Gallium)'
1571   endif
1572   lines += 'OSMesa:          lib' + osmesa_lib_name + suffix
1573 else
1574   lines += 'OSMesa:          no'
1575 endif
1576
1577 if with_dri
1578   lines += ''
1579   lines += 'DRI platform:    ' + with_dri_platform
1580   if dri_drivers.length() != 0 and dri_drivers != ['']
1581     lines += 'DRI drivers:     ' + ' '.join(dri_drivers)
1582   else
1583     lines += 'DRI drivers:     no'
1584   endif
1585   lines += 'DRI driver dir:  ' + dri_drivers_path
1586 endif
1587
1588 if with_glx != 'disabled'
1589   lines += ''
1590   if with_glx == 'dri'
1591     lines += 'GLX:             DRI-based'
1592   elif with_glx == 'xlib'
1593     lines += 'GLX:             Xlib-based'
1594   elif with_glx == 'gallium-xlib'
1595     lines += 'GLX:             Xlib-based (Gallium)'
1596   else
1597     lines += 'GLX:             ' + with_glx
1598   endif
1599 endif
1600
1601 lines += ''
1602 lines += 'EGL:             ' + (with_egl ? 'yes' : 'no')
1603 if with_egl
1604   egl_drivers = []
1605   if with_dri
1606     egl_drivers += 'builtin:egl_dri2'
1607   endif
1608   if with_dri3
1609     egl_drivers += 'builtin:egl_dri3'
1610   endif
1611   lines += 'EGL drivers:     ' + ' '.join(egl_drivers)
1612 endif
1613 lines += 'GBM:             ' + (with_gbm ? 'yes' : 'no')
1614 if with_platforms
1615   lines += 'EGL/Vulkan/VL platforms:   ' + ' '.join(_platforms)
1616 endif
1617
1618 lines += ''
1619 if with_any_vk
1620   lines += 'Vulkan drivers:  ' + ' '.join(_vulkan_drivers)
1621   lines += 'Vulkan ICD dir:  ' + with_vulkan_icd_dir
1622 else
1623   lines += 'Vulkan drivers:  no'
1624 endif
1625
1626 lines += ''
1627 if with_llvm
1628   lines += 'llvm:            yes'
1629   lines += 'llvm-version:    ' + dep_llvm.version()
1630 else
1631   lines += 'llvm:            no'
1632 endif
1633
1634 lines += ''
1635 if with_gallium
1636   lines += 'Gallium drivers: ' + ' '.join(gallium_drivers)
1637   gallium_st = ['mesa']
1638   if with_gallium_xa
1639     gallium_st += 'xa'
1640   endif
1641   if with_gallium_xvmc
1642     gallium_st += 'xvmc'
1643   endif
1644   if with_gallium_xvmc
1645     gallium_st += 'xvmc'
1646   endif
1647   if with_gallium_vdpau
1648     gallium_st += 'vdpau'
1649   endif
1650   if with_gallium_omx != 'disabled'
1651     gallium_st += 'omx' + with_gallium_omx
1652   endif
1653   if with_gallium_va
1654     gallium_st += 'va'
1655   endif
1656   if with_gallium_st_nine
1657     gallium_st += 'nine'
1658   endif
1659   if with_gallium_opencl
1660     gallium_st += 'clover'
1661   endif
1662   lines += 'Gallium st:      ' + ' '.join(gallium_st)
1663 else
1664   lines += 'Gallium:         no'
1665 endif
1666
1667 lines += 'HUD lmsensors:   ' + (dep_lmsensors.found() ? 'yes' : 'no')
1668
1669 lines += ''
1670 lines += 'Shared-glapi:    ' + (with_shared_glapi ? 'yes' : 'no')
1671
1672
1673 indent = '        '
1674 summary = indent + ('\n' + indent).join(lines)
1675 message('Configuration summary:\n@0@\n'.format(summary))