meson.build

   1 project('glib', 'c', 'cpp',
   2   version : '2.59.0',
   3   meson_version : '>= 0.48.0',
   4   default_options : [
   5     'buildtype=debugoptimized',
   6     'warning_level=1',
   7     'c_std=gnu89'
   8   ]
   9 )
  10
  11 cc = meson.get_compiler('c')
  12 cxx = meson.get_compiler('cpp')
  13
  14 cc_can_run = not meson.is_cross_build() or meson.has_exe_wrapper()
  15
  16 if cc.get_id() == 'msvc'
  17   # Ignore several spurious warnings for things glib does very commonly
  18   # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  19   # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  20   # NOTE: Only add warnings here if you are sure they're spurious
  21   add_project_arguments('/wd4035', '/wd4715', '/wd4116',
  22     '/wd4046', '/wd4068', '/wo4090', '/FImsvc_recommended_pragmas.h',language : 'c')
  23   # Disable SAFESEH with MSVC for plugins and libs that use external deps that
  24   # are built with MinGW
  25   noseh_link_args = ['/SAFESEH:NO']
  26   # Set the input and exec encoding to utf-8, like is the default with GCC
  27   add_project_arguments(cc.get_supported_arguments(['/utf-8']), language: 'c')
  28 else
  29   noseh_link_args = []
  30   # -mms-bitfields vs -fnative-struct ?
  31 endif
  32
  33 host_system = host_machine.system()
  34
  35 glib_version = meson.project_version()
  36 glib_api_version = '2.0'
  37 version_arr = glib_version.split('.')
  38 major_version = version_arr[0].to_int()
  39 minor_version = version_arr[1].to_int()
  40 micro_version = version_arr[2].to_int()
  41
  42 interface_age = minor_version.is_odd() ? 0 : micro_version
  43 binary_age = 100 * minor_version + micro_version
  44
  45 soversion = 0
  46 # Maintain compatibility with previous libtool versioning
  47 # current = minor * 100 + micro
  48 current = binary_age - interface_age
  49 library_version = '@0@.@1@.@2@'.format(soversion, current, interface_age)
  50 darwin_versions = [current + 1, '@0@.@1@'.format(current + 1, interface_age)]
  51
  52 configinc = include_directories('.')
  53 glibinc = include_directories('glib')
  54 gobjectinc = include_directories('gobject')
  55 gmoduleinc = include_directories('gmodule')
  56 gioinc = include_directories('gio')
  57
  58 glib_prefix = get_option('prefix')
  59 glib_bindir = join_paths(glib_prefix, get_option('bindir'))
  60 glib_libdir = join_paths(glib_prefix, get_option('libdir'))
  61 glib_libexecdir = join_paths(glib_prefix, get_option('libexecdir'))
  62 glib_datadir = join_paths(glib_prefix, get_option('datadir'))
  63 glib_pkgdatadir = join_paths(glib_datadir, 'glib-2.0')
  64 glib_includedir = join_paths(glib_prefix, get_option('includedir'))
  65 glib_giomodulesdir = get_option('gio_module_dir')
  66 if glib_giomodulesdir == ''
  67   glib_giomodulesdir = join_paths(glib_libdir, 'gio', 'modules')
  68 endif
  69
  70 glib_pkgconfigreldir = join_paths(glib_libdir, 'pkgconfig')
  71
  72 installed_tests_metadir = join_paths(glib_datadir, 'installed-tests', meson.project_name())
  73 installed_tests_execdir = join_paths(glib_libexecdir, 'installed-tests', meson.project_name())
  74 installed_tests_enabled = get_option('installed_tests')
  75 installed_tests_template = files('template.test.in')
  76 installed_tests_template_tap = files('template-tap.test.in')
  77
  78 add_project_arguments('-D_GNU_SOURCE', language: 'c')
  79
  80 # Disable strict aliasing;
  81 # see https://bugzilla.gnome.org/show_bug.cgi?id=791622
  82 if cc.has_argument('-fno-strict-aliasing')
  83   add_project_arguments('-fno-strict-aliasing', language: 'c')
  84 endif
  85
  86 ########################
  87 # Configuration begins #
  88 ########################
  89 glib_conf = configuration_data()
  90 glibconfig_conf = configuration_data()
  91
  92 # accumulated list of defines as we check for them, so we can easily
  93 # use them later in test programs (autoconf does this automatically)
  94 glib_conf_prefix = ''
  95
  96 glib_conf.set('GLIB_MAJOR_VERSION', major_version)
  97 glib_conf.set('GLIB_MINOR_VERSION', minor_version)
  98 glib_conf.set('GLIB_MICRO_VERSION', micro_version)
  99 glib_conf.set('GLIB_INTERFACE_AGE', interface_age)
 100 glib_conf.set('GLIB_BINARY_AGE', binary_age)
 101 glib_conf.set_quoted('GETTEXT_PACKAGE', 'glib20')
 102 glib_conf.set_quoted('PACKAGE_BUGREPORT', 'https://gitlab.gnome.org/GNOME/glib/issues/new')
 103 glib_conf.set_quoted('PACKAGE_NAME', 'glib')
 104 glib_conf.set_quoted('PACKAGE_STRING', 'glib @0@'.format(meson.project_version()))
 105 glib_conf.set_quoted('PACKAGE_TARNAME', 'glib')
 106 glib_conf.set_quoted('PACKAGE_URL', '')
 107 glib_conf.set_quoted('PACKAGE_VERSION', meson.project_version())
 108 glib_conf.set('ENABLE_NLS', 1)
 109
 110 # used by the .rc.in files
 111 glibconfig_conf.set('LT_CURRENT_MINUS_AGE', soversion)
 112
 113 glib_conf.set('_GNU_SOURCE', 1)
 114
 115 if host_system == 'windows'
 116   # Poll doesn't work on devices on Windows
 117   glib_conf.set('BROKEN_POLL', true)
 118 endif
 119
 120 if host_system == 'windows' and cc.get_id() != 'msvc'
 121   # FIXME: Ideally we shouldn't depend on this on Windows and should use
 122   # 64 bit capable Windows API that also works with MSVC.
 123   # The autotools build did set this for mingw and while meson sets it
 124   # for gcc/clang by default, it doesn't do so on Windows.
 125   glib_conf.set('_FILE_OFFSET_BITS', 64)
 126 endif
 127
 128 # Check for GNU visibility attributes
 129 g_have_gnuc_visibility = cc.compiles('''
 130   void
 131   __attribute__ ((visibility ("hidden")))
 132        f_hidden (void)
 133   {
 134   }
 135   void
 136   __attribute__ ((visibility ("internal")))
 137        f_internal (void)
 138   {
 139   }
 140   void
 141   __attribute__ ((visibility ("protected")))
 142        f_protected (void)
 143   {
 144   }
 145   void
 146   __attribute__ ((visibility ("default")))
 147        f_default (void)
 148   {
 149   }
 150   int main (void)
 151   {
 152     f_hidden();
 153     f_internal();
 154     f_protected();
 155     f_default();
 156     return 0;
 157   }
 158   ''',
 159   # Not supported by MSVC, but MSVC also won't support visibility,
 160   # so it's OK to pass -Werror explicitly. Replace with
 161   # override_options : 'werror=true' once that is supported
 162   args: ['-Werror'],
 163   name : 'GNU C visibility attributes test')
 164
 165 if g_have_gnuc_visibility
 166   glibconfig_conf.set('G_HAVE_GNUC_VISIBILITY', '1')
 167 endif
 168
 169 # Detect and set symbol visibility
 170 glib_hidden_visibility_args = []
 171 if get_option('default_library') != 'static'
 172   if host_system == 'windows'
 173     glib_conf.set('DLL_EXPORT', true)
 174     if cc.get_id() == 'msvc'
 175       glib_conf.set('_GLIB_EXTERN', '__declspec(dllexport) extern')
 176     elif cc.has_argument('-fvisibility=hidden')
 177       glib_conf.set('_GLIB_EXTERN', '__attribute__((visibility("default"))) __declspec(dllexport) extern')
 178       glib_hidden_visibility_args = ['-fvisibility=hidden']
 179     endif
 180   elif cc.has_argument('-fvisibility=hidden')
 181     glib_conf.set('_GLIB_EXTERN', '__attribute__((visibility("default"))) extern')
 182     glib_hidden_visibility_args = ['-fvisibility=hidden']
 183   endif
 184 endif
 185
 186 if host_system == 'windows' and get_option('default_library') == 'static'
 187     glibconfig_conf.set('GLIB_STATIC_COMPILATION', '1')
 188     glibconfig_conf.set('GOBJECT_STATIC_COMPILATION', '1')
 189 endif
 190
 191 # FIXME: what about Cygwin (G_WITH_CYGWIN)
 192 if host_system == 'windows'
 193   glib_os = '''#define G_OS_WIN32
 194 #define G_PLATFORM_WIN32'''
 195 else
 196   glib_os = '#define G_OS_UNIX'
 197 endif
 198 glibconfig_conf.set('glib_os', glib_os)
 199
 200 # We need to know the build type to determine what .lib files we need on Visual Studio
 201 # for dependencies that don't normally come with pkg-config files for Visual Studio builds
 202 buildtype = get_option('buildtype')
 203
 204 glib_debug_cflags = []
 205 if buildtype.startswith('debug')
 206   glib_debug_cflags += ['-DG_ENABLE_DEBUG']
 207 elif buildtype == 'release'
 208   glib_debug_cflags += ['-DG_DISABLE_CAST_CHECKS']
 209 endif
 210
 211 add_project_arguments(glib_debug_cflags, language: 'c')
 212
 213 # check for header files
 214
 215 headers = [
 216   'alloca.h',
 217   'crt_externs.h',
 218   'dirent.h', # MSC does not come with this by default
 219   'float.h',
 220   'fstab.h',
 221   'grp.h',
 222   'inttypes.h',
 223   'limits.h',
 224   'linux/magic.h',
 225   'locale.h',
 226   'mach/mach_time.h',
 227   'memory.h',
 228   'mntent.h',
 229   'poll.h',
 230   'pwd.h',
 231   'sched.h',
 232   'spawn.h',
 233   'stdint.h',
 234   'stdlib.h',
 235   'string.h',
 236   'strings.h',
 237   'sys/auxv.h',
 238   'sys/event.h',
 239   'sys/filio.h',
 240   'sys/inotify.h',
 241   'sys/mkdev.h',
 242   'sys/mntctl.h',
 243   'sys/mnttab.h',
 244   'sys/mount.h',
 245   'sys/param.h',
 246   'sys/resource.h',
 247   'sys/select.h',
 248   'sys/statfs.h',
 249   'sys/stat.h',
 250   'sys/statvfs.h',
 251   'sys/sysctl.h',
 252   'sys/time.h', # MSC does not come with this by default
 253   'sys/times.h',
 254   'sys/types.h',
 255   'sys/uio.h',
 256   'sys/vfs.h',
 257   'sys/vfstab.h',
 258   'sys/vmount.h',
 259   'sys/wait.h',
 260   'termios.h',
 261   'unistd.h',
 262   'values.h',
 263   'xlocale.h',
 264 ]
 265
 266 foreach h : headers
 267   if cc.has_header(h)
 268     define = 'HAVE_' + h.underscorify().to_upper()
 269     glib_conf.set(define, 1)
 270     glib_conf_prefix = glib_conf_prefix + '#define @0@ 1\n'.format(define)
 271   endif
 272 endforeach
 273
 274 # FIXME: Use cc.check_header from Meson 0.47.
 275 # FreeBSD includes a malloc.h which always throw compilation error.
 276 if cc.compiles('#include <malloc.h>', name : 'malloc.h')
 277   glib_conf.set('HAVE_MALLOC_H', 1)
 278   glib_conf_prefix = glib_conf_prefix + '#define HAVE_MALLOC_H 1\n'
 279 endif
 280
 281 if cc.has_header('linux/netlink.h')
 282   glib_conf.set('HAVE_NETLINK', 1)
 283 endif
 284
 285 if glib_conf.has('HAVE_LOCALE_H')
 286   if cc.has_header_symbol('locale.h', 'LC_MESSAGES')
 287     glib_conf.set('HAVE_LC_MESSAGES', 1)
 288   endif
 289 endif
 290
 291 struct_stat_blkprefix = '''
 292 #include <sys/types.h>
 293 #include <sys/stat.h>
 294 #ifdef HAVE_UNISTD_H
 295 #include <unistd.h>
 296 #endif
 297 #ifdef HAVE_SYS_STATFS_H
 298 #include <sys/statfs.h>
 299 #endif
 300 #ifdef HAVE_SYS_PARAM_H
 301 #include <sys/param.h>
 302 #endif
 303 #ifdef HAVE_SYS_MOUNT_H
 304 #include <sys/mount.h>
 305 #endif
 306 '''
 307
 308 struct_members = [
 309   [ 'stat', 'st_mtimensec' ],
 310   [ 'stat', 'st_mtim.tv_nsec' ],
 311   [ 'stat', 'st_atimensec' ],
 312   [ 'stat', 'st_atim.tv_nsec' ],
 313   [ 'stat', 'st_ctimensec' ],
 314   [ 'stat', 'st_ctim.tv_nsec' ],
 315   [ 'stat', 'st_birthtime' ],
 316   [ 'stat', 'st_birthtimensec' ],
 317   [ 'stat', 'st_birthtim' ],
 318   [ 'stat', 'st_birthtim.tv_nsec' ],
 319   [ 'stat', 'st_blksize', struct_stat_blkprefix ],
 320   [ 'stat', 'st_blocks', struct_stat_blkprefix ],
 321   [ 'statfs', 'f_fstypename', struct_stat_blkprefix ],
 322   [ 'statfs', 'f_bavail', struct_stat_blkprefix ],
 323   [ 'dirent', 'd_type', '''#include <sys/types.h>
 324                            #include <dirent.h>''' ],
 325   [ 'statvfs', 'f_basetype', '#include <sys/statvfs.h>' ],
 326   [ 'statvfs', 'f_fstypename', '#include <sys/statvfs.h>' ],
 327   [ 'tm', 'tm_gmtoff', '#include <time.h>' ],
 328   [ 'tm', '__tm_gmtoff', '#include <time.h>' ],
 329 ]
 330
 331 foreach m : struct_members
 332   header_check_prefix = glib_conf_prefix
 333   if m.length() == 3
 334     header_check_prefix = header_check_prefix + m[2]
 335   else
 336     header_check_prefix = header_check_prefix + '#include <sys/stat.h>'
 337   endif
 338   if cc.has_member('struct ' + m[0], m[1], prefix : header_check_prefix)
 339     define = 'HAVE_STRUCT_@0@_@1@'.format(m[0].to_upper(), m[1].underscorify().to_upper())
 340     glib_conf.set(define, 1)
 341     glib_conf_prefix = glib_conf_prefix + '#define @0@ 1\n'.format(define)
 342   else
 343   endif
 344 endforeach
 345
 346 # Compiler flags
 347 if cc.get_id() == 'gcc' or cc.get_id() == 'clang'
 348   warning_c_args = [
 349     '-Wall',
 350     '-Wduplicated-branches',
 351     '-Wimplicit-fallthrough',
 352     '-Wmisleading-indentation',
 353     '-Wstrict-prototypes',
 354     '-Wunused',
 355     # Due to pervasive use of things like GPOINTER_TO_UINT(), we do not support
 356     # building with -Wbad-function-cast.
 357     '-Wno-bad-function-cast',
 358     '-Werror=declaration-after-statement',
 359     '-Werror=format=2',
 360     '-Werror=implicit-function-declaration',
 361     '-Werror=init-self',
 362     '-Werror=missing-include-dirs',
 363     '-Werror=missing-prototypes',
 364     '-Werror=pointer-arith',
 365   ]
 366   warning_c_link_args = [
 367     '-Wl,-z,nodelete',
 368   ]
 369   if get_option('bsymbolic_functions')
 370     warning_c_link_args += ['-Wl,-Bsymbolic-functions']
 371   endif
 372 else
 373   warning_c_args = []
 374   warning_c_link_args = []
 375 endif
 376
 377 add_project_arguments(cc.get_supported_arguments(warning_c_args), language: 'c')
 378
 379 # FIXME: We cannot build some of the GResource tests with -z nodelete, which
 380 # means we cannot use that flag in add_project_link_arguments(), and must add
 381 # it to the relevant targets manually. We do the same with -Bsymbolic-functions
 382 # because that is what the autotools build did.
 383 # See https://github.com/mesonbuild/meson/pull/3520 for a way to eventually
 384 # improve this.
 385 glib_link_flags = cc.get_supported_link_arguments(warning_c_link_args)
 386
 387 # Windows Support (7+)
 388 if host_system == 'windows'
 389   glib_conf.set('_WIN32_WINNT', '0x0601')
 390 endif
 391
 392 functions = [
 393   'endmntent',
 394   'endservent',
 395   'fallocate',
 396   'fchmod',
 397   'fchown',
 398   'fdwalk',
 399   'fsync',
 400   'getauxval',
 401   'getc_unlocked',
 402   'getfsstat',
 403   'getgrgid_r',
 404   'getmntent_r',
 405   'getpwuid_r',
 406   'getresuid',
 407   'getvfsstat',
 408   'gmtime_r',
 409   'hasmntopt',
 410   'inotify_init1',
 411   'issetugid',
 412   'kevent',
 413   'kqueue',
 414   'lchmod',
 415   'lchown',
 416   'link',
 417   'localtime_r',
 418   'lstat',
 419   'mbrtowc',
 420   'memalign',
 421   'mmap',
 422   'newlocale',
 423   'pipe2',
 424   'poll',
 425   'prlimit',
 426   'readlink',
 427   'recvmmsg',
 428   'sendmmsg',
 429   'setenv',
 430   'setmntent',
 431   'strerror_r',
 432   'strnlen',
 433   'strsignal',
 434   'strtod_l',
 435   'strtoll_l',
 436   'strtoull_l',
 437   'symlink',
 438   'timegm',
 439   'unsetenv',
 440   'uselocale',
 441   'utimes',
 442   'valloc',
 443   'vasprintf',
 444   'vsnprintf',
 445   'wcrtomb',
 446   'wcslen',
 447   'wcsnlen',
 448   'sysctlbyname',
 449   '_NSGetEnviron',
 450 ]
 451
 452 if glib_conf.has('HAVE_SYS_STATVFS_H')
 453   functions += ['statvfs']
 454 else
 455   have_func_statvfs = false
 456 endif
 457 if glib_conf.has('HAVE_SYS_STATFS_H') or glib_conf.has('HAVE_SYS_MOUNT_H')
 458   functions += ['statfs']
 459 else
 460   have_func_statfs = false
 461 endif
 462
 463 if host_system == 'windows'
 464   iphlpapi_dep = cc.find_library('iphlpapi')
 465   iphlpapi_funcs = ['if_nametoindex', 'if_indextoname']
 466   foreach ifunc : iphlpapi_funcs
 467     iphl_prefix =  '''#define _WIN32_WINNT @0@
 468       #include <winsock2.h>
 469       #include <iphlpapi.h>'''.format(glib_conf.get('_WIN32_WINNT'))
 470     if cc.has_function(ifunc,
 471                        prefix : iphl_prefix,
 472                        dependencies : iphlpapi_dep)
 473       idefine = 'HAVE_' + ifunc.underscorify().to_upper()
 474       glib_conf.set(idefine, 1)
 475       glib_conf_prefix = glib_conf_prefix + '#define @0@ 1\n'.format(idefine)
 476       set_variable('have_func_' + ifunc, true)
 477     else
 478       set_variable('have_func_' + ifunc, false)
 479     endif
 480   endforeach
 481 else
 482   functions += ['if_indextoname', 'if_nametoindex']
 483 endif
 484
 485 # AIX splice is something else
 486 if host_system != 'aix'
 487   functions += ['splice']
 488 endif
 489
 490 foreach f : functions
 491   if cc.has_function(f)
 492     define = 'HAVE_' + f.underscorify().to_upper()
 493     glib_conf.set(define, 1)
 494     glib_conf_prefix = glib_conf_prefix + '#define @0@ 1\n'.format(define)
 495     set_variable('have_func_' + f, true)
 496   else
 497     set_variable('have_func_' + f, false)
 498   endif
 499 endforeach
 500
 501 # Check that stpcpy() is usable; must use header
 502 if cc.has_function('stpcpy', prefix : '#include <string.h>')
 503   glib_conf.set('HAVE_STPCPY', 1)
 504 endif
 505
 506 # Check that posix_memalign() is usable; must use header
 507 if cc.has_function('posix_memalign', prefix : '#include <stdlib.h>')
 508   glib_conf.set('HAVE_POSIX_MEMALIGN', 1)
 509 endif
 510
 511 # Check that posix_spawn() is usable; must use header
 512 if cc.has_function('posix_spawn', prefix : '#include <spawn.h>')
 513   glib_conf.set('HAVE_POSIX_SPAWN', 1)
 514 endif
 515
 516 # Check whether strerror_r returns char *
 517 if have_func_strerror_r
 518   if cc.compiles('''#define _GNU_SOURCE
 519                     #include <string.h>
 520                     int func (void) {
 521                       char error_string[256];
 522                       char *ptr = strerror_r (-2, error_string, 256);
 523                       char c = *strerror_r (-2, error_string, 256);
 524                       return c != 0 && ptr != (void*) 0L;
 525                     }
 526                  ''',
 527                  name : 'strerror_r() returns char *')
 528     glib_conf.set('STRERROR_R_CHAR_P', 1,
 529                   description: 'Defined if strerror_r returns char *')
 530   endif
 531 endif
 532
 533 # Special-case these functions that have alternative names on Windows/MSVC
 534 if cc.has_function('snprintf') or cc.has_header_symbol('stdio.h', 'snprintf')
 535   glib_conf.set('HAVE_SNPRINTF', 1)
 536   glib_conf_prefix = glib_conf_prefix + '#define HAVE_SNPRINTF 1\n'
 537 elif cc.has_function('_snprintf') or cc.has_header_symbol('stdio.h', '_snprintf')
 538   hack_define = '1\n#define snprintf _snprintf'
 539   glib_conf.set('HAVE_SNPRINTF', hack_define)
 540   glib_conf_prefix = glib_conf_prefix + '#define HAVE_SNPRINTF ' + hack_define
 541 endif
 542
 543 if cc.has_function('strcasecmp')
 544   glib_conf.set('HAVE_STRCASECMP', 1)
 545   glib_conf_prefix = glib_conf_prefix + '#define HAVE_STRCASECMP 1\n'
 546 elif cc.has_function('_stricmp')
 547   hack_define = '1\n#define strcasecmp _stricmp'
 548   glib_conf.set('HAVE_STRCASECMP', hack_define)
 549   glib_conf_prefix = glib_conf_prefix + '#define HAVE_STRCASECMP ' + hack_define
 550 endif
 551
 552 if cc.has_function('strncasecmp')
 553   glib_conf.set('HAVE_STRNCASECMP', 1)
 554   glib_conf_prefix = glib_conf_prefix + '#define HAVE_STRNCASECMP 1\n'
 555 elif cc.has_function('_strnicmp')
 556   hack_define = '1\n#define strncasecmp _strnicmp'
 557   glib_conf.set('HAVE_STRNCASECMP', hack_define)
 558   glib_conf_prefix = glib_conf_prefix + '#define HAVE_STRNCASECMP ' + hack_define
 559 endif
 560
 561 if cc.has_header_symbol('sys/sysmacros.h', 'major')
 562   glib_conf.set('MAJOR_IN_SYSMACROS', 1)
 563 elif cc.has_header_symbol('sys/mkdev.h', 'major')
 564   glib_conf.set('MAJOR_IN_MKDEV', 1)
 565 elif cc.has_header_symbol('sys/types.h', 'major')
 566   glib_conf.set('MAJOR_IN_TYPES', 1)
 567 endif
 568
 569 if cc.has_header_symbol('dlfcn.h', 'RTLD_LAZY')
 570   glib_conf.set('HAVE_RTLD_LAZY', 1)
 571 endif
 572
 573 if cc.has_header_symbol('dlfcn.h', 'RTLD_NOW')
 574   glib_conf.set('HAVE_RTLD_NOW', 1)
 575 endif
 576
 577 if cc.has_header_symbol('dlfcn.h', 'RTLD_GLOBAL')
 578   glib_conf.set('HAVE_RTLD_GLOBAL', 1)
 579 endif
 580
 581 # Check whether to use statfs or statvfs
 582 # Some systems have both statfs and statvfs, pick the most "native" for these
 583 if have_func_statfs and have_func_statvfs
 584   # on solaris and irix, statfs doesn't even have the f_bavail field
 585   if not glib_conf.has('HAVE_STRUCT_STATFS_F_BAVAIL')
 586     have_func_statfs = false
 587   else
 588     # at least on linux, statfs is the actual syscall
 589     have_func_statvfs = false
 590   endif
 591 endif
 592 if have_func_statfs
 593   glib_conf.set('USE_STATFS', 1)
 594   stat_func_to_use = 'statfs'
 595 elif have_func_statvfs
 596   glib_conf.set('USE_STATVFS', 1)
 597   stat_func_to_use = 'statvfs'
 598 else
 599   stat_func_to_use = 'neither'
 600 endif
 601 message('Checking whether to use statfs or statvfs .. ' + stat_func_to_use)
 602
 603 if host_system == 'linux'
 604   if cc.has_function('mkostemp',
 605                      prefix: '''#define _GNU_SOURCE
 606                                 #include <stdlib.h>''')
 607     glib_conf.set('HAVE_MKOSTEMP', 1)
 608   endif
 609 endif
 610
 611 osx_ldflags = []
 612 glib_have_os_x_9_or_later = false
 613 glib_have_carbon = false
 614 glib_have_cocoa = false
 615 if host_system == 'darwin'
 616   add_languages('objc')
 617   objcc = meson.get_compiler('objc')
 618
 619   osx_ldflags += ['-Wl,-framework,CoreFoundation']
 620
 621   # Mac OS X Carbon support
 622   glib_have_carbon = objcc.compiles('''#include <Carbon/Carbon.h>
 623                                        #include <CoreServices/CoreServices.h>''',
 624                                     name : 'Mac OS X Carbon support')
 625
 626   if glib_have_carbon
 627     glib_conf.set('HAVE_CARBON', true)
 628     osx_ldflags += '-Wl,-framework,Carbon'
 629     glib_have_os_x_9_or_later = objcc.compiles('''#include <AvailabilityMacros.h>
 630                                                   #if MAC_OS_X_VERSION_MIN_REQUIRED < 1090
 631                                                   #error Compiling for minimum OS X version before 10.9
 632                                                   #endif''',
 633                                                name : 'OS X 9 or later')
 634   endif
 635
 636   # Mac OS X Cocoa support
 637   glib_have_cocoa = objcc.compiles('''#include <Cocoa/Cocoa.h>
 638                                       #ifdef GNUSTEP_BASE_VERSION
 639                                       #error "Detected GNUstep, not Cocoa"
 640                                       #endif''',
 641                                    name : 'Mac OS X Cocoa support')
 642
 643   if glib_have_cocoa
 644     glib_conf.set('HAVE_COCOA', true)
 645     osx_ldflags += ['-Wl,-framework,Foundation', '-Wl,-framework,AppKit']
 646   endif
 647
 648   # FIXME: libgio mix C and objC source files and there is no way to reliably
 649   # know which language flags it's going to use to link. Add to both languages
 650   # for now. See https://github.com/mesonbuild/meson/issues/3585.
 651   add_project_link_arguments(osx_ldflags, language : ['objc', 'c'])
 652 endif
 653
 654 # Check for futex(2)
 655 if cc.links('''#include <linux/futex.h>
 656                #include <sys/syscall.h>
 657                #include <unistd.h>
 658                int main (int argc, char ** argv) {
 659                  syscall (__NR_futex, NULL, FUTEX_WAKE, FUTEX_WAIT);
 660                  return 0;
 661                }''', name : 'futex(2) system call')
 662   glib_conf.set('HAVE_FUTEX', 1)
 663 endif
 664
 665 # Check for eventfd(2)
 666 if cc.links('''#include <sys/eventfd.h>
 667                #include <unistd.h>
 668                int main (int argc, char ** argv) {
 669                  eventfd (0, EFD_CLOEXEC);
 670                  return 0;
 671                }''', name : 'eventfd(2) system call')
 672   glib_conf.set('HAVE_EVENTFD', 1)
 673 endif
 674
 675 clock_gettime_test_code = '''
 676   #include <time.h>
 677   struct timespec t;
 678   int main (int argc, char ** argv) {
 679     return clock_gettime(CLOCK_REALTIME, &t);
 680   }'''
 681 librt = []
 682 if cc.links(clock_gettime_test_code, name : 'clock_gettime')
 683   glib_conf.set('HAVE_CLOCK_GETTIME', 1)
 684 elif cc.links(clock_gettime_test_code, args : '-lrt', name : 'clock_gettime in librt')
 685   glib_conf.set('HAVE_CLOCK_GETTIME', 1)
 686   librt = cc.find_library('rt')
 687 endif
 688
 689 # if statfs() takes 2 arguments (Posix) or 4 (Solaris)
 690 if have_func_statfs
 691   if cc.compiles(glib_conf_prefix + '''
 692                  #include <unistd.h>
 693                         #ifdef HAVE_SYS_PARAM_H
 694                         #include <sys/param.h>
 695                         #endif
 696                         #ifdef HAVE_SYS_VFS_H
 697                         #include <sys/vfs.h>
 698                         #endif
 699                         #ifdef HAVE_SYS_MOUNT_H
 700                         #include <sys/mount.h>
 701                         #endif
 702                         #ifdef HAVE_SYS_STATFS_H
 703                         #include <sys/statfs.h>
 704                         #endif
 705                         void some_func (void) {
 706                           struct statfs st;
 707                           statfs("/", &st);
 708                         }''', name : 'number of arguments to statfs() (n=2)')
 709     glib_conf.set('STATFS_ARGS', 2)
 710   elif cc.compiles(glib_conf_prefix + '''
 711                    #include <unistd.h>
 712                           #ifdef HAVE_SYS_PARAM_H
 713                           #include <sys/param.h>
 714                           #endif
 715                           #ifdef HAVE_SYS_VFS_H
 716                           #include <sys/vfs.h>
 717                           #endif
 718                           #ifdef HAVE_SYS_MOUNT_H
 719                           #include <sys/mount.h>
 720                           #endif
 721                           #ifdef HAVE_SYS_STATFS_H
 722                           #include <sys/statfs.h>
 723                           #endif
 724                           void some_func (void) {
 725                             struct statfs st;
 726                             statfs("/", &st, sizeof (st), 0);
 727                           }''', name : 'number of arguments to statfs() (n=4)')
 728     glib_conf.set('STATFS_ARGS', 4)
 729   else
 730     error('Unable to determine number of arguments to statfs()')
 731   endif
 732 endif
 733
 734 # open takes O_DIRECTORY as an option
 735 #AC_MSG_CHECKING([])
 736 if cc.compiles('''#include <fcntl.h>
 737                   #include <sys/types.h>
 738                   #include <sys/stat.h>],
 739                   void some_func (void) {
 740                     open(0, O_DIRECTORY, 0);
 741                   }''', name : 'open() option O_DIRECTORY')
 742   glib_conf.set('HAVE_OPEN_O_DIRECTORY', 1)
 743 endif
 744
 745 # Check whether there is a vsnprintf() function with C99 semantics installed.
 746 # (similar tests to AC_FUNC_VSNPRINTF_C99)
 747 # Check whether there is a snprintf() function with C99 semantics installed.
 748 # (similar tests to AC_FUNC_SNPRINTF_C99)
 749 # Check whether there is a printf() function with Unix98 semantics installed.
 750 # (similar tests to AC_FUNC_PRINTF_UNIX98)
 751 have_good_vsnprintf = false
 752 have_good_snprintf = false
 753 have_good_printf = false
 754
 755 if host_system == 'windows' and cc.get_id() == 'msvc'
 756   # Unfortunately the Visual Studio 2015+ implementations of C99-style
 757   # snprintf and vsnprintf don't seem to be quite good enough.
 758   # (Sorry, I don't know exactly what is the problem,
 759   # but it is related to floating point formatting and decimal point vs. comma.)
 760   # The simple tests in AC_FUNC_VSNPRINTF_C99 and AC_FUNC_SNPRINTF_C99 aren't
 761   # rigorous enough to notice, though.
 762   glib_conf.set('HAVE_C99_SNPRINTF', false)
 763   glib_conf.set('HAVE_C99_VSNPRINTF', false)
 764   glib_conf.set('HAVE_UNIX98_PRINTF', false)
 765 else
 766   vsnprintf_c99_test_code = '''
 767 #include <stdio.h>
 768 #include <stdarg.h>
 769
 770 int
 771 doit(char * s, ...)
 772 {
 773   char buffer[32];
 774   va_list args;
 775   int r;
 776
 777   va_start(args, s);
 778   r = vsnprintf(buffer, 5, s, args);
 779   va_end(args);
 780
 781   if (r != 7)
 782     exit(1);
 783
 784   /* AIX 5.1 and Solaris seems to have a half-baked vsnprintf()
 785      implementation. The above will return 7 but if you replace
 786      the size of the buffer with 0, it borks! */
 787   va_start(args, s);
 788   r = vsnprintf(buffer, 0, s, args);
 789   va_end(args);
 790
 791   if (r != 7)
 792     exit(1);
 793
 794   exit(0);
 795 }
 796
 797 int
 798 main(void)
 799 {
 800   doit("1234567");
 801   exit(1);
 802 }'''
 803
 804   if cc_can_run
 805     rres = cc.run(vsnprintf_c99_test_code, name : 'C99 vsnprintf')
 806     if rres.compiled() and rres.returncode() == 0
 807       glib_conf.set('HAVE_C99_VSNPRINTF', 1)
 808       have_good_vsnprintf = true
 809     endif
 810   else
 811       have_good_vsnprintf = meson.get_cross_property('have_c99_vsnprintf', false)
 812       glib_conf.set('HAVE_C99_VSNPRINTF', have_good_vsnprintf)
 813   endif
 814
 815   snprintf_c99_test_code = '''
 816 #include <stdio.h>
 817 #include <stdarg.h>
 818
 819 int
 820 doit()
 821 {
 822   char buffer[32];
 823   va_list args;
 824   int r;
 825
 826   r = snprintf(buffer, 5, "1234567");
 827
 828   if (r != 7)
 829     exit(1);
 830
 831   r = snprintf(buffer, 0, "1234567");
 832
 833   if (r != 7)
 834     exit(1);
 835
 836   r = snprintf(NULL, 0, "1234567");
 837
 838   if (r != 7)
 839     exit(1);
 840
 841   exit(0);
 842 }
 843
 844 int
 845 main(void)
 846 {
 847   doit();
 848   exit(1);
 849 }'''
 850
 851   if cc_can_run
 852     rres = cc.run(snprintf_c99_test_code, name : 'C99 snprintf')
 853     if rres.compiled() and rres.returncode() == 0
 854       glib_conf.set('HAVE_C99_SNPRINTF', 1)
 855       have_good_snprintf = true
 856     endif
 857   else
 858       have_good_snprintf = meson.get_cross_property('have_c99_snprintf', false)
 859       glib_conf.set('HAVE_C99_SNPRINTF', have_good_snprintf)
 860   endif
 861
 862   printf_unix98_test_code = '''
 863 #include <stdio.h>
 864
 865 int
 866 main (void)
 867 {
 868   char buffer[128];
 869
 870   sprintf (buffer, "%2\$d %3\$d %1\$d", 1, 2, 3);
 871   if (strcmp ("2 3 1", buffer) == 0)
 872     exit (0);
 873   exit (1);
 874 }'''
 875
 876   if cc_can_run
 877     rres = cc.run(printf_unix98_test_code, name : 'Unix98 printf positional parameters')
 878     if rres.compiled() and rres.returncode() == 0
 879       glib_conf.set('HAVE_UNIX98_PRINTF', 1)
 880       have_good_printf = true
 881     endif
 882   else
 883       have_good_printf = meson.get_cross_property('have_unix98_printf', false)
 884       glib_conf.set('HAVE_UNIX98_PRINTF', have_good_printf)
 885   endif
 886 endif
 887
 888 if host_system == 'windows'
 889   glib_conf.set_quoted('EXEEXT', '.exe')
 890 else
 891   glib_conf.set('EXEEXT', '')
 892 endif
 893
 894 if have_good_vsnprintf and have_good_snprintf and have_good_printf
 895   # Our printf is 'good' only if vsnpintf()/snprintf()/printf() supports C99 well enough
 896   glib_conf.set('HAVE_GOOD_PRINTF', 1)
 897 else
 898   glib_conf.set('HAVE_VASPRINTF', 1)
 899 endif
 900
 901 glibconfig_conf.set('GLIB_USING_SYSTEM_PRINTF',
 902                     have_good_vsnprintf and have_good_snprintf and have_good_printf)
 903
 904 # Check whether the printf() family supports Unix98 %n$ positional parameters
 905 # AC_FUNC_PRINTF_UNIX98
 906 # Nothing uses HAVE_UNIX98_PRINTF
 907
 908
 909 # Check for nl_langinfo and CODESET
 910 if cc.links('''#include <langinfo.h>
 911                int main (int argc, char ** argv) {
 912                  char *codeset = nl_langinfo (CODESET);
 913                  return 0;
 914                }''', name : 'nl_langinfo and CODESET')
 915   glib_conf.set('HAVE_LANGINFO_CODESET', 1)
 916   glib_conf.set('HAVE_CODESET', 1)
 917 endif
 918
 919 # Check for nl_langinfo and LC_TIME parts that are needed in gdatetime.c
 920 if cc.links('''#include <langinfo.h>
 921                int main (int argc, char ** argv) {
 922                  char *str;
 923                  str = nl_langinfo (PM_STR);
 924                  str = nl_langinfo (D_T_FMT);
 925                  str = nl_langinfo (D_FMT);
 926                  str = nl_langinfo (T_FMT);
 927                  str = nl_langinfo (T_FMT_AMPM);
 928                  str = nl_langinfo (MON_1);
 929                  str = nl_langinfo (ABMON_12);
 930                  str = nl_langinfo (DAY_1);
 931                  str = nl_langinfo (ABDAY_7);
 932                  return 0;
 933                }''', name : 'nl_langinfo (PM_STR)')
 934   glib_conf.set('HAVE_LANGINFO_TIME', 1)
 935 endif
 936 if cc.links('''#include <langinfo.h>
 937                int main (int argc, char ** argv) {
 938                  char *str;
 939                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT0_MB);
 940                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT1_MB);
 941                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT2_MB);
 942                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT3_MB);
 943                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT4_MB);
 944                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT5_MB);
 945                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT6_MB);
 946                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT7_MB);
 947                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT8_MB);
 948                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT9_MB);
 949                  return 0;
 950                }''', name : 'nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)')
 951   glib_conf.set('HAVE_LANGINFO_OUTDIGIT', 1)
 952 endif
 953
 954 # Check for nl_langinfo and alternative month names
 955 if cc.links('''#ifndef _GNU_SOURCE
 956               # define _GNU_SOURCE
 957               #endif
 958               #include <langinfo.h>
 959                int main (int argc, char ** argv) {
 960                  char *str;
 961                  str = nl_langinfo (ALTMON_1);
 962                  str = nl_langinfo (ALTMON_2);
 963                  str = nl_langinfo (ALTMON_3);
 964                  str = nl_langinfo (ALTMON_4);
 965                  str = nl_langinfo (ALTMON_5);
 966                  str = nl_langinfo (ALTMON_6);
 967                  str = nl_langinfo (ALTMON_7);
 968                  str = nl_langinfo (ALTMON_8);
 969                  str = nl_langinfo (ALTMON_9);
 970                  str = nl_langinfo (ALTMON_10);
 971                  str = nl_langinfo (ALTMON_11);
 972                  str = nl_langinfo (ALTMON_12);
 973                  return 0;
 974                }''', name : 'nl_langinfo (ALTMON_n)')
 975   glib_conf.set('HAVE_LANGINFO_ALTMON', 1)
 976 endif
 977
 978 # Check for nl_langinfo and abbreviated alternative month names
 979 if cc.links('''#ifndef _GNU_SOURCE
 980               # define _GNU_SOURCE
 981               #endif
 982               #include <langinfo.h>
 983                int main (int argc, char ** argv) {
 984                  char *str;
 985                  str = nl_langinfo (_NL_ALTMON_1);
 986                  str = nl_langinfo (_NL_ALTMON_2);
 987                  str = nl_langinfo (_NL_ALTMON_3);
 988                  str = nl_langinfo (_NL_ALTMON_4);
 989                  str = nl_langinfo (_NL_ALTMON_5);
 990                  str = nl_langinfo (_NL_ALTMON_6);
 991                  str = nl_langinfo (_NL_ALTMON_7);
 992                  str = nl_langinfo (_NL_ALTMON_8);
 993                  str = nl_langinfo (_NL_ALTMON_9);
 994                  str = nl_langinfo (_NL_ALTMON_10);
 995                  str = nl_langinfo (_NL_ALTMON_11);
 996                  str = nl_langinfo (_NL_ALTMON_12);
 997                  return 0;
 998                }''', name : 'nl_langinfo (_NL_ALTMON_n)')
 999   glib_conf.set('HAVE_LANGINFO_ABALTMON', 1)
