meson.build

   1 project('pulseaudio', 'c', 'cpp',
   2         version : run_command(find_program('git-version-gen'), join_paths(meson.current_source_dir(), '.tarball-version')).stdout().strip(),
   3         meson_version : '>= 0.47.0',
   4         default_options : [ 'c_std=gnu11', 'cpp_std=c++11' ]
   5         )
   6
   7 pa_version_str = meson.project_version()
   8 # For tarballs, the first split will do nothing, but for builds in git, we
   9 # split out suffixes when there are commits since the last tag
  10 # (e.g.: v11.99.1-3-gad14bdb24 -> v11.99.1)
  11 version_split = pa_version_str.split('-')[0].split('.')
  12 pa_version_major = version_split[0].split('v')[0]
  13 pa_version_minor = version_split[1]
  14 if version_split.length() > 2
  15   pa_version_micro = version_split[2]
  16 else
  17   pa_version_micro = '0'
  18 endif
  19 pa_version_major_minor = pa_version_major + '.' + pa_version_minor
  20
  21 pa_api_version = 12
  22 pa_protocol_version = 33
  23
  24 apiversion = '1.0'
  25 soversion = 0
  26 # FIXME: this doesn't actually do what we want it to
  27 # maintaining compatibility with the previous libtool versioning
  28 # current = minor * 100 + micro
  29 libversion = '@0@.@1@.0'.format(soversion, pa_version_minor.to_int() * 100 + pa_version_micro.to_int())
  30
  31 # The ABI-stable GLib adapter for client applications.
  32 # For the version x:y:z always will hold y=z.
  33 libpulse_mainloop_glib_version = '0.5.0'
  34
  35 # Paths
  36
  37 prefix = get_option('prefix')
  38 assert(prefix.startswith('/'), 'Prefix is not absolute: "@0@"'.format(prefix))
  39
  40 bindir = join_paths(prefix, get_option('bindir'))
  41 libdir = join_paths(prefix, get_option('libdir'))
  42 libexecdir = join_paths(prefix, get_option('libexecdir'))
  43 datadir = join_paths(prefix, get_option('datadir'))
  44 localstatedir = join_paths(prefix, get_option('localstatedir'))
  45 sysconfdir = join_paths(prefix, get_option('sysconfdir'))
  46
  47 pulselibexecdir = join_paths(libexecdir, 'pulse')
  48
  49 pulsedspdir = get_option('pulsedspdir')
  50 if pulsedspdir == ''
  51   join_paths(libdir, 'pulseaudio')
  52 endif
  53
  54 # Configuration data
  55
  56 cc = meson.get_compiler('c')
  57
  58 cdata = configuration_data()
  59 cdata.set_quoted('PACKAGE', 'pulseaudio')
  60 cdata.set_quoted('PACKAGE_NAME', 'pulseaudio')
  61 cdata.set_quoted('PACKAGE_VERSION', pa_version_str)
  62 cdata.set_quoted('CANONICAL_HOST', host_machine.cpu())
  63 cdata.set('PA_MAJOR', pa_version_major)
  64 cdata.set('PA_MINOR', pa_version_minor)
  65 cdata.set('PA_API_VERSION', pa_api_version)
  66 cdata.set('PA_PROTOCOL_VERSION', pa_protocol_version)
  67 cdata.set_quoted('PA_MACHINE_ID', join_paths(sysconfdir, 'machine-id'))
  68 cdata.set_quoted('PA_MACHINE_ID_FALLBACK', join_paths(localstatedir, 'lib', 'dbus', 'machine-id'))
  69 cdata.set_quoted('PA_SRCDIR', join_paths(meson.current_source_dir(), 'src'))
  70 cdata.set_quoted('PA_BUILDDIR', meson.current_build_dir())
  71 cdata.set_quoted('PA_SOEXT', '.so')
  72 cdata.set_quoted('PA_DEFAULT_CONFIG_DIR', join_paths(sysconfdir, 'pulse'))
  73 cdata.set_quoted('PA_BINARY', join_paths(bindir, 'pulseaudio'))
  74 cdata.set_quoted('PA_SYSTEM_RUNTIME_PATH', join_paths(localstatedir, 'run', 'pulse'))
  75 cdata.set_quoted('PA_SYSTEM_CONFIG_PATH', join_paths(localstatedir, 'lib', 'pulse'))
  76 cdata.set_quoted('PA_SYSTEM_STATE_PATH', join_paths(localstatedir, 'lib', 'pulse'))
  77 cdata.set_quoted('PA_DLSEARCHPATH', join_paths(libdir, 'pulse-' + pa_version_major_minor, 'modules'))
  78 cdata.set_quoted('PA_SYSTEM_USER', get_option('system_user'))
  79 cdata.set_quoted('PA_SYSTEM_GROUP', get_option('system_group'))
  80 cdata.set_quoted('PA_ACCESS_GROUP', get_option('access_group'))
  81 cdata.set_quoted('PA_CFLAGS', 'Not yet supported on meson')
  82 cdata.set_quoted('PA_ALSA_PATHS_DIR', join_paths(datadir, 'pulseaudio', 'alsa-mixer', 'paths'))
  83 cdata.set_quoted('PA_ALSA_PROFILE_SETS_DIR', join_paths(datadir, 'pulseaudio', 'alsa-mixer', 'profile-sets'))
  84 cdata.set_quoted('DESKTOPFILEDIR', join_paths(datadir, 'applications'))
  85
  86 # Headers
  87
  88 check_headers = [
  89   'arpa/inet.h',
  90   'cpuid.h',
  91   'execinfo.h',
  92   'grp.h',
  93   'langinfo.h',
  94   'locale.h',
  95   'netdb.h',
  96   'netinet/in.h',
  97   'netinet/in_systm.h',
  98   'netinet/ip.h',
  99   'netinet/tcp.h',
 100   'pcreposix.h',
 101   'poll.h',
 102   'pwd.h',
 103   'regex.h',
 104   'sched.h',
 105   'sys/capability.h',
 106   'sys/ioctl.h',
 107   'sys/mman.h',
 108   'sys/prctl.h',
 109   'sys/resource.h',
 110   'sys/select.h',
 111   'sys/socket.h',
 112   'sys/un.h',
 113   'sys/wait.h',
 114   'valgrind/memcheck.h',
 115   'xlocale.h',
 116 ]
 117
 118 foreach h : check_headers
 119   if cc.has_header(h)
 120     define = 'HAVE_' + h.underscorify().to_upper()
 121     cdata.set(define, 1)
 122   endif
 123 endforeach
 124
 125 # FIXME: move this to the above set
 126 if cc.has_header('pthread.h')
 127   cdata.set('HAVE_PTHREAD', 1)
 128 endif
 129
 130 # Functions
 131
 132 check_functions = [
 133   'accept4',
 134   'clock_gettime',
 135   'fchmod',
 136   'fchown',
 137   'fork',
 138   'fstat',
 139   'getaddrinfo',
 140   'getgrgid_r',
 141   'getpwnam_r',
 142   'gettimeofday',
 143   'getuid',
 144   'lstat',
 145   'memfd_create',
 146   'mlock',
 147   'nanosleep',
 148   'paccept',
 149   'pipe',
 150   'pipe2',
 151   'posix_madvise',
 152   'readlink',
 153   'setegid',
 154   'seteuid',
 155   'setregid',
 156   'setreuid',
 157   'setresgid',
 158   'setresuid',
 159   'setsid',
 160   'sig2str',
 161   'sigaction',
 162   'strtod_l',
 163   'symlink',
 164   'sysconf',
 165   'uname',
 166 ]
 167
 168 foreach f : check_functions
 169   if cc.has_function(f)
 170     define = 'HAVE_' + f.underscorify().to_upper()
 171     cdata.set(define, 1)
 172   endif
 173 endforeach
 174
 175 shm_dep = cc.find_library('rt', required : false)
 176 if shm_dep.found()
 177   cdata.set('HAVE_SHM_OPEN', 1)
 178 endif
 179
 180 if cc.has_function('SYS_memfd_create', prefix : '#include <sys/syscall.h>')
 181   cdata.set('HAVE_MEMFD', 1)
 182 endif
 183
 184 # Types
 185
 186 # FIXME: do we ever care about gid_t not being defined / smaller than an int?
 187 cdata.set('GETGROUPS_T', 'gid_t')
 188
 189 # Include paths
 190
 191 configinc = include_directories('.')
 192 topinc = include_directories('src')
 193
 194 # CFLAGS
 195
 196 pa_c_args = ['-DHAVE_CONFIG_H', '-D_GNU_SOURCE']
 197 server_c_args = ['-D__INCLUDED_FROM_PULSE_AUDIO']
 198 cdata.set('MESON_BUILD', 1)
 199
 200 # Core Dependencies
 201
 202 libm_dep = cc.find_library('m', required : true)
 203 thread_dep = dependency('threads')
 204 cap_dep = cc.find_library('cap', required : false)
 205
 206 if get_option('database') == 'tdb'
 207   database_dep = dependency('tdb')
 208 elif get_option('database') == 'gdbm'
 209   database_dep = cc.find_library('gdbm', required : true)
 210 endif
 211
 212 if get_option('ipv6')
 213   cdata.set('HAVE_IPV6', 1)
 214 endif
 215
 216 atomictest = '''void func() {
 217   volatile int atomic = 2;
 218   __sync_bool_compare_and_swap (&atomic, 2, 3);
 219 }
 220 '''
 221 if cc.compiles(atomictest)
 222   cdata.set('HAVE_ATOMIC_BUILTINS', true)
 223 else
 224   # FIXME: check if we need libatomic_ops
 225 endif
 226
 227 # FIXME: make sure it's >= 2.2
 228 ltdl_dep = cc.find_library('ltdl', required : true)
 229 # FIXME: can meson support libtool -dlopen/-dlpreopen things?
 230 #        and do we still want to support this at all?
 231 cdata.set('DISABLE_LIBTOOL_PRELOAD', 1)
 232
 233 sndfile_dep = dependency('sndfile', version : '>= 1.0.20')
 234
 235 dbus_dep = dependency('dbus-1', version : '>= 1.4.12', required : get_option('dbus'))
 236 if dbus_dep.found()
 237   cdata.set('HAVE_DBUS', 1)
 238 endif
 239
 240 gio_dep = dependency('gio-2.0', version : '>= 2.26.0', required : get_option('gsettings'))
 241 if gio_dep.found()
 242   cdata.set('HAVE_GSETTINGS', 1)
 243 endif
 244
 245 glib_dep = dependency('glib-2.0', version : '>= 2.4.0', required: get_option('glib'))
 246 if glib_dep.found()
 247   cdata.set('HAVE_GLIB', 1)
 248 endif
 249
 250 gtk_dep = dependency('gtk+-3.0', required : get_option('gtk'))
 251 if gtk_dep.found()
 252   cdata.set('HAVE_GTK', 1)
 253 endif
 254
 255 x11_dep = dependency('x11-xcb', required : get_option('x11'))
 256 if x11_dep.found()
 257   xcb_dep  = dependency('xcb',  required : true, version : '>= 1.6')
 258   ice_dep  = dependency('ice',  required : true)
 259   sm_dep   = dependency('sm',   required : true)
 260   xtst_dep = dependency('xtst', required : true)
 261   cdata.set('HAVE_X11', 1)
 262 endif
 263
 264 alsa_dep = dependency('alsa', version : '>= 1.0.24', required : get_option('alsa'))
 265 if alsa_dep.found()
 266   cdata.set('HAVE_ALSA', 1)
 267   cdata.set('HAVE_ALSA_UCM', 1)
 268 endif
 269
 270 asyncns_dep = dependency('libasyncns', version : '>= 0.1', required : get_option('asyncns'))
 271 if asyncns_dep.found()
 272   cdata.set('HAVE_LIBASYNCNS', 1)
 273 endif
 274
 275 systemd_dep = dependency('libsystemd', required : get_option('systemd'))
 276 if systemd_dep.found()
 277   cdata.set('HAVE_SYSTEMD_DAEMON', 1)
 278   cdata.set('HAVE_SYSTEMD_LOGIN', 1)
 279   cdata.set('HAVE_SYSTEMD_JOURNAL', 1)
 280 endif
 281
 282 # FIXME: support ORC
 283 cdata.set('DISABLE_ORC', 1)
 284
 285 # Module dependencies
 286
 287 if cc.has_header('sys/soundcard.h')
 288   cdata.set('HAVE_OSS_OUTPUT', 1)
 289   cdata.set('HAVE_OSS_WRAPPER', 1)
 290   cdata.set_quoted('PULSEDSP_LOCATION', pulsedspdir)
 291 endif
 292
 293 if get_option('hal-compat')
 294   cdata.set('HAVE_HAL_COMPAT', 1)
 295 endif
 296
 297 avahi_dep = dependency('avahi-client', version : '>= 0.6.0', required : get_option('avahi'))
 298 if avahi_dep.found()
 299   cdata.set('HAVE_AVAHI', 1)
 300 endif
 301
 302 bluez_dep = dependency('bluez', version : '>= 5.0', required : get_option('bluez5'))
 303 sbc_dep = dependency('sbc', version : '>= 1.0', required : false)
 304 if bluez_dep.found()
 305   assert(dbus_dep.found(), 'BlueZ requires D-Bus support')
 306   assert(sbc_dep.found(), 'BlueZ requires SBC support')
 307   cdata.set('HAVE_SBC', 1)
 308   cdata.set('HAVE_BLUEZ', 1)
 309   cdata.set('HAVE_BLUEZ_5', 1)
 310   if get_option('bluez5-native-headset')
 311     cdata.set('HAVE_BLUEZ_5_NATIVE_HEADSET', 1)
 312   endif
 313   if get_option('bluez5-ofono-headset')
 314     cdata.set('HAVE_BLUEZ_5_OFONO_HEADSET', 1)
 315   endif
 316 endif
 317
 318 fftw_dep = dependency('fftw3f', required : get_option('fftw'))
 319 if fftw_dep.found()
 320   cdata.set('HAVE_FFTW', 1)
 321 endif
 322
 323 jack_dep = dependency('jack', version : '>= 0.117.0', required : get_option('jack'))
 324 if jack_dep.found()
 325   cdata.set('HAVE_JACK', 1)
 326 endif
 327
 328 lirc_dep = dependency('lirc', required : get_option('lirc'))
 329 if lirc_dep.found()
 330   cdata.set('HAVE_LIRC', 1)
 331 endif
 332
 333 openssl_dep = dependency('openssl', version : '>= 0.9', required : get_option('openssl'))
 334 if openssl_dep.found()
 335   cdata.set('HAVE_OPENSSL', 1)
 336 endif
 337
 338 speex_dep = dependency('speexdsp', version : '>= 1.2', required : get_option('speex'))
 339 if speex_dep.found()
 340   cdata.set('HAVE_SPEEX', 1)
 341 endif
 342
 343 udev_dep = dependency('libudev', version : '>= 143', required : get_option('udev'))
 344 if udev_dep.found()
 345   cdata.set('HAVE_UDEV', 1)
 346 endif
 347
 348 webrtc_dep = dependency('webrtc-audio-processing', version : '>= 0.2', required : get_option('webrtc-aec'))
 349 if webrtc_dep.found()
 350   cdata.set('HAVE_WEBRTC', 1)
 351 endif
 352
 353 # Some sanity checks
 354
 355 if not speex_dep.found() and not webrtc_dep.found() and not get_option('adrian-aec')
 356   error('At least one echo canceller implementation must be available!')
 357 endif
 358
 359 # Now generate config.h from everything above
 360 configure_file(output : 'config.h', configuration : cdata)
 361
 362 subdir('man')
 363 subdir('src')