meson.build

   1 project('pulseaudio', 'c', 'cpp',
   2         version : run_command(find_program('git-version-gen'), join_paths(meson.current_source_dir(), '.tarball-version')).stdout().strip(),
   3         meson_version : '>= 0.50.0',
   4         default_options : [ 'c_std=gnu11', 'cpp_std=c++11' ]
   5         )
   6
   7 meson.add_dist_script('scripts/save-tarball-version.sh', meson.project_version())
   8
   9 pa_version_str = meson.project_version()
  10 # For tarballs, the first split will do nothing, but for builds in git, we
  11 # split out suffixes when there are commits since the last tag
  12 # (e.g.: v11.99.1-3-gad14bdb24 -> v11.99.1)
  13 version_split = pa_version_str.split('-')[0].split('.')
  14 pa_version_major = version_split[0].split('v')[0]
  15 pa_version_minor = version_split[1]
  16 if version_split.length() > 2
  17   pa_version_micro = version_split[2]
  18 else
  19   pa_version_micro = '0'
  20 endif
  21 pa_version_major_minor = pa_version_major + '.' + pa_version_minor
  22
  23 pa_api_version = 12
  24 pa_protocol_version = 35
  25
  26 # The stable ABI for client applications, for the version info x:y:z
  27 # always will hold x=z
  28 libpulse_version_info = [23, 0, 23]
  29
  30 # A simplified, synchronous, ABI-stable interface for client
  31 # applications, for the version info x:y:z always will hold x=z
  32 libpulse_simple_version_info = [1, 1, 1]
  33
  34 # The ABI-stable GLib adapter for client applications, for the version
  35 # info x:y:z always will hold x=z
  36 libpulse_mainloop_glib_version_info = [0, 6, 0]
  37
  38 libpulse_version = '@0@.@1@.@2@'.format(
  39   libpulse_version_info[0] - libpulse_version_info[2],
  40   libpulse_version_info[0],
  41   libpulse_version_info[1],
  42 )
  43
  44 libpulse_simple_version = '@0@.@1@.@2@'.format(
  45   libpulse_simple_version_info[0] - libpulse_simple_version_info[2],
  46   libpulse_simple_version_info[0],
  47   libpulse_simple_version_info[1],
  48 )
  49
  50 libpulse_mainloop_glib_version = '@0@.@1@.@2@'.format(
  51   libpulse_mainloop_glib_version_info[0] - libpulse_mainloop_glib_version_info[2],
  52   libpulse_mainloop_glib_version_info[0],
  53   libpulse_mainloop_glib_version_info[1],
  54 )
  55
  56 # Paths
  57
  58 prefix = get_option('prefix')
  59 assert(prefix.startswith('/'), 'Prefix is not absolute: "@0@"'.format(prefix))
  60
  61 bindir = join_paths(prefix, get_option('bindir'))
  62 includedir = join_paths(prefix, get_option('includedir'))
  63 libdir = join_paths(prefix, get_option('libdir'))
  64 libexecdir = join_paths(prefix, get_option('libexecdir'))
  65 mandir = join_paths(prefix, get_option('mandir'))
  66 datadir = join_paths(prefix, get_option('datadir'))
  67 localedir = join_paths(prefix, get_option('localedir'))
  68 localstatedir = join_paths(prefix, get_option('localstatedir'))
  69 sysconfdir = join_paths(prefix, get_option('sysconfdir'))
  70 privlibdir = join_paths(libdir, 'pulseaudio')
  71
  72 if host_machine.system() == 'windows'
  73   # Windows only supports loading libraries from the same dir as the executable
  74   privlibdir = bindir
  75 endif
  76
  77 alsadatadir = get_option('alsadatadir')
  78 if alsadatadir == ''
  79   alsadatadir = join_paths(datadir, 'pulseaudio', 'alsa-mixer')
  80 endif
  81
  82 pkgconfigdir = join_paths(libdir, 'pkgconfig')
  83 pulselibexecdir = join_paths(libexecdir, 'pulse')
  84 pulsesysconfdir = join_paths(sysconfdir, 'pulse')
  85
  86 modlibexecdir = get_option('modlibexecdir')
  87 if modlibexecdir == ''
  88   modlibexecdir = join_paths(libdir, 'pulse-' + pa_version_major_minor, 'modules')
  89 endif
  90
  91 padsplibdir = get_option('padsplibdir')
  92 if padsplibdir == ''
  93   padsplibdir = privlibdir
  94 endif
  95
  96 pulsedsp_location = get_option('pulsedsp-location')
  97 if pulsedsp_location == ''
  98   pulsedsp_location = join_paths(prefix, padsplibdir)
  99 endif
 100
 101 systemduserunitdir = get_option('systemduserunitdir')
 102 # the default value is set below
 103
 104 udevrulesdir = get_option('udevrulesdir')
 105 if udevrulesdir == ''
 106   # absolute path, otherwise meson prepends the prefix
 107   udevrulesdir = '/lib/udev/rules.d'
 108 endif
 109
 110 vapidir = join_paths(datadir, 'vala', 'vapi')
 111
 112 bashcompletiondir = get_option('bashcompletiondir')
 113 if bashcompletiondir == ''
 114   bash_completion_dep = dependency('bash-completion', required : false)
 115   if bash_completion_dep.found()
 116     bashcompletiondir = bash_completion_dep.get_pkgconfig_variable('completionsdir')
 117   else
 118     bashcompletiondir = join_paths(datadir, 'bash-completion', 'completions')
 119   endif
 120 endif
 121
 122 zshcompletiondir = get_option('zshcompletiondir')
 123 if zshcompletiondir == ''
 124   zshcompletiondir = join_paths(datadir, 'zsh', 'site-functions')
 125 endif
 126
 127 # Configuration data
 128
 129 cc = meson.get_compiler('c')
 130
 131 cdata = configuration_data()
 132 cdata.set_quoted('PACKAGE', 'pulseaudio')
 133 cdata.set_quoted('PACKAGE_NAME', 'pulseaudio')
 134 cdata.set_quoted('PACKAGE_VERSION', pa_version_str)
 135 cdata.set('PA_MAJOR', pa_version_major)
 136 cdata.set('PA_MINOR', pa_version_minor)
 137 cdata.set('PA_API_VERSION', pa_api_version)
 138 cdata.set('PA_PROTOCOL_VERSION', pa_protocol_version)
 139 cdata.set_quoted('PA_MACHINE_ID', join_paths(sysconfdir, 'machine-id'))
 140 cdata.set_quoted('PA_MACHINE_ID_FALLBACK', join_paths(localstatedir, 'lib', 'dbus', 'machine-id'))
 141 cdata.set_quoted('PA_SRCDIR', join_paths(meson.current_source_dir(), 'src'))
 142 cdata.set_quoted('PA_BUILDDIR', meson.current_build_dir())
 143 cdata.set_quoted('PA_SOEXT', '.so')
 144 cdata.set_quoted('PA_DEFAULT_CONFIG_DIR', pulsesysconfdir)
 145 cdata.set('PA_DEFAULT_CONFIG_DIR_UNQUOTED', pulsesysconfdir)
 146 cdata.set_quoted('PA_BINARY', join_paths(bindir, 'pulseaudio'))
 147 cdata.set_quoted('PA_SYSTEM_RUNTIME_PATH', join_paths(localstatedir, 'run', 'pulse'))
 148 cdata.set_quoted('PA_SYSTEM_CONFIG_PATH', join_paths(localstatedir, 'lib', 'pulse'))
 149 cdata.set_quoted('PA_SYSTEM_STATE_PATH', join_paths(localstatedir, 'lib', 'pulse'))
 150 cdata.set_quoted('PA_DLSEARCHPATH', modlibexecdir)
 151 cdata.set_quoted('PA_SYSTEM_USER', get_option('system_user'))
 152 cdata.set_quoted('PA_SYSTEM_GROUP', get_option('system_group'))
 153 cdata.set_quoted('PA_ACCESS_GROUP', get_option('access_group'))
 154 cdata.set_quoted('PA_CFLAGS', 'Not yet supported on meson')
 155 cdata.set_quoted('PA_ALSA_PATHS_DIR', join_paths(alsadatadir, 'paths'))
 156 cdata.set_quoted('PA_ALSA_PROFILE_SETS_DIR', join_paths(alsadatadir, 'profile-sets'))
 157 cdata.set_quoted('DESKTOPFILEDIR', join_paths(datadir, 'applications'))
 158 cdata.set_quoted('PULSE_LOCALEDIR', localedir)
 159 cdata.set_quoted('GETTEXT_PACKAGE', 'pulseaudio')
 160 cdata.set('ENABLE_NLS', 1)
 161 cdata.set('top_srcdir', meson.source_root())
 162
 163 # Platform specifics
 164 # First some defaults to keep config file generation happy
 165 cdata.set('HAVE_COREAUDIO', 0)
 166 cdata.set('HAVE_WAVEOUT', 0)
 167
 168 platform_socket_dep = []
 169 platform_dep = []
 170
 171 # FIXME: This was not tested. Maybe some flags should better be CFLAGS,
 172 # rather than ending up in the config.h file?
 173 if host_machine.system() == 'darwin'
 174   cdata.set('OS_IS_DARWIN', 1)
 175   cdata.set('_DARWIN_C_SOURCE', '200112L') # Needed to get NSIG on Mac OS
 176 elif host_machine.system() == 'windows'
 177   cdata.set('OS_IS_WIN32', 1)
 178   cdata.set('HAVE_WINDOWS_H', 1)
 179   cdata.set('HAVE_WAVEOUT', 1)
 180   cdata.set('HAVE_WINSOCK2_H', 1)
 181   cdata.set('HAVE_WS2TCPIP_H', 1)
 182   cdata.set('WIN32_LEAN_AND_MEAN', 1) # Needed to avoid including unnecessary headers on Windows
 183   cdata.set('gid_t', 'int')
 184   cdata.set('uid_t', 'int')
 185   ws2_32_dep = meson.get_compiler('c').find_library('ws2_32')
 186   winsock_dep = meson.get_compiler('c').find_library('wsock32')
 187   ole32_dep = meson.get_compiler('c').find_library('ole32')
 188   ssp_dep = meson.get_compiler('c').find_library('ssp')
 189   pcreposix_dep = meson.get_compiler('c').find_library('pcreposix')
 190   platform_socket_dep = [ws2_32_dep, winsock_dep]
 191   platform_dep = [ole32_dep, ssp_dep, pcreposix_dep]
 192 elif host_machine.system() == 'freebsd'
 193   cdata.set('OS_IS_FREEBSD', 1)
 194 #elif host_machine.system() == 'solaris'
 195 #  # Apparently meson has no solaris support?
 196 #  # Needed to get declarations for msg_control and msg_controllen on Solaris
 197 #  cdata.set('_XOPEN_SOURCE', 600)
 198 #  cdata.set('__EXTENSIONS__', 1)
 199 endif
 200
 201 if cc.has_type('_Bool')
 202   cdata.set('HAVE_STD_BOOL', 1)
 203 endif
 204
 205 if host_machine.cpu_family() == 'x86_64' or cc.sizeof('void *') >= 8
 206   cdata.set('HAVE_FAST_64BIT_OPERATIONS', 1)
 207 endif
 208
 209 # Headers
 210
 211 check_headers = [
 212   'arpa/inet.h',
 213   'byteswap.h',
 214   'cpuid.h',
 215   'dlfcn.h',
 216   'execinfo.h',
 217   'grp.h',
 218   'langinfo.h',
 219   'linux/sockios.h',
 220   'locale.h',
 221   'netdb.h',
 222   'netinet/in.h',
 223   'netinet/in_systm.h',
 224   'netinet/ip.h',
 225   'netinet/tcp.h',
 226   'pcreposix.h',
 227   'poll.h',
 228   'pwd.h',
 229   'regex.h',
 230   'sched.h',
 231   'stdint.h',
 232   'sys/atomic.h',
 233   'sys/capability.h',
 234   'sys/conf.h',
 235   'sys/dl.h',
 236   'sys/eventfd.h',
 237   'sys/filio.h',
 238   'sys/ioctl.h',
 239   'sys/mman.h',
 240   'sys/prctl.h',
 241   'sys/resource.h',
 242   'sys/select.h',
 243   'sys/socket.h',
 244   'sys/syscall.h',
 245   'sys/uio.h',
 246   'sys/un.h',
 247   'sys/wait.h',
 248   'syslog.h',
 249   'xlocale.h',
 250 ]
 251
 252 foreach h : check_headers
 253   if cc.has_header(h)
 254     define = 'HAVE_' + h.underscorify().to_upper()
 255     cdata.set(define, 1)
 256   endif
 257 endforeach
 258
 259 if cc.has_header('valgrind/memcheck.h', required: get_option('valgrind'))
 260   cdata.set('HAVE_VALGRIND_MEMCHECK_H', 1)
 261 endif
 262
 263 # FIXME: move this to the above set
 264 if host_machine.system() != 'windows'
 265   if cc.has_header('pthread.h')
 266     cdata.set('HAVE_PTHREAD', 1)
 267   endif
 268 endif
 269
 270 if cc.has_header_symbol('pthread.h', 'PTHREAD_PRIO_INHERIT')
 271   cdata.set('HAVE_PTHREAD_PRIO_INHERIT', 1)
 272 endif
 273
 274 # Functions
 275
 276 check_functions = [
 277   'accept4',
 278   'clock_gettime',
 279   'ctime_r',
 280   'fchmod',
 281   'fchown',
 282   'fork',
 283   'fstat',
 284   'getaddrinfo',
 285   'getgrgid_r',
 286   'getgrnam_r',
 287   'getpwnam_r',
 288   'getpwuid_r',
 289   'gettimeofday',
 290   'getuid',
 291   'lrintf',
 292   'lstat',
 293   'memfd_create',
 294   'mkfifo',
 295   'mlock',
 296   'nanosleep',
 297   'open64',
 298   'paccept',
 299   'pipe',
 300   'pipe2',
 301   'posix_fadvise',
 302   'posix_madvise',
 303   'posix_memalign',
 304   'ppoll',
 305   'readlink',
 306   'setegid',
 307   'seteuid',
 308   'setpgid',
 309   'setregid',
 310   'setresgid',
 311   'setresuid',
 312   'setreuid',
 313   'setsid',
 314   'sig2str',
 315   'sigaction',
 316   'strerror_r',
 317   'strtod_l',
 318   'strtof',
 319   'symlink',
 320   'sysconf',
 321   'uname',
 322 ]
 323
 324 foreach f : check_functions
 325   if cc.has_function(f)
 326     define = 'HAVE_' + f.underscorify().to_upper()
 327
 328     if f == 'posix_memalign' and host_machine.system() == 'windows'
 329       message('Win32/mingw32 does not properly define posix_memalign.')
 330     elif f == 'fork' and host_machine.system() == 'windows'
 331       # __builtin_fork is defined and compiles properly, but calling __builtin_fork() does not.
 332       # This causes Meson to think that Windows has a fork() which causes a link error...
 333       message('Win32/mingw32 does not properly define fork.')
 334     else
 335       cdata.set(define, 1)
 336     endif
 337   endif
 338 endforeach
 339
 340 if cc.has_header_symbol('sys/syscall.h', 'SYS_memfd_create') \
 341   or cc.has_function('memfd_create')
 342   cdata.set('HAVE_MEMFD', 1)
 343 endif
 344
 345 if cc.has_function('dgettext')
 346   if host_machine.system() != 'windows'
 347     libintl_dep = []
 348   else
 349     libintl_dep = cc.find_library('intl')
 350   endif
 351 else
 352   libintl_dep = cc.find_library('intl')
 353 endif
 354
 355 # Symbols
 356
 357 if cc.has_header_symbol('signal.h', 'SIGXCPU')
 358   cdata.set('HAVE_SIGXCPU', 1)
 359 endif
 360
 361 if not cc.has_header_symbol('netinet/in.h', 'INADDR_NONE')
 362   if not cc.has_header_symbol('winsock2.h', 'INADDR_NONE')
 363     # Define INADDR_NONE if not found (Solaris)
 364     cdata.set('INADDR_NONE', '0xffffffff')
 365   endif
 366 endif
 367
 368 check_decls = [
 369   [ 'environ', 'unistd.h', '#define _GNU_SOURCE' ],
 370   [ 'SOUND_PCM_READ_RATE', 'sys/soundcard.h', '' ],
 371   [ 'SOUND_PCM_READ_CHANNELS', 'sys/soundcard.h', '' ],
 372   [ 'SOUND_PCM_READ_BITS', 'sys/soundcard.h', '' ],
 373 ]
 374
 375 foreach s : check_decls
 376   if cc.has_header_symbol(s[1], s[0], prefix : s[2])
 377     define = 'HAVE_DECL_' + s[0].to_upper()
 378     cdata.set(define, 1)
 379   endif
 380 endforeach
 381
 382 # Types
 383
 384 # FIXME: do we ever care about gid_t not being defined / smaller than an int?
 385 cdata.set('GETGROUPS_T', 'gid_t')
 386
 387 # Include paths
 388
 389 configinc = include_directories('.')
 390 topinc = include_directories('src')
 391
 392 # CFLAGS/LDFLAGS
 393
 394 pa_c_args = ['-DHAVE_CONFIG_H', '-D_GNU_SOURCE']
 395 server_c_args = ['-D__INCLUDED_FROM_PULSE_AUDIO']
 396 cdata.set('MESON_BUILD', 1)
 397
 398 # On ELF systems we don't want the libraries to be unloaded since we don't clean them up properly,
 399 # so we request the nodelete flag to be enabled.
 400 # On other systems, we don't really know how to do that, but it's welcome if somebody can tell.
 401 # Windows doesn't support this flag.
 402 if host_machine.system() != 'windows'
 403   nodelete_link_args = ['-Wl,-z,nodelete']
 404 else
 405   nodelete_link_args = []
 406 endif
 407
 408 # Code coverage
 409
 410 if get_option('gcov')
 411   add_project_arguments('--coverage', language: ['c', 'cpp'])
 412   add_project_link_arguments('--coverage', language: ['c', 'cpp'])
 413 endif
 414
 415 # Core Dependencies
 416
 417 libm_dep = cc.find_library('m', required : true)
 418
 419 thread_dep = dependency('threads')
 420 foreach f : [
 421   'pthread_getname_np',
 422   'pthread_setaffinity_np',
 423   'pthread_setname_np',
 424 ]
 425   if cc.has_function(f, dependencies : thread_dep)
 426     define = 'HAVE_' + f.underscorify().to_upper()
 427     cdata.set(define, 1)
 428   endif
 429 endforeach
 430
 431 cap_dep = cc.find_library('cap', required : false)
 432
 433 shm_dep = cc.find_library('rt', required : false)
 434 if cc.has_function('shm_open', dependencies : shm_dep)
 435   cdata.set('HAVE_SHM_OPEN', 1)
 436 endif
 437
 438 dl_dep = cc.find_library('dl', required : false)
 439 if cc.has_function('dladdr', dependencies : dl_dep)
 440   cdata.set('HAVE_DLADDR', 1)
 441 endif
 442
 443 have_iconv = false
 444 if cc.has_function('iconv_open')
 445   iconv_dep = dependency('', required : false)
 446   have_iconv = true
 447   # tell the libiconv header to pretend to be libc iconv
 448   cdata.set('LIBICONV_PLUG', 1)
 449 else
 450   iconv_dep = cc.find_library('iconv', required : false)
 451   have_iconv = iconv_dep.found()
 452 endif
 453 if have_iconv
 454   cdata.set('HAVE_ICONV', 1)
 455   iconvconsttest = '''#include <iconv.h>
 456 size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 457 '''
 458   if cc.compiles(iconvconsttest, dependencies : iconv_dep)
 459     cdata.set('ICONV_CONST', '')
 460   else
 461     cdata.set('ICONV_CONST', 'const')
 462   endif
 463 endif
 464
 465 # Used for backtraces on BSD
 466 execinfo_dep = cc.find_library('execinfo', required : false)
 467
 468 # Atomic operations
 469
 470 if get_option('atomic-arm-memory-barrier')
 471     cdata.set('ATOMIC_ARM_MEMORY_BARRIER_ENABLED', 1)
 472 endif
 473
 474 need_libatomic_ops = false
 475
 476 atomictest = '''void func() {
 477   volatile int atomic = 2;
 478   __sync_bool_compare_and_swap (&atomic, 2, 3);
 479 }
 480 '''
 481
 482 if cc.compiles(atomictest)
 483   cdata.set('HAVE_ATOMIC_BUILTINS', 1)
 484
 485   newatomictest = '''void func() {
 486     int c = 0;
 487     __atomic_store_n(&c, 4, __ATOMIC_SEQ_CST);
 488   }
 489   '''
 490
 491   if(cc.compiles(newatomictest))
 492     cdata.set('HAVE_ATOMIC_BUILTINS_MEMORY_MODEL', 1)
 493   endif
 494
 495 elif host_machine.cpu_family() == 'arm'
 496   if host_machine.system() == 'linux' and get_option('atomic-arm-linux-helpers')
 497     cdata.set('ATOMIC_ARM_LINUX_HELPERS', 1)
 498   else
 499     armatomictest = '''int func() {
 500       volatile int a=0;
 501       int o=0, n=1, r;
 502       asm volatile (
 503               "ldrex    %0, [%1]\n"
 504               "subs  %0, %0, %2\n"
 505               "strexeq %0, %3, [%1]\n"
 506               : "=&r" (r)
 507               : "r" (&a), "Ir" (o), "r" (n)
 508       : "cc");
 509       return (a==1 ? 0 : -1);
 510     }
 511     '''
 512
 513     if cc.compiles(armatomictest)
 514       cdata.set('ATOMIC_ARM_INLINE_ASM', 1)
 515     else
 516       need_libatomic_ops = true
 517     endif
 518   endif # arm && !linux
 519
 520 elif not ['freebsd', 'netbsd'].contains(host_machine.system())
 521   need_libatomic_ops = true
 522 endif # !atomic helpers && !arm
 523
 524 if need_libatomic_ops
 525   assert(cc.has_header('atomic_ops.h'), 'Need libatomic_ops')
 526
 527   cdata.set('AO_REQUIRE_CAS', 1)
 528
 529   if host_machine.system() != 'windows'
 530     libatomic_ops_dep = cc.find_library('atomic_ops', required : true)
 531   else
 532     libatomic_ops_dep = dependency('', required: false)
 533   endif
 534 else
 535   libatomic_ops_dep = dependency('', required: false)
 536 endif
 537
 538 # ARM checks
 539 # ARMV6 instructions we need
 540 if host_machine.cpu_family() == 'arm'
 541   armv6test = '''int func() {
 542     volatile int a = -60000, b = 0xaaaabbbb, c = 0xccccdddd;
 543     asm volatile ("ldr r0, %2 \n"
 544                   "ldr r2, %3 \n"
 545                   "ldr r3, %4 \n"
 546                   "ssat r1, #8, r0 \n"
 547                   "str r1, %0 \n"
 548                   "pkhbt r1, r3, r2, LSL #8 \n"
 549                   "str r1, %1 \n"
 550                   : "=m" (a), "=m" (b)
 551                   : "m" (a), "m" (b), "m" (c)
 552                   : "r0", "r1", "r2", "r3", "cc");
 553     return (a == -128 && b == 0xaabbdddd) ? 0 : -1;
 554   }
 555   '''
 556
 557   if cc.compiles(armv6test)
 558     cdata.set('HAVE_ARMV6', 1)
 559   endif
 560 endif
 561 # NEON checks are automatically done by the unstable-simd module
 562
 563 # FIXME: make sure it's >= 2.2
 564 ltdl_dep = cc.find_library('ltdl', required : true)
 565 # FIXME: can meson support libtool -dlopen/-dlpreopen things?
 566 #        and do we still want to support this at all?
 567 cdata.set('DISABLE_LIBTOOL_PRELOAD', 1)
 568
 569 if get_option('database') == 'tdb'
 570   database_dep = dependency('tdb')
 571 elif get_option('database') == 'gdbm'
 572   database_dep = cc.find_library('gdbm', required : true)
 573 else
 574   database_dep = dependency('', required: false)
 575 endif
 576
 577 if get_option('ipv6')
 578   cdata.set('HAVE_IPV6', 1)
 579 endif
 580
 581 if get_option('legacy-database-entry-format')
 582   cdata.set('ENABLE_LEGACY_DATABASE_ENTRY_FORMAT', 1)
 583 endif
 584
 585 if get_option('stream-restore-clear-old-devices')
 586   cdata.set('STREAM_RESTORE_CLEAR_OLD_DEVICES', 1)
 587 endif
 588
 589 if get_option('running-from-build-tree')
 590   cdata.set('HAVE_RUNNING_FROM_BUILD_TREE', 1)
 591 endif
 592
 593 alsa_dep = dependency('alsa', version : '>= 1.0.24', required : get_option('alsa'))
 594 if alsa_dep.found()
 595   cdata.set('HAVE_ALSA', 1)
 596   cdata.set('HAVE_ALSA_UCM', 1)
 597 endif
 598
 599 asyncns_dep = dependency('libasyncns', version : '>= 0.1', required : get_option('asyncns'))
 600 if asyncns_dep.found()
 601   cdata.set('HAVE_LIBASYNCNS', 1)
 602 endif
 603
 604 dbus_dep = dependency('dbus-1', version : '>= 1.4.12', required : get_option('dbus'))
 605 if dbus_dep.found()
 606   cdata.set('HAVE_DBUS', 1)
 607 endif
 608
 609 gio_dep = dependency('gio-2.0', version : '>= 2.26.0', required : get_option('gsettings'))
 610 if gio_dep.found()
 611   cdata.set('HAVE_GSETTINGS', 1)
 612 endif
 613
 614 glib_dep = dependency('glib-2.0', version : '>= 2.28.0', required: get_option('glib'))
 615 if glib_dep.found()
 616   cdata.set('HAVE_GLIB', 1)
 617 endif
 618
 619 gtk_dep = dependency('gtk+-3.0', required : get_option('gtk'))
 620 if gtk_dep.found()
 621   cdata.set('HAVE_GTK', 1)
 622 endif
 623
 624 have_orcc = false
 625 orcc_args = []
 626 orc_dep = dependency('orc-0.4', version : '>= 0.4.11', required : get_option('orc'))
 627 orcc = find_program('orcc', required : get_option('orc'))
 628 if orc_dep.found() and orcc.found()
 629   have_orcc = true
 630   orcc_args = [orcc]
 631   #orcc_args = [orcc, '--include', 'glib.h']
 632   cdata.set('HAVE_ORC', 1)
 633 else
 634   cdata.set('DISABLE_ORC', 1)
 635 endif
 636
 637 samplerate_dep = dependency('samplerate', version : '>= 0.1.0', required : get_option('samplerate'))
 638 if samplerate_dep.found()
 639   cdata.set('HAVE_LIBSAMPLERATE', 1)
 640 endif
 641
 642 sndfile_dep = dependency('sndfile', version : '>= 1.0.20')
 643
 644 soxr_dep = dependency('soxr', version : '>= 0.1.1', required : get_option('soxr'))
 645 if soxr_dep.found()
 646   cdata.set('HAVE_SOXR', 1)
 647 endif
 648
 649 libsystemd_dep = dependency('libsystemd', required : get_option('systemd'))
 650 if libsystemd_dep.found()
 651   cdata.set('HAVE_SYSTEMD_DAEMON', 1)
 652   cdata.set('HAVE_SYSTEMD_LOGIN', 1)
 653   cdata.set('HAVE_SYSTEMD_JOURNAL', 1)
 654 endif
 655 systemd_dep = dependency('systemd', required : get_option('systemd'))
 656 if systemd_dep.found() and systemduserunitdir == ''
 657   systemduserunitdir = systemd_dep.get_pkgconfig_variable('systemduserunitdir')
 658 endif
 659
 660 libelogind_dep = dependency('libelogind', required : get_option('elogind'))
 661 if libelogind_dep.found()
 662   cdata.set('HAVE_SYSTEMD_LOGIN', 1)
 663 endif
 664
 665 tcpwrap_dep = cc.find_library('wrap', required: get_option('tcpwrap'))
 666 if cc.has_header('tcpd.h') and cc.has_function('hosts_access', dependencies : tcpwrap_dep)
 667   cdata.set('HAVE_LIBWRAP', 1)
 668 endif
 669
 670 x11_dep = dependency('x11-xcb', required : get_option('x11'))
 671 if x11_dep.found()
 672   xcb_dep  = dependency('xcb',  required : true, version : '>= 1.6')
 673   ice_dep  = dependency('ice',  required : true)
 674   sm_dep   = dependency('sm',   required : true)
 675   xtst_dep = dependency('xtst', required : true)
 676   cdata.set('HAVE_X11', 1)
 677   if cc.has_function('XSetIOErrorExitHandler', dependencies: x11_dep)
 678     cdata.set('HAVE_XSETIOERROREXITHANDLER', 1)
 679   endif
 680 endif
 681
 682 # Module dependencies
 683 if cc.has_header('sys/soundcard.h', required: get_option('oss-output'))
 684   cdata.set('HAVE_OSS_OUTPUT', 1)
 685   cdata.set('HAVE_OSS_WRAPPER', 1)
 686   cdata.set('PULSEDSP_LOCATION', pulsedsp_location)
 687 endif
 688
 689 if get_option('hal-compat')
 690   cdata.set('HAVE_HAL_COMPAT', 1)
 691 endif
 692
 693 avahi_dep = dependency('avahi-client', version : '>= 0.6.0', required : get_option('avahi'), disabler : true)
 694 if avahi_dep.found()
 695   cdata.set('HAVE_AVAHI', 1)
 696 endif
 697
 698 sbc_dep = dependency('sbc', version : '>= 1.0', required : false)
 699 if get_option('bluez5')
 700   assert(dbus_dep.found(), 'BlueZ requires D-Bus support')
 701   assert(sbc_dep.found(), 'BlueZ requires SBC support')
 702   cdata.set('HAVE_SBC', 1)
 703   cdata.set('HAVE_BLUEZ', 1)
 704   cdata.set('HAVE_BLUEZ_5', 1)
 705   if get_option('bluez5-native-headset')
 706     cdata.set('HAVE_BLUEZ_5_NATIVE_HEADSET', 1)
 707   endif
 708   if get_option('bluez5-ofono-headset')
 709     cdata.set('HAVE_BLUEZ_5_OFONO_HEADSET', 1)
 710   endif
 711 endif
 712
 713 fftw_dep = dependency('fftw3f', required : get_option('fftw'))
 714 if fftw_dep.found()
 715   cdata.set('HAVE_FFTW', 1)
 716 endif
 717
 718 jack_dep = dependency('jack', version : '>= 0.117.0', required : get_option('jack'))
 719 if jack_dep.found()
 720   cdata.set('HAVE_JACK', 1)
 721 endif
 722
 723 lirc_dep = dependency('lirc', required : get_option('lirc'))
 724 if lirc_dep.found()
 725   cdata.set('HAVE_LIRC', 1)
 726 endif
 727
 728 openssl_dep = dependency('openssl', version : '>= 0.9', required : get_option('openssl'))
 729 if openssl_dep.found()
 730   cdata.set('HAVE_OPENSSL', 1)
 731 endif
 732
 733 speex_dep = dependency('speexdsp', version : '>= 1.2', required : get_option('speex'))
 734 if speex_dep.found()
 735   cdata.set('HAVE_SPEEX', 1)
 736 endif
 737
 738 udev_dep = dependency('libudev', version : '>= 143', required : get_option('udev'))
 739 if udev_dep.found()
 740   cdata.set('HAVE_UDEV', 1)
 741 endif
 742
 743 webrtc_dep = dependency('webrtc-audio-processing', version : '>= 0.2', required : get_option('webrtc-aec'))
 744 if webrtc_dep.found()
 745   cdata.set('HAVE_WEBRTC', 1)
 746 endif
 747
 748 gst_dep = dependency('gstreamer-1.0', version : '>= 1.14', required : get_option('gstreamer'))
 749 gstapp_dep = dependency('gstreamer-app-1.0', required : get_option('gstreamer'))
 750 gstrtp_dep = dependency('gstreamer-rtp-1.0', required : get_option('gstreamer'))
 751
 752 have_gstreamer = false
 753 if gst_dep.found() and gstapp_dep.found() and gstrtp_dep.found()
 754   have_gstreamer = true
 755 endif
 756
 757 bluez5_gst_dep = dependency('gstreamer-1.0', version : '>= 1.14', required : get_option('bluez5-gstreamer'))
 758 bluez5_gstapp_dep = dependency('gstreamer-app-1.0', required : get_option('bluez5-gstreamer'))
 759 have_bluez5_gstreamer = false
 760 if bluez5_gst_dep.found() and bluez5_gstapp_dep.found()
 761   have_bluez5_gstreamer = true
 762   cdata.set('HAVE_GSTLDAC', 1)
 763   cdata.set('HAVE_GSTAPTX', 1)
 764 endif
 765
 766 # These are required for the CMake file generation
 767 cdata.set('PA_LIBDIR', libdir)
 768 cdata.set('PA_INCDIR', includedir)
 769 if glib_dep.found()
 770   cdata.set('HAVE_GLIB20', 1) # to match the AM_CONDITIONAL for CMake file generation
 771 endif
 772
 773 # Test dependencies
 774
 775 check_dep = dependency('check', version : '>= 0.9.10', required : get_option('tests'))
 776
 777 # Subdirs
 778
 779 subdir('doxygen')
 780 subdir('po')
 781 if get_option('man')
 782   subdir('man')
 783 endif
 784 subdir('shell-completion/bash')
 785 subdir('shell-completion/zsh')
 786 subdir('src')
 787 subdir('vala')
 788
 789 # Now generate config.h from everything above
 790 configure_file(output : 'config.h', configuration : cdata)
 791
 792 # pkg-config files
 793
 794 pc_cdata = configuration_data()
 795
 796 pc_cdata.set('prefix', prefix)
 797 pc_cdata.set('exec_prefix', prefix)
 798 pc_cdata.set('libdir', libdir)
 799 pc_cdata.set('includedir', includedir)
 800 pc_cdata.set('modlibexecdir', modlibexecdir)
 801 pc_cdata.set('PACKAGE_VERSION', pa_version_str)
 802 pc_cdata.set('PA_MAJORMINOR', pa_version_major_minor)
 803 # FIXME: the line below is wrong. Currently the meson thread dep lacks documentation,
 804 # and doesn't allow introspection, ie. none of get_pkgconfig_variable() or
 805 # get_configtool_variable() work with it, so we have no way to get this flag right,
 806 # unless we do all the work ourselves. See current work in glib, also meson #553.
 807 pc_cdata.set('PTHREAD_LIBS', '-pthread')
 808
 809 pc_files = [
 810   'libpulse.pc',
 811   'libpulse-simple.pc',
 812 ]
 813
 814 if glib_dep.found()
 815   pc_files += 'libpulse-mainloop-glib.pc'
 816 endif
 817
 818 foreach file : pc_files
 819   configure_file(
 820     input : file + '.in',
 821     output : file,
 822     configuration : pc_cdata,
 823     install_dir : pkgconfigdir)
 824 endforeach
 825
 826 # CMake files
 827
 828 m4 = find_program('m4', required: true)
 829
 830 cmakedir = join_paths(libdir, 'cmake', 'PulseAudio')
 831
 832 cmake_template_file = configure_file(
 833   input : 'PulseAudioConfig.cmake.in',
 834   output : 'PulseAudioConfig.cmake.tmp',
 835   configuration: cdata,
 836 )
 837
 838 custom_target('PulseAudioConfig.cmake',
 839   input : cmake_template_file,
 840   output : 'PulseAudioConfig.cmake',
 841   capture : true,
 842   command : [m4, '@INPUT@'],
 843   build_by_default : true,
 844   install : true,
 845   install_dir : cmakedir,
 846 )
 847
 848 configure_file(
 849   input : 'PulseAudioConfigVersion.cmake.in',
 850   output : 'PulseAudioConfigVersion.cmake',
 851   configuration: cdata,
 852   install : true,
 853   install_dir : cmakedir,
 854 )
 855
 856 ############################################################
 857
 858 # Final summary
 859
 860 summary = [
 861   '',
 862   '---{ @0@ @1@ }---'.format(meson.project_name(), meson.project_version()),
 863   '',
 864   'prefix:                        @0@'.format(prefix),
 865   'bindir:                        @0@'.format(bindir),
 866   'libdir:                        @0@'.format(libdir),
 867   'libexecdir:                    @0@'.format(libexecdir),
 868   'mandir:                        @0@'.format(mandir),
 869   'datadir:                       @0@'.format(datadir),
 870   'sysconfdir:                    @0@'.format(sysconfdir),
 871   'localstatedir:                 @0@'.format(localstatedir),
 872   'modlibexecdir:                 @0@'.format(modlibexecdir),
 873   'alsadatadir:                   @0@'.format(alsadatadir),
 874   'System Runtime Path:           @0@'.format(cdata.get_unquoted('PA_SYSTEM_RUNTIME_PATH')),
 875   'System State Path:             @0@'.format(cdata.get_unquoted('PA_SYSTEM_STATE_PATH')),
 876   'System Config Path:            @0@'.format(cdata.get_unquoted('PA_SYSTEM_CONFIG_PATH')),
 877   'Bash completions directory:    @0@'.format(bashcompletiondir),
 878   'Zsh completions directory:     @0@'.format(zshcompletiondir),
 879   'Compiler:                      @0@ @1@'.format(cc.get_id(), cc.version()),
 880 #  'CFLAGS:                        @0@'.format(${CFLAGS}),
 881 #  'CPPFLAGS:                      @0@'.format(${CPPFLAGS}),
 882 #  'LIBS:                          @0@'.format(${LIBS}),
 883   '',
 884   'Enable memfd shared memory:    @0@'.format(cdata.has('HAVE_MEMFD')),
 885   'Enable X11:                    @0@'.format(x11_dep.found()),
 886   '  Safe X11 I/O errors:         @0@'.format(cdata.has('HAVE_XSETIOERROREXITHANDLER')),
 887   'Enable OSS Output:             @0@'.format(cdata.has('HAVE_OSS_OUTPUT')),
 888   'Enable OSS Wrapper:            @0@'.format(cdata.has('HAVE_OSS_WRAPPER')),
 889 #  'Enable EsounD:                 @0@'.format(${ENABLE_ESOUND}),
 890   'Enable Alsa:                   @0@'.format(alsa_dep.found()),
 891 #  'Enable CoreAudio:              @0@'.format(${ENABLE_COREAUDIO}),
 892 #  'Enable Solaris:                @0@'.format(${ENABLE_SOLARIS}),
 893 #  'Enable WaveOut:                @0@'.format(${ENABLE_WAVEOUT}),
 894   'Enable GLib 2:                 @0@'.format(glib_dep.found()),
 895   'Enable GSettings:              @0@'.format(gio_dep.found()),
 896   'Enable Gtk+ 3:                 @0@'.format(gtk_dep.found()),
 897   'Enable Avahi:                  @0@'.format(avahi_dep.found()),
 898   'Enable Jack:                   @0@'.format(jack_dep.found()),
 899   'Enable Async DNS:              @0@'.format(asyncns_dep.found()),
 900   'Enable LIRC:                   @0@'.format(lirc_dep.found()),
 901   'Enable D-Bus:                  @0@'.format(dbus_dep.found()),
 902   '  Enable BlueZ 5:              @0@'.format(get_option('bluez5')),
 903   '    Enable native headsets:    @0@'.format(get_option('bluez5-native-headset')),
 904   '    Enable  ofono headsets:    @0@'.format(get_option('bluez5-ofono-headset')),
 905   '    Enable GStreamer based codecs: @0@'.format(have_bluez5_gstreamer),
 906   'Enable udev:                   @0@'.format(udev_dep.found()),
 907   '  Enable HAL->udev compat:     @0@'.format(get_option('hal-compat')),
 908   'Enable systemd:                @0@'.format(libsystemd_dep.found()),
 909   'Enable elogind:                @0@'.format(libelogind_dep.found()),
 910   'Enable TCP Wrappers:           @0@'.format(tcpwrap_dep.found()),
 911   'Enable libsamplerate:          @0@'.format(samplerate_dep.found()),
 912   'Enable IPv6:                   @0@'.format(get_option('ipv6')),
 913   'Enable OpenSSL (for Airtunes): @0@'.format(openssl_dep.found()),
 914   'Enable FFTW:                   @0@'.format(fftw_dep.found()),
 915   'Enable ORC:                    @0@'.format(have_orcc),
 916   'Enable GStreamer:              @0@'.format(have_gstreamer),
 917   'Enable Adrian echo canceller:  @0@'.format(get_option('adrian-aec')),
 918   'Enable Speex (resampler, AEC): @0@'.format(speex_dep.found()),
 919   'Enable SoXR (resampler):       @0@'.format(soxr_dep.found()),
 920   'Enable WebRTC echo canceller:  @0@'.format(webrtc_dep.found()),
 921   'Enable Gcov coverage:          @0@'.format(get_option('gcov')),
 922   'Enable Valgrind:               @0@'.format(cdata.has('HAVE_VALGRIND_MEMCHECK_H')),
 923   'Enable man pages:              @0@'.format(get_option('man')),
 924   'Enable unit tests:             @0@'.format(get_option('tests')),
 925   '',
 926   'Database:                      @0@'.format(get_option('database')),
 927   'Legacy Database Entry Support: @0@'.format(get_option('legacy-database-entry-format')),
 928   'module-stream-restore:',
 929   '  Clear old devices:           @0@'.format(get_option('stream-restore-clear-old-devices')),
 930   'Running from build tree:       @0@'.format(get_option('running-from-build-tree')),
 931   'System User:                   @0@'.format(cdata.get_unquoted('PA_SYSTEM_USER')),
 932   'System Group:                  @0@'.format(cdata.get_unquoted('PA_SYSTEM_GROUP')),
 933   'Access Group:                  @0@'.format(cdata.get_unquoted('PA_ACCESS_GROUP')),
 934 #  'Enable per-user EsounD socket: @0@'.format(${ENABLE_PER_USER_ESOUND_SOCKET}),
 935 #  'Force preopen:                 @0@'.format(${FORCE_PREOPEN}),
 936 #  'Preopened modules:             @0@'.format(${PREOPEN_MODS}),
 937 ]
 938
 939 message('\n    '.join(summary))
 940
 941 # Sanity checks
 942
 943 if not speex_dep.found() and not webrtc_dep.found() and not get_option('adrian-aec')
 944   error('At least one echo canceller implementation must be available!')
 945 endif
 946
 947 if samplerate_dep.found()
 948   warning('Support for libsamplerate is DEPRECATED')
 949 endif
 950
 951 if host_machine.system() != 'windows'
 952   if not dbus_dep.found()
 953     message = [
 954       'You do not have D-Bus support enabled. It is strongly recommended',
 955       'that you enable D-Bus support if your platform supports it.',
 956       'Many parts of PulseAudio use D-Bus, from ConsoleKit interaction',
 957       'to the Device Reservation Protocol to speak to JACK, Bluetooth',
 958       'support and even a native control protocol for communicating and',
 959       'controlling the PulseAudio daemon itself.',
 960     ]
 961     warning('\n' + '\n'.join(message))
 962   endif
 963   if host_machine.system() == 'linux' and not udev_dep.found()
 964     message = [
 965       'You do not have udev support enabled. It is strongly recommended',
 966       'that you enable udev support if your platform supports it as it is',
 967       'the primary method used to detect hardware audio devices (on Linux)',
 968       'and is thus a critical part of PulseAudio on that platform.',
 969     ]
 970     warning('\n' + '\n'.join(message))
 971   endif
 972   if not speex_dep.found()
 973     message = [
 974       'You do not have speex support enabled. It is strongly recommended',
 975       'that you enable speex support if your platform supports it as it is',
 976       'the primary method used for audio resampling and is thus a critical',
 977       'part of PulseAudio on that platform.',
 978     ]
 979     warning('\n' + '\n'.join(message))
 980   endif
 981 endif