meson.build

   1 project('pulseaudio', 'c', 'cpp',
   2         version : run_command(find_program('git-version-gen'), join_paths(meson.current_source_dir(), '.tarball-version')).stdout().strip(),
   3         meson_version : '>= 0.50.0',
   4         default_options : [ 'c_std=gnu11', 'cpp_std=c++11' ]
   5         )
   6
   7 pa_version_str = meson.project_version()
   8 # For tarballs, the first split will do nothing, but for builds in git, we
   9 # split out suffixes when there are commits since the last tag
  10 # (e.g.: v11.99.1-3-gad14bdb24 -> v11.99.1)
  11 version_split = pa_version_str.split('-')[0].split('.')
  12 pa_version_major = version_split[0].split('v')[0]
  13 pa_version_minor = version_split[1]
  14 if version_split.length() > 2
  15   pa_version_micro = version_split[2]
  16 else
  17   pa_version_micro = '0'
  18 endif
  19 pa_version_major_minor = pa_version_major + '.' + pa_version_minor
  20
  21 pa_api_version = 12
  22 pa_protocol_version = 35
  23
  24 # The stable ABI for client applications, for the version info x:y:z
  25 # always will hold x=z
  26 libpulse_version_info = [23, 0, 23]
  27
  28 # A simplified, synchronous, ABI-stable interface for client
  29 # applications, for the version info x:y:z always will hold x=z
  30 libpulse_simple_version_info = [1, 1, 1]
  31
  32 # The ABI-stable GLib adapter for client applications, for the version
  33 # info x:y:z always will hold x=z
  34 libpulse_mainloop_glib_version_info = [0, 6, 0]
  35
  36 libpulse_version = '@0@.@1@.@2@'.format(
  37   libpulse_version_info[0] - libpulse_version_info[2],
  38   libpulse_version_info[0],
  39   libpulse_version_info[1],
  40 )
  41
  42 libpulse_simple_version = '@0@.@1@.@2@'.format(
  43   libpulse_simple_version_info[0] - libpulse_simple_version_info[2],
  44   libpulse_simple_version_info[0],
  45   libpulse_simple_version_info[1],
  46 )
  47
  48 libpulse_mainloop_glib_version = '@0@.@1@.@2@'.format(
  49   libpulse_mainloop_glib_version_info[0] - libpulse_mainloop_glib_version_info[2],
  50   libpulse_mainloop_glib_version_info[0],
  51   libpulse_mainloop_glib_version_info[1],
  52 )
  53
  54 # Paths
  55
  56 prefix = get_option('prefix')
  57 assert(prefix.startswith('/'), 'Prefix is not absolute: "@0@"'.format(prefix))
  58
  59 bindir = join_paths(prefix, get_option('bindir'))
  60 includedir = join_paths(prefix, get_option('includedir'))
  61 libdir = join_paths(prefix, get_option('libdir'))
  62 libexecdir = join_paths(prefix, get_option('libexecdir'))
  63 mandir = join_paths(prefix, get_option('mandir'))
  64 datadir = join_paths(prefix, get_option('datadir'))
  65 localedir = join_paths(prefix, get_option('localedir'))
  66 localstatedir = join_paths(prefix, get_option('localstatedir'))
  67 sysconfdir = join_paths(prefix, get_option('sysconfdir'))
  68 privlibdir = join_paths(libdir, 'pulseaudio')
  69
  70 alsadatadir = get_option('alsadatadir')
  71 if alsadatadir == ''
  72   alsadatadir = join_paths(datadir, 'pulseaudio', 'alsa-mixer')
  73 endif
  74
  75 pkgconfigdir = join_paths(libdir, 'pkgconfig')
  76 pulselibexecdir = join_paths(libexecdir, 'pulse')
  77 pulsesysconfdir = join_paths(sysconfdir, 'pulse')
  78
  79 modlibexecdir = get_option('modlibexecdir')
  80 if modlibexecdir == ''
  81   modlibexecdir = join_paths(libdir, 'pulse-' + pa_version_major_minor, 'modules')
  82 endif
  83
  84 padsplibdir = get_option('padsplibdir')
  85 if padsplibdir == ''
  86   padsplibdir = privlibdir
  87 endif
  88
  89 pulsedsp_location = get_option('pulsedsp-location')
  90 if pulsedsp_location == ''
  91   pulsedsp_location = join_paths(prefix, padsplibdir)
  92 endif
  93
  94 systemduserunitdir = get_option('systemduserunitdir')
  95 # the default value is set below
  96
  97 udevrulesdir = get_option('udevrulesdir')
  98 if udevrulesdir == ''
  99   # absolute path, otherwise meson prepends the prefix
 100   udevrulesdir = '/lib/udev/rules.d'
 101 endif
 102
 103 vapidir = join_paths(datadir, 'vala', 'vapi')
 104
 105 bashcompletiondir = get_option('bashcompletiondir')
 106 if bashcompletiondir == ''
 107   bash_completion_dep = dependency('bash-completion', required : false)
 108   if bash_completion_dep.found()
 109     bashcompletiondir = bash_completion_dep.get_pkgconfig_variable('completionsdir')
 110   else
 111     bashcompletiondir = join_paths(datadir, 'bash-completion', 'completions')
 112   endif
 113 endif
 114
 115 zshcompletiondir = get_option('zshcompletiondir')
 116 if zshcompletiondir == ''
 117   zshcompletiondir = join_paths(datadir, 'zsh', 'site-functions')
 118 endif
 119
 120 # Configuration data
 121
 122 cc = meson.get_compiler('c')
 123
 124 cdata = configuration_data()
 125 cdata.set_quoted('PACKAGE', 'pulseaudio')
 126 cdata.set_quoted('PACKAGE_NAME', 'pulseaudio')
 127 cdata.set_quoted('PACKAGE_VERSION', pa_version_str)
 128 cdata.set_quoted('CANONICAL_HOST', target_machine.cpu_family())
 129 cdata.set('PA_MAJOR', pa_version_major)
 130 cdata.set('PA_MINOR', pa_version_minor)
 131 cdata.set('PA_API_VERSION', pa_api_version)
 132 cdata.set('PA_PROTOCOL_VERSION', pa_protocol_version)
 133 cdata.set_quoted('PA_MACHINE_ID', join_paths(sysconfdir, 'machine-id'))
 134 cdata.set_quoted('PA_MACHINE_ID_FALLBACK', join_paths(localstatedir, 'lib', 'dbus', 'machine-id'))
 135 cdata.set_quoted('PA_SRCDIR', join_paths(meson.current_source_dir(), 'src'))
 136 cdata.set_quoted('PA_BUILDDIR', meson.current_build_dir())
 137 cdata.set_quoted('PA_SOEXT', '.so')
 138 cdata.set_quoted('PA_DEFAULT_CONFIG_DIR', pulsesysconfdir)
 139 cdata.set('PA_DEFAULT_CONFIG_DIR_UNQUOTED', pulsesysconfdir)
 140 cdata.set_quoted('PA_BINARY', join_paths(bindir, 'pulseaudio'))
 141 cdata.set_quoted('PA_SYSTEM_RUNTIME_PATH', join_paths(localstatedir, 'run', 'pulse'))
 142 cdata.set_quoted('PA_SYSTEM_CONFIG_PATH', join_paths(localstatedir, 'lib', 'pulse'))
 143 cdata.set_quoted('PA_SYSTEM_STATE_PATH', join_paths(localstatedir, 'lib', 'pulse'))
 144 cdata.set_quoted('PA_DLSEARCHPATH', modlibexecdir)
 145 cdata.set_quoted('PA_SYSTEM_USER', get_option('system_user'))
 146 cdata.set_quoted('PA_SYSTEM_GROUP', get_option('system_group'))
 147 cdata.set_quoted('PA_ACCESS_GROUP', get_option('access_group'))
 148 cdata.set_quoted('PA_CFLAGS', 'Not yet supported on meson')
 149 cdata.set_quoted('PA_ALSA_PATHS_DIR', join_paths(alsadatadir, 'paths'))
 150 cdata.set_quoted('PA_ALSA_PROFILE_SETS_DIR', join_paths(alsadatadir, 'profile-sets'))
 151 cdata.set_quoted('DESKTOPFILEDIR', join_paths(datadir, 'applications'))
 152 cdata.set_quoted('PULSE_LOCALEDIR', localedir)
 153 cdata.set_quoted('GETTEXT_PACKAGE', 'pulseaudio')
 154 cdata.set('ENABLE_NLS', 1)
 155 cdata.set('top_srcdir', meson.source_root())
 156
 157 # Platform specifics
 158 # First some defaults to keep config file generation happy
 159 cdata.set('HAVE_COREAUDIO', 0)
 160 cdata.set('HAVE_WAVEOUT', 0)
 161
 162 platform_socket_dep = []
 163 platform_dep = []
 164
 165 # FIXME: This was not tested. Maybe some flags should better be CFLAGS,
 166 # rather than ending up in the config.h file?
 167 if host_machine.system() == 'darwin'
 168   cdata.set('OS_IS_DARWIN', 1)
 169   cdata.set('_DARWIN_C_SOURCE', '200112L') # Needed to get NSIG on Mac OS
 170 elif host_machine.system() == 'windows'
 171   cdata.set('OS_IS_WIN32', 1)
 172   cdata.set('HAVE_WINDOWS_H', 1)
 173   cdata.set('HAVE_WAVEOUT', 1)
 174   cdata.set('HAVE_WINSOCK2_H', 1)
 175   cdata.set('HAVE_WS2TCPIP_H', 1)
 176   cdata.set('WIN32_LEAN_AND_MEAN', 1) # Needed to avoid including unnecessary headers on Windows
 177   cdata.set('gid_t', 'int')
 178   cdata.set('uid_t', 'int')
 179   ws2_32_dep = meson.get_compiler('c').find_library('ws2_32')
 180   winsock_dep = meson.get_compiler('c').find_library('wsock32')
 181   ole32_dep = meson.get_compiler('c').find_library('ole32')
 182   ssp_dep = meson.get_compiler('c').find_library('ssp')
 183   pcreposix_dep = meson.get_compiler('c').find_library('pcreposix')
 184   platform_socket_dep = [ws2_32_dep, winsock_dep]
 185   platform_dep = [ole32_dep, ssp_dep, pcreposix_dep]
 186 #elif host_machine.system() == 'solaris'
 187 #  # Apparently meson has no solaris support?
 188 #  # Needed to get declarations for msg_control and msg_controllen on Solaris
 189 #  cdata.set('_XOPEN_SOURCE', 600)
 190 #  cdata.set('__EXTENSIONS__', 1)
 191 endif
 192
 193 if cc.has_type('_Bool')
 194   cdata.set('HAVE_STD_BOOL', 1)
 195 endif
 196
 197 if host_machine.cpu_family() == 'x86_64' or cc.sizeof('void *') >= 8
 198   cdata.set('HAVE_FAST_64BIT_OPERATIONS', 1)
 199 endif
 200
 201 # Headers
 202
 203 check_headers = [
 204   'arpa/inet.h',
 205   'byteswap.h',
 206   'cpuid.h',
 207   'dlfcn.h',
 208   'execinfo.h',
 209   'grp.h',
 210   'langinfo.h',
 211   'linux/sockios.h',
 212   'locale.h',
 213   'netdb.h',
 214   'netinet/in.h',
 215   'netinet/in_systm.h',
 216   'netinet/ip.h',
 217   'netinet/tcp.h',
 218   'pcreposix.h',
 219   'poll.h',
 220   'pwd.h',
 221   'regex.h',
 222   'sched.h',
 223   'stdint.h',
 224   'sys/atomic.h',
 225   'sys/capability.h',
 226   'sys/conf.h',
 227   'sys/dl.h',
 228   'sys/eventfd.h',
 229   'sys/filio.h',
 230   'sys/ioctl.h',
 231   'sys/mman.h',
 232   'sys/prctl.h',
 233   'sys/resource.h',
 234   'sys/select.h',
 235   'sys/socket.h',
 236   'sys/syscall.h',
 237   'sys/uio.h',
 238   'sys/un.h',
 239   'sys/wait.h',
 240   'syslog.h',
 241   'xlocale.h',
 242 ]
 243
 244 foreach h : check_headers
 245   if cc.has_header(h)
 246     define = 'HAVE_' + h.underscorify().to_upper()
 247     cdata.set(define, 1)
 248   endif
 249 endforeach
 250
 251 if cc.has_header('valgrind/memcheck.h', required: get_option('valgrind'))
 252   cdata.set('HAVE_VALGRIND_MEMCHECK_H', 1)
 253 endif
 254
 255 # FIXME: move this to the above set
 256 if host_machine.system() != 'windows'
 257   if cc.has_header('pthread.h')
 258     cdata.set('HAVE_PTHREAD', 1)
 259   endif
 260 endif
 261
 262 if cc.has_header_symbol('pthread.h', 'PTHREAD_PRIO_INHERIT')
 263   cdata.set('HAVE_PTHREAD_PRIO_INHERIT', 1)
 264 endif
 265
 266 # Functions
 267
 268 check_functions = [
 269   'accept4',
 270   'clock_gettime',
 271   'ctime_r',
 272   'fchmod',
 273   'fchown',
 274   'fork',
 275   'fstat',
 276   'getaddrinfo',
 277   'getgrgid_r',
 278   'getgrnam_r',
 279   'getpwnam_r',
 280   'getpwuid_r',
 281   'gettimeofday',
 282   'getuid',
 283   'lrintf',
 284   'lstat',
 285   'memfd_create',
 286   'mkfifo',
 287   'mlock',
 288   'nanosleep',
 289   'open64',
 290   'paccept',
 291   'pipe',
 292   'pipe2',
 293   'posix_fadvise',
 294   'posix_madvise',
 295   'posix_memalign',
 296   'ppoll',
 297   'readlink',
 298   'setegid',
 299   'seteuid',
 300   'setpgid',
 301   'setregid',
 302   'setresgid',
 303   'setresuid',
 304   'setreuid',
 305   'setsid',
 306   'sig2str',
 307   'sigaction',
 308   'strerror_r',
 309   'strtod_l',
 310   'strtof',
 311   'symlink',
 312   'sysconf',
 313   'uname',
 314 ]
 315
 316 foreach f : check_functions
 317   if cc.has_function(f)
 318     define = 'HAVE_' + f.underscorify().to_upper()
 319
 320     if f == 'posix_memalign' and host_machine.system() == 'windows'
 321       message('Win32/mingw32 does not properly define posix_memalign.')
 322     elif f == 'fork' and host_machine.system() == 'windows'
 323       # __builtin_fork is defined and compiles properly, but calling __builtin_fork() does not.
 324       # This causes Meson to think that Windows has a fork() which causes a link error...
 325       message('Win32/mingw32 does not properly define fork.')
 326     else
 327       cdata.set(define, 1)
 328     endif
 329   endif
 330 endforeach
 331
 332 if cc.has_header_symbol('sys/syscall.h', 'SYS_memfd_create')
 333   cdata.set('HAVE_MEMFD', 1)
 334 endif
 335
 336 if cc.has_function('dgettext')
 337   if host_machine.system() != 'windows'
 338     libintl_dep = []
 339   else
 340     libintl_dep = cc.find_library('intl')
 341   endif
 342 else
 343   libintl_dep = cc.find_library('intl')
 344 endif
 345
 346 # Symbols
 347
 348 if cc.has_header_symbol('signal.h', 'SIGXCPU')
 349   cdata.set('HAVE_SIGXCPU', 1)
 350 endif
 351
 352 if not cc.has_header_symbol('netinet/in.h', 'INADDR_NONE')
 353   if not cc.has_header_symbol('winsock2.h', 'INADDR_NONE')
 354     # Define INADDR_NONE if not found (Solaris)
 355     cdata.set('INADDR_NONE', '0xffffffff')
 356   endif
 357 endif
 358
 359 check_decls = [
 360   [ 'environ', 'unistd.h', '#define _GNU_SOURCE' ],
 361   [ 'SOUND_PCM_READ_RATE', 'sys/soundcard.h', '' ],
 362   [ 'SOUND_PCM_READ_CHANNELS', 'sys/soundcard.h', '' ],
 363   [ 'SOUND_PCM_READ_BITS', 'sys/soundcard.h', '' ],
 364 ]
 365
 366 foreach s : check_decls
 367   if cc.has_header_symbol(s[1], s[0], prefix : s[2])
 368     define = 'HAVE_DECL_' + s[0].to_upper()
 369     cdata.set(define, 1)
 370   endif
 371 endforeach
 372
 373 # Types
 374
 375 # FIXME: do we ever care about gid_t not being defined / smaller than an int?
 376 cdata.set('GETGROUPS_T', 'gid_t')
 377
 378 # Include paths
 379
 380 configinc = include_directories('.')
 381 topinc = include_directories('src')
 382
 383 # CFLAGS/LDFLAGS
 384
 385 pa_c_args = ['-DHAVE_CONFIG_H', '-D_GNU_SOURCE']
 386 server_c_args = ['-D__INCLUDED_FROM_PULSE_AUDIO']
 387 cdata.set('MESON_BUILD', 1)
 388
 389 # On ELF systems we don't want the libraries to be unloaded since we don't clean them up properly,
 390 # so we request the nodelete flag to be enabled.
 391 # On other systems, we don't really know how to do that, but it's welcome if somebody can tell.
 392 # Windows doesn't support this flag.
 393 if host_machine.system() != 'windows'
 394   nodelete_link_args = ['-Wl,-z,nodelete']
 395 else
 396   nodelete_link_args = []
 397 endif
 398
 399 # Code coverage
 400
 401 if get_option('gcov')
 402   add_project_arguments('--coverage', language: ['c', 'cpp'])
 403   add_project_link_arguments('--coverage', language: ['c', 'cpp'])
 404 endif
 405
 406 # Core Dependencies
 407
 408 libm_dep = cc.find_library('m', required : true)
 409
 410 thread_dep = dependency('threads')
 411 foreach f : [
 412   'pthread_getname_np',
 413   'pthread_setaffinity_np',
 414   'pthread_setname_np',
 415 ]
 416   if cc.has_function(f, dependencies : thread_dep)
 417     define = 'HAVE_' + f.underscorify().to_upper()
 418     cdata.set(define, 1)
 419   endif
 420 endforeach
 421
 422 cap_dep = cc.find_library('cap', required : false)
 423
 424 shm_dep = cc.find_library('rt', required : false)
 425 if shm_dep.found()
 426   cdata.set('HAVE_SHM_OPEN', 1)
 427 endif
 428
 429 dl_dep = cc.find_library('dl', required : false)
 430 if dl_dep.found()
 431   cdata.set('HAVE_DLADDR', 1)
 432 endif
 433
 434 have_iconv = false
 435 if cc.has_function('iconv_open')
 436   iconv_dep = dependency('', required : false)
 437   have_iconv = true
 438 else
 439   iconv_dep = cc.find_library('iconv', required : false)
 440   have_iconv = iconv_dep.found()
 441 endif
 442 if have_iconv
 443   cdata.set('HAVE_ICONV', 1)
 444   iconvconsttest = '''#include <iconv.h>
 445 size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 446 '''
 447   if cc.compiles(iconvconsttest, dependencies : iconv_dep)
 448     cdata.set('ICONV_CONST', '')
 449   else
 450     cdata.set('ICONV_CONST', 'const')
 451   endif
 452 endif
 453
 454 # Atomic operations
 455
 456 if get_option('atomic-arm-memory-barrier')
 457     cdata.set('ATOMIC_ARM_MEMORY_BARRIER_ENABLED', 1)
 458 endif
 459
 460 need_libatomic_ops = false
 461
 462 atomictest = '''void func() {
 463   volatile int atomic = 2;
 464   __sync_bool_compare_and_swap (&atomic, 2, 3);
 465 }
 466 '''
 467
 468 if cc.compiles(atomictest)
 469   cdata.set('HAVE_ATOMIC_BUILTINS', 1)
 470
 471   newatomictest = '''void func() {
 472     int c = 0;
 473     __atomic_store_n(&c, 4, __ATOMIC_SEQ_CST);
 474   }
 475   '''
 476
 477   if(cc.compiles(newatomictest))
 478     cdata.set('HAVE_ATOMIC_BUILTINS_MEMORY_MODEL', 1)
 479   endif
 480
 481 elif host_machine.cpu_family() == 'arm'
 482   if host_machine.system() == 'linux' and get_option('atomic-arm-linux-helpers')
 483     cdata.set('ATOMIC_ARM_LINUX_HELPERS', 1)
 484   else
 485     armatomictest = '''int func() {
 486       volatile int a=0;
 487       int o=0, n=1, r;
 488       asm volatile (
 489               "ldrex    %0, [%1]\n"
 490               "subs  %0, %0, %2\n"
 491               "strexeq %0, %3, [%1]\n"
 492               : "=&r" (r)
 493               : "r" (&a), "Ir" (o), "r" (n)
 494       : "cc");
 495       return (a==1 ? 0 : -1);
 496     }
 497     '''
 498
 499     if cc.compiles(armatomictest)
 500       cdata.set('ATOMIC_ARM_INLINE_ASM', 1)
 501     else
 502       need_libatomic_ops = true
 503     endif
 504   endif # arm && !linux
 505
 506 elif not ['freebsd', 'netbsd'].contains(host_machine.system())
 507   need_libatomic_ops = true
 508 endif # !atomic helpers && !arm
 509
 510 if need_libatomic_ops
 511   assert(cc.has_header('atomic_ops.h'), 'Need libatomic_ops')
 512
 513   cdata.set('AO_REQUIRE_CAS', 1)
 514
 515   if host_machine.system() != 'windows'
 516     libatomic_ops_dep = cc.find_library('atomic_ops', required : true)
 517   else
 518     libatomic_ops_dep = dependency('', required: false)
 519   endif
 520 else
 521   libatomic_ops_dep = dependency('', required: false)
 522 endif
 523
 524 # ARM checks
 525 # ARMV6 instructions we need
 526 if host_machine.cpu_family() == 'arm'
 527   armv6test = '''int func() {
 528     volatile int a = -60000, b = 0xaaaabbbb, c = 0xccccdddd;
 529     asm volatile ("ldr r0, %2 \n"
 530                   "ldr r2, %3 \n"
 531                   "ldr r3, %4 \n"
 532                   "ssat r1, #8, r0 \n"
 533                   "str r1, %0 \n"
 534                   "pkhbt r1, r3, r2, LSL #8 \n"
 535                   "str r1, %1 \n"
 536                   : "=m" (a), "=m" (b)
 537                   : "m" (a), "m" (b), "m" (c)
 538                   : "r0", "r1", "r2", "r3", "cc");
 539     return (a == -128 && b == 0xaabbdddd) ? 0 : -1;
 540   }
 541   '''
 542
 543   if cc.compiles(armv6test)
 544     cdata.set('HAVE_ARMV6', 1)
 545   endif
 546 endif
 547 # NEON checks are automatically done by the unstable-simd module
 548
 549 # FIXME: make sure it's >= 2.2
 550 ltdl_dep = cc.find_library('ltdl', required : true)
 551 # FIXME: can meson support libtool -dlopen/-dlpreopen things?
 552 #        and do we still want to support this at all?
 553 cdata.set('DISABLE_LIBTOOL_PRELOAD', 1)
 554
 555 if get_option('database') == 'tdb'
 556   database_dep = dependency('tdb')
 557 elif get_option('database') == 'gdbm'
 558   database_dep = cc.find_library('gdbm', required : true)
 559 else
 560   database_dep = dependency('', required: false)
 561 endif
 562
 563 if get_option('ipv6')
 564   cdata.set('HAVE_IPV6', 1)
 565 endif
 566
 567 if get_option('legacy-database-entry-format')
 568   cdata.set('ENABLE_LEGACY_DATABASE_ENTRY_FORMAT', 1)
 569 endif
 570
 571 if get_option('stream-restore-clear-old-devices')
 572   cdata.set('STREAM_RESTORE_CLEAR_OLD_DEVICES', 1)
 573 endif
 574
 575 if get_option('running-from-build-tree')
 576   cdata.set('HAVE_RUNNING_FROM_BUILD_TREE', 1)
 577 endif
 578
 579 alsa_dep = dependency('alsa', version : '>= 1.0.24', required : get_option('alsa'))
 580 if alsa_dep.found()
 581   cdata.set('HAVE_ALSA', 1)
 582   cdata.set('HAVE_ALSA_UCM', 1)
 583 endif
 584
 585 asyncns_dep = dependency('libasyncns', version : '>= 0.1', required : get_option('asyncns'))
 586 if asyncns_dep.found()
 587   cdata.set('HAVE_LIBASYNCNS', 1)
 588 endif
 589
 590 dbus_dep = dependency('dbus-1', version : '>= 1.4.12', required : get_option('dbus'))
 591 if dbus_dep.found()
 592   cdata.set('HAVE_DBUS', 1)
 593 endif
 594
 595 gio_dep = dependency('gio-2.0', version : '>= 2.26.0', required : get_option('gsettings'))
 596 if gio_dep.found()
 597   cdata.set('HAVE_GSETTINGS', 1)
 598 endif
 599
 600 glib_dep = dependency('glib-2.0', version : '>= 2.28.0', required: get_option('glib'))
 601 if glib_dep.found()
 602   cdata.set('HAVE_GLIB', 1)
 603 endif
 604
 605 gtk_dep = dependency('gtk+-3.0', required : get_option('gtk'))
 606 if gtk_dep.found()
 607   cdata.set('HAVE_GTK', 1)
 608 endif
 609
 610 have_orcc = false
 611 orcc_args = []
 612 orc_dep = dependency('orc-0.4', version : '>= 0.4.11', required : get_option('orc'))
 613 orcc = find_program('orcc', required : get_option('orc'))
 614 if orc_dep.found() and orcc.found()
 615   have_orcc = true
 616   orcc_args = [orcc]
 617   #orcc_args = [orcc, '--include', 'glib.h']
 618   cdata.set('HAVE_ORC', 1)
 619 else
 620   cdata.set('DISABLE_ORC', 1)
 621 endif
 622
 623 samplerate_dep = dependency('samplerate', version : '>= 0.1.0', required : get_option('samplerate'))
 624 if samplerate_dep.found()
 625   cdata.set('HAVE_LIBSAMPLERATE', 1)
 626 endif
 627
 628 sndfile_dep = dependency('sndfile', version : '>= 1.0.20')
 629
 630 soxr_dep = dependency('soxr', version : '>= 0.1.1', required : get_option('soxr'))
 631 if soxr_dep.found()
 632   cdata.set('HAVE_SOXR', 1)
 633 endif
 634
 635 libsystemd_dep = dependency('libsystemd', required : get_option('systemd'))
 636 if libsystemd_dep.found()
 637   cdata.set('HAVE_SYSTEMD_DAEMON', 1)
 638   cdata.set('HAVE_SYSTEMD_LOGIN', 1)
 639   cdata.set('HAVE_SYSTEMD_JOURNAL', 1)
 640 endif
 641 systemd_dep = dependency('systemd', required : get_option('systemd'))
 642 if systemd_dep.found() and systemduserunitdir == ''
 643   systemduserunitdir = systemd_dep.get_pkgconfig_variable('systemduserunitdir')
 644 endif
 645
 646 x11_dep = dependency('x11-xcb', required : get_option('x11'))
 647 if x11_dep.found()
 648   xcb_dep  = dependency('xcb',  required : true, version : '>= 1.6')
 649   ice_dep  = dependency('ice',  required : true)
 650   sm_dep   = dependency('sm',   required : true)
 651   xtst_dep = dependency('xtst', required : true)
 652   cdata.set('HAVE_X11', 1)
 653   if cc.has_function('XSetIOErrorExitHandler', dependencies: x11_dep)
 654     cdata.set('HAVE_XSETIOERROREXITHANDLER', 1)
 655   endif
 656 endif
 657
 658 # Module dependencies
 659 if cc.has_header('sys/soundcard.h', required: get_option('oss-output'))
 660   cdata.set('HAVE_OSS_OUTPUT', 1)
 661   cdata.set('HAVE_OSS_WRAPPER', 1)
 662   cdata.set('PULSEDSP_LOCATION', pulsedsp_location)
 663 endif
 664
 665 if get_option('hal-compat')
 666   cdata.set('HAVE_HAL_COMPAT', 1)
 667 endif
 668
 669 avahi_dep = dependency('avahi-client', version : '>= 0.6.0', required : get_option('avahi'), disabler : true)
 670 if avahi_dep.found()
 671   cdata.set('HAVE_AVAHI', 1)
 672 endif
 673
 674 sbc_dep = dependency('sbc', version : '>= 1.0', required : false)
 675 if get_option('bluez5')
 676   assert(dbus_dep.found(), 'BlueZ requires D-Bus support')
 677   assert(sbc_dep.found(), 'BlueZ requires SBC support')
 678   cdata.set('HAVE_SBC', 1)
 679   cdata.set('HAVE_BLUEZ', 1)
 680   cdata.set('HAVE_BLUEZ_5', 1)
 681   if get_option('bluez5-native-headset')
 682     cdata.set('HAVE_BLUEZ_5_NATIVE_HEADSET', 1)
 683   endif
 684   if get_option('bluez5-ofono-headset')
 685     cdata.set('HAVE_BLUEZ_5_OFONO_HEADSET', 1)
 686   endif
 687 endif
 688
 689 fftw_dep = dependency('fftw3f', required : get_option('fftw'))
 690 if fftw_dep.found()
 691   cdata.set('HAVE_FFTW', 1)
 692 endif
 693
 694 jack_dep = dependency('jack', version : '>= 0.117.0', required : get_option('jack'))
 695 if jack_dep.found()
 696   cdata.set('HAVE_JACK', 1)
 697 endif
 698
 699 lirc_dep = dependency('lirc', required : get_option('lirc'))
 700 if lirc_dep.found()
 701   cdata.set('HAVE_LIRC', 1)
 702 endif
 703
 704 openssl_dep = dependency('openssl', version : '>= 0.9', required : get_option('openssl'))
 705 if openssl_dep.found()
 706   cdata.set('HAVE_OPENSSL', 1)
 707 endif
 708
 709 speex_dep = dependency('speexdsp', version : '>= 1.2', required : get_option('speex'))
 710 if speex_dep.found()
 711   cdata.set('HAVE_SPEEX', 1)
 712 endif
 713
 714 udev_dep = dependency('libudev', version : '>= 143', required : get_option('udev'))
 715 if udev_dep.found()
 716   cdata.set('HAVE_UDEV', 1)
 717 endif
 718
 719 webrtc_dep = dependency('webrtc-audio-processing', version : '>= 0.2', required : get_option('webrtc-aec'))
 720 if webrtc_dep.found()
 721   cdata.set('HAVE_WEBRTC', 1)
 722 endif
 723
 724 gst_dep = dependency('gstreamer-1.0', version : '>= 1.14', required : get_option('gstreamer'))
 725 gstapp_dep = dependency('gstreamer-app-1.0', required : get_option('gstreamer'))
 726 gstrtp_dep = dependency('gstreamer-rtp-1.0', required : get_option('gstreamer'))
 727
 728 have_gstreamer = false
 729 if gst_dep.found() and gstapp_dep.found() and gstrtp_dep.found()
 730   have_gstreamer = true
 731 endif
 732
 733 # These are required for the CMake file generation
 734 cdata.set('PA_LIBDIR', libdir)
 735 cdata.set('PA_INCDIR', includedir)
 736 if glib_dep.found()
 737   cdata.set('HAVE_GLIB20', 1) # to match the AM_CONDITIONAL for CMake file generation
 738 endif
 739
 740 # Test dependencies
 741
 742 check_dep = dependency('check', version : '>= 0.9.10', required : get_option('tests'))
 743
 744 # Subdirs
 745
 746 subdir('doxygen')
 747 subdir('po')
 748 if get_option('man')
 749   subdir('man')
 750 endif
 751 subdir('shell-completion/bash')
 752 subdir('shell-completion/zsh')
 753 subdir('src')
 754 subdir('vala')
 755
 756 # Now generate config.h from everything above
 757 configure_file(output : 'config.h', configuration : cdata)
 758
 759 # pkg-config files
 760
 761 pc_cdata = configuration_data()
 762
 763 pc_cdata.set('prefix', prefix)
 764 pc_cdata.set('exec_prefix', prefix)
 765 pc_cdata.set('libdir', libdir)
 766 pc_cdata.set('includedir', includedir)
 767 pc_cdata.set('modlibexecdir', modlibexecdir)
 768 pc_cdata.set('PACKAGE_VERSION', pa_version_str)
 769 pc_cdata.set('PA_MAJORMINOR', pa_version_major_minor)
 770 # FIXME: the line below is wrong. Currently the meson thread dep lacks documentation,
 771 # and doesn't allow introspection, ie. none of get_pkgconfig_variable() or
 772 # get_configtool_variable() work with it, so we have no way to get this flag right,
 773 # unless we do all the work ourselves. See current work in glib, also meson #553.
 774 pc_cdata.set('PTHREAD_LIBS', '-pthread')
 775
 776 pc_files = [
 777   'libpulse.pc',
 778   'libpulse-simple.pc',
 779 ]
 780
 781 if glib_dep.found()
 782   pc_files += 'libpulse-mainloop-glib.pc'
 783 endif
 784
 785 foreach file : pc_files
 786   configure_file(
 787     input : file + '.in',
 788     output : file,
 789     configuration : pc_cdata,
 790     install_dir : pkgconfigdir)
 791 endforeach
 792
 793 # CMake files
 794
 795 m4 = find_program('m4', required: true)
 796
 797 cmakedir = join_paths(libdir, 'cmake', 'PulseAudio')
 798
 799 cmake_template_file = configure_file(
 800   input : 'PulseAudioConfig.cmake.in',
 801   output : 'PulseAudioConfig.cmake.tmp',
 802   configuration: cdata,
 803 )
 804
 805 custom_target('PulseAudioConfig.cmake',
 806   input : cmake_template_file,
 807   output : 'PulseAudioConfig.cmake',
 808   capture : true,
 809   command : [m4, '@INPUT@'],
 810   build_by_default : true,
 811   install : true,
 812   install_dir : cmakedir,
 813 )
 814
 815 configure_file(
 816   input : 'PulseAudioConfigVersion.cmake.in',
 817   output : 'PulseAudioConfigVersion.cmake',
 818   configuration: cdata,
 819   install : true,
 820   install_dir : cmakedir,
 821 )
 822
 823 ############################################################
 824
 825 # Final summary
 826
 827 summary = [
 828   '',
 829   '---{ @0@ @1@ }---'.format(meson.project_name(), meson.project_version()),
 830   '',
 831   'prefix:                        @0@'.format(prefix),
 832   'bindir:                        @0@'.format(bindir),
 833   'libdir:                        @0@'.format(libdir),
 834   'libexecdir:                    @0@'.format(libexecdir),
 835   'mandir:                        @0@'.format(mandir),
 836   'datadir:                       @0@'.format(datadir),
 837   'sysconfdir:                    @0@'.format(sysconfdir),
 838   'localstatedir:                 @0@'.format(localstatedir),
 839   'modlibexecdir:                 @0@'.format(modlibexecdir),
 840   'alsadatadir:                   @0@'.format(alsadatadir),
 841   'System Runtime Path:           @0@'.format(cdata.get_unquoted('PA_SYSTEM_RUNTIME_PATH')),
 842   'System State Path:             @0@'.format(cdata.get_unquoted('PA_SYSTEM_STATE_PATH')),
 843   'System Config Path:            @0@'.format(cdata.get_unquoted('PA_SYSTEM_CONFIG_PATH')),
 844   'Bash completions directory:    @0@'.format(bashcompletiondir),
 845   'Zsh completions directory:     @0@'.format(zshcompletiondir),
 846   'Compiler:                      @0@ @1@'.format(cc.get_id(), cc.version()),
 847 #  'CFLAGS:                        @0@'.format(${CFLAGS}),
 848 #  'CPPFLAGS:                      @0@'.format(${CPPFLAGS}),
 849 #  'LIBS:                          @0@'.format(${LIBS}),
 850   '',
 851   'Enable memfd shared memory:    @0@'.format(cdata.has('HAVE_MEMFD')),
 852   'Enable X11:                    @0@'.format(x11_dep.found()),
 853   '  Safe X11 I/O errors:         @0@'.format(cdata.has('HAVE_XSETIOERROREXITHANDLER')),
 854   'Enable OSS Output:             @0@'.format(cdata.has('HAVE_OSS_OUTPUT')),
 855   'Enable OSS Wrapper:            @0@'.format(cdata.has('HAVE_OSS_WRAPPER')),
 856 #  'Enable EsounD:                 @0@'.format(${ENABLE_ESOUND}),
 857   'Enable Alsa:                   @0@'.format(alsa_dep.found()),
 858 #  'Enable CoreAudio:              @0@'.format(${ENABLE_COREAUDIO}),
 859 #  'Enable Solaris:                @0@'.format(${ENABLE_SOLARIS}),
 860 #  'Enable WaveOut:                @0@'.format(${ENABLE_WAVEOUT}),
 861   'Enable GLib 2:                 @0@'.format(glib_dep.found()),
 862 #  'Enable GConf:                  @0@'.format(${ENABLE_GCONF}),
 863   'Enable GSettings:              @0@'.format(gio_dep.found()),
 864   'Enable Gtk+ 3:                 @0@'.format(gtk_dep.found()),
 865   'Enable Avahi:                  @0@'.format(avahi_dep.found()),
 866   'Enable Jack:                   @0@'.format(jack_dep.found()),
 867   'Enable Async DNS:              @0@'.format(asyncns_dep.found()),
 868   'Enable LIRC:                   @0@'.format(lirc_dep.found()),
 869   'Enable D-Bus:                  @0@'.format(dbus_dep.found()),
 870   '  Enable BlueZ 5:              @0@'.format(get_option('bluez5')),
 871   '    Enable native headsets:    @0@'.format(get_option('bluez5-native-headset')),
 872   '    Enable  ofono headsets:    @0@'.format(get_option('bluez5-ofono-headset')),
 873   'Enable udev:                   @0@'.format(udev_dep.found()),
 874   '  Enable HAL->udev compat:     @0@'.format(get_option('hal-compat')),
 875   'Enable systemd:                @0@'.format(libsystemd_dep.found()),
 876 #  'Enable TCP Wrappers:           @0@'.format(${ENABLE_TCPWRAP}),
 877   'Enable libsamplerate:          @0@'.format(samplerate_dep.found()),
 878   'Enable IPv6:                   @0@'.format(get_option('ipv6')),
 879   'Enable OpenSSL (for Airtunes): @0@'.format(openssl_dep.found()),
 880   'Enable FFTW:                   @0@'.format(fftw_dep.found()),
 881   'Enable ORC:                    @0@'.format(have_orcc),
 882   'Enable GStreamer:              @0@'.format(have_gstreamer),
 883   'Enable Adrian echo canceller:  @0@'.format(get_option('adrian-aec')),
 884   'Enable Speex (resampler, AEC): @0@'.format(speex_dep.found()),
 885   'Enable SoXR (resampler):       @0@'.format(soxr_dep.found()),
 886   'Enable WebRTC echo canceller:  @0@'.format(webrtc_dep.found()),
 887   'Enable Gcov coverage:          @0@'.format(get_option('gcov')),
 888   'Enable Valgrind:               @0@'.format(cdata.has('HAVE_VALGRIND_MEMCHECK_H')),
 889   'Enable man pages:              @0@'.format(get_option('man')),
 890   'Enable unit tests:             @0@'.format(get_option('tests')),
 891   '',
 892   'Database:                      @0@'.format(get_option('database')),
 893   'Legacy Database Entry Support: @0@'.format(get_option('legacy-database-entry-format')),
 894   'module-stream-restore:',
 895   '  Clear old devices:           @0@'.format(get_option('stream-restore-clear-old-devices')),
 896   'Running from build tree:       @0@'.format(get_option('running-from-build-tree')),
 897   'System User:                   @0@'.format(cdata.get_unquoted('PA_SYSTEM_USER')),
 898   'System Group:                  @0@'.format(cdata.get_unquoted('PA_SYSTEM_GROUP')),
 899   'Access Group:                  @0@'.format(cdata.get_unquoted('PA_ACCESS_GROUP')),
 900 #  'Enable per-user EsounD socket: @0@'.format(${ENABLE_PER_USER_ESOUND_SOCKET}),
 901 #  'Force preopen:                 @0@'.format(${FORCE_PREOPEN}),
 902 #  'Preopened modules:             @0@'.format(${PREOPEN_MODS}),
 903 ]
 904
 905 message('\n    '.join(summary))
 906
 907 # Sanity checks
 908
 909 if not speex_dep.found() and not webrtc_dep.found() and not get_option('adrian-aec')
 910   error('At least one echo canceller implementation must be available!')
 911 endif
 912
 913 if samplerate_dep.found()
 914   warning('Support for libsamplerate is DEPRECATED')
 915 endif
 916
 917 if host_machine.system() != 'windows'
 918   if not dbus_dep.found()
 919     message = [
 920       'You do not have D-Bus support enabled. It is strongly recommended',
 921       'that you enable D-Bus support if your platform supports it.',
 922       'Many parts of PulseAudio use D-Bus, from ConsoleKit interaction',
 923       'to the Device Reservation Protocol to speak to JACK, Bluetooth',
 924       'support and even a native control protocol for communicating and',
 925       'controlling the PulseAudio daemon itself.',
 926     ]
 927     warning('\n' + '\n'.join(message))
 928   endif
 929   if not udev_dep.found()
 930     message = [
 931       'You do not have udev support enabled. It is strongly recommended',
 932       'that you enable udev support if your platform supports it as it is',
 933       'the primary method used to detect hardware audio devices (on Linux)',
 934       'and is thus a critical part of PulseAudio on that platform.',
 935     ]
 936     warning('\n' + '\n'.join(message))
 937   endif
 938   if not speex_dep.found()
 939     message = [
 940       'You do not have speex support enabled. It is strongly recommended',
 941       'that you enable speex support if your platform supports it as it is',
 942       'the primary method used for audio resampling and is thus a critical',
 943       'part of PulseAudio on that platform.',
 944     ]
 945     warning('\n' + '\n'.join(message))
 946   endif
 947 endif