1000 endif
1001
1002 # Check if C compiler supports the 'signed' keyword
1003 if not cc.compiles('''signed char x;''', name : 'signed')
1004   glib_conf.set('signed', '/* NOOP */')
1005 endif
1006
1007 # Check if the ptrdiff_t type exists
1008 if cc.has_header_symbol('stddef.h', 'ptrdiff_t')
1009   glib_conf.set('HAVE_PTRDIFF_T', 1)
1010 endif
1011
1012 # Check for sig_atomic_t type
1013 if cc.links('''#include <signal.h>
1014                #include <sys/types.h>
1015                sig_atomic_t val = 42;
1016                int main (int argc, char ** argv) {
1017                  return val == 42 ? 0 : 1;
1018                }''', name : 'sig_atomic_t')
1019   glib_conf.set('HAVE_SIG_ATOMIC_T', 1)
1020 endif
1021
1022 # Check if 'long long' works
1023 # jm_AC_TYPE_LONG_LONG
1024 if cc.compiles('''long long ll = 1LL;
1025                   int i = 63;
1026                   int some_func (void) {
1027                     long long llmax = (long long) -1;
1028                     return ll << i | ll >> i | llmax / ll | llmax % ll;
1029                   }''', name : 'long long')
1030   glib_conf.set('HAVE_LONG_LONG', 1)
1031   have_long_long = true
1032 else
1033   have_long_long = false
1034 endif
1035
1036 # Test whether the compiler supports the 'long double' type.
1037 if cc.compiles('''/* The Stardent Vistra knows sizeof(long double), but does not support it.  */
1038                   long double foo = 0.0;
1039                   /* On Ultrix 4.3 cc, long double is 4 and double is 8.  */
1040                   int array [2*(sizeof(long double) >= sizeof(double)) - 1];''',
1041                name : 'long double')
1042   glib_conf.set('HAVE_LONG_DOUBLE', 1)
1043 endif
1044
1045 # Test whether <stddef.h> has the 'wchar_t' type.
1046 if cc.has_header_symbol('stddef.h', 'wchar_t')
1047   glib_conf.set('HAVE_WCHAR_T', 1)
1048 endif
1049
1050 # Test whether <wchar.h> has the 'wint_t' type.
1051 if cc.has_header_symbol('wchar.h', 'wint_t')
1052   glib_conf.set('HAVE_WINT_T', 1)
1053 endif
1054
1055 found_uintmax_t = false
1056
1057 # Define HAVE_INTTYPES_H_WITH_UINTMAX if <inttypes.h> exists,
1058 # doesn't clash with <sys/types.h>, and declares uintmax_t.
1059 # jm_AC_HEADER_INTTYPES_H
1060 if cc.compiles('''#include <sys/types.h>
1061                   #include <inttypes.h>
1062                   void some_func (void) {
1063                     uintmax_t i = (uintmax_t) -1;
1064                   }''', name : 'uintmax_t in inttypes.h')
1065   glib_conf.set('HAVE_INTTYPES_H_WITH_UINTMAX', 1)
1066   found_uintmax_t = true
1067 endif
1068
1069 # Define HAVE_STDINT_H_WITH_UINTMAX if <stdint.h> exists,
1070 # doesn't clash with <sys/types.h>, and declares uintmax_t.
1071 # jm_AC_HEADER_STDINT_H
1072 if cc.compiles('''#include <sys/types.h>
1073                   #include <stdint.h>
1074                   void some_func (void) {
1075                     uintmax_t i = (uintmax_t) -1;
1076                   }''', name : 'uintmax_t in stdint.h')
1077   glib_conf.set('HAVE_STDINT_H_WITH_UINTMAX', 1)
1078   found_uintmax_t = true
1079 endif
1080
1081 # Define intmax_t to 'long' or 'long long'
1082 # if it is not already defined in <stdint.h> or <inttypes.h>.
1083 # For simplicity, we assume that a header file defines 'intmax_t' if and
1084 # only if it defines 'uintmax_t'.
1085 if found_uintmax_t
1086   glib_conf.set('HAVE_INTMAX_T', 1)
1087 elif have_long_long
1088   glib_conf.set('intmax_t', 'long long')
1089 else
1090   glib_conf.set('intmax_t', 'long')
1091 endif
1092
1093 char_size = cc.sizeof('char')
1094 short_size = cc.sizeof('short')
1095 int_size = cc.sizeof('int')
1096 voidp_size = cc.sizeof('void*')
1097 long_size = cc.sizeof('long')
1098 if have_long_long
1099   long_long_size = cc.sizeof('long long')
1100 else
1101   long_long_size = 0
1102 endif
1103 sizet_size = cc.sizeof('size_t')
1104 if cc.get_id() == 'msvc'
1105   ssizet_size = cc.sizeof('SSIZE_T', prefix : '#include <BaseTsd.h>')
1106 else
1107   ssizet_size = cc.sizeof('ssize_t')
1108 endif
1109
1110 # Some platforms (Apple) hard-code int64_t to long long instead of
1111 # using long on 64-bit architectures. This can cause type mismatch
1112 # warnings when trying to interface with code using the standard
1113 # library type. Test for the warnings and set gint64 to whichever
1114 # works.
1115 if long_long_size == long_size
1116   if cc.compiles('''#if defined(_AIX) && !defined(__GNUC__)
1117                     #pragma options langlvl=stdc99
1118                     #endif
1119                     #pragma GCC diagnostic error "-Wincompatible-pointer-types"
1120                     #include <stdint.h>
1121                     #include <stdio.h>
1122                     int main () {
1123                       int64_t i1 = 1;
1124                       long *i2 = &i1;
1125                       return 1;
1126                     }''', name : 'int64_t is long')
1127     int64_t_typedef = 'long'
1128   elif cc.compiles('''#if defined(_AIX) && !defined(__GNUC__)
1129                       #pragma options langlvl=stdc99
1130                       #endif
1131                       #pragma GCC diagnostic error "-Wincompatible-pointer-types"
1132                       #include <stdint.h>
1133                       #include <stdio.h>
1134                       int main () {
1135                         int64_t i1 = 1;
1136                         long long *i2 = &i1;
1137                         return 1;
1138                       }''', name : 'int64_t is long long')
1139     int64_t_typedef = 'long long'
1140   endif
1141 endif
1142
1143 int64_m = 'll'
1144 char_align = cc.alignment('char')
1145 short_align = cc.alignment('short')
1146 int_align = cc.alignment('int')
1147 voidp_align = cc.alignment('void*')
1148 long_align = cc.alignment('long')
1149 long_long_align = cc.alignment('long long')
1150 # NOTE: We don't check for size of __int64 because long long is guaranteed to
1151 # be 64-bit in C99, and it is available on all supported compilers
1152 sizet_align = cc.alignment('size_t')
1153
1154 glib_conf.set('ALIGNOF_UNSIGNED_LONG', long_align)
1155
1156 glib_conf.set('SIZEOF_CHAR', char_size)
1157 glib_conf.set('SIZEOF_INT', int_size)
1158 glib_conf.set('SIZEOF_SHORT', short_size)
1159 glib_conf.set('SIZEOF_LONG', long_size)
1160 glib_conf.set('SIZEOF_LONG_LONG', long_long_size)
1161 glib_conf.set('SIZEOF_SIZE_T', sizet_size)
1162 glib_conf.set('SIZEOF_SSIZE_T', ssizet_size)
1163 glib_conf.set('SIZEOF_VOID_P', voidp_size)
1164
1165 if short_size == 2
1166   gint16 = 'short'
1167   gint16_modifier='h'
1168   gint16_format='hi'
1169   guint16_format='hu'
1170 elif int_size == 2
1171   gint16 = 'int'
1172   gint16_modifier=''
1173   gint16_format='i'
1174   guint16_format='u'
1175 else
1176   error('Compiler provides no native 16-bit integer type')
1177 endif
1178 glibconfig_conf.set('gint16', gint16)
1179 glibconfig_conf.set_quoted('gint16_modifier', gint16_modifier)
1180 glibconfig_conf.set_quoted('gint16_format', gint16_format)
1181 glibconfig_conf.set_quoted('guint16_format', guint16_format)
1182
1183 if short_size == 4
1184   gint32 = 'short'
1185   gint32_modifier='h'
1186   gint32_format='hi'
1187   guint32_format='hu'
1188   guint32_align = short_align
1189 elif int_size == 4
1190   gint32 = 'int'
1191   gint32_modifier=''
1192   gint32_format='i'
1193   guint32_format='u'
1194   guint32_align = int_align
1195 elif long_size == 4
1196   gint32 = 'long'
1197   gint32_modifier='l'
1198   gint32_format='li'
1199   guint32_format='lu'
1200   guint32_align = long_align
1201 else
1202   error('Compiler provides no native 32-bit integer type')
1203 endif
1204 glibconfig_conf.set('gint32', gint32)
1205 glibconfig_conf.set_quoted('gint32_modifier', gint32_modifier)
1206 glibconfig_conf.set_quoted('gint32_format', gint32_format)
1207 glibconfig_conf.set_quoted('guint32_format', guint32_format)
1208 glib_conf.set('ALIGNOF_GUINT32', guint32_align)
1209
1210 if int_size == 8
1211   gint64 = 'int'
1212   gint64_modifier=''
1213   gint64_format='i'
1214   guint64_format='u'
1215   glib_extension=''
1216   gint64_constant='(val)'
1217   guint64_constant='(val)'
1218   guint64_align = int_align
1219 elif long_size == 8 and (long_long_size != long_size or int64_t_typedef == 'long')
1220   gint64 = 'long'
1221   glib_extension=''
1222   gint64_modifier='l'
1223   gint64_format='li'
1224   guint64_format='lu'
1225   gint64_constant='(val##L)'
1226   guint64_constant='(val##UL)'
1227   guint64_align = long_align
1228 elif long_long_size == 8 and (long_long_size != long_size or int64_t_typedef == 'long long')
1229   gint64 = 'long long'
1230   glib_extension='G_GNUC_EXTENSION '
1231   gint64_modifier=int64_m
1232   gint64_format=int64_m + 'i'
1233   guint64_format=int64_m + 'u'
1234   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
1235   guint64_constant='(G_GNUC_EXTENSION (val##ULL))'
1236   guint64_align = long_long_align
1237 else
1238   error('Compiler provides no native 64-bit integer type')
1239 endif
1240 glibconfig_conf.set('glib_extension', glib_extension)
1241 glibconfig_conf.set('gint64', gint64)
1242 glibconfig_conf.set_quoted('gint64_modifier', gint64_modifier)
1243 glibconfig_conf.set_quoted('gint64_format', gint64_format)
1244 glibconfig_conf.set_quoted('guint64_format', guint64_format)
1245 glibconfig_conf.set('gint64_constant', gint64_constant)
1246 glibconfig_conf.set('guint64_constant', guint64_constant)
1247 glib_conf.set('ALIGNOF_GUINT64', guint64_align)
1248
1249 if host_system == 'windows'
1250   glibconfig_conf.set('g_pid_type', 'void*')
1251   glibconfig_conf.set_quoted('g_pid_format', 'p')
1252   if host_machine.cpu_family() == 'x86_64'
1253     glibconfig_conf.set_quoted('g_pollfd_format', '%#' + int64_m + 'x')
1254   else
1255     glibconfig_conf.set_quoted('g_pollfd_format', '%#x')
1256   endif
1257   glibconfig_conf.set('g_dir_separator', '\\\\')
1258   glibconfig_conf.set('g_searchpath_separator', ';')
1259 else
1260   glibconfig_conf.set('g_pid_type', 'int')
1261   glibconfig_conf.set_quoted('g_pid_format', 'i')
1262   glibconfig_conf.set_quoted('g_pollfd_format', '%d')
1263   glibconfig_conf.set('g_dir_separator', '/')
1264   glibconfig_conf.set('g_searchpath_separator', ':')
1265 endif
1266
1267 if sizet_size == short_size
1268   glibconfig_conf.set('glib_size_type_define', 'short')
1269   glibconfig_conf.set_quoted('gsize_modifier', 'h')
1270   glibconfig_conf.set_quoted('gssize_modifier', 'h')
1271   glibconfig_conf.set_quoted('gsize_format', 'hu')
1272   glibconfig_conf.set_quoted('gssize_format', 'hi')
1273   glibconfig_conf.set('glib_msize_type', 'SHRT')
1274 elif sizet_size == int_size
1275   glibconfig_conf.set('glib_size_type_define', 'int')
1276   glibconfig_conf.set_quoted('gsize_modifier', '')
1277   glibconfig_conf.set_quoted('gssize_modifier', '')
1278   glibconfig_conf.set_quoted('gsize_format', 'u')
1279   glibconfig_conf.set_quoted('gssize_format', 'i')
1280   glibconfig_conf.set('glib_msize_type', 'INT')
1281 elif sizet_size == long_size
1282   glibconfig_conf.set('glib_size_type_define', 'long')
1283   glibconfig_conf.set_quoted('gsize_modifier', 'l')
1284   glibconfig_conf.set_quoted('gssize_modifier', 'l')
1285   glibconfig_conf.set_quoted('gsize_format', 'lu')
1286   glibconfig_conf.set_quoted('gssize_format', 'li')
1287   glibconfig_conf.set('glib_msize_type', 'LONG')
1288 elif sizet_size == long_long_size
1289   glibconfig_conf.set('glib_size_type_define', 'long long')
1290   glibconfig_conf.set_quoted('gsize_modifier', int64_m)
1291   glibconfig_conf.set_quoted('gssize_modifier', int64_m)
1292   glibconfig_conf.set_quoted('gsize_format', int64_m + 'u')
1293   glibconfig_conf.set_quoted('gssize_format', int64_m + 'i')
1294   glibconfig_conf.set('glib_msize_type', 'INT64')
1295 else
1296   error('Could not determine size of size_t.')
1297 endif
1298
1299 if voidp_size == int_size
1300   glibconfig_conf.set('glib_intptr_type_define', 'int')
1301   glibconfig_conf.set_quoted('gintptr_modifier', '')
1302   glibconfig_conf.set_quoted('gintptr_format', 'i')
1303   glibconfig_conf.set_quoted('guintptr_format', 'u')
1304   glibconfig_conf.set('glib_gpi_cast', '(gint)')
1305   glibconfig_conf.set('glib_gpui_cast', '(guint)')
1306 elif voidp_size == long_size
1307   glibconfig_conf.set('glib_intptr_type_define', 'long')
1308   glibconfig_conf.set_quoted('gintptr_modifier', 'l')
1309   glibconfig_conf.set_quoted('gintptr_format', 'li')
1310   glibconfig_conf.set_quoted('guintptr_format', 'lu')
1311   glibconfig_conf.set('glib_gpi_cast', '(glong)')
1312   glibconfig_conf.set('glib_gpui_cast', '(gulong)')
1313 elif voidp_size == long_long_size
1314   glibconfig_conf.set('glib_intptr_type_define', 'long long')
1315   glibconfig_conf.set_quoted('gintptr_modifier', int64_m)
1316   glibconfig_conf.set_quoted('gintptr_format', int64_m + 'i')
1317   glibconfig_conf.set_quoted('guintptr_format', int64_m + 'u')
1318   glibconfig_conf.set('glib_gpi_cast', '(gint64)')
1319   glibconfig_conf.set('glib_gpui_cast', '(guint64)')
1320 else
1321   error('Could not determine size of void *')
1322 endif
1323
1324 if long_size != 8 and long_long_size != 8 and int_size != 8
1325   error('GLib requires a 64-bit type. You might want to consider using the GNU C compiler.')
1326 endif
1327
1328 glibconfig_conf.set('gintbits', int_size * 8)
1329 glibconfig_conf.set('glongbits', long_size * 8)
1330 glibconfig_conf.set('gsizebits', sizet_size * 8)
1331 glibconfig_conf.set('gssizebits', ssizet_size * 8)
1332
1333 # XXX: https://gitlab.gnome.org/GNOME/glib/issues/1413
1334 if host_system == 'windows'
1335   g_module_suffix = 'dll'
1336 else
1337   g_module_suffix = 'so'
1338 endif
1339 glibconfig_conf.set('g_module_suffix', g_module_suffix)
1340
1341 glibconfig_conf.set('GLIB_MAJOR_VERSION', major_version)
1342 glibconfig_conf.set('GLIB_MINOR_VERSION', minor_version)
1343 glibconfig_conf.set('GLIB_MICRO_VERSION', micro_version)
1344 glibconfig_conf.set('GLIB_VERSION', glib_version)
1345
1346 glibconfig_conf.set('glib_void_p', voidp_size)
1347 glibconfig_conf.set('glib_long', long_size)
1348 glibconfig_conf.set('glib_size_t', sizet_size)
1349 glibconfig_conf.set('glib_ssize_t', ssizet_size)
1350 if host_machine.endian() == 'big'
1351   glibconfig_conf.set('g_byte_order', 'G_BIG_ENDIAN')
1352   glibconfig_conf.set('g_bs_native', 'BE')
1353   glibconfig_conf.set('g_bs_alien', 'LE')
1354 else
1355   glibconfig_conf.set('g_byte_order', 'G_LITTLE_ENDIAN')
1356   glibconfig_conf.set('g_bs_native', 'LE')
1357   glibconfig_conf.set('g_bs_alien', 'BE')
1358 endif
1359
1360 # === va_copy checks ===
1361 # we currently check for all three va_copy possibilities, so we get
1362 # all results in config.log for bug reports.
1363
1364 va_copy_func = ''
1365 foreach try_func : [ '__va_copy', 'va_copy' ]
1366   if cc.compiles('''#include <stdarg.h>
1367                     #include <stdlib.h>
1368                     #ifdef _MSC_VER
1369                     # include "msvc_recommended_pragmas.h"
1370                     #endif
1371                     void f (int i, ...) {
1372                     va_list args1, args2;
1373                     va_start (args1, i);
1374                     @0@ (args2, args1);
1375                     if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1376                       exit (1);
1377                     va_end (args1); va_end (args2);
1378                     }
1379                     int main() {
1380                       f (0, 42);
1381                       return 0;
1382                     }'''.format(try_func),
1383                     name : try_func + ' check')
1384     va_copy_func = try_func
1385   endif
1386 endforeach
1387 if va_copy_func != ''
1388   glib_conf.set('G_VA_COPY', va_copy_func)
1389   glib_vacopy = '#define G_VA_COPY ' + va_copy_func
1390 else
1391   glib_vacopy = '/* #undef G_VA_COPY */'
1392 endif
1393
1394 va_list_val_copy_prog = '''
1395   #include <stdarg.h>
1396   #include <stdlib.h>
1397   void f (int i, ...) {
1398     va_list args1, args2;
1399     va_start (args1, i);
1400     args2 = args1;
1401     if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1402       exit (1);
1403     va_end (args1); va_end (args2);
1404   }
1405   int main() {
1406     f (0, 42);
1407     return 0;
1408   }'''
1409
1410 if cc_can_run
1411   rres = cc.run(va_list_val_copy_prog, name : 'va_lists can be copied as values')
1412   glib_va_val_copy = rres.returncode() == 0
1413 else
1414   glib_va_val_copy = meson.get_cross_property('va_val_copy', true)
1415 endif
1416 if not glib_va_val_copy
1417   glib_vacopy = glib_vacopy + '\n#define G_VA_COPY_AS_ARRAY 1'
1418   glib_conf.set('G_VA_COPY_AS_ARRAY', 1)
1419 endif
1420 glibconfig_conf.set('glib_vacopy', glib_vacopy)
1421
1422 # check for flavours of varargs macros
1423 g_have_iso_c_varargs = cc.compiles('''
1424   void some_func (void) {
1425     int a(int p1, int p2, int p3);
1426     #define call_a(...) a(1,__VA_ARGS__)
1427     call_a(2,3);
1428   }''', name : 'ISO C99 varargs macros in C')
1429
1430 if g_have_iso_c_varargs
1431   glibconfig_conf.set('g_have_iso_c_varargs', '''
1432 #ifndef __cplusplus
1433 # define G_HAVE_ISO_VARARGS 1
1434 #endif''')
1435 endif
1436
1437 g_have_iso_cxx_varargs = cxx.compiles('''
1438   void some_func (void) {
1439     int a(int p1, int p2, int p3);
1440     #define call_a(...) a(1,__VA_ARGS__)
1441     call_a(2,3);
1442   }''', name : 'ISO C99 varargs macros in C++')
1443
1444 if g_have_iso_cxx_varargs
1445   glibconfig_conf.set('g_have_iso_cxx_varargs', '''
1446 #ifdef __cplusplus
1447 # define G_HAVE_ISO_VARARGS 1
1448 #endif''')
1449 endif
1450
1451 g_have_gnuc_varargs = cc.compiles('''
1452   void some_func (void) {
1453     int a(int p1, int p2, int p3);
1454     #define call_a(params...) a(1,params)
1455     call_a(2,3);
1456   }''', name : 'GNUC varargs macros')
1457
1458 if cc.has_header('alloca.h')
1459   glibconfig_conf.set('GLIB_HAVE_ALLOCA_H', true)
1460 endif
1461 has_syspoll = cc.has_header('sys/poll.h')
1462 has_systypes = cc.has_header('sys/types.h')
1463 if has_syspoll
1464   glibconfig_conf.set('GLIB_HAVE_SYS_POLL_H', true)
1465 endif
1466 has_winsock2 = cc.has_header('winsock2.h')
1467
1468 if has_syspoll and has_systypes
1469   poll_includes = '''
1470       #include<sys/poll.h>
1471       #include<sys/types.h>'''
1472 elif has_winsock2
1473   poll_includes = '''
1474       #define _WIN32_WINNT @0@
1475       #include <winsock2.h>'''.format(glib_conf.get('_WIN32_WINNT'))
1476 else
1477   # FIXME?
1478   error('FIX POLL* defines')
1479 endif
1480
1481 poll_defines = [
1482   [ 'POLLIN', 'g_pollin', 1 ],
1483   [ 'POLLOUT', 'g_pollout', 4 ],
1484   [ 'POLLPRI', 'g_pollpri', 2 ],
1485   [ 'POLLERR', 'g_pollerr', 8 ],
1486   [ 'POLLHUP', 'g_pollhup', 16 ],
1487   [ 'POLLNVAL', 'g_pollnval', 32 ],
1488 ]
1489
1490 if has_syspoll and has_systypes
1491   foreach d : poll_defines
1492     val = cc.compute_int(d[0], prefix: poll_includes)
1493     glibconfig_conf.set(d[1], val)
1494   endforeach
1495 elif has_winsock2
1496   # Due to a missed bug in configure.ac the poll test
1497   # never succeeded on Windows and used some pre-defined
1498   # values as a fallback. Keep using them to maintain
1499   # ABI compatibility with autotools builds of glibs
1500   # and with *any* glib-using code compiled against them,
1501   # since these values end up in a public header glibconfig.h.
1502   foreach d : poll_defines
1503     glibconfig_conf.set(d[1], d[2])
1504   endforeach
1505 endif
1506
1507 # Internet address families
1508 # FIXME: what about Cygwin (G_WITH_CYGWIN)
1509 if host_system == 'windows'
1510   inet_includes = '''
1511       #include <winsock2.h>'''
1512 else
1513   inet_includes = '''
1514       #include <sys/types.h>
1515       #include <sys/socket.h>'''
1516 endif
1517
1518 inet_defines = [
1519   [ 'AF_UNIX', 'g_af_unix' ],
1520   [ 'AF_INET', 'g_af_inet' ],
1521   [ 'AF_INET6', 'g_af_inet6' ],
1522   [ 'MSG_OOB', 'g_msg_oob' ],
1523   [ 'MSG_PEEK', 'g_msg_peek' ],
1524   [ 'MSG_DONTROUTE', 'g_msg_dontroute' ],
1525 ]
1526 foreach d : inet_defines
1527   val = cc.compute_int(d[0], prefix: inet_includes)
1528   glibconfig_conf.set(d[1], val)
1529 endforeach
1530
1531 # We need a more robust approach here...
1532 host_cpu_family = host_machine.cpu_family()
1533 if host_cpu_family == 'x86' or host_cpu_family == 'x86_64' or host_cpu_family == 's390' or host_cpu_family == 's390x' or host_cpu_family.startswith('arm') or host_cpu_family == 'aarch64' or host_cpu_family.startswith('crisv32') or host_cpu_family.startswith('etrax')
1534   glib_memory_barrier_needed = false
1535 elif host_cpu_family.startswith('sparc') or host_cpu_family.startswith('alpha') or host_cpu_family.startswith('powerpc') or host_cpu_family == 'ia64'
1536   glib_memory_barrier_needed = true
1537 else
1538   warning('Unknown host cpu: ' + host_cpu_family)
1539   glib_memory_barrier_needed = true
1540 endif
1541 glibconfig_conf.set('G_ATOMIC_OP_MEMORY_BARRIER_NEEDED', glib_memory_barrier_needed)
1542
1543 # We need to decide at configure time if GLib will use real atomic
1544 # operations ("lock free") or emulated ones with a mutex.  This is
1545 # because we must put this information in glibconfig.h so we know if
1546 # it is safe or not to inline using compiler intrinsics directly from
1547 # the header.
1548 #
1549 # We also publish the information via G_ATOMIC_LOCK_FREE in case the
1550 # user is interested in knowing if they can use the atomic ops across
1551 # processes.
1552 #
1553 # We can currently support the atomic ops natively when building GLib
1554 # with recent versions of GCC or MSVC.
1555 #
1556 # Note that the atomic ops are only available with GCC on x86 when
1557 # using -march=i486 or higher.  If we detect that the atomic ops are
1558 # not available but would be available given the right flags, we want
1559 # to abort and advise the user to fix their CFLAGS.  It's better to do
1560 # that then to silently fall back on emulated atomic ops just because
1561 # the user had the wrong build environment.
1562 atomictest = '''int main() {
1563   volatile int atomic = 2;
1564   __sync_bool_compare_and_swap (&atomic, 2, 3);
1565   return 0;
1566 }
1567 '''
1568
1569 atomicdefine = '''
1570 #ifndef __GCC_HAVE_SYNC_COMPARE_AND_SWAP_4
1571 #error "compiler has atomic ops, but doesn't define __GCC_HAVE_SYNC_COMPARE_AND_SWAP_4"
1572 #endif
1573 '''
1574
1575 # We know that we can always use real ("lock free") atomic operations with MSVC
1576 if cc.get_id() == 'msvc' or cc.links(atomictest, name : 'atomic ops')
1577   have_atomic_lock_free = true
1578   if (host_system == 'android' or host_system == 'linux') and not cc.compiles(atomicdefine, name : 'atomic ops define')
1579     # When building for armv5 on Linux, gcc provides
1580     # __sync_bool_compare_and_swap but doesn't define
1581     # __GCC_HAVE_SYNC_COMPARE_AND_SWAP_4
1582     glib_conf.set('__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4', true)
1583   endif
1584 else
1585   have_atomic_lock_free = false
1586   if host_machine.cpu_family() == 'x86' and cc.links(atomictest, args : '-march=i486')
1587     error('GLib must be built with -march=i486 or later.')
1588   endif
1589 endif
1590 glibconfig_conf.set('G_ATOMIC_LOCK_FREE', have_atomic_lock_free)
1591
1592 # === Threads ===
1593
1594 # Determination of thread implementation
1595 if host_system == 'windows' and not get_option('force_posix_threads')
1596   thread_dep = []
1597   threads_implementation = 'win32'
1598   glibconfig_conf.set('g_threads_impl_def', 'WIN32')
1599   glib_conf.set('THREADS_WIN32', 1)
1600 else
1601   thread_dep = dependency('threads')
1602   threads_implementation = 'posix'
1603   pthread_prefix = '''
1604       #ifndef _GNU_SOURCE
1605       # define _GNU_SOURCE
1606       #endif
1607       #include <pthread.h>'''
1608   glibconfig_conf.set('g_threads_impl_def', 'POSIX')
1609   glib_conf.set('THREADS_POSIX', 1)
1610   if cc.has_header_symbol('pthread.h', 'pthread_attr_setstacksize')
1611     glib_conf.set('HAVE_PTHREAD_ATTR_SETSTACKSIZE', 1)
1612   endif
1613   if cc.has_header_symbol('pthread.h', 'pthread_condattr_setclock')
1614     glib_conf.set('HAVE_PTHREAD_CONDATTR_SETCLOCK', 1)
1615   endif
1616   if cc.has_header_symbol('pthread.h', 'pthread_cond_timedwait_relative_np')
1617     glib_conf.set('HAVE_PTHREAD_COND_TIMEDWAIT_RELATIVE_NP', 1)
1618   endif
1619   if cc.has_header_symbol('pthread.h', 'pthread_getname_np', prefix : pthread_prefix)
1620     glib_conf.set('HAVE_PTHREAD_GETNAME_NP', 1)
1621   endif
1622   # Assume that pthread_setname_np is available in some form; same as configure
1623   if cc.links(pthread_prefix + '''
1624               int main() {
1625                 pthread_setname_np("example");
1626                 return 0;
1627               }''',
1628               name : 'pthread_setname_np(const char*)',
1629               dependencies : thread_dep)
1630     # macOS and iOS
1631     glib_conf.set('HAVE_PTHREAD_SETNAME_NP_WITHOUT_TID', 1)
1632   elif cc.links(pthread_prefix + '''
1633                 int main() {
1634                   pthread_setname_np(pthread_self(), "example");
1635                   return 0;
1636                 }''',
1637                 name : 'pthread_setname_np(pthread_t, const char*)',
1638                 dependencies : thread_dep)
1639     # Linux, Solaris, etc.
1640     glib_conf.set('HAVE_PTHREAD_SETNAME_NP_WITH_TID', 1)
1641   endif
1642 endif
1643
1644 # FIXME: we should make it print the result and always return 0, so that
1645 # the output in meson shows up as green
1646 stack_grows_check_prog = '''
1647   volatile int *a = 0, *b = 0;
1648   void f (int i) {
1649     volatile int x = 5;
1650     if (i == 0)
1651       b = &x;
1652     else
1653       f (i - 1);
1654   }
1655   int main () {
1656     volatile int y = 7;
1657     a = &y;
1658     f (100);
1659     return b > a ? 0 : 1;
1660   }'''
1661
1662 if cc_can_run
1663   rres = cc.run(stack_grows_check_prog, name : 'stack grows check')
1664   growing_stack = rres.returncode() == 0
1665 else
1666   growing_stack = meson.get_cross_property('growing_stack', false)
1667 endif
1668
1669 glibconfig_conf.set10('G_HAVE_GROWING_STACK', growing_stack)
1670
1671 # Tests for iconv
1672 #
1673 # USE_LIBICONV_GNU: Using GNU libiconv
1674 # USE_LIBICONV_NATIVE: Using a native impl of iconv in a separate library
1675 #
1676 # We should never use the MinGW C library's iconv. On Windows we use the
1677 # GNU implementation that ships with MinGW.
1678
1679 # On Windows, just always use the built-in implementation
1680 if host_system == 'windows'
1681   libiconv = []
1682   glib_conf.set('USE_LIBICONV_NATIVE', true)
1683 else
1684   found_iconv = false
1685   iconv_opt = get_option('iconv')
1686   if iconv_opt == 'libc'
1687     if cc.has_function('iconv_open')
1688       libiconv = []
1689       found_iconv = true
1690     endif
1691   elif iconv_opt == 'gnu'
1692     if cc.has_header_symbol('iconv.h', 'libiconv_open')
1693       glib_conf.set('USE_LIBICONV_GNU', true)
1694       libiconv = [cc.find_library('iconv')]
1695       found_iconv = true
1696     endif
1697   elif iconv_opt == 'native'
1698     if cc.has_header_symbol('iconv.h', 'iconv_open')
1699       glib_conf.set('USE_LIBICONV_NATIVE', true)
1700       libiconv = [cc.find_library('iconv')]
1701       found_iconv = true
1702     endif
1703   endif
1704
1705   if not found_iconv
1706     error('iconv implementation "@0@" not found'.format(iconv_opt))
1707   endif
1708
1709 endif
1710
1711 if get_option('internal_pcre')
1712   pcre = []
1713   use_system_pcre = false
1714 else
1715   pcre = dependency('libpcre', version: '>= 8.31', required : false) # Should check for Unicode support, too. FIXME
1716   if not pcre.found()
1717     if cc.get_id() == 'msvc'
1718     # MSVC: Search for the PCRE library by the configuration, which corresponds
1719     # to the output of CMake builds of PCRE.  Note that debugoptimized
1720     # is really a Release build with .PDB files.
1721       if buildtype == 'debug'
1722         pcre = cc.find_library('pcred', required : false)
1723       else
1724         pcre = cc.find_library('pcre', required : false)
1725       endif
1726     endif
1727   endif
1728   use_system_pcre = pcre.found()
1729 endif
1730 glib_conf.set('USE_SYSTEM_PCRE', use_system_pcre)
1731
1732 use_pcre_static_flag = false
1733
1734 if host_system == 'windows'
1735   if not use_system_pcre
1736     use_pcre_static_flag = true
1737   else
1738     pcre_static = cc.links('''#define PCRE_STATIC
1739                               #include <pcre.h>
1740                               int main() {
1741                                 void *p = NULL;
1742                                 pcre_free(p);
1743                                 return 0;
1744                               }''',
1745                            dependencies: pcre,
1746                            name : 'Windows system PCRE is a static build')
1747     if pcre_static
1748       use_pcre_static_flag = true
1749     endif
1750   endif
1751 endif
1752
1753 libm = cc.find_library('m', required : false)
1754 libffi_dep = dependency('libffi', version : '>= 3.0.0', fallback : ['libffi', 'ffi_dep'])
1755
1756 # Don't use the bundled ZLib sources until we are sure that we can't find it on
1757 # the system
1758 libz_dep = dependency('zlib', required : false)
1759 if not libz_dep.found()
1760   if cc.get_id() != 'msvc'
1761     libz_dep = cc.find_library('z', required : false)
1762   else
1763     libz_dep = cc.find_library('zlib1', required : false)
1764     if not libz_dep.found()
1765       libz_dep = cc.find_library('zlib', required : false)
1766     endif
1767   endif
1768   if not libz_dep.found() or not cc.has_header('zlib.h')
1769     libz_dep = subproject('zlib').get_variable('zlib_dep')
1770   endif
1771 endif
1772
1773 # First check in libc, fallback to libintl, and as last chance build
1774 # proxy-libintl subproject.
1775 # FIXME: glib-gettext.m4 has much more checks to detect broken/uncompatible
1776 # implementations. This could be extended if issues are found in some platforms.
1777 if cc.has_function('ngettext')
1778   libintl = []
1779   have_bind_textdomain_codeset = cc.has_function('bind_textdomain_codeset')
1780 else
1781   libintl = cc.find_library('intl', required : false)
1782   if not libintl.found()
1783     libintl = subproject('proxy-libintl').get_variable('intl_dep')
1784     have_bind_textdomain_codeset = true  # proxy-libintl supports it
1785   else
1786     have_bind_textdomain_codeset = cc.has_function('bind_textdomain_codeset',
1787                                                    dependencies : libintl)
1788   endif
1789 endif
1790
1791 glib_conf.set('HAVE_BIND_TEXTDOMAIN_CODESET', have_bind_textdomain_codeset)
1792
1793 # We require gettext to always be present
1794 glib_conf.set('HAVE_DCGETTEXT', 1)
1795 glib_conf.set('HAVE_GETTEXT', 1)
1796
1797 glib_conf.set_quoted('GLIB_LOCALE_DIR', join_paths(glib_datadir, 'locale'))
1798
1799 # libmount is only used by gio, but we need to fetch the libs to generate the
1800 # pkg-config file below
1801 libmount_dep = []
1802 if host_system == 'linux' and get_option('libmount')
1803   libmount_dep = [dependency('mount', version : '>=2.23', required : true)]
1804   glib_conf.set('HAVE_LIBMOUNT', 1)
1805 endif
1806
1807 if host_system == 'windows'
1808   winsock2 = cc.find_library('ws2_32')
1809 endif
1810
1811 selinux_dep = []
1812 if host_system == 'linux'
1813   selinux_dep = dependency('libselinux', required: get_option('selinux'))
1814
1815   glib_conf.set('HAVE_SELINUX', selinux_dep.found())
1816 endif
1817
1818 xattr_dep = []
1819 if host_system != 'windows' and get_option('xattr')
1820   # either glibc or libattr can provide xattr support
1821   # for both of them, we check for getxattr being in
1822   # the library and a valid xattr header.
1823
1824   # try glibc
1825   if cc.has_function('getxattr') and cc.has_header('sys/xattr.h')
1826     glib_conf.set('HAVE_SYS_XATTR_H', 1)
1827     glib_conf_prefix = glib_conf_prefix + '#define @0@ 1\n'.format('HAVE_SYS_XATTR_H')
1828   #failure. try libattr
1829   elif cc.has_header_symbol('attr/xattr.h', 'getxattr')
1830     glib_conf.set('HAVE_ATTR_XATTR_H', 1)
1831     glib_conf_prefix = glib_conf_prefix + '#define @0@ 1\n'.format('HAVE_ATTR_XATTR_H')
1832     xattr_dep = [cc.find_library('xattr')]
1833   else
1834     error('No getxattr implementation found in C library or libxattr')
1835   endif
1836
1837   glib_conf.set('HAVE_XATTR', 1)
1838   if cc.compiles(glib_conf_prefix + '''
1839                  #include <stdio.h>
1840                  #ifdef HAVE_SYS_TYPES_H
1841                  #include <sys/types.h>
1842                  #endif
1843                  #ifdef HAVE_SYS_XATTR_H
1844                  #include <sys/xattr.h>
1845                  #elif HAVE_ATTR_XATTR_H
1846                  #include <attr/xattr.h>
1847                  #endif
1848
1849                  int main (void) {
1850                    ssize_t len = getxattr("", "", NULL, 0, 0, XATTR_NOFOLLOW);
1851                    return len;
1852                  }''',
1853                  name : 'XATTR_NOFOLLOW')
1854     glib_conf.set('HAVE_XATTR_NOFOLLOW', 1)
1855   endif
1856 endif
1857
1858 # Test if we have strlcpy/strlcat with a compatible implementation:
1859 # https://bugzilla.gnome.org/show_bug.cgi?id=53933
1860 if cc_can_run
1861   rres = cc.run('''#include <stdlib.h>
1862                    #include <string.h>
1863                    int main() {
1864                      char p[10];
1865                      (void) strlcpy (p, "hi", 10);
1866                      if (strlcat (p, "bye", 0) != 3)
1867                        return 1;
1868                      return 0;
1869                    }''',
1870                 name : 'OpenBSD strlcpy/strlcat')
1871   if rres.compiled() and rres.returncode() == 0
1872     glib_conf.set('HAVE_STRLCPY', 1)
1873   endif
1874 elif meson.get_cross_property('have_strlcpy', false)
1875   glib_conf.set('HAVE_STRLCPY', 1)
1876 endif
1877
1878 python = import('python').find_installation('python3')
1879 # used for '#!/usr/bin/env <name>'
1880 python_name = 'python3'
1881
1882 python_version = python.language_version()
1883 python_version_req = '>=3.4'
1884 if not python_version.version_compare(python_version_req)
1885   error('Requires Python @0@, @1@ found.'.format(python_version_req, python_version))
1886 endif
1887
1888 # Determine which user environment-dependent files that we want to install
1889 have_bash = find_program('bash', required : false).found() # For completion scripts
1890 have_sh = find_program('sh', required : false).found() # For glib-gettextize
1891
1892 # FIXME: How to detect Solaris? https://github.com/mesonbuild/meson/issues/1578
1893 if host_system == 'sunos'
1894   glib_conf.set('_XOPEN_SOURCE_EXTENDED', 1)
1895   glib_conf.set('_XOPEN_SOURCE', 2)
1896   glib_conf.set('__EXTENSIONS__',1)
1897 endif
1898
1899 # Sadly Meson does not expose this value:
1900 # https://github.com/mesonbuild/meson/pull/3460
1901 if host_system == 'windows'
1902   # Autotools explicitly removed --Wl,--export-all-symbols from windows builds,
1903   # with no explanation. Do the same here for now but this could be revisited if
1904   # if causes issues.
1905   export_dynamic_ldflags = []
1906 elif host_system == 'cygwin'
1907   export_dynamic_ldflags = ['-Wl,--export-all-symbols']
1908 elif host_system == 'darwin'
1909   export_dynamic_ldflags = []
1910 else
1911   export_dynamic_ldflags = ['-Wl,--export-dynamic']
1912 endif
1913
1914 win32_cflags = []
1915 win32_ldflags = []
1916 if host_system == 'windows' and cc.get_id() != 'msvc'
1917   # Ensure MSVC-compatible struct packing convention is used when
1918   # compiling for Win32 with gcc. It is used for the whole project and exposed
1919   # in glib-2.0.pc.
1920   win32_cflags = ['-mms-bitfields']
1921   add_project_arguments(win32_cflags, language : 'c')
1922
1923   # Win32 API libs, used only by libglib and exposed in glib-2.0.pc
1924   win32_ldflags = ['-lws2_32', '-lole32', '-lwinmm', '-lshlwapi']
1925 elif host_system == 'cygwin'
1926   win32_ldflags = ['-luser32', '-lkernel32']
1927 endif
1928
1929 # Tracing: dtrace
1930 want_dtrace = get_option('dtrace')
1931 enable_dtrace = false
1932
1933 # Since dtrace support is opt-in we just error out if it was requested but
1934 # is not available. We don't bother with autodetection yet.
1935 if want_dtrace
1936   if glib_have_carbon
1937     error('GLib dtrace support not yet compatible with macOS dtrace')
1938   endif
1939   dtrace = find_program('dtrace', required : true) # error out if not found
1940   if not cc.has_header('sys/sdt.h')
1941     error('dtrace support needs sys/sdt.h header')
1942   endif
1943   # FIXME: autotools build also passes -fPIC -DPIC but is it needed in this case?
1944   dtrace_obj_gen = generator(dtrace,
1945     output : '@BASENAME@.o',
1946     arguments : ['-G', '-s', '@INPUT@', '-o', '@OUTPUT@'])
1947   # FIXME: $(SED) -e "s,define STAP_HAS_SEMAPHORES 1,undef STAP_HAS_SEMAPHORES,"
1948   #               -e "s,define _SDT_HAS_SEMAPHORES 1,undef _SDT_HAS_SEMAPHORES,"
1949   dtrace_hdr_gen = generator(dtrace,
1950     output : '@BASENAME@.h',
1951     arguments : ['-h', '-s', '@INPUT@', '-o', '@OUTPUT@'])
1952   glib_conf.set('HAVE_DTRACE', 1)
1953   enable_dtrace = true
1954 endif
1955
1956 # systemtap
1957 want_systemtap = get_option('systemtap')
1958 enable_systemtap = false
1959
1960 if want_systemtap and enable_dtrace
1961   tapset_install_dir = get_option('tapset_install_dir')
1962   if tapset_install_dir == ''
1963     tapset_install_dir = join_paths(get_option('datadir'), 'systemtap/tapset', host_machine.cpu_family())
1964   endif
1965   stp_cdata = configuration_data()
1966   stp_cdata.set('ABS_GLIB_RUNTIME_LIBDIR', glib_libdir)
1967   stp_cdata.set('LT_CURRENT', minor_version * 100)
1968   stp_cdata.set('LT_REVISION', micro_version)
1969   enable_systemtap = true
1970 endif
1971
1972 test_timeout = 60
1973 test_timeout_slow = 120
1974
1975 pkg = import('pkgconfig')
1976 windows = import('windows')
1977 subdir('glib')
1978 subdir('gobject')
1979 subdir('gthread')
1980 subdir('gmodule')
1981 subdir('gio')
1982 subdir('fuzzing')
1983 subdir('tests')
1984
1985 # xgettext is optional (on Windows for instance)
1986 if find_program('xgettext', required : get_option('nls')).found()
1987   subdir('po')
1988 endif
1989
1990 # Install glib-gettextize executable, if a UNIX-style shell is found
1991 if have_sh
1992   # These should not contain " quotes around the values
1993   gettextize_conf = configuration_data()
1994   gettextize_conf.set('PACKAGE', 'glib')
1995   gettextize_conf.set('VERSION', meson.project_version())
1996   gettextize_conf.set('prefix', glib_prefix)
1997   gettextize_conf.set('datarootdir', glib_datadir)
1998   gettextize_conf.set('datadir', glib_datadir)
1999   configure_file(input : 'glib-gettextize.in',
2000     install : true,
2001     install_dir : glib_bindir,
2002     output : 'glib-gettextize',
2003     configuration : gettextize_conf)
2004 endif
2005
2006 # Install m4 macros that other projects use
2007 install_data('m4macros/glib-2.0.m4', 'm4macros/glib-gettext.m4', 'm4macros/gsettings.m4',
2008   install_dir : join_paths(get_option('datadir'), 'aclocal'))
2009
2010 if host_system != 'windows'
2011   # Install Valgrind suppression file (except on Windows,
2012   # as Valgrind is currently not supported on Windows)
2013   install_data('glib.supp',
2014     install_dir : join_paths(get_option('datadir'), 'glib-2.0', 'valgrind'))
2015 endif
2016
2017 configure_file(output : 'config.h', configuration : glib_conf)
2018
2019 if host_system == 'windows'
2020   install_headers([ 'msvc_recommended_pragmas.h' ], subdir : 'glib-2.0')
2021 endif
2022
2023 if get_option('man')
2024   xsltproc = find_program('xsltproc', required : true)
2025   xsltproc_command = [
2026     xsltproc,
2027     '--nonet',
2028     '--stringparam', 'man.output.quietly', '1',
2029     '--stringparam', 'funcsynopsis.style', 'ansi',
2030     '--stringparam', 'man.th.extra1.suppress', '1',
2031     '--stringparam', 'man.authors.section.enabled', '0',
2032     '--stringparam', 'man.copyright.section.enabled', '0',
2033     '-o', '@OUTPUT@',
2034     'http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl',
2035     '@INPUT@',
2036   ]
2037   man1_dir = get_option('mandir') + '/man1'
2038 endif
2039
2040 gnome = import('gnome')
2041 subdir('docs/reference/glib')
2042 subdir('docs/reference/gobject')
2043 subdir('docs/reference/gio')