meson.build

   1 project('gst-libav', 'c', 'cpp',
   2   version : '1.13.0.1',
   3   meson_version : '>= 0.36.0',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0]
  10 gst_version_minor = version_arr[1]
  11 gst_version_micro = version_arr[2]
  12 gst_version_nano = version_arr.get(3, 0)
  13
  14 libavfilter_dep = dependency('libavfilter', version: '>= 6.47.100')
  15 libavformat_dep = dependency('libavformat', version: '>= 57.41.100')
  16 libavcodec_dep = dependency('libavcodec', version: '>= 57.48.101')
  17 libavutil_dep = dependency('libavutil', version: '>= 55.28.100')
  18
  19 libav_deps = [libavfilter_dep, libavformat_dep, libavcodec_dep, libavutil_dep]
  20
  21 cc = meson.get_compiler('c')
  22
  23 check_ffmpeg_src = '''#include <libavcodec/avcodec.h>
  24 #if LIBAVCODEC_VERSION_MICRO >= 100
  25 /* FFmpeg uses 100+ as its micro version */
  26 #else
  27 #error libav provider should be FFmpeg
  28 #endif'''
  29
  30 if not cc.compiles(check_ffmpeg_src, dependencies : libav_deps, name : 'libav is provided by FFmpeg')
  31     error('Uncompatible libavcodec found')
  32 endif
  33
  34 cdata = configuration_data()
  35 cdata.set('LIBAV_SOURCE', '"system install"')
  36 cdata.set('PACKAGE_VERSION', '"@0@"'.format(gst_version))
  37 cdata.set('PACKAGE', '"gst-libav"')
  38
  39 # GStreamer package name and origin url
  40 gst_package_name = get_option('with-package-name')
  41 if gst_package_name == ''
  42   if gst_version_nano == 0
  43     cdata.set_quoted('GST_PACKAGE_NAME', 'GStreamer FFMPEG Plug-ins source release')
  44   elif gst_version_nano == 1
  45     cdata.set_quoted('GST_PACKAGE_NAME', 'GStreamer FFMPEG Plug-ins git')
  46   else
  47     cdata.set_quoted('GST_PACKAGE_NAME', 'GStreamer FFMPEG Plug-ins prerelease')
  48   endif
  49 endif
  50 cdata.set_quoted('GST_PACKAGE_ORIGIN', get_option('with-package-origin'))
  51
  52
  53 check_headers = [['unistd.h', 'HAVE_UNISTD_H']]
  54
  55 foreach h : check_headers
  56   if cc.has_header(h.get(0))
  57     cdata.set(h.get(1), 1)
  58   endif
  59 endforeach
  60
  61 gst_req = '>= @0@.@1@.0'.format(gst_version_major, gst_version_minor)
  62 gst_dep = dependency('gstreamer-1.0', version : gst_req,
  63   fallback : ['gstreamer', 'gst_dep'])
  64 gstbase_dep = dependency('gstreamer-base-1.0', version : gst_req,
  65   fallback : ['gstreamer', 'gst_base_dep'])
  66
  67 gstvideo_dep = dependency('gstreamer-video-1.0', version : gst_req,
  68     fallback : ['gst-plugins-base', 'video_dep'])
  69 gstaudio_dep = dependency('gstreamer-audio-1.0', version : gst_req,
  70     fallback : ['gst-plugins-base', 'audio_dep'])
  71 gstpbutils_dep = dependency('gstreamer-pbutils-1.0', version : gst_req,
  72     fallback : ['gst-plugins-base', 'pbutils_dep'])
  73 libm = cc.find_library('m', required : false)
  74
  75 configure_file(output : 'config.h', configuration : cdata)
  76
  77 gst_libav_args = ['-DHAVE_CONFIG_H']
  78 if cc.get_id() != 'msvc'
  79   gst_libav_args += ['-Wno-deprecated-declarations']
  80 else
  81   # Ignore several spurious warnings for things gstreamer does very commonly
  82   # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  83   # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  84   # NOTE: Only add warnings here if you are sure they're spurious
  85   add_project_arguments(
  86       '/wd4018', # implicit signed/unsigned conversion
  87       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  88       '/wd4244', # lossy type conversion (e.g. double -> int)
  89       '/wd4305', # truncating type conversion (e.g. double -> float)
  90       language : 'c')
  91 endif
  92
  93 if gst_dep.type_name() == 'internal'
  94     gst_proj = subproject('gstreamer')
  95
  96     if gst_proj.get_variable('disable_gst_debug')
  97         message('GStreamer debug system is disabled')
  98         add_project_arguments('-Wno-unused', language: 'c')
  99     else
 100         message('GStreamer debug system is enabled')
 101     endif
 102 else
 103     # We can't check that in the case of subprojects as we won't
 104     # be able to build against an internal dependency (which is not built yet)
 105     if not cc.compiles('''
 106 #include <gst/gstconfig.h>
 107 #ifdef GST_DISABLE_GST_DEBUG
 108 #error "debugging disabled, make compiler fail"
 109 #endif''' , dependencies: gst_dep)
 110         message('GStreamer debug system is disabled')
 111         add_project_arguments('-Wno-unused', language: 'c')
 112     else
 113         message('GStreamer debug system is enabled')
 114     endif
 115 endif
 116
 117 configinc = include_directories('.')
 118 plugins_install_dir = '@0@/gstreamer-1.0'.format(get_option('libdir'))
 119 subdir('ext/libav/')
 120
 121 python3 = find_program('python3')
 122 run_command(python3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')