meson.build

   1 project('gst-editing-services', 'c',
   2   version : '1.13.0.1',
   3   meson_version : '>= 0.36.0',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0]
  10 gst_version_minor = version_arr[1]
  11 gst_version_micro = version_arr[2]
  12 if version_arr.length() == 4
  13   gst_version_nano = version_arr[3]
  14 else
  15   gst_version_nano = 0
  16 endif
  17
  18 apiversion = '1.0'
  19 soversion = 0
  20 # maintaining compatibility with the previous libtool versioning
  21 # current = minor * 100 + micro
  22 libversion = '@0@.@1@.0'.format(soversion, gst_version_minor.to_int() * 100 + gst_version_micro.to_int())
  23
  24 glib_req = '>= 2.40.0'
  25 gst_req = '>= @0@.@1@.0'.format(gst_version_major, gst_version_minor)
  26
  27 cc = meson.get_compiler('c')
  28 # Ignore several spurious warnings for things gstreamer does very commonly
  29 # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  30 # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  31 # NOTE: Only add warnings here if you are sure they're spurious
  32 if cc.get_id() == 'msvc'
  33   add_project_arguments(
  34       '/wd4018', # implicit signed/unsigned conversion
  35       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  36       '/wd4244', # lossy type conversion (e.g. double -> int)
  37       '/wd4305', # truncating type conversion (e.g. double -> float)
  38       language : 'c')
  39 endif
  40
  41 cdata = configuration_data()
  42 cdata.set('VERSION', '"@0@"'.format(gst_version))
  43 cdata.set('PACKAGE', '"gst-editing-services"')
  44 cdata.set('PACKAGE_VERSION', '"@0@"'.format(gst_version))
  45 cdata.set('PACKAGE_BUGREPORT', '"http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer"')
  46 cdata.set('PACKAGE_NAME', '"GStreamer Editing Services"')
  47 cdata.set('GST_PACKAGE_NAME', '"GStreamer Editing Services"')
  48 cdata.set('GST_PACKAGE_ORIGIN', '"Unknown package origin"')
  49 cdata.set('GST_LICENSE', '"LGPL"')
  50
  51 # Mandatory GST deps
  52 gst_dep = dependency('gstreamer-' + apiversion, version : gst_req,
  53     fallback : ['gstreamer', 'gst_dep'])
  54 gstpbutils_dep = dependency('gstreamer-pbutils-' + apiversion, version : gst_req,
  55     fallback : ['gst-plugins-base', 'pbutils_dep'])
  56 gstvideo_dep = dependency('gstreamer-video-' + apiversion, version : gst_req,
  57     fallback : ['gst-plugins-base', 'video_dep'])
  58 gstbase_dep = dependency('gstreamer-base-1.0', version : gst_req,
  59     fallback : ['gstreamer', 'gst_base_dep'])
  60 if host_machine.system() != 'windows'
  61   gstcheck_dep = dependency('gstreamer-check-1.0', version : gst_req,
  62     fallback : ['gstreamer', 'gst_check_dep'], required: false)
  63 endif
  64 gstcontroller_dep = dependency('gstreamer-controller-1.0', version : gst_req,
  65   fallback : ['gstreamer', 'gst_controller_dep'])
  66 gstvalidate_dep = dependency('gst-validate-1.0', version : gst_req, required : false,
  67   fallback : ['gst-devtools', 'validate_dep'])
  68
  69 gio_dep = dependency('gio-2.0', fallback: ['glib', 'libgio_dep'])
  70 libxml_dep = dependency('libxml-2.0')
  71
  72 # TODO Properly port to Gtk 3
  73 # gtk_dep = dependency('gtk+-3.0', required : false)
  74
  75 libges_deps = [gst_dep, gstbase_dep, gstvideo_dep, gstpbutils_dep,
  76                gstcontroller_dep, gio_dep, libxml_dep]
  77
  78 if gstvalidate_dep.found()
  79     libges_deps = libges_deps + [gstvalidate_dep]
  80     cdata.set('HAVE_GST_VALIDATE', 1)
  81 endif
  82
  83 configure_file(output : 'config.h', configuration : cdata)
  84
  85
  86 gir = find_program('g-ir-scanner', required : false)
  87 gnome = import('gnome')
  88
  89 # Fixme, not very elegant.
  90 build_gir = gir.found() and not meson.is_cross_build() and not get_option('disable_introspection')
  91 gir_init_section = [ '--add-init-section=' + \
  92     'extern void gst_init(gint*,gchar**);' + \
  93     'extern void ges_init(void);' + \
  94     'g_setenv("GST_REGISTRY_1.0", "/no/way/this/exists.reg", TRUE);' + \
  95     'g_setenv("GST_PLUGIN_PATH_1_0", "", TRUE);' + \
  96     'g_setenv("GST_PLUGIN_SYSTEM_PATH_1_0", "", TRUE);' + \
  97     'g_setenv("GST_DEBUG", "0", TRUE);' + \
  98     'gst_init(NULL,NULL);' + \
  99     'ges_init();' ]
 100
 101 ges_c_args = ['-DHAVE_CONFIG_H']
 102 plugins_install_dir = '@0@/gstreamer-1.0'.format(get_option('libdir'))
 103
 104 vs_module_defs_dir = meson.current_source_dir() + '/win32/common/'
 105
 106 if gst_dep.type_name() == 'internal'
 107     gst_proj = subproject('gstreamer')
 108
 109     if gst_proj.get_variable('disable_gst_debug')
 110         message('GStreamer debug system is disabled')
 111         add_project_arguments('-Wno-unused', language: 'c')
 112     else
 113         message('GStreamer debug system is enabled')
 114     endif
 115 else
 116     # We can't check that in the case of subprojects as we won't
 117     # be able to build against an internal dependency (which is not built yet)
 118     if not cc.compiles('''
 119 #include <gst/gstconfig.h>
 120 #ifdef GST_DISABLE_GST_DEBUG
 121 #error "debugging disabled, make compiler fail"
 122 #endif''' , dependencies: gst_dep)
 123         message('GStreamer debug system is disabled')
 124         add_global_arguments('-Wno-unused', language: 'c')
 125     else
 126         message('GStreamer debug system is enabled')
 127     endif
 128 endif
 129
 130 configinc = include_directories('.')
 131 subdir('ges')
 132 subdir('plugins')
 133 subdir('tools')
 134 subdir('pkgconfig')
 135 subdir('tests')
 136 subdir('examples')
 137
 138 if build_machine.system() == 'windows'
 139   message('Disabling gtk-doc while building on Windows')
 140 elif get_option('disable_gtkdoc')
 141   message('gtk-doc is disabled via options')
 142 else
 143   if find_program('gtkdoc-scan', required : false).found()
 144     subdir('docs')
 145   else
 146     message('Not building documentation as gtk-doc was not found')
 147   endif
 148 endif
 149
 150 python3 = find_program('python3')
 151 run_command(python3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')