meson.build

   1 project('pulseaudio', 'c', 'cpp',
   2         version : run_command(find_program('git-version-gen'), join_paths(meson.current_source_dir(), '.tarball-version')).stdout().strip(),
   3         meson_version : '>= 0.50.0',
   4         default_options : [ 'c_std=gnu11', 'cpp_std=c++11' ]
   5         )
   6
   7 pa_version_str = meson.project_version()
   8 # For tarballs, the first split will do nothing, but for builds in git, we
   9 # split out suffixes when there are commits since the last tag
  10 # (e.g.: v11.99.1-3-gad14bdb24 -> v11.99.1)
  11 version_split = pa_version_str.split('-')[0].split('.')
  12 pa_version_major = version_split[0].split('v')[0]
  13 pa_version_minor = version_split[1]
  14 if version_split.length() > 2
  15   pa_version_micro = version_split[2]
  16 else
  17   pa_version_micro = '0'
  18 endif
  19 pa_version_major_minor = pa_version_major + '.' + pa_version_minor
  20
  21 pa_api_version = 12
  22 pa_protocol_version = 33
  23
  24 apiversion = '1.0'
  25 soversion = 0
  26 # FIXME: this doesn't actually do what we want it to
  27 # maintaining compatibility with the previous libtool versioning
  28 # current = minor * 100 + micro
  29 libversion = '@0@.@1@.0'.format(soversion, pa_version_minor.to_int() * 100 + pa_version_micro.to_int())
  30
  31 # A simplified, synchronous, ABI-stable interface for client applications.
  32 # For the version x:y:z always will hold y=z.
  33 libpulse_simple_version = '1.1.1'
  34
  35 # The ABI-stable GLib adapter for client applications.
  36 # For the version x:y:z always will hold y=z.
  37 libpulse_mainloop_glib_version = '0.5.0'
  38
  39 # Paths
  40
  41 prefix = get_option('prefix')
  42 assert(prefix.startswith('/'), 'Prefix is not absolute: "@0@"'.format(prefix))
  43
  44 bindir = join_paths(prefix, get_option('bindir'))
  45 libdir = join_paths(prefix, get_option('libdir'))
  46 libexecdir = join_paths(prefix, get_option('libexecdir'))
  47 datadir = join_paths(prefix, get_option('datadir'))
  48 localstatedir = join_paths(prefix, get_option('localstatedir'))
  49 sysconfdir = join_paths(prefix, get_option('sysconfdir'))
  50 privlibdir = join_paths(get_option('libdir'), 'pulseaudio')
  51 alsadatadir = join_paths(datadir, 'pulseaudio', 'alsa-mixer')
  52
  53 pulselibexecdir = join_paths(libexecdir, 'pulse')
  54 pulsesysconfdir = join_paths(sysconfdir, 'pulse')
  55
  56 modlibexecdir = get_option('modlibexecdir')
  57 if modlibexecdir == ''
  58   modlibexecdir = join_paths(libdir, 'pulse-' + pa_version_major_minor, 'modules')
  59 endif
  60
  61 pulsedspdir = get_option('pulsedspdir')
  62 if pulsedspdir == ''
  63   join_paths(libdir, 'pulseaudio')
  64 endif
  65
  66 bashcompletiondir = get_option('bashcompletiondir')
  67 if bashcompletiondir == ''
  68   bash_completion_dep = dependency('bash-completion', required : false)
  69   if bash_completion_dep.found()
  70     bashcompletiondir = bash_completion_dep.get_pkgconfig_variable('completionsdir')
  71   else
  72     bashcompletiondir = join_paths(datadir, 'bash-completion', 'completions')
  73   endif
  74 endif
  75
  76 zshcompletiondir = get_option('zshcompletiondir')
  77 if zshcompletiondir == ''
  78   zshcompletiondir = join_paths(datadir, 'zsh', 'site-functions')
  79 endif
  80
  81 # Configuration data
  82
  83 cc = meson.get_compiler('c')
  84
  85 cdata = configuration_data()
  86 cdata.set_quoted('PACKAGE', 'pulseaudio')
  87 cdata.set_quoted('PACKAGE_NAME', 'pulseaudio')
  88 cdata.set_quoted('PACKAGE_VERSION', pa_version_str)
  89 cdata.set_quoted('CANONICAL_HOST', host_machine.cpu())
  90 cdata.set('PA_MAJOR', pa_version_major)
  91 cdata.set('PA_MINOR', pa_version_minor)
  92 cdata.set('PA_API_VERSION', pa_api_version)
  93 cdata.set('PA_PROTOCOL_VERSION', pa_protocol_version)
  94 cdata.set_quoted('PA_MACHINE_ID', join_paths(sysconfdir, 'machine-id'))
  95 cdata.set_quoted('PA_MACHINE_ID_FALLBACK', join_paths(localstatedir, 'lib', 'dbus', 'machine-id'))
  96 cdata.set_quoted('PA_SRCDIR', join_paths(meson.current_source_dir(), 'src'))
  97 cdata.set_quoted('PA_BUILDDIR', meson.current_build_dir())
  98 cdata.set_quoted('PA_SOEXT', '.so')
  99 cdata.set_quoted('PA_DEFAULT_CONFIG_DIR', pulsesysconfdir)
 100 cdata.set_quoted('PA_BINARY', join_paths(bindir, 'pulseaudio'))
 101 cdata.set_quoted('PA_SYSTEM_RUNTIME_PATH', join_paths(localstatedir, 'run', 'pulse'))
 102 cdata.set_quoted('PA_SYSTEM_CONFIG_PATH', join_paths(localstatedir, 'lib', 'pulse'))
 103 cdata.set_quoted('PA_SYSTEM_STATE_PATH', join_paths(localstatedir, 'lib', 'pulse'))
 104 cdata.set_quoted('PA_DLSEARCHPATH', modlibexecdir)
 105 cdata.set_quoted('PA_SYSTEM_USER', get_option('system_user'))
 106 cdata.set_quoted('PA_SYSTEM_GROUP', get_option('system_group'))
 107 cdata.set_quoted('PA_ACCESS_GROUP', get_option('access_group'))
 108 cdata.set_quoted('PA_CFLAGS', 'Not yet supported on meson')
 109 cdata.set_quoted('PA_ALSA_PATHS_DIR', join_paths(alsadatadir, 'paths'))
 110 cdata.set_quoted('PA_ALSA_PROFILE_SETS_DIR', join_paths(alsadatadir, 'profile-sets'))
 111 cdata.set_quoted('DESKTOPFILEDIR', join_paths(datadir, 'applications'))
 112
 113 # Platform specifics
 114 # First some defaults to keep config file generation happy
 115 cdata.set('HAVE_COREAUDIO', 0)
 116 cdata.set('HAVE_WAVEOUT', 0)
 117 # FIXME: This was not tested. Maybe some flags should better be CFLAGS,
 118 # rather than ending up in the config.h file?
 119 if host_machine.system() == 'darwin'
 120   cdata.set('OS_IS_DARWIN', 1)
 121   cdata.set('_DARWIN_C_SOURCE', '200112L') # Needed to get NSIG on Mac OS
 122 elif host_machine.system() == 'windows'
 123   cdata.set('OS_IS_WIN32', 1)
 124   cdata.set('WIN32_LEAN_AND_MEAN', 1) # Needed to avoid including unnecessary headers on Windows
 125 #elif host_machine.system() == 'solaris'
 126 #  # Apparently meson has no solaris support?
 127 #  # Needed to get declarations for msg_control and msg_controllen on Solaris
 128 #  cdata.set('_XOPEN_SOURCE', 600)
 129 #  cdata.set('__EXTENSIONS__', 1)
 130 endif
 131
 132 # Headers
 133
 134 check_headers = [
 135   'arpa/inet.h',
 136   'cpuid.h',
 137   'execinfo.h',
 138   'grp.h',
 139   'langinfo.h',
 140   'locale.h',
 141   'netdb.h',
 142   'netinet/in.h',
 143   'netinet/in_systm.h',
 144   'netinet/ip.h',
 145   'netinet/tcp.h',
 146   'pcreposix.h',
 147   'poll.h',
 148   'pwd.h',
 149   'regex.h',
 150   'sched.h',
 151   'sys/capability.h',
 152   'sys/eventfd.h',
 153   'sys/ioctl.h',
 154   'sys/mman.h',
 155   'sys/prctl.h',
 156   'sys/resource.h',
 157   'sys/select.h',
 158   'sys/socket.h',
 159   'sys/un.h',
 160   'sys/wait.h',
 161   'valgrind/memcheck.h',
 162   'xlocale.h',
 163 ]
 164
 165 foreach h : check_headers
 166   if cc.has_header(h)
 167     define = 'HAVE_' + h.underscorify().to_upper()
 168     cdata.set(define, 1)
 169   endif
 170 endforeach
 171
 172 # FIXME: move this to the above set
 173 if cc.has_header('pthread.h')
 174   cdata.set('HAVE_PTHREAD', 1)
 175 endif
 176
 177 # Functions
 178
 179 check_functions = [
 180   'accept4',
 181   'clock_gettime',
 182   'fchmod',
 183   'fchown',
 184   'fork',
 185   'fstat',
 186   'getaddrinfo',
 187   'getgrgid_r',
 188   'getpwnam_r',
 189   'gettimeofday',
 190   'getuid',
 191   'lstat',
 192   'memfd_create',
 193   'mkfifo',
 194   'mlock',
 195   'nanosleep',
 196   'paccept',
 197   'pipe',
 198   'pipe2',
 199   'posix_madvise',
 200   'readlink',
 201   'setegid',
 202   'seteuid',
 203   'setregid',
 204   'setreuid',
 205   'setresgid',
 206   'setresuid',
 207   'setsid',
 208   'sig2str',
 209   'sigaction',
 210   'strtod_l',
 211   'symlink',
 212   'sysconf',
 213   'uname',
 214 ]
 215
 216 foreach f : check_functions
 217   if cc.has_function(f)
 218     define = 'HAVE_' + f.underscorify().to_upper()
 219     cdata.set(define, 1)
 220   endif
 221 endforeach
 222
 223 if cc.has_function('SYS_memfd_create', prefix : '#include <sys/syscall.h>')
 224   cdata.set('HAVE_MEMFD', 1)
 225 endif
 226
 227 # Symbols
 228
 229 if cc.has_header_symbol('signal.h', 'SIGXCPU')
 230   cdata.set('HAVE_SIGXCPU', 1)
 231 endif
 232
 233 if not cc.has_header_symbol('netinet/in.h', 'INADDR_NONE')
 234   if not cc.has_header_symbol('winsock2.h', 'INADDR_NONE')
 235     # Define INADDR_NONE if not found (Solaris)
 236     cdata.set('INADDR_NONE', '0xffffffff')
 237   endif
 238 endif
 239
 240 # Types
 241
 242 # FIXME: do we ever care about gid_t not being defined / smaller than an int?
 243 cdata.set('GETGROUPS_T', 'gid_t')
 244
 245 # Include paths
 246
 247 configinc = include_directories('.')
 248 topinc = include_directories('src')
 249
 250 # CFLAGS
 251
 252 pa_c_args = ['-DHAVE_CONFIG_H', '-D_GNU_SOURCE']
 253 server_c_args = ['-D__INCLUDED_FROM_PULSE_AUDIO']
 254 cdata.set('MESON_BUILD', 1)
 255
 256 # Core Dependencies
 257
 258 libm_dep = cc.find_library('m', required : true)
 259 thread_dep = dependency('threads')
 260 cap_dep = cc.find_library('cap', required : false)
 261
 262 shm_dep = cc.find_library('rt', required : false)
 263 if shm_dep.found()
 264   cdata.set('HAVE_SHM_OPEN', 1)
 265 endif
 266
 267 atomictest = '''void func() {
 268   volatile int atomic = 2;
 269   __sync_bool_compare_and_swap (&atomic, 2, 3);
 270 }
 271 '''
 272 if cc.compiles(atomictest)
 273   cdata.set('HAVE_ATOMIC_BUILTINS', true)
 274 else
 275   # FIXME: check if we need libatomic_ops
 276 endif
 277
 278 # FIXME: make sure it's >= 2.2
 279 ltdl_dep = cc.find_library('ltdl', required : true)
 280 # FIXME: can meson support libtool -dlopen/-dlpreopen things?
 281 #        and do we still want to support this at all?
 282 cdata.set('DISABLE_LIBTOOL_PRELOAD', 1)
 283
 284 if get_option('database') == 'tdb'
 285   database_dep = dependency('tdb')
 286 elif get_option('database') == 'gdbm'
 287   database_dep = cc.find_library('gdbm', required : true)
 288 else
 289   database_dep = dependency('', required: false)
 290 endif
 291
 292 if get_option('ipv6')
 293   cdata.set('HAVE_IPV6', 1)
 294 endif
 295
 296 if get_option('legacy-database-entry-format')
 297   cdata.set('ENABLE_LEGACY_DATABASE_ENTRY_FORMAT', 1)
 298 endif
 299
 300 alsa_dep = dependency('alsa', version : '>= 1.0.24', required : get_option('alsa'))
 301 if alsa_dep.found()
 302   cdata.set('HAVE_ALSA', 1)
 303   cdata.set('HAVE_ALSA_UCM', 1)
 304 endif
 305
 306 asyncns_dep = dependency('libasyncns', version : '>= 0.1', required : get_option('asyncns'))
 307 if asyncns_dep.found()
 308   cdata.set('HAVE_LIBASYNCNS', 1)
 309 endif
 310
 311 dbus_dep = dependency('dbus-1', version : '>= 1.4.12', required : get_option('dbus'))
 312 if dbus_dep.found()
 313   cdata.set('HAVE_DBUS', 1)
 314 endif
 315
 316 gio_dep = dependency('gio-2.0', version : '>= 2.26.0', required : get_option('gsettings'))
 317 if gio_dep.found()
 318   cdata.set('HAVE_GSETTINGS', 1)
 319 endif
 320
 321 glib_dep = dependency('glib-2.0', version : '>= 2.4.0', required: get_option('glib'))
 322 if glib_dep.found()
 323   cdata.set('HAVE_GLIB', 1)
 324 endif
 325
 326 gtk_dep = dependency('gtk+-3.0', required : get_option('gtk'))
 327 if gtk_dep.found()
 328   cdata.set('HAVE_GTK', 1)
 329 endif
 330
 331 samplerate_dep = dependency('samplerate', version : '>= 0.1.0', required : get_option('samplerate'))
 332 if samplerate_dep.found()
 333   cdata.set('HAVE_LIBSAMPLERATE', 1)
 334 endif
 335
 336 sndfile_dep = dependency('sndfile', version : '>= 1.0.20')
 337
 338 soxr_dep = dependency('soxr', version : '>= 0.1.1', required : get_option('soxr'))
 339 if soxr_dep.found()
 340   cdata.set('HAVE_SOXR', 1)
 341 endif
 342
 343 systemd_dep = dependency('libsystemd', required : get_option('systemd'))
 344 if systemd_dep.found()
 345   cdata.set('HAVE_SYSTEMD_DAEMON', 1)
 346   cdata.set('HAVE_SYSTEMD_LOGIN', 1)
 347   cdata.set('HAVE_SYSTEMD_JOURNAL', 1)
 348 endif
 349
 350 x11_dep = dependency('x11-xcb', required : get_option('x11'))
 351 if x11_dep.found()
 352   xcb_dep  = dependency('xcb',  required : true, version : '>= 1.6')
 353   ice_dep  = dependency('ice',  required : true)
 354   sm_dep   = dependency('sm',   required : true)
 355   xtst_dep = dependency('xtst', required : true)
 356   cdata.set('HAVE_X11', 1)
 357 endif
 358
 359 # FIXME: support ORC
 360 cdata.set('DISABLE_ORC', 1)
 361
 362 # Module dependencies
 363
 364 if cc.has_header('sys/soundcard.h')
 365   cdata.set('HAVE_OSS_OUTPUT', 1)
 366   cdata.set('HAVE_OSS_WRAPPER', 1)
 367   cdata.set_quoted('PULSEDSP_LOCATION', pulsedspdir)
 368 endif
 369
 370 if get_option('hal-compat')
 371   cdata.set('HAVE_HAL_COMPAT', 1)
 372 endif
 373
 374 avahi_dep = dependency('avahi-client', version : '>= 0.6.0', required : get_option('avahi'), disabler : true)
 375 if avahi_dep.found()
 376   cdata.set('HAVE_AVAHI', 1)
 377 endif
 378
 379 bluez_dep = dependency('bluez', version : '>= 5.0', required : get_option('bluez5'))
 380 sbc_dep = dependency('sbc', version : '>= 1.0', required : false)
 381 if bluez_dep.found()
 382   assert(dbus_dep.found(), 'BlueZ requires D-Bus support')
 383   assert(sbc_dep.found(), 'BlueZ requires SBC support')
 384   cdata.set('HAVE_SBC', 1)
 385   cdata.set('HAVE_BLUEZ', 1)
 386   cdata.set('HAVE_BLUEZ_5', 1)
 387   if get_option('bluez5-native-headset')
 388     cdata.set('HAVE_BLUEZ_5_NATIVE_HEADSET', 1)
 389   endif
 390   if get_option('bluez5-ofono-headset')
 391     cdata.set('HAVE_BLUEZ_5_OFONO_HEADSET', 1)
 392   endif
 393 endif
 394
 395 fftw_dep = dependency('fftw3f', required : get_option('fftw'))
 396 if fftw_dep.found()
 397   cdata.set('HAVE_FFTW', 1)
 398 endif
 399
 400 jack_dep = dependency('jack', version : '>= 0.117.0', required : get_option('jack'))
 401 if jack_dep.found()
 402   cdata.set('HAVE_JACK', 1)
 403 endif
 404
 405 lirc_dep = dependency('lirc', required : get_option('lirc'))
 406 if lirc_dep.found()
 407   cdata.set('HAVE_LIRC', 1)
 408 endif
 409
 410 openssl_dep = dependency('openssl', version : '>= 0.9', required : get_option('openssl'))
 411 if openssl_dep.found()
 412   cdata.set('HAVE_OPENSSL', 1)
 413 endif
 414
 415 speex_dep = dependency('speexdsp', version : '>= 1.2', required : get_option('speex'))
 416 if speex_dep.found()
 417   cdata.set('HAVE_SPEEX', 1)
 418 endif
 419
 420 udev_dep = dependency('libudev', version : '>= 143', required : get_option('udev'))
 421 if udev_dep.found()
 422   cdata.set('HAVE_UDEV', 1)
 423 endif
 424
 425 webrtc_dep = dependency('webrtc-audio-processing', version : '>= 0.2', required : get_option('webrtc-aec'))
 426 if webrtc_dep.found()
 427   cdata.set('HAVE_WEBRTC', 1)
 428 endif
 429
 430 # Test dependencies
 431
 432 check_dep = dependency('check', version : '>= 0.9.10', required : get_option('tests'))
 433
 434 # Now generate config.h from everything above
 435 configure_file(output : 'config.h', configuration : cdata)
 436
 437 subdir('man')
 438 subdir('shell-completion/bash')
 439 subdir('shell-completion/zsh')
 440 subdir('src')
 441
 442 ############################################################
 443
 444 # Final summary
 445
 446 summary = [
 447   '',
 448   '---{ @0@ @1@ }---'.format(meson.project_name(), meson.project_version()),
 449   '',
 450   'prefix:                        @0@'.format(prefix),
 451   'bindir:                        @0@'.format(bindir),
 452   'libdir:                        @0@'.format(libdir),
 453   'libexecdir:                    @0@'.format(libexecdir),
 454   'datadir:                       @0@'.format(datadir),
 455   'sysconfdir:                    @0@'.format(sysconfdir),
 456   'localstatedir:                 @0@'.format(localstatedir),
 457   'modlibexecdir:                 @0@'.format(modlibexecdir),
 458   'System Runtime Path:           @0@'.format(cdata.get_unquoted('PA_SYSTEM_RUNTIME_PATH')),
 459   'System State Path:             @0@'.format(cdata.get_unquoted('PA_SYSTEM_STATE_PATH')),
 460   'System Config Path:            @0@'.format(cdata.get_unquoted('PA_SYSTEM_CONFIG_PATH')),
 461   'Bash completions directory:    @0@'.format(bashcompletiondir),
 462   'Zsh completions directory:     @0@'.format(zshcompletiondir),
 463   'Compiler:                      @0@ @1@'.format(cc.get_id(), cc.version()),
 464 #  'CFLAGS:                        @0@'.format(${CFLAGS}),
 465 #  'CPPFLAGS:                      @0@'.format(${CPPFLAGS}),
 466 #  'LIBS:                          @0@'.format(${LIBS}),
 467   '',
 468   'Enable memfd shared memory:    @0@'.format(cdata.has('HAVE_MEMFD')),
 469   'Enable X11:                    @0@'.format(x11_dep.found()),
 470 #  'Enable OSS Output:             @0@'.format(${ENABLE_OSS_OUTPUT}),
 471 #  'Enable OSS Wrapper:            @0@'.format(${ENABLE_OSS_WRAPPER}),
 472 #  'Enable EsounD:                 @0@'.format(${ENABLE_ESOUND}),
 473   'Enable Alsa:                   @0@'.format(alsa_dep.found()),
 474 #  'Enable CoreAudio:              @0@'.format(${ENABLE_COREAUDIO}),
 475 #  'Enable Solaris:                @0@'.format(${ENABLE_SOLARIS}),
 476 #  'Enable WaveOut:                @0@'.format(${ENABLE_WAVEOUT}),
 477   'Enable GLib 2:                 @0@'.format(glib_dep.found()),
 478 #  'Enable GConf:                  @0@'.format(${ENABLE_GCONF}),
 479   'Enable GSettings:              @0@'.format(gio_dep.found()),
 480   'Enable Gtk+ 3:                 @0@'.format(gtk_dep.found()),
 481   'Enable Avahi:                  @0@'.format(avahi_dep.found()),
 482   'Enable Jack:                   @0@'.format(jack_dep.found()),
 483   'Enable Async DNS:              @0@'.format(asyncns_dep.found()),
 484   'Enable LIRC:                   @0@'.format(lirc_dep.found()),
 485   'Enable D-Bus:                  @0@'.format(dbus_dep.found()),
 486   '  Enable BlueZ 5:              @0@'.format(bluez_dep.found()),
 487   '    Enable native headsets:    @0@'.format(get_option('bluez5-native-headset')),
 488   '    Enable  ofono headsets:    @0@'.format(get_option('bluez5-ofono-headset')),
 489   'Enable udev:                   @0@'.format(udev_dep.found()),
 490   '  Enable HAL->udev compat:     @0@'.format(get_option('hal-compat')),
 491   'Enable systemd:                @0@'.format(systemd_dep.found()),
 492 #  'Enable TCP Wrappers:           @0@'.format(${ENABLE_TCPWRAP}),
 493   'Enable libsamplerate:          @0@'.format(samplerate_dep.found()),
 494   'Enable IPv6:                   @0@'.format(get_option('ipv6')),
 495   'Enable OpenSSL (for Airtunes): @0@'.format(openssl_dep.found()),
 496   'Enable FFTW:                   @0@'.format(fftw_dep.found()),
 497 #  'Enable orc:                    @0@'.format(${ENABLE_ORC}),
 498   'Enable Adrian echo canceller:  @0@'.format(get_option('adrian-aec')),
 499   'Enable Speex (resampler, AEC): @0@'.format(speex_dep.found()),
 500   'Enable SoXR (resampler):       @0@'.format(soxr_dep.found()),
 501   'Enable WebRTC echo canceller:  @0@'.format(webrtc_dep.found()),
 502 #  'Enable gcov coverage:          @0@'.format(${ENABLE_GCOV}),
 503   'Enable unit tests:             @0@'.format(get_option('tests')),
 504   '',
 505   'Database:                      @0@'.format(get_option('database')),
 506   'Legacy Database Entry Support: @0@'.format(get_option('legacy-database-entry-format')),
 507   'System User:                   @0@'.format(cdata.get_unquoted('PA_SYSTEM_USER')),
 508   'System Group:                  @0@'.format(cdata.get_unquoted('PA_SYSTEM_GROUP')),
 509   'Access Group:                  @0@'.format(cdata.get_unquoted('PA_ACCESS_GROUP')),
 510 #  'Enable per-user EsounD socket: @0@'.format(${ENABLE_PER_USER_ESOUND_SOCKET}),
 511 #  'Force preopen:                 @0@'.format(${FORCE_PREOPEN}),
 512 #  'Preopened modules:             @0@'.format(${PREOPEN_MODS}),
 513 ]
 514
 515 message('\n    '.join(summary))
 516
 517 # Sanity checks
 518
 519 if not speex_dep.found() and not webrtc_dep.found() and not get_option('adrian-aec')
 520   error('At least one echo canceller implementation must be available!')
 521 endif
 522
 523 if samplerate_dep.found()
 524   warning('Support for libsamplerate is DEPRECATED')
 525 endif
 526
 527 if host_machine.system() != 'windows'
 528   if not dbus_dep.found()
 529     message = [
 530       'You do not have D-Bus support enabled. It is strongly recommended',
 531       'that you enable D-Bus support if your platform supports it.',
 532       'Many parts of PulseAudio use D-Bus, from ConsoleKit interaction',
 533       'to the Device Reservation Protocol to speak to JACK, Bluetooth',
 534       'support and even a native control protocol for communicating and',
 535       'controlling the PulseAudio daemon itself.',
 536     ]
 537     warning('\n' + '\n'.join(message))
 538   endif
 539   if not udev_dep.found()
 540     message = [
 541       'You do not have udev support enabled. It is strongly recommended',
 542       'that you enable udev support if your platform supports it as it is',
 543       'the primary method used to detect hardware audio devices (on Linux)',
 544       'and is thus a critical part of PulseAudio on that platform.',
 545     ]
 546     warning('\n' + '\n'.join(message))
 547   endif
 548   if not speex_dep.found()
 549     message = [
 550       'You do not have speex support enabled. It is strongly recommended',
 551       'that you enable speex support if your platform supports it as it is',
 552       'the primary method used for audio resampling and is thus a critical',
 553       'part of PulseAudio on that platform.',
 554     ]
 555     warning('\n' + '\n'.join(message))
 556   endif
 557 endif