meson.build

   1 project('pulseaudio', 'c', 'cpp',
   2         version : run_command(find_program('git-version-gen'), join_paths(meson.current_source_dir(), '.tarball-version')).stdout().strip(),
   3         meson_version : '>= 0.50.0',
   4         default_options : [ 'c_std=gnu11', 'cpp_std=c++11' ]
   5         )
   6
   7 pa_version_str = meson.project_version()
   8 # For tarballs, the first split will do nothing, but for builds in git, we
   9 # split out suffixes when there are commits since the last tag
  10 # (e.g.: v11.99.1-3-gad14bdb24 -> v11.99.1)
  11 version_split = pa_version_str.split('-')[0].split('.')
  12 pa_version_major = version_split[0].split('v')[0]
  13 pa_version_minor = version_split[1]
  14 if version_split.length() > 2
  15   pa_version_micro = version_split[2]
  16 else
  17   pa_version_micro = '0'
  18 endif
  19 pa_version_major_minor = pa_version_major + '.' + pa_version_minor
  20
  21 pa_api_version = 12
  22 pa_protocol_version = 33
  23
  24 apiversion = '1.0'
  25 soversion = 0
  26 # FIXME: this doesn't actually do what we want it to
  27 # maintaining compatibility with the previous libtool versioning
  28 # current = minor * 100 + micro
  29 libversion = '@0@.@1@.0'.format(soversion, pa_version_minor.to_int() * 100 + pa_version_micro.to_int())
  30
  31 # A simplified, synchronous, ABI-stable interface for client applications.
  32 # For the version x:y:z always will hold y=z.
  33 libpulse_simple_version = '1.1.1'
  34
  35 # The ABI-stable GLib adapter for client applications.
  36 # For the version x:y:z always will hold y=z.
  37 libpulse_mainloop_glib_version = '0.5.0'
  38
  39 # Paths
  40
  41 prefix = get_option('prefix')
  42 assert(prefix.startswith('/'), 'Prefix is not absolute: "@0@"'.format(prefix))
  43
  44 bindir = join_paths(prefix, get_option('bindir'))
  45 includedir = join_paths(prefix, get_option('includedir'))
  46 libdir = join_paths(prefix, get_option('libdir'))
  47 libexecdir = join_paths(prefix, get_option('libexecdir'))
  48 mandir = join_paths(prefix, get_option('mandir'))
  49 datadir = join_paths(prefix, get_option('datadir'))
  50 localstatedir = join_paths(prefix, get_option('localstatedir'))
  51 sysconfdir = join_paths(prefix, get_option('sysconfdir'))
  52 privlibdir = join_paths(get_option('libdir'), 'pulseaudio')
  53 alsadatadir = join_paths(datadir, 'pulseaudio', 'alsa-mixer')
  54
  55 pkgconfigdir = join_paths(libdir, 'pkgconfig')
  56 pulselibexecdir = join_paths(libexecdir, 'pulse')
  57 pulsesysconfdir = join_paths(sysconfdir, 'pulse')
  58
  59 modlibexecdir = get_option('modlibexecdir')
  60 if modlibexecdir == ''
  61   modlibexecdir = join_paths(libdir, 'pulse-' + pa_version_major_minor, 'modules')
  62 endif
  63
  64 pulsedspdir = get_option('pulsedspdir')
  65 if pulsedspdir == ''
  66   pulsedspdir = join_paths(libdir, 'pulseaudio')
  67 endif
  68
  69 systemduserunitdir = get_option('systemduserunitdir')
  70 # the default value is set below
  71
  72 udevrulesdir = get_option('udevrulesdir')
  73 if udevrulesdir == ''
  74   # absolute path, otherwise meson prepends the prefix
  75   udevrulesdir = '/lib/udev/rules.d'
  76 endif
  77
  78 vapidir = join_paths(datadir, 'vala', 'vapi')
  79
  80 bashcompletiondir = get_option('bashcompletiondir')
  81 if bashcompletiondir == ''
  82   bash_completion_dep = dependency('bash-completion', required : false)
  83   if bash_completion_dep.found()
  84     bashcompletiondir = bash_completion_dep.get_pkgconfig_variable('completionsdir')
  85   else
  86     bashcompletiondir = join_paths(datadir, 'bash-completion', 'completions')
  87   endif
  88 endif
  89
  90 zshcompletiondir = get_option('zshcompletiondir')
  91 if zshcompletiondir == ''
  92   zshcompletiondir = join_paths(datadir, 'zsh', 'site-functions')
  93 endif
  94
  95 # Configuration data
  96
  97 cc = meson.get_compiler('c')
  98
  99 cdata = configuration_data()
 100 cdata.set_quoted('PACKAGE', 'pulseaudio')
 101 cdata.set_quoted('PACKAGE_NAME', 'pulseaudio')
 102 cdata.set_quoted('PACKAGE_VERSION', pa_version_str)
 103 cdata.set_quoted('CANONICAL_HOST', host_machine.cpu())
 104 cdata.set('PA_MAJOR', pa_version_major)
 105 cdata.set('PA_MINOR', pa_version_minor)
 106 cdata.set('PA_API_VERSION', pa_api_version)
 107 cdata.set('PA_PROTOCOL_VERSION', pa_protocol_version)
 108 cdata.set_quoted('PA_MACHINE_ID', join_paths(sysconfdir, 'machine-id'))
 109 cdata.set_quoted('PA_MACHINE_ID_FALLBACK', join_paths(localstatedir, 'lib', 'dbus', 'machine-id'))
 110 cdata.set_quoted('PA_SRCDIR', join_paths(meson.current_source_dir(), 'src'))
 111 cdata.set_quoted('PA_BUILDDIR', meson.current_build_dir())
 112 cdata.set_quoted('PA_SOEXT', '.so')
 113 cdata.set_quoted('PA_DEFAULT_CONFIG_DIR', pulsesysconfdir)
 114 cdata.set_quoted('PA_BINARY', join_paths(bindir, 'pulseaudio'))
 115 cdata.set_quoted('PA_SYSTEM_RUNTIME_PATH', join_paths(localstatedir, 'run', 'pulse'))
 116 cdata.set_quoted('PA_SYSTEM_CONFIG_PATH', join_paths(localstatedir, 'lib', 'pulse'))
 117 cdata.set_quoted('PA_SYSTEM_STATE_PATH', join_paths(localstatedir, 'lib', 'pulse'))
 118 cdata.set_quoted('PA_DLSEARCHPATH', modlibexecdir)
 119 cdata.set_quoted('PA_SYSTEM_USER', get_option('system_user'))
 120 cdata.set_quoted('PA_SYSTEM_GROUP', get_option('system_group'))
 121 cdata.set_quoted('PA_ACCESS_GROUP', get_option('access_group'))
 122 cdata.set_quoted('PA_CFLAGS', 'Not yet supported on meson')
 123 cdata.set_quoted('PA_ALSA_PATHS_DIR', join_paths(alsadatadir, 'paths'))
 124 cdata.set_quoted('PA_ALSA_PROFILE_SETS_DIR', join_paths(alsadatadir, 'profile-sets'))
 125 cdata.set_quoted('DESKTOPFILEDIR', join_paths(datadir, 'applications'))
 126
 127 # Platform specifics
 128 # First some defaults to keep config file generation happy
 129 cdata.set('HAVE_COREAUDIO', 0)
 130 cdata.set('HAVE_WAVEOUT', 0)
 131 # FIXME: This was not tested. Maybe some flags should better be CFLAGS,
 132 # rather than ending up in the config.h file?
 133 if host_machine.system() == 'darwin'
 134   cdata.set('OS_IS_DARWIN', 1)
 135   cdata.set('_DARWIN_C_SOURCE', '200112L') # Needed to get NSIG on Mac OS
 136 elif host_machine.system() == 'windows'
 137   cdata.set('OS_IS_WIN32', 1)
 138   cdata.set('WIN32_LEAN_AND_MEAN', 1) # Needed to avoid including unnecessary headers on Windows
 139 #elif host_machine.system() == 'solaris'
 140 #  # Apparently meson has no solaris support?
 141 #  # Needed to get declarations for msg_control and msg_controllen on Solaris
 142 #  cdata.set('_XOPEN_SOURCE', 600)
 143 #  cdata.set('__EXTENSIONS__', 1)
 144 endif
 145
 146 # Headers
 147
 148 check_headers = [
 149   'arpa/inet.h',
 150   'cpuid.h',
 151   'execinfo.h',
 152   'grp.h',
 153   'langinfo.h',
 154   'locale.h',
 155   'netdb.h',
 156   'netinet/in.h',
 157   'netinet/in_systm.h',
 158   'netinet/ip.h',
 159   'netinet/tcp.h',
 160   'pcreposix.h',
 161   'poll.h',
 162   'pwd.h',
 163   'regex.h',
 164   'sched.h',
 165   'sys/capability.h',
 166   'sys/eventfd.h',
 167   'sys/ioctl.h',
 168   'sys/filio.h',
 169   'sys/mman.h',
 170   'sys/prctl.h',
 171   'sys/resource.h',
 172   'sys/select.h',
 173   'sys/socket.h',
 174   'sys/un.h',
 175   'sys/wait.h',
 176   'valgrind/memcheck.h',
 177   'xlocale.h',
 178 ]
 179
 180 foreach h : check_headers
 181   if cc.has_header(h)
 182     define = 'HAVE_' + h.underscorify().to_upper()
 183     cdata.set(define, 1)
 184   endif
 185 endforeach
 186
 187 # FIXME: move this to the above set
 188 if cc.has_header('pthread.h')
 189   cdata.set('HAVE_PTHREAD', 1)
 190 endif
 191
 192 # Functions
 193
 194 check_functions = [
 195   'accept4',
 196   'clock_gettime',
 197   'fchmod',
 198   'fchown',
 199   'fork',
 200   'fstat',
 201   'getaddrinfo',
 202   'getgrgid_r',
 203   'getpwnam_r',
 204   'gettimeofday',
 205   'getuid',
 206   'lstat',
 207   'memfd_create',
 208   'mkfifo',
 209   'mlock',
 210   'nanosleep',
 211   'paccept',
 212   'pipe',
 213   'pipe2',
 214   'posix_madvise',
 215   'readlink',
 216   'setegid',
 217   'seteuid',
 218   'setregid',
 219   'setreuid',
 220   'setresgid',
 221   'setresuid',
 222   'setsid',
 223   'sig2str',
 224   'sigaction',
 225   'strtod_l',
 226   'symlink',
 227   'sysconf',
 228   'uname',
 229 ]
 230
 231 foreach f : check_functions
 232   if cc.has_function(f)
 233     define = 'HAVE_' + f.underscorify().to_upper()
 234     cdata.set(define, 1)
 235   endif
 236 endforeach
 237
 238 if cc.has_function('SYS_memfd_create', prefix : '#include <sys/syscall.h>')
 239   cdata.set('HAVE_MEMFD', 1)
 240 endif
 241
 242 # Symbols
 243
 244 if cc.has_header_symbol('signal.h', 'SIGXCPU')
 245   cdata.set('HAVE_SIGXCPU', 1)
 246 endif
 247
 248 if not cc.has_header_symbol('netinet/in.h', 'INADDR_NONE')
 249   if not cc.has_header_symbol('winsock2.h', 'INADDR_NONE')
 250     # Define INADDR_NONE if not found (Solaris)
 251     cdata.set('INADDR_NONE', '0xffffffff')
 252   endif
 253 endif
 254
 255 # Types
 256
 257 # FIXME: do we ever care about gid_t not being defined / smaller than an int?
 258 cdata.set('GETGROUPS_T', 'gid_t')
 259
 260 # Include paths
 261
 262 configinc = include_directories('.')
 263 topinc = include_directories('src')
 264
 265 # CFLAGS
 266
 267 pa_c_args = ['-DHAVE_CONFIG_H', '-D_GNU_SOURCE']
 268 server_c_args = ['-D__INCLUDED_FROM_PULSE_AUDIO']
 269 cdata.set('MESON_BUILD', 1)
 270
 271 # Code coverage
 272
 273 if get_option('gcov')
 274   add_project_arguments('--coverage', language: ['c', 'cpp'])
 275   add_project_link_arguments('--coverage', language: ['c', 'cpp'])
 276 endif
 277
 278 # Core Dependencies
 279
 280 libm_dep = cc.find_library('m', required : true)
 281 thread_dep = dependency('threads')
 282 cap_dep = cc.find_library('cap', required : false)
 283
 284 shm_dep = cc.find_library('rt', required : false)
 285 if shm_dep.found()
 286   cdata.set('HAVE_SHM_OPEN', 1)
 287 endif
 288
 289
 290 atomictest = '''void func() {
 291   volatile int atomic = 2;
 292   __sync_bool_compare_and_swap (&atomic, 2, 3);
 293 }
 294 '''
 295 if cc.compiles(atomictest)
 296   newatomictest = '''void func() {
 297     int c = 0;
 298     __atomic_store_n(&c, 4, __ATOMIC_SEQ_CST);
 299   }
 300   '''
 301
 302   if(cc.compiles(newatomictest))
 303     cdata.set('HAVE_ATOMIC_BUILTINS_MEMORY_MODEL', true)
 304   endif
 305
 306   cdata.set('HAVE_ATOMIC_BUILTINS', true)
 307 else
 308   # FIXME: check if we need libatomic_ops
 309 endif
 310
 311 # FIXME: make sure it's >= 2.2
 312 ltdl_dep = cc.find_library('ltdl', required : true)
 313 # FIXME: can meson support libtool -dlopen/-dlpreopen things?
 314 #        and do we still want to support this at all?
 315 cdata.set('DISABLE_LIBTOOL_PRELOAD', 1)
 316
 317 if get_option('database') == 'tdb'
 318   database_dep = dependency('tdb')
 319 elif get_option('database') == 'gdbm'
 320   database_dep = cc.find_library('gdbm', required : true)
 321 else
 322   database_dep = dependency('', required: false)
 323 endif
 324
 325 if get_option('ipv6')
 326   cdata.set('HAVE_IPV6', 1)
 327 endif
 328
 329 if get_option('legacy-database-entry-format')
 330   cdata.set('ENABLE_LEGACY_DATABASE_ENTRY_FORMAT', 1)
 331 endif
 332
 333 if get_option('running-from-build-tree')
 334   cdata.set('HAVE_RUNNING_FROM_BUILD_TREE', 1)
 335 endif
 336
 337 alsa_dep = dependency('alsa', version : '>= 1.0.24', required : get_option('alsa'))
 338 if alsa_dep.found()
 339   cdata.set('HAVE_ALSA', 1)
 340   cdata.set('HAVE_ALSA_UCM', 1)
 341 endif
 342
 343 asyncns_dep = dependency('libasyncns', version : '>= 0.1', required : get_option('asyncns'))
 344 if asyncns_dep.found()
 345   cdata.set('HAVE_LIBASYNCNS', 1)
 346 endif
 347
 348 dbus_dep = dependency('dbus-1', version : '>= 1.4.12', required : get_option('dbus'))
 349 if dbus_dep.found()
 350   cdata.set('HAVE_DBUS', 1)
 351 endif
 352
 353 gio_dep = dependency('gio-2.0', version : '>= 2.26.0', required : get_option('gsettings'))
 354 if gio_dep.found()
 355   cdata.set('HAVE_GSETTINGS', 1)
 356 endif
 357
 358 glib_dep = dependency('glib-2.0', version : '>= 2.4.0', required: get_option('glib'))
 359 if glib_dep.found()
 360   cdata.set('HAVE_GLIB', 1)
 361 endif
 362
 363 gtk_dep = dependency('gtk+-3.0', required : get_option('gtk'))
 364 if gtk_dep.found()
 365   cdata.set('HAVE_GTK', 1)
 366 endif
 367
 368 have_orcc = false
 369 orcc_args = []
 370 orc_dep = dependency('orc-0.4', version : '>= 0.4.11', required : get_option('orc'))
 371 orcc = find_program('orcc', required : get_option('orc'))
 372 if orc_dep.found() and orcc.found()
 373   have_orcc = true
 374   orcc_args = [orcc]
 375   #orcc_args = [orcc, '--include', 'glib.h']
 376   cdata.set('HAVE_ORC', 1)
 377 else
 378   cdata.set('DISABLE_ORC', 1)
 379 endif
 380
 381 samplerate_dep = dependency('samplerate', version : '>= 0.1.0', required : get_option('samplerate'))
 382 if samplerate_dep.found()
 383   cdata.set('HAVE_LIBSAMPLERATE', 1)
 384 endif
 385
 386 sndfile_dep = dependency('sndfile', version : '>= 1.0.20')
 387
 388 soxr_dep = dependency('soxr', version : '>= 0.1.1', required : get_option('soxr'))
 389 if soxr_dep.found()
 390   cdata.set('HAVE_SOXR', 1)
 391 endif
 392
 393 libsystemd_dep = dependency('libsystemd', required : get_option('systemd'))
 394 if libsystemd_dep.found()
 395   cdata.set('HAVE_SYSTEMD_DAEMON', 1)
 396   cdata.set('HAVE_SYSTEMD_LOGIN', 1)
 397   cdata.set('HAVE_SYSTEMD_JOURNAL', 1)
 398 endif
 399 systemd_dep = dependency('systemd', required : get_option('systemd'))
 400 if systemd_dep.found() and systemduserunitdir == ''
 401   systemduserunitdir = systemd_dep.get_pkgconfig_variable('systemduserunitdir')
 402 endif
 403
 404 x11_dep = dependency('x11-xcb', required : get_option('x11'))
 405 if x11_dep.found()
 406   xcb_dep  = dependency('xcb',  required : true, version : '>= 1.6')
 407   ice_dep  = dependency('ice',  required : true)
 408   sm_dep   = dependency('sm',   required : true)
 409   xtst_dep = dependency('xtst', required : true)
 410   cdata.set('HAVE_X11', 1)
 411 endif
 412
 413 # Module dependencies
 414
 415 if cc.has_header('sys/soundcard.h')
 416   cdata.set('HAVE_OSS_OUTPUT', 1)
 417   cdata.set('HAVE_OSS_WRAPPER', 1)
 418   cdata.set_quoted('PULSEDSP_LOCATION', pulsedspdir)
 419 endif
 420
 421 if get_option('hal-compat')
 422   cdata.set('HAVE_HAL_COMPAT', 1)
 423 endif
 424
 425 avahi_dep = dependency('avahi-client', version : '>= 0.6.0', required : get_option('avahi'), disabler : true)
 426 if avahi_dep.found()
 427   cdata.set('HAVE_AVAHI', 1)
 428 endif
 429
 430 bluez_dep = dependency('bluez', version : '>= 5.0', required : get_option('bluez5'))
 431 sbc_dep = dependency('sbc', version : '>= 1.0', required : false)
 432 if bluez_dep.found()
 433   assert(dbus_dep.found(), 'BlueZ requires D-Bus support')
 434   assert(sbc_dep.found(), 'BlueZ requires SBC support')
 435   cdata.set('HAVE_SBC', 1)
 436   cdata.set('HAVE_BLUEZ', 1)
 437   cdata.set('HAVE_BLUEZ_5', 1)
 438   if get_option('bluez5-native-headset')
 439     cdata.set('HAVE_BLUEZ_5_NATIVE_HEADSET', 1)
 440   endif
 441   if get_option('bluez5-ofono-headset')
 442     cdata.set('HAVE_BLUEZ_5_OFONO_HEADSET', 1)
 443   endif
 444 endif
 445
 446 fftw_dep = dependency('fftw3f', required : get_option('fftw'))
 447 if fftw_dep.found()
 448   cdata.set('HAVE_FFTW', 1)
 449 endif
 450
 451 jack_dep = dependency('jack', version : '>= 0.117.0', required : get_option('jack'))
 452 if jack_dep.found()
 453   cdata.set('HAVE_JACK', 1)
 454 endif
 455
 456 lirc_dep = dependency('lirc', required : get_option('lirc'))
 457 if lirc_dep.found()
 458   cdata.set('HAVE_LIRC', 1)
 459 endif
 460
 461 openssl_dep = dependency('openssl', version : '>= 0.9', required : get_option('openssl'))
 462 if openssl_dep.found()
 463   cdata.set('HAVE_OPENSSL', 1)
 464 endif
 465
 466 speex_dep = dependency('speexdsp', version : '>= 1.2', required : get_option('speex'))
 467 if speex_dep.found()
 468   cdata.set('HAVE_SPEEX', 1)
 469 endif
 470
 471 udev_dep = dependency('libudev', version : '>= 143', required : get_option('udev'))
 472 if udev_dep.found()
 473   cdata.set('HAVE_UDEV', 1)
 474 endif
 475
 476 webrtc_dep = dependency('webrtc-audio-processing', version : '>= 0.2', required : get_option('webrtc-aec'))
 477 if webrtc_dep.found()
 478   cdata.set('HAVE_WEBRTC', 1)
 479 endif
 480
 481 # These are required for the CMake file generation
 482 cdata.set('PA_LIBDIR', libdir)
 483 cdata.set('PA_INCDIR', includedir)
 484 if glib_dep.found()
 485   cdata.set('HAVE_GLIB20', 1) # to match the AM_CONDITIONAL for CMake file generation
 486 endif
 487
 488 # Test dependencies
 489
 490 check_dep = dependency('check', version : '>= 0.9.10', required : get_option('tests'))
 491
 492 # Now generate config.h from everything above
 493 configure_file(output : 'config.h', configuration : cdata)
 494
 495 # pkg-config files
 496
 497 pc_cdata = configuration_data()
 498
 499 pc_cdata.set('prefix', prefix)
 500 pc_cdata.set('exec_prefix', prefix)
 501 pc_cdata.set('libdir', libdir)
 502 pc_cdata.set('includedir', includedir)
 503 pc_cdata.set('modlibexecdir', modlibexecdir)
 504 pc_cdata.set('PACKAGE_VERSION', pa_version_str)
 505 pc_cdata.set('PA_MAJORMINOR', pa_version_major_minor)
 506 # FIXME: the line below is wrong. Currently the meson thread dep lacks documentation,
 507 # and doesn't allow introspection, ie. none of get_pkgconfig_variable() or
 508 # get_configtool_variable() work with it, so we have no way to get this flag right,
 509 # unless we do all the work ourselves. See current work in glib, also meson #553.
 510 pc_cdata.set('PTHREAD_LIBS', '-pthread')
 511
 512 pc_files = [
 513   'libpulse.pc',
 514   'libpulse-simple.pc',
 515 ]
 516
 517 if glib_dep.found()
 518   pc_files += 'libpulse-mainloop-glib.pc'
 519 endif
 520
 521 foreach file : pc_files
 522   configure_file(
 523     input : file + '.in',
 524     output : file,
 525     configuration : pc_cdata,
 526     install_dir : pkgconfigdir)
 527 endforeach
 528
 529 # CMake files
 530
 531 m4 = find_program('m4', required: true)
 532
 533 cmakedir = join_paths(libdir, 'cmake', 'PulseAudio')
 534
 535 cmake_template_file = configure_file(
 536   input : 'PulseAudioConfig.cmake.in',
 537   output : 'PulseAudioConfig.cmake.tmp',
 538   configuration: cdata,
 539 )
 540
 541 custom_target('PulseAudioConfig.cmake',
 542   input : cmake_template_file,
 543   output : 'PulseAudioConfig.cmake',
 544   capture : true,
 545   command : [m4, '@INPUT@'],
 546   build_by_default : true,
 547   install : true,
 548   install_dir : cmakedir,
 549 )
 550
 551 configure_file(
 552   input : 'PulseAudioConfigVersion.cmake.in',
 553   output : 'PulseAudioConfigVersion.cmake',
 554   configuration: cdata,
 555   install : true,
 556   install_dir : cmakedir,
 557 )
 558
 559 # Subdirs
 560
 561 subdir('po')
 562 if get_option('man')
 563   subdir('man')
 564 endif
 565 subdir('shell-completion/bash')
 566 subdir('shell-completion/zsh')
 567 subdir('src')
 568 subdir('vala')
 569
 570 ############################################################
 571
 572 # Final summary
 573
 574 summary = [
 575   '',
 576   '---{ @0@ @1@ }---'.format(meson.project_name(), meson.project_version()),
 577   '',
 578   'prefix:                        @0@'.format(prefix),
 579   'bindir:                        @0@'.format(bindir),
 580   'libdir:                        @0@'.format(libdir),
 581   'libexecdir:                    @0@'.format(libexecdir),
 582   'mandir:                        @0@'.format(mandir),
 583   'datadir:                       @0@'.format(datadir),
 584   'sysconfdir:                    @0@'.format(sysconfdir),
 585   'localstatedir:                 @0@'.format(localstatedir),
 586   'modlibexecdir:                 @0@'.format(modlibexecdir),
 587   'System Runtime Path:           @0@'.format(cdata.get_unquoted('PA_SYSTEM_RUNTIME_PATH')),
 588   'System State Path:             @0@'.format(cdata.get_unquoted('PA_SYSTEM_STATE_PATH')),
 589   'System Config Path:            @0@'.format(cdata.get_unquoted('PA_SYSTEM_CONFIG_PATH')),
 590   'Bash completions directory:    @0@'.format(bashcompletiondir),
 591   'Zsh completions directory:     @0@'.format(zshcompletiondir),
 592   'Compiler:                      @0@ @1@'.format(cc.get_id(), cc.version()),
 593 #  'CFLAGS:                        @0@'.format(${CFLAGS}),
 594 #  'CPPFLAGS:                      @0@'.format(${CPPFLAGS}),
 595 #  'LIBS:                          @0@'.format(${LIBS}),
 596   '',
 597   'Enable memfd shared memory:    @0@'.format(cdata.has('HAVE_MEMFD')),
 598   'Enable X11:                    @0@'.format(x11_dep.found()),
 599 #  'Enable OSS Output:             @0@'.format(${ENABLE_OSS_OUTPUT}),
 600 #  'Enable OSS Wrapper:            @0@'.format(${ENABLE_OSS_WRAPPER}),
 601 #  'Enable EsounD:                 @0@'.format(${ENABLE_ESOUND}),
 602   'Enable Alsa:                   @0@'.format(alsa_dep.found()),
 603 #  'Enable CoreAudio:              @0@'.format(${ENABLE_COREAUDIO}),
 604 #  'Enable Solaris:                @0@'.format(${ENABLE_SOLARIS}),
 605 #  'Enable WaveOut:                @0@'.format(${ENABLE_WAVEOUT}),
 606   'Enable GLib 2:                 @0@'.format(glib_dep.found()),
 607 #  'Enable GConf:                  @0@'.format(${ENABLE_GCONF}),
 608   'Enable GSettings:              @0@'.format(gio_dep.found()),
 609   'Enable Gtk+ 3:                 @0@'.format(gtk_dep.found()),
 610   'Enable Avahi:                  @0@'.format(avahi_dep.found()),
 611   'Enable Jack:                   @0@'.format(jack_dep.found()),
 612   'Enable Async DNS:              @0@'.format(asyncns_dep.found()),
 613   'Enable LIRC:                   @0@'.format(lirc_dep.found()),
 614   'Enable D-Bus:                  @0@'.format(dbus_dep.found()),
 615   '  Enable BlueZ 5:              @0@'.format(bluez_dep.found()),
 616   '    Enable native headsets:    @0@'.format(get_option('bluez5-native-headset')),
 617   '    Enable  ofono headsets:    @0@'.format(get_option('bluez5-ofono-headset')),
 618   'Enable udev:                   @0@'.format(udev_dep.found()),
 619   '  Enable HAL->udev compat:     @0@'.format(get_option('hal-compat')),
 620   'Enable systemd:                @0@'.format(libsystemd_dep.found()),
 621 #  'Enable TCP Wrappers:           @0@'.format(${ENABLE_TCPWRAP}),
 622   'Enable libsamplerate:          @0@'.format(samplerate_dep.found()),
 623   'Enable IPv6:                   @0@'.format(get_option('ipv6')),
 624   'Enable OpenSSL (for Airtunes): @0@'.format(openssl_dep.found()),
 625   'Enable FFTW:                   @0@'.format(fftw_dep.found()),
 626   'Enable ORC:                    @0@'.format(have_orcc),
 627   'Enable Adrian echo canceller:  @0@'.format(get_option('adrian-aec')),
 628   'Enable Speex (resampler, AEC): @0@'.format(speex_dep.found()),
 629   'Enable SoXR (resampler):       @0@'.format(soxr_dep.found()),
 630   'Enable WebRTC echo canceller:  @0@'.format(webrtc_dep.found()),
 631   'Enable Gcov coverage:          @0@'.format(get_option('gcov')),
 632   'Enable man pages:              @0@'.format(get_option('man')),
 633   'Enable unit tests:             @0@'.format(get_option('tests')),
 634   '',
 635   'Database:                      @0@'.format(get_option('database')),
 636   'Legacy Database Entry Support: @0@'.format(get_option('legacy-database-entry-format')),
 637   'Running from build tree:       @0@'.format(get_option('running-from-build-tree')),
 638   'System User:                   @0@'.format(cdata.get_unquoted('PA_SYSTEM_USER')),
 639   'System Group:                  @0@'.format(cdata.get_unquoted('PA_SYSTEM_GROUP')),
 640   'Access Group:                  @0@'.format(cdata.get_unquoted('PA_ACCESS_GROUP')),
 641 #  'Enable per-user EsounD socket: @0@'.format(${ENABLE_PER_USER_ESOUND_SOCKET}),
 642 #  'Force preopen:                 @0@'.format(${FORCE_PREOPEN}),
 643 #  'Preopened modules:             @0@'.format(${PREOPEN_MODS}),
 644 ]
 645
 646 message('\n    '.join(summary))
 647
 648 # Sanity checks
 649
 650 if not speex_dep.found() and not webrtc_dep.found() and not get_option('adrian-aec')
 651   error('At least one echo canceller implementation must be available!')
 652 endif
 653
 654 if samplerate_dep.found()
 655   warning('Support for libsamplerate is DEPRECATED')
 656 endif
 657
 658 if host_machine.system() != 'windows'
 659   if not dbus_dep.found()
 660     message = [
 661       'You do not have D-Bus support enabled. It is strongly recommended',
 662       'that you enable D-Bus support if your platform supports it.',
 663       'Many parts of PulseAudio use D-Bus, from ConsoleKit interaction',
 664       'to the Device Reservation Protocol to speak to JACK, Bluetooth',
 665       'support and even a native control protocol for communicating and',
 666       'controlling the PulseAudio daemon itself.',
 667     ]
 668     warning('\n' + '\n'.join(message))
 669   endif
 670   if not udev_dep.found()
 671     message = [
 672       'You do not have udev support enabled. It is strongly recommended',
 673       'that you enable udev support if your platform supports it as it is',
 674       'the primary method used to detect hardware audio devices (on Linux)',
 675       'and is thus a critical part of PulseAudio on that platform.',
 676     ]
 677     warning('\n' + '\n'.join(message))
 678   endif
 679   if not speex_dep.found()
 680     message = [
 681       'You do not have speex support enabled. It is strongly recommended',
 682       'that you enable speex support if your platform supports it as it is',
 683       'the primary method used for audio resampling and is thus a critical',
 684       'part of PulseAudio on that platform.',
 685     ]
 686     warning('\n' + '\n'.join(message))
 687   endif
 688 endif