meson.build

   1 project(
   2     'libxkbcommon',
   3     'c',
   4     version: '1.2.1',
   5     default_options: [
   6         'c_std=c11',
   7         'warning_level=2',
   8         'b_lundef=true',
   9     ],
  10     meson_version : '>= 0.49.0',
  11 )
  12 pkgconfig = import('pkgconfig')
  13 cc = meson.get_compiler('c')
  14
  15 dir_libexec = get_option('prefix')/get_option('libexecdir')/'xkbcommon'
  16
  17 # Compiler flags.
  18 cflags = [
  19     '-fno-strict-aliasing',
  20     '-fsanitize-undefined-trap-on-error',
  21     '-Wno-unused-parameter',
  22     '-Wno-missing-field-initializers',
  23     '-Wpointer-arith',
  24     '-Wmissing-declarations',
  25     '-Wformat=2',
  26     '-Wstrict-prototypes',
  27     '-Wmissing-prototypes',
  28     '-Wnested-externs',
  29     '-Wbad-function-cast',
  30     '-Wshadow',
  31     '-Wlogical-op',
  32     '-Wdate-time',
  33     '-Wwrite-strings',
  34     '-Wno-documentation-deprecated-sync',
  35 ]
  36 add_project_arguments(cc.get_supported_arguments(cflags), language: 'c')
  37
  38
  39 # The XKB config root.
  40 XKBCONFIGROOT = get_option('xkb-config-root')
  41 if XKBCONFIGROOT == ''
  42     xkeyboard_config_dep = dependency('xkeyboard-config', required: false)
  43     if xkeyboard_config_dep.found()
  44         XKBCONFIGROOT = xkeyboard_config_dep.get_pkgconfig_variable('xkb_base')
  45     else
  46         XKBCONFIGROOT = get_option('prefix')/get_option('datadir')/'X11'/'xkb'
  47   endif
  48 endif
  49
  50 XKBCONFIGEXTRAPATH = get_option('xkb-config-extra-path')
  51 if XKBCONFIGEXTRAPATH == ''
  52     XKBCONFIGEXTRAPATH = get_option('prefix')/get_option('sysconfdir')/'xkb'
  53 endif
  54
  55 # The X locale directory for compose.
  56 XLOCALEDIR = get_option('x-locale-root')
  57 if XLOCALEDIR == ''
  58     XLOCALEDIR = get_option('prefix')/get_option('datadir')/'X11'/'locale'
  59 endif
  60
  61
  62 # config.h.
  63 configh_data = configuration_data()
  64 configh_data.set('EXIT_INVALID_USAGE', '2')
  65 configh_data.set_quoted('LIBXKBCOMMON_VERSION', meson.project_version())
  66 configh_data.set_quoted('LIBXKBCOMMON_TOOL_PATH', dir_libexec)
  67 # Like AC_USE_SYSTEM_EXTENSIONS, what #define to use to get extensions
  68 # beyond the base POSIX function set.
  69 if host_machine.system() == 'sunos'
  70   system_extensions = '__EXTENSIONS__'
  71 else
  72   system_extensions = '_GNU_SOURCE'
  73 endif
  74 configh_data.set(system_extensions, 1)
  75 system_ext_define = '#define ' + system_extensions
  76 configh_data.set_quoted('DFLT_XKB_CONFIG_ROOT', XKBCONFIGROOT)
  77 configh_data.set_quoted('DFLT_XKB_CONFIG_EXTRA_PATH', XKBCONFIGEXTRAPATH)
  78 configh_data.set_quoted('XLOCALEDIR', XLOCALEDIR)
  79 configh_data.set_quoted('DEFAULT_XKB_RULES', get_option('default-rules'))
  80 configh_data.set_quoted('DEFAULT_XKB_MODEL', get_option('default-model'))
  81 configh_data.set_quoted('DEFAULT_XKB_LAYOUT', get_option('default-layout'))
  82 if get_option('default-variant') != ''
  83     configh_data.set_quoted('DEFAULT_XKB_VARIANT', get_option('default-variant'))
  84 else
  85     configh_data.set('DEFAULT_XKB_VARIANT', 'NULL')
  86 endif
  87 if get_option('default-options') != ''
  88     configh_data.set_quoted('DEFAULT_XKB_OPTIONS', get_option('default-options'))
  89 else
  90     configh_data.set('DEFAULT_XKB_OPTIONS', 'NULL')
  91 endif
  92 if cc.has_header('unistd.h')
  93     configh_data.set('HAVE_UNISTD_H', 1)
  94 endif
  95 if cc.links('int main(){if(__builtin_expect(1<0,0)){}}', name: '__builtin_expect')
  96     configh_data.set('HAVE___BUILTIN_EXPECT', 1)
  97 endif
  98 if cc.has_header_symbol('unistd.h', 'eaccess', prefix: system_ext_define)
  99     configh_data.set('HAVE_EACCESS', 1)
 100 endif
 101 if cc.has_header_symbol('unistd.h', 'euidaccess', prefix: system_ext_define)
 102     configh_data.set('HAVE_EUIDACCESS', 1)
 103 endif
 104 if cc.has_header_symbol('sys/mman.h', 'mmap')
 105     configh_data.set('HAVE_MMAP', 1)
 106 endif
 107 if cc.has_header_symbol('stdlib.h', 'mkostemp', prefix: system_ext_define)
 108     configh_data.set('HAVE_MKOSTEMP', 1)
 109 endif
 110 if cc.has_header_symbol('fcntl.h', 'posix_fallocate', prefix: system_ext_define)
 111     configh_data.set('HAVE_POSIX_FALLOCATE', 1)
 112 endif
 113 if cc.has_header_symbol('string.h', 'strndup', prefix: system_ext_define)
 114     configh_data.set('HAVE_STRNDUP', 1)
 115 endif
 116 if cc.has_header_symbol('stdio.h', 'asprintf', prefix: system_ext_define)
 117     configh_data.set('HAVE_ASPRINTF', 1)
 118 elif cc.has_header_symbol('stdio.h', 'vasprintf', prefix: system_ext_define)
 119     configh_data.set('HAVE_VASPRINTF', 1)
 120 endif
 121 if cc.has_header_symbol('stdlib.h', 'secure_getenv', prefix: system_ext_define)
 122     configh_data.set('HAVE_SECURE_GETENV', 1)
 123 elif cc.has_header_symbol('stdlib.h', '__secure_getenv', prefix: system_ext_define)
 124     configh_data.set('HAVE___SECURE_GETENV', 1)
 125 else
 126     message('C library does not support secure_getenv, using getenv instead')
 127 endif
 128 have_getopt_long = cc.has_header_symbol('getopt.h', 'getopt_long',
 129                                         prefix: '#define _GNU_SOURCE')
 130 if not cc.has_header_symbol('limits.h', 'PATH_MAX', prefix: system_ext_define)
 131     if host_machine.system() == 'windows'
 132         # see https://docs.microsoft.com/en-us/windows/win32/fileio/naming-a-file#maximum-path-length-limitation
 133         configh_data.set('PATH_MAX', 260)
 134     else
 135         configh_data.set('PATH_MAX', 4096)
 136     endif
 137 endif
 138
 139 # Silence some security & deprecation warnings on MSVC
 140 # for some unix/C functions we use.
 141 # https://docs.microsoft.com/en-us/cpp/error-messages/compiler-warnings/compiler-warning-level-3-c4996?view=vs-2019
 142 configh_data.set('_CRT_SECURE_NO_WARNINGS', 1)
 143 configh_data.set('_CRT_NONSTDC_NO_WARNINGS', 1)
 144 configh_data.set('_CRT_NONSTDC_NO_DEPRECATE', 1)
 145 # Reduce unnecessary includes on MSVC.
 146 configh_data.set('WIN32_LEAN_AND_MEAN', 1)
 147
 148 # Supports -Wl,--version-script?
 149 have_version_script = cc.links(
 150     'int main(){}',
 151     args: '-Wl,--version-script=' + meson.source_root()/'xkbcommon.map',
 152     name: '-Wl,--version-script',
 153 )
 154
 155 map_to_def = find_program('scripts/map-to-def')
 156
 157 # libxkbcommon.
 158 # Note: we use some yacc extensions, which work with either GNU bison
 159 # (preferred) or byacc (with backtracking enabled).
 160 bison = find_program('bison', 'win_bison', required: false)
 161 if bison.found()
 162     yacc_gen = generator(
 163         bison,
 164         output: ['@BASENAME@.c', '@BASENAME@.h'],
 165         arguments: ['--defines=@OUTPUT1@', '-o', '@OUTPUT0@', '-p', '_xkbcommon_', '@INPUT@'],
 166     )
 167 else
 168     byacc = find_program('byacc', required: false)
 169     if byacc.found()
 170         yacc_gen = generator(
 171             byacc,
 172             output: ['@BASENAME@.c', '@BASENAME@.h'],
 173             arguments: ['-H', '@OUTPUT1@', '-o', '@OUTPUT0@', '-p', '_xkbcommon_', '@INPUT@'],
 174         )
 175     else
 176         error('Could not find a compatible YACC program (bison or byacc)')
 177     endif
 178 endif
 179 libxkbcommon_sources = [
 180     'src/compose/parser.c',
 181     'src/compose/parser.h',
 182     'src/compose/paths.c',
 183     'src/compose/paths.h',
 184     'src/compose/state.c',
 185     'src/compose/table.c',
 186     'src/compose/table.h',
 187     'src/xkbcomp/action.c',
 188     'src/xkbcomp/action.h',
 189     'src/xkbcomp/ast.h',
 190     'src/xkbcomp/ast-build.c',
 191     'src/xkbcomp/ast-build.h',
 192     'src/xkbcomp/compat.c',
 193     'src/xkbcomp/expr.c',
 194     'src/xkbcomp/expr.h',
 195     'src/xkbcomp/include.c',
 196     'src/xkbcomp/include.h',
 197     'src/xkbcomp/keycodes.c',
 198     'src/xkbcomp/keymap.c',
 199     'src/xkbcomp/keymap-dump.c',
 200     'src/xkbcomp/keywords.c',
 201     yacc_gen.process('src/xkbcomp/parser.y'),
 202     'src/xkbcomp/parser-priv.h',
 203     'src/xkbcomp/rules.c',
 204     'src/xkbcomp/rules.h',
 205     'src/xkbcomp/scanner.c',
 206     'src/xkbcomp/symbols.c',
 207     'src/xkbcomp/types.c',
 208     'src/xkbcomp/vmod.c',
 209     'src/xkbcomp/vmod.h',
 210     'src/xkbcomp/xkbcomp.c',
 211     'src/xkbcomp/xkbcomp-priv.h',
 212     'src/atom.c',
 213     'src/atom.h',
 214     'src/context.c',
 215     'src/context.h',
 216     'src/context-priv.c',
 217     'src/darray.h',
 218     'src/keysym.c',
 219     'src/keysym.h',
 220     'src/keysym-utf.c',
 221     'src/ks_tables.h',
 222     'src/keymap.c',
 223     'src/keymap.h',
 224     'src/keymap-priv.c',
 225     'src/scanner-utils.h',
 226     'src/state.c',
 227     'src/text.c',
 228     'src/text.h',
 229     'src/utf8.c',
 230     'src/utf8.h',
 231     'src/utils.c',
 232     'src/utils.h',
 233 ]
 234 libxkbcommon_link_args = []
 235 libxkbcommon_link_deps = []
 236 if have_version_script
 237     libxkbcommon_link_args += '-Wl,--version-script=' + meson.source_root()/'xkbcommon.map'
 238     libxkbcommon_link_deps += 'xkbcommon.map'
 239 elif cc.get_argument_syntax() == 'msvc'
 240     libxkbcommon_def = custom_target('xkbcommon.def',
 241         command: [map_to_def, '@INPUT@', '@OUTPUT@'],
 242         input: 'xkbcommon.map',
 243         output: 'kxbcommon.def',
 244     )
 245     libxkbcommon_link_deps += libxkbcommon_def
 246     libxkbcommon_link_args += '/DEF:' + libxkbcommon_def.full_path()
 247 endif
 248 libxkbcommon = library(
 249     'xkbcommon',
 250     'include/xkbcommon/xkbcommon.h',
 251     libxkbcommon_sources,
 252     link_args: libxkbcommon_link_args,
 253     link_depends: libxkbcommon_link_deps,
 254     gnu_symbol_visibility: 'hidden',
 255     version: '0.0.0',
 256     install: true,
 257     include_directories: include_directories('src', 'include'),
 258 )
 259 install_headers(
 260     'include/xkbcommon/xkbcommon.h',
 261     'include/xkbcommon/xkbcommon-compat.h',
 262     'include/xkbcommon/xkbcommon-compose.h',
 263     'include/xkbcommon/xkbcommon-keysyms.h',
 264     'include/xkbcommon/xkbcommon-names.h',
 265     subdir: 'xkbcommon',
 266 )
 267
 268 dep_libxkbcommon = declare_dependency(
 269     link_with: libxkbcommon,
 270     include_directories: include_directories('include'),
 271 )
 272 pkgconfig.generate(
 273     libxkbcommon,
 274     name: 'xkbcommon',
 275     filebase: 'xkbcommon',
 276     version: meson.project_version(),
 277     description: 'XKB API common to servers and clients',
 278 )
 279
 280
 281 # libxkbcommon-x11.
 282 if get_option('enable-x11')
 283     xcb_dep = dependency('xcb', version: '>=1.10', required: false)
 284     xcb_xkb_dep = dependency('xcb-xkb', version: '>=1.10', required: false)
 285     if not xcb_dep.found() or not xcb_xkb_dep.found()
 286         error('''X11 support requires xcb-xkb >= 1.10 which was not found.
 287 You can disable X11 support with -Denable-x11=false.''')
 288     endif
 289
 290     libxkbcommon_x11_sources = [
 291         'src/x11/keymap.c',
 292         'src/x11/state.c',
 293         'src/x11/util.c',
 294         'src/x11/x11-priv.h',
 295         'src/context.h',
 296         'src/context-priv.c',
 297         'src/keymap.h',
 298         'src/keymap-priv.c',
 299         'src/atom.h',
 300         'src/atom.c',
 301     ]
 302     libxkbcommon_x11_link_args = []
 303     libxkbcommon_x11_link_deps = []
 304     if have_version_script
 305         libxkbcommon_x11_link_args += '-Wl,--version-script=' + meson.source_root()/'xkbcommon-x11.map'
 306         libxkbcommon_x11_link_deps += 'xkbcommon-x11.map'
 307     elif cc.get_argument_syntax() == 'msvc'
 308         libxkbcommon_x11_def = custom_target('xkbcommon-x11.def',
 309             command: [map_to_def, '@INPUT@', '@OUTPUT@'],
 310             input: 'xkbcommon-x11.map',
 311             output: 'xkbcommon-x11.def',
 312         )
 313         libxkbcommon_x11_link_deps += libxkbcommon_x11_def
 314         libxkbcommon_x11_link_args += '/DEF:' + libxkbcommon_x11_def.full_path()
 315     endif
 316     libxkbcommon_x11 = library(
 317         'xkbcommon-x11',
 318         'include/xkbcommon/xkbcommon-x11.h',
 319         libxkbcommon_x11_sources,
 320         link_args: libxkbcommon_x11_link_args,
 321         link_depends: libxkbcommon_x11_link_deps,
 322         gnu_symbol_visibility: 'hidden',
 323         version: '0.0.0',
 324         install: true,
 325         include_directories: include_directories('src', 'include'),
 326         link_with: libxkbcommon,
 327         dependencies: [
 328             xcb_dep,
 329             xcb_xkb_dep,
 330         ],
 331     )
 332     install_headers(
 333         'include/xkbcommon/xkbcommon-x11.h',
 334         subdir: 'xkbcommon',
 335     )
 336     dep_libxkbcommon_x11 = declare_dependency(
 337         link_with: libxkbcommon_x11,
 338         include_directories: include_directories('include'),
 339     )
 340     pkgconfig.generate(
 341         libxkbcommon_x11,
 342         name: 'xkbcommon-x11',
 343         filebase: 'xkbcommon-x11',
 344         version: meson.project_version(),
 345         description: 'XKB API common to servers and clients - X11 support',
 346         requires: ['xkbcommon'],
 347         requires_private: ['xcb>=1.10', 'xcb-xkb>=1.10'],
 348     )
 349 endif
 350
 351 # libxkbregistry
 352 if get_option('enable-xkbregistry')
 353     dep_libxml = dependency('libxml-2.0')
 354     deps_libxkbregistry = [dep_libxml]
 355     libxkbregistry_sources = [
 356         'src/registry.c',
 357         'src/utils.h',
 358         'src/utils.c',
 359         'src/util-list.h',
 360         'src/util-list.c',
 361     ]
 362     libxkbregistry_link_args = []
 363     libxkbregistry_link_deps = []
 364     if have_version_script
 365         libxkbregistry_link_args += '-Wl,--version-script=' + meson.source_root()/'xkbregistry.map'
 366         libxkbregistry_link_deps += 'xkbregistry.map'
 367     elif cc.get_argument_syntax() == 'msvc'
 368         libxkbregistry_def = custom_target('xkbregistry.def',
 369             command: [map_to_def, '@INPUT@', '@OUTPUT@'],
 370             input: 'xkbregistry.map',
 371             output: 'xkbregistry.def',
 372         )
 373         libxkbregistry_link_deps += libxkbregistry_def
 374         libxkbregistry_link_args += '/DEF:' + libxkbregistry_def.full_path()
 375     endif
 376     libxkbregistry = library(
 377         'xkbregistry',
 378         'include/xkbcommon/xkbregistry.h',
 379         libxkbregistry_sources,
 380         link_args: libxkbregistry_link_args,
 381         link_depends: libxkbregistry_link_deps,
 382         gnu_symbol_visibility: 'hidden',
 383         dependencies: deps_libxkbregistry,
 384         version: '0.0.0',
 385         install: true,
 386         include_directories: include_directories('src', 'include'),
 387     )
 388     install_headers(
 389         'include/xkbcommon/xkbregistry.h',
 390         subdir: 'xkbcommon',
 391     )
 392     pkgconfig.generate(
 393         libxkbregistry,
 394         name: 'xkbregistry',
 395         filebase: 'xkbregistry',
 396         version: meson.project_version(),
 397         description: 'XKB API to query available rules, models, layouts, variants and options',
 398     )
 399
 400     dep_libxkbregistry = declare_dependency(
 401         link_with: libxkbregistry,
 402         include_directories: include_directories('include'),
 403     )
 404 endif
 405
 406 man_pages = []
 407
 408 # Tools
 409 build_tools = have_getopt_long
 410 if build_tools
 411     libxkbcommon_tools_internal = static_library(
 412         'tools-internal',
 413         'tools/tools-common.h',
 414         'tools/tools-common.c',
 415         dependencies: dep_libxkbcommon,
 416     )
 417     tools_dep = declare_dependency(
 418         include_directories: [include_directories('tools', 'include')],
 419         link_with: libxkbcommon_tools_internal,
 420     )
 421
 422     executable('xkbcli', 'tools/xkbcli.c',
 423                dependencies: tools_dep, install: true)
 424     install_man('tools/xkbcli.1')
 425
 426     xkbcli_compile_keymap = executable('xkbcli-compile-keymap',
 427                                        'tools/compile-keymap.c',
 428                                        dependencies: tools_dep,
 429                                        install: true,
 430                                        install_dir: dir_libexec)
 431     install_man('tools/xkbcli-compile-keymap.1')
 432     # The same tool again, but with access to some private APIs.
 433     executable('compile-keymap',
 434                'tools/compile-keymap.c',
 435                libxkbcommon_sources,
 436                dependencies: [tools_dep],
 437                c_args: ['-DENABLE_PRIVATE_APIS'],
 438                include_directories: [include_directories('src', 'include')],
 439                install: false)
 440     configh_data.set10('HAVE_XKBCLI_COMPILE_KEYMAP', true)
 441     executable('xkbcli-how-to-type',
 442                'tools/how-to-type.c',
 443                dependencies: tools_dep,
 444                install: true,
 445                install_dir: dir_libexec)
 446     install_man('tools/xkbcli-how-to-type.1')
 447     configh_data.set10('HAVE_XKBCLI_HOW_TO_TYPE', true)
 448     if cc.has_header('linux/input.h')
 449         executable('xkbcli-interactive-evdev',
 450                    'tools/interactive-evdev.c',
 451                    dependencies: tools_dep,
 452                    install: true,
 453                    install_dir: dir_libexec)
 454         configh_data.set10('HAVE_XKBCLI_INTERACTIVE_EVDEV', true)
 455         install_man('tools/xkbcli-interactive-evdev.1')
 456     endif
 457     if get_option('enable-x11')
 458         x11_tools_dep = declare_dependency(
 459             link_with: libxkbcommon_x11,
 460             dependencies: [
 461                 tools_dep,
 462                 xcb_dep,
 463                 xcb_xkb_dep,
 464             ],
 465         )
 466         executable('xkbcli-interactive-x11',
 467                    'tools/interactive-x11.c',
 468                    dependencies: x11_tools_dep,
 469                    install: true,
 470                    install_dir: dir_libexec)
 471         install_man('tools/xkbcli-interactive-x11.1')
 472         configh_data.set10('HAVE_XKBCLI_INTERACTIVE_X11', true)
 473     endif
 474     if get_option('enable-wayland')
 475         wayland_client_dep = dependency('wayland-client', version: '>=1.2.0', required: false)
 476         wayland_protocols_dep = dependency('wayland-protocols', version: '>=1.12', required: false)
 477         wayland_scanner_dep = dependency('wayland-scanner', required: false, native: true)
 478         if not wayland_client_dep.found() or not wayland_protocols_dep.found() or not wayland_scanner_dep.found()
 479             error('''The Wayland xkbcli programs require wayland-client >= 1.2.0, wayland-protocols >= 1.7 which were not found.
 480 You can disable the Wayland xkbcli programs with -Denable-wayland=false.''')
 481         endif
 482
 483         wayland_scanner = find_program(wayland_scanner_dep.get_pkgconfig_variable('wayland_scanner'))
 484         wayland_scanner_code_gen = generator(
 485             wayland_scanner,
 486             output: '@BASENAME@-protocol.c',
 487             arguments: ['code', '@INPUT@', '@OUTPUT@'],
 488         )
 489         wayland_scanner_client_header_gen = generator(
 490             wayland_scanner,
 491             output: '@BASENAME@-client-protocol.h',
 492             arguments: ['client-header', '@INPUT@', '@OUTPUT@'],
 493         )
 494         wayland_protocols_datadir = wayland_protocols_dep.get_pkgconfig_variable('pkgdatadir')
 495         xdg_shell_xml = wayland_protocols_datadir/'stable/xdg-shell/xdg-shell.xml'
 496         xdg_shell_sources = [
 497             wayland_scanner_code_gen.process(xdg_shell_xml),
 498             wayland_scanner_client_header_gen.process(xdg_shell_xml),
 499         ]
 500         executable('xkbcli-interactive-wayland',
 501                    'tools/interactive-wayland.c',
 502                    xdg_shell_sources,
 503                    dependencies: [tools_dep, wayland_client_dep],
 504                    install: true,
 505                    install_dir: dir_libexec)
 506         install_man('tools/xkbcli-interactive-wayland.1')
 507         configh_data.set10('HAVE_XKBCLI_INTERACTIVE_WAYLAND', true)
 508     endif
 509
 510     if get_option('enable-xkbregistry')
 511         configh_data.set10('HAVE_XKBCLI_LIST', true)
 512         executable('xkbcli-list',
 513                    'tools/registry-list.c',
 514                    dependencies: dep_libxkbregistry,
 515                    install: true,
 516                    install_dir: dir_libexec)
 517         install_man('tools/xkbcli-list.1')
 518     endif
 519 endif
 520
 521
 522 # xkeyboard-config "verifier"
 523 xkct_config = configuration_data()
 524 xkct_config.set('MESON_BUILD_ROOT', meson.build_root())
 525 xkct_config.set('XKB_CONFIG_ROOT', XKBCONFIGROOT)
 526 configure_file(input: 'test/xkeyboard-config-test.py.in',
 527                output: 'xkeyboard-config-test',
 528                configuration: xkct_config)
 529
 530 # Tests
 531 test_env = environment()
 532 test_env.set('XKB_LOG_LEVEL', 'debug')
 533 test_env.set('XKB_LOG_VERBOSITY', '10')
 534 test_env.set('top_srcdir', meson.source_root())
 535 test_env.set('top_builddir', meson.build_root())
 536 test_env.set('HAVE_XKBCLI_INTERACTIVE_EVDEV', configh_data.get('HAVE_XKBCLI_INTERACTIVE_EVDEV', 0).to_string())
 537 test_env.set('HAVE_XKBCLI_INTERACTIVE_WAYLAND', configh_data.get('HAVE_XKBCLI_INTERACTIVE_WAYLAND', 0).to_string())
 538 test_env.set('HAVE_XKBCLI_INTERACTIVE_X11', configh_data.get('HAVE_XKBCLI_INTERACTIVE_X11', 0).to_string())
 539 test_env.set('HAVE_XKBCLI_LIST', configh_data.get('HAVE_XKBCLI_LIST', 0).to_string())
 540
 541 test_configh_data = configuration_data()
 542 test_configh_data.set_quoted('TEST_XKB_CONFIG_ROOT', meson.source_root()/'test'/'data')
 543 configure_file(output: 'test-config.h', configuration: test_configh_data)
 544
 545 # Some tests need to use unexported symbols, so we link them against
 546 # an internal copy of libxkbcommon with all symbols exposed.
 547 libxkbcommon_test_internal = static_library(
 548     'xkbcommon-test-internal',
 549     'test/common.c',
 550     'test/test.h',
 551     'test/evdev-scancodes.h',
 552     'bench/bench.c',
 553     'bench/bench.h',
 554     libxkbcommon_sources,
 555     include_directories: include_directories('src', 'include'),
 556 )
 557 test_dep = declare_dependency(
 558     include_directories: include_directories('src', 'include'),
 559     link_with: libxkbcommon_test_internal,
 560 )
 561 if get_option('enable-x11')
 562     libxkbcommon_x11_internal = static_library(
 563         'xkbcommon-x11-internal',
 564         libxkbcommon_x11_sources,
 565         include_directories: include_directories('src', 'include'),
 566         link_with: libxkbcommon_test_internal,
 567         dependencies: [
 568             xcb_dep,
 569             xcb_xkb_dep,
 570         ],
 571     )
 572     x11_test_dep = declare_dependency(
 573         link_with: libxkbcommon_x11_internal,
 574         dependencies: [
 575             test_dep,
 576             xcb_dep,
 577             xcb_xkb_dep,
 578         ],
 579     )
 580 endif
 581 test(
 582     'keysym',
 583     executable('test-keysym', 'test/keysym.c', dependencies: test_dep),
 584     env: test_env,
 585 )
 586 test(
 587     'keymap',
 588     executable('test-keymap', 'test/keymap.c', dependencies: test_dep),
 589     env: test_env,
 590 )
 591 test(
 592     'filecomp',
 593     executable('test-filecomp', 'test/filecomp.c', dependencies: test_dep),
 594     env: test_env,
 595 )
 596 # TODO: This test currently uses some functions that don't exist on Windows.
 597 if cc.get_id() != 'msvc'
 598   test(
 599       'context',
 600       executable('test-context', 'test/context.c', dependencies: test_dep),
 601       env: test_env,
 602   )
 603 endif
 604 test(
 605     'rules-file',
 606     executable('test-rules-file', 'test/rules-file.c', dependencies: test_dep),
 607     env: test_env,
 608 )
 609 test(
 610     'rules-file-includes',
 611     executable('test-rules-file-includes', 'test/rules-file-includes.c', dependencies: test_dep),
 612     env: test_env,
 613 )
 614 test(
 615     'stringcomp',
 616     executable('test-stringcomp', 'test/stringcomp.c', dependencies: test_dep),
 617     env: test_env,
 618 )
 619 test(
 620     'buffercomp',
 621     executable('test-buffercomp', 'test/buffercomp.c', dependencies: test_dep),
 622     env: test_env,
 623 )
 624 test(
 625     'log',
 626     executable('test-log', 'test/log.c', dependencies: test_dep),
 627     env: test_env,
 628 )
 629 test(
 630     'atom',
 631     executable('test-atom', 'test/atom.c', dependencies: test_dep),
 632     env: test_env,
 633 )
 634 test(
 635     'utf8',
 636     executable('test-utf8', 'test/utf8.c', dependencies: test_dep),
 637     env: test_env,
 638 )
 639 test(
 640     'state',
 641     executable('test-state', 'test/state.c', dependencies: test_dep),
 642     env: test_env,
 643 )
 644 test(
 645     'keyseq',
 646     executable('test-keyseq', 'test/keyseq.c', dependencies: test_dep),
 647     env: test_env,
 648 )
 649 test(
 650     'rulescomp',
 651     executable('test-rulescomp', 'test/rulescomp.c', dependencies: test_dep),
 652     env: test_env,
 653 )
 654 test(
 655     'compose',
 656     executable('test-compose', 'test/compose.c', dependencies: test_dep),
 657     env: test_env,
 658 )
 659 test(
 660     'utils',
 661     executable('test-utils', 'test/utils.c', dependencies: test_dep),
 662     env: test_env,
 663 )
 664 test(
 665     'symbols-leak-test',
 666     find_program('test/symbols-leak-test.py'),
 667     env: test_env,
 668     suite: ['python-tests'],
 669 )
 670 if get_option('enable-x11')
 671     test(
 672         'x11',
 673         executable('test-x11', 'test/x11.c', dependencies: x11_test_dep),
 674         env: test_env,
 675     )
 676     # test/x11comp is meant to be run, but it is (temporarily?) disabled.
 677     # See: https://github.com/xkbcommon/libxkbcommon/issues/30
 678     executable('test-x11comp', 'test/x11comp.c', dependencies: x11_test_dep)
 679 endif
 680 if get_option('enable-xkbregistry')
 681     test(
 682         'registry',
 683         executable('test-registry', 'test/registry.c',
 684                    include_directories: include_directories('src'),
 685                    dependencies: dep_libxkbregistry),
 686         env: test_env,
 687     )
 688 endif
 689 if build_tools
 690     test('tool-option-parsing',
 691          find_program('test/tool-option-parsing.py'),
 692          env: test_env,
 693          suite: ['python-tests'])
 694
 695     # A set of keysyms to test for. Add one or two symbols to this array
 696     # whenever the xorgproto gets updated to make sure we resolve them.
 697     keysyms_to_test = [
 698         'XF86Macro23',
 699     ]
 700
 701     env = environment()
 702     env.set('XKB_CONFIG_ROOT', meson.source_root()/'test'/'data')
 703     foreach keysym: keysyms_to_test
 704         test('keysym-test-@0@'.format(keysym),
 705              find_program('test/test-keysym.py'),
 706              env: env,
 707              args: [keysym, '--tool', xkbcli_compile_keymap],
 708              suite: ['python-tests'])
 709     endforeach
 710 endif
 711
 712 valgrind = find_program('valgrind', required: false)
 713 if valgrind.found()
 714     add_test_setup('valgrind',
 715         exe_wrapper: [valgrind,
 716                        '--leak-check=full',
 717                        '--track-origins=yes',
 718                        '--gen-suppressions=all',
 719                        '--error-exitcode=99'],
 720         timeout_multiplier : 10)
 721 else
 722     message('valgrind not found, disabling valgrind test setup')
 723 endif
 724
 725
 726 # Fuzzing target programs.
 727 executable('fuzz-keymap', 'fuzz/keymap/target.c', dependencies: test_dep)
 728 executable('fuzz-compose', 'fuzz/compose/target.c', dependencies: test_dep)
 729
 730
 731 # Benchmarks.
 732 bench_env = environment()
 733 bench_env.set('top_srcdir', meson.source_root())
 734 benchmark(
 735     'key-proc',
 736     executable('bench-key-proc', 'bench/key-proc.c', dependencies: test_dep),
 737     env: bench_env,
 738 )
 739 benchmark(
 740     'rules',
 741     executable('bench-rules', 'bench/rules.c', dependencies: test_dep),
 742     env: bench_env,
 743 )
 744 benchmark(
 745     'rulescomp',
 746     executable('bench-rulescomp', 'bench/rulescomp.c', dependencies: test_dep),
 747     env: bench_env,
 748 )
 749 benchmark(
 750     'compose',
 751     executable('bench-compose', 'bench/compose.c', dependencies: test_dep),
 752     env: bench_env,
 753 )
 754 benchmark(
 755     'atom',
 756     executable('bench-atom', 'bench/atom.c', dependencies: test_dep),
 757     env: bench_env,
 758 )
 759 if get_option('enable-x11')
 760   benchmark(
 761       'x11',
 762       executable('bench-x11', 'bench/x11.c', dependencies: x11_test_dep),
 763       env: bench_env,
 764   )
 765 endif
 766
 767
 768 # Documentation.
 769 if get_option('enable-docs')
 770     doxygen = find_program('doxygen', required: false)
 771     if not doxygen.found()
 772         error('''Documentation requires doxygen which was not found.
 773 You can disable the documentation with -Denable-docs=false.''')
 774     endif
 775     doxygen_wrapper = find_program('scripts/doxygen-wrapper')
 776
 777     doxygen_input = [
 778         'README.md',
 779         'doc/doxygen-extra.css',
 780         'doc/quick-guide.md',
 781         'doc/compat.md',
 782         'doc/user-configuration.md',
 783         'doc/rules-format.md',
 784         'doc/keymap-format-text-v1.md',
 785         'include/xkbcommon/xkbcommon.h',
 786         'include/xkbcommon/xkbcommon-names.h',
 787         'include/xkbcommon/xkbcommon-x11.h',
 788         'include/xkbcommon/xkbcommon-compose.h',
 789         'include/xkbcommon/xkbregistry.h',
 790     ]
 791     doxygen_data = configuration_data()
 792     doxygen_data.set('PACKAGE_NAME', meson.project_name())
 793     doxygen_data.set('PACKAGE_VERSION', meson.project_version())
 794     doxygen_data.set('INPUT', ' '.join(doxygen_input))
 795     doxygen_data.set('OUTPUT_DIRECTORY', meson.build_root())
 796     doxyfile = configure_file(
 797         input: 'doc/Doxyfile.in',
 798         output: 'Doxyfile',
 799         configuration: doxygen_data,
 800     )
 801     # TODO: Meson should provide this.
 802     docdir = get_option('datadir')/'doc'/meson.project_name()
 803     custom_target(
 804         'doc',
 805         input: [doxyfile] + doxygen_input,
 806         output: 'html',
 807         command: [doxygen_wrapper, doxygen.path(), meson.build_root()/'Doxyfile', meson.source_root()],
 808         install: true,
 809         install_dir: docdir,
 810         build_by_default: true,
 811     )
 812 endif
 813
 814 configure_file(output: 'config.h', configuration: configh_data)
 815
 816
 817 # Stable variables for projects using xkbcommon as a subproject.
 818 # These variables should not be renamed.
 819 libxkbcommon_dep = dep_libxkbcommon
 820 if get_option('enable-x11')
 821   libxkbcommon_x11_dep = dep_libxkbcommon_x11
 822 endif
 823 if get_option('enable-xkbregistry')
 824   libxkbregistry_dep = dep_libxkbregistry
 825 endif