meson.build

   1 project('gst-plugins-base', 'c',
   2   version : '1.13.0.1',
   3   meson_version : '>= 0.36.0',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0]
  10 gst_version_minor = version_arr[1]
  11 gst_version_micro = version_arr[2]
  12 if version_arr.length() == 4
  13   gst_version_nano = version_arr[3]
  14 else
  15   gst_version_nano = 0
  16 endif
  17
  18 have_cxx = add_languages('cpp', required : false)
  19
  20 glib_req = '>= 2.40.0'
  21 orc_req = '>= 0.4.24'
  22 gst_req = '>= @0@.@1@.0'.format(gst_version_major, gst_version_minor)
  23
  24 api_version = '1.0'
  25 soversion = 0
  26 # maintaining compatibility with the previous libtool versioning
  27 # current = minor * 100 + micro
  28 # FIXME: should be able to convert string to int somehow so we can just do maths
  29 libversion = '@0@.@1@.0'.format(soversion, gst_version_minor.to_int() * 100 + gst_version_micro.to_int())
  30
  31 plugins_install_dir = '@0@/gstreamer-1.0'.format(get_option('libdir'))
  32
  33 cc = meson.get_compiler('c')
  34
  35 if cc.get_id() == 'msvc'
  36   # Ignore several spurious warnings for things gstreamer does very commonly
  37   # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  38   # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  39   # NOTE: Only add warnings here if you are sure they're spurious
  40   add_project_arguments(
  41       '/wd4018', # implicit signed/unsigned conversion
  42       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  43       '/wd4244', # lossy type conversion (e.g. double -> int)
  44       '/wd4305', # truncating type conversion (e.g. double -> float)
  45       language : 'c')
  46   # Disable SAFESEH with MSVC for plugins and libs that use external deps that
  47   # are built with MinGW
  48   noseh_link_args = ['/SAFESEH:NO']
  49 else
  50   noseh_link_args = []
  51 endif
  52
  53 core_conf = configuration_data()
  54 check_headers = [
  55   ['HAVE_DLFCN_H', 'dlfcn.h'],
  56   ['HAVE_EMMINTRIN_H', 'emmintrin.h'],
  57   ['HAVE_INTTYPES_H', 'inttypes.h'],
  58   ['HAVE_MEMORY_H', 'memory.h'],
  59   ['HAVE_PROCESS_H', 'process.h'],
  60   ['HAVE_SMMINTRIN_H', 'smmintrin.h'],
  61   ['HAVE_STDINT_H', 'stdint.h'],
  62   ['HAVE_STDLIB_H', 'stdlib.h'],
  63   ['HAVE_STRINGS_H', 'strings.h'],
  64   ['HAVE_STRING_H', 'string.h'],
  65   ['HAVE_SYS_SOCKET_H', 'sys/socket.h'],
  66   ['HAVE_SYS_STAT_H', 'sys/stat.h'],
  67   ['HAVE_SYS_TYPES_H', 'sys/types.h'],
  68   ['HAVE_SYS_WAIT_H', 'sys/wait.h'],
  69   ['HAVE_UNISTD_H', 'unistd.h'],
  70   ['HAVE_WINSOCK2_H', 'winsock2.h'],
  71   ['HAVE_XMMINTRIN_H', 'xmmintrin.h'],
  72 ]
  73 foreach h : check_headers
  74   if cc.has_header(h.get(1))
  75     core_conf.set(h.get(0), 1)
  76   endif
  77 endforeach
  78
  79 check_functions = [
  80   ['HAVE_DCGETTEXT', 'dcgettext', '#include<libintl.h>'],
  81   ['HAVE_GMTIME_R', 'gmtime_r', '#include<time.h>'],
  82   ['HAVE_LRINTF', 'lrintf', '#include<math.h>'],
  83   ['HAVE_MMAP', 'mmap', '#include<sys/mman.h>'],
  84   ['HAVE_LOG2', 'log2', '#include<math.h>'],
  85 ]
  86
  87 libm = cc.find_library('m', required : false)
  88 foreach f : check_functions
  89   if cc.has_function(f.get(1), prefix : f.get(2), dependencies : libm)
  90     core_conf.set(f.get(0), 1)
  91   endif
  92 endforeach
  93
  94 core_conf.set('SIZEOF_CHAR', cc.sizeof('char'))
  95 core_conf.set('SIZEOF_INT', cc.sizeof('int'))
  96 core_conf.set('SIZEOF_LONG', cc.sizeof('long'))
  97 core_conf.set('SIZEOF_SHORT', cc.sizeof('short'))
  98 core_conf.set('SIZEOF_VOIDP', cc.sizeof('void*'))
  99
 100 core_conf.set('GETTEXT_PACKAGE', '"gst-plugins-base-1.0"')
 101 core_conf.set('PACKAGE', '"gst-plugins-base"')
 102 core_conf.set('VERSION', '"@0@"'.format(gst_version))
 103 core_conf.set('PACKAGE_VERSION', '"@0@"'.format(gst_version))
 104 core_conf.set('GST_API_VERSION', '"@0@"'.format(api_version))
 105 core_conf.set('GST_INSTALL_PLUGINS_HELPER', '"/FIXME"')
 106 core_conf.set('GST_DATADIR', '"/FIXME"')
 107 core_conf.set('GST_LICENSE', '"LGPL"')
 108
 109 # GStreamer package name and origin url
 110 gst_package_name = get_option('with-package-name')
 111 if gst_package_name == ''
 112   if gst_version_nano == 0
 113     gst_package_name = 'GStreamer Base Plug-ins source release'
 114   elif gst_version_nano == 1
 115     gst_package_name = 'GStreamer Base Plug-ins git'
 116   else
 117     gst_package_name = 'GStreamer Base Plug-ins prerelease'
 118   endif
 119 endif
 120 core_conf.set_quoted('GST_PACKAGE_NAME', gst_package_name)
 121 core_conf.set_quoted('GST_PACKAGE_ORIGIN', get_option('with-package-origin'))
 122
 123 # FIXME: These should be configure options
 124 core_conf.set('DEFAULT_VIDEOSINK', '"autovideosink"')
 125 core_conf.set('DEFAULT_AUDIOSINK', '"autoaudiosink"')
 126
 127 # Set whether the audioresampling method should be detected at runtime
 128 core_conf.set('AUDIORESAMPLE_FORMAT_' + get_option('audioresample_format').to_upper(), true)
 129
 130 gst_plugins_base_args = ['-DHAVE_CONFIG_H']
 131 if get_option('default_library') == 'static'
 132   gst_plugins_base_args += ['-DGST_STATIC_COMPILATION']
 133 endif
 134
 135 # X11 checks are for sys/ and tests/
 136 x11_dep = dependency('x11', required : false)
 137 # GLib checks are for the entire project
 138 giounix_dep = dependency('gio-unix-2.0', version : glib_req, required : false)
 139 # Almost everything that uses glib also uses gobject
 140 glib_deps = [dependency('glib-2.0', version : glib_req, fallback: ['glib', 'libglib_dep']),
 141              dependency('gobject-2.0', fallback: ['glib', 'libgobject_dep'])]
 142 gio_dep = dependency('gio-2.0', fallback: ['glib', 'libgio_dep'])
 143
 144 core_conf.set('HAVE_X', x11_dep.found())
 145 core_conf.set('HAVE_GIO_UNIX_2_0',
 146     (gio_dep.type_name() != 'pkgconfig' and host_machine.system() != 'windows')
 147     or giounix_dep.found())
 148
 149 if gio_dep.type_name() == 'pkgconfig'
 150     core_conf.set_quoted('GIO_MODULE_DIR',
 151         gio_dep.get_pkgconfig_variable('giomoduledir'))
 152     core_conf.set_quoted('GIO_LIBDIR',
 153         gio_dep.get_pkgconfig_variable('libdir'))
 154     core_conf.set_quoted('GIO_PREFIX',
 155         gio_dep.get_pkgconfig_variable('prefix'))
 156 else
 157     core_conf.set_quoted('GIO_MODULE_DIR', join_paths(get_option('prefix'),
 158       get_option('libdir'), 'gio/modules'))
 159     core_conf.set_quoted('GIO_LIBDIR', join_paths(get_option('prefix'),
 160       get_option('libdir')))
 161     core_conf.set_quoted('GIO_PREFIX', get_option('prefix'))
 162 endif
 163
 164 configinc = include_directories('.')
 165 libsinc = include_directories('gst-libs')
 166
 167 # To use the subproject make subprojects directory
 168 # and put gstreamer meson git there (symlinking is fine)
 169 gst_dep = dependency('gstreamer-1.0', version : gst_req,
 170   fallback : ['gstreamer', 'gst_dep'])
 171 gst_base_dep = dependency('gstreamer-base-1.0', version : gst_req,
 172   fallback : ['gstreamer', 'gst_base_dep'])
 173 gst_net_dep = dependency('gstreamer-net-1.0', version : gst_req,
 174   fallback : ['gstreamer', 'gst_net_dep'])
 175 if host_machine.system() != 'windows'
 176   gst_check_dep = dependency('gstreamer-check-1.0', version : gst_req,
 177     fallback : ['gstreamer', 'gst_check_dep'])
 178 endif
 179 gst_controller_dep = dependency('gstreamer-controller-1.0', version : gst_req,
 180   fallback : ['gstreamer', 'gst_controller_dep'])
 181
 182 vs_module_defs_dir = meson.current_source_dir() + '/win32/common/'
 183
 184 # Used by the *_mkenum.py helper scripts
 185 glib_mkenums = find_program('glib-mkenums')
 186
 187 have_orcc = false
 188 orcc_args = []
 189 if get_option('use_orc') != 'no'
 190   need_orc = get_option('use_orc') == 'yes'
 191   # Used by various libraries/elements that use Orc code
 192   orc_dep = dependency('orc-0.4', version : orc_req, required : need_orc)
 193   orcc = find_program('orcc', required : need_orc)
 194   if orc_dep.found() and orcc.found()
 195     have_orcc = true
 196     orcc_args = [orcc, '--include', 'glib.h']
 197     core_conf.set('HAVE_ORC', 1)
 198   else
 199     message('Orc Compiler not found, will use backup C code')
 200     core_conf.set('DISABLE_ORC', 1)
 201   endif
 202 else
 203   core_conf.set('DISABLE_ORC', 1)
 204 endif
 205
 206 # Used to build SSE* things in audio-resampler
 207 sse_args = '-msse'
 208 sse2_args = '-msse2'
 209 sse41_args = '-msse4.1'
 210
 211 have_sse = cc.has_argument(sse_args)
 212 have_sse2 = cc.has_argument(sse2_args)
 213 have_sse41 = cc.has_argument(sse41_args)
 214
 215 # FIXME: Meson should have a way for portably adding -fPIC when needed for use
 216 # with static libraries that are linked into shared libraries. Or, it should
 217 # add it by default with an option to turn it off if needed.
 218 pic_args = ['-fPIC']
 219 if host_machine.system() == 'windows'
 220   pic_args = []
 221 endif
 222
 223 if gst_dep.type_name() == 'internal'
 224     gst_proj = subproject('gstreamer')
 225
 226     if gst_proj.get_variable('disable_gst_debug')
 227         message('GStreamer debug system is disabled')
 228         add_project_arguments('-Wno-unused', language: 'c')
 229     else
 230         message('GStreamer debug system is enabled')
 231     endif
 232 else
 233     # We can't check that in the case of subprojects as we won't
 234     # be able to build against an internal dependency (which is not built yet)
 235     if not cc.compiles('''
 236 #include <gst/gstconfig.h>
 237 #ifdef GST_DISABLE_GST_DEBUG
 238 #error "debugging disabled, make compiler fail"
 239 #endif''' , dependencies: gst_dep)
 240         message('GStreamer debug system is disabled')
 241         add_project_arguments('-Wno-unused', language: 'c')
 242     else
 243         message('GStreamer debug system is enabled')
 244     endif
 245 endif
 246
 247 gir = find_program('g-ir-scanner', required : false)
 248 gnome = import('gnome')
 249 build_gir = gir.found() and not meson.is_cross_build() and not get_option('disable_introspection')
 250 gir_init_section = [ '--add-init-section=extern void gst_init(gint*,gchar**);' + \
 251     'g_setenv("GST_REGISTRY_DISABLE", "yes", TRUE);' + \
 252     'g_setenv("GST_REGISTRY_1.0", "@0@", TRUE);'.format(meson.current_build_dir() + '/gir_empty_registry.reg') + \
 253     'g_setenv("GST_PLUGIN_PATH_1_0", "", TRUE);' + \
 254     'g_setenv("GST_PLUGIN_SYSTEM_PATH_1_0", "", TRUE);' + \
 255     'gst_init(NULL,NULL);' ]
 256
 257 subdir('gst-libs')
 258 subdir('gst')
 259 subdir('ext')
 260 subdir('sys')
 261 subdir('tools')
 262 subdir('tests')
 263 subdir('pkgconfig')
 264 subdir('po')
 265
 266 if build_machine.system() == 'windows'
 267   message('Disabling gtk-doc while building on Windows')
 268 elif get_option('disable_gtkdoc')
 269   message('gtk-doc is disabled via options')
 270 else
 271   if find_program('gtkdoc-scan', required : false).found()
 272     subdir('docs')
 273   else
 274     message('Not building documentation as gtk-doc was not found')
 275   endif
 276 endif
 277
 278 # Use core_conf after all subdirs have set values
 279 configure_file(output : 'config.h', configuration : core_conf)
 280
 281 python3 = import('python3').find_python()
 282 run_command(python3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')