meson.build

   1 project('gst-editing-services', 'c',
   2   version : '1.13.0.1',
   3   meson_version : '>= 0.36.0',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version = meson.project_version()
  10 version_arr = gst_version.split('.')
  11 gst_version_major = version_arr[0].to_int()
  12 gst_version_minor = version_arr[1].to_int()
  13 gst_version_micro = version_arr[2].to_int()
  14  if version_arr.length() == 4
  15   gst_version_nano = version_arr[3].to_int()
  16 else
  17   gst_version_nano = 0
  18 endif
  19
  20 apiversion = '1.0'
  21 soversion = 0
  22 # maintaining compatibility with the previous libtool versioning
  23 # current = minor * 100 + micro
  24 libversion = '@0@.@1@.0'.format(soversion, gst_version_minor * 100 + gst_version_micro)
  25
  26 glib_req = '>= 2.40.0'
  27 gst_req = '>= @0@.@1@.0'.format(gst_version_major, gst_version_minor)
  28
  29 cc = meson.get_compiler('c')
  30 # Ignore several spurious warnings for things gstreamer does very commonly
  31 # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  32 # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  33 # NOTE: Only add warnings here if you are sure they're spurious
  34 if cc.get_id() == 'msvc'
  35   add_project_arguments(
  36       '/wd4018', # implicit signed/unsigned conversion
  37       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  38       '/wd4244', # lossy type conversion (e.g. double -> int)
  39       '/wd4305', # truncating type conversion (e.g. double -> float)
  40       language : 'c')
  41 endif
  42
  43 # Symbol visibility
  44 if cc.has_argument('-fvisibility=hidden')
  45   add_project_arguments('-fvisibility=hidden', language: 'c')
  46 endif
  47
  48 # Disable strict aliasing
  49 if cc.has_argument('-fno-strict-aliasing')
  50   add_project_arguments('-fno-strict-aliasing', language: 'c')
  51 endif
  52
  53 cdata = configuration_data()
  54 cdata.set('VERSION', '"@0@"'.format(gst_version))
  55 cdata.set('PACKAGE', '"gst-editing-services"')
  56 cdata.set('PACKAGE_VERSION', '"@0@"'.format(gst_version))
  57 cdata.set('PACKAGE_BUGREPORT', '"http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer"')
  58 cdata.set('PACKAGE_NAME', '"GStreamer Editing Services"')
  59 cdata.set('GST_PACKAGE_NAME', '"GStreamer Editing Services"')
  60 cdata.set('GST_PACKAGE_ORIGIN', '"Unknown package origin"')
  61 cdata.set('GST_LICENSE', '"LGPL"')
  62
  63 # Mandatory GST deps
  64 gst_dep = dependency('gstreamer-' + apiversion, version : gst_req,
  65     fallback : ['gstreamer', 'gst_dep'])
  66 gstpbutils_dep = dependency('gstreamer-pbutils-' + apiversion, version : gst_req,
  67     fallback : ['gst-plugins-base', 'pbutils_dep'])
  68 gstvideo_dep = dependency('gstreamer-video-' + apiversion, version : gst_req,
  69     fallback : ['gst-plugins-base', 'video_dep'])
  70 gstbase_dep = dependency('gstreamer-base-1.0', version : gst_req,
  71     fallback : ['gstreamer', 'gst_base_dep'])
  72 if host_machine.system() != 'windows'
  73   gstcheck_dep = dependency('gstreamer-check-1.0', version : gst_req,
  74     fallback : ['gstreamer', 'gst_check_dep'], required: false)
  75 endif
  76 gstcontroller_dep = dependency('gstreamer-controller-1.0', version : gst_req,
  77   fallback : ['gstreamer', 'gst_controller_dep'])
  78 gstvalidate_dep = dependency('gst-validate-1.0', version : gst_req, required : false,
  79   fallback : ['gst-devtools', 'validate_dep'])
  80
  81 gio_dep = dependency('gio-2.0', fallback: ['glib', 'libgio_dep'])
  82 libxml_dep = dependency('libxml-2.0')
  83
  84 # TODO Properly port to Gtk 3
  85 # gtk_dep = dependency('gtk+-3.0', required : false)
  86
  87 libges_deps = [gst_dep, gstbase_dep, gstvideo_dep, gstpbutils_dep,
  88                gstcontroller_dep, gio_dep, libxml_dep]
  89
  90 if gstvalidate_dep.found()
  91     libges_deps = libges_deps + [gstvalidate_dep]
  92     cdata.set('HAVE_GST_VALIDATE', 1)
  93 endif
  94
  95 configure_file(output : 'config.h', configuration : cdata)
  96
  97
  98 gir = find_program('g-ir-scanner', required : false)
  99 gnome = import('gnome')
 100
 101 # Fixme, not very elegant.
 102 build_gir = gir.found() and not meson.is_cross_build() and not get_option('disable_introspection')
 103 gir_init_section = [ '--add-init-section=' + \
 104     'extern void gst_init(gint*,gchar**);' + \
 105     'extern void ges_init(void);' + \
 106     'g_setenv("GST_REGISTRY_1.0", "/no/way/this/exists.reg", TRUE);' + \
 107     'g_setenv("GST_PLUGIN_PATH_1_0", "", TRUE);' + \
 108     'g_setenv("GST_PLUGIN_SYSTEM_PATH_1_0", "", TRUE);' + \
 109     'g_setenv("GST_DEBUG", "0", TRUE);' + \
 110     'gst_init(NULL,NULL);' + \
 111     'ges_init();' ]
 112
 113 ges_c_args = ['-DHAVE_CONFIG_H']
 114 plugins_install_dir = '@0@/gstreamer-1.0'.format(get_option('libdir'))
 115
 116 if gst_dep.type_name() == 'internal'
 117     gst_proj = subproject('gstreamer')
 118
 119     if gst_proj.get_variable('disable_gst_debug')
 120         message('GStreamer debug system is disabled')
 121         add_project_arguments('-Wno-unused', language: 'c')
 122     else
 123         message('GStreamer debug system is enabled')
 124     endif
 125 else
 126     # We can't check that in the case of subprojects as we won't
 127     # be able to build against an internal dependency (which is not built yet)
 128     if not cc.compiles('''
 129 #include <gst/gstconfig.h>
 130 #ifdef GST_DISABLE_GST_DEBUG
 131 #error "debugging disabled, make compiler fail"
 132 #endif''' , dependencies: gst_dep)
 133         message('GStreamer debug system is disabled')
 134         add_global_arguments('-Wno-unused', language: 'c')
 135     else
 136         message('GStreamer debug system is enabled')
 137     endif
 138 endif
 139
 140 configinc = include_directories('.')
 141 subdir('ges')
 142 subdir('plugins')
 143 subdir('tools')
 144 subdir('pkgconfig')
 145 subdir('tests')
 146 subdir('examples')
 147
 148 if build_machine.system() == 'windows'
 149   message('Disabling gtk-doc while building on Windows')
 150 elif get_option('disable_gtkdoc')
 151   message('gtk-doc is disabled via options')
 152 else
 153   if find_program('gtkdoc-scan', required : false).found()
 154     subdir('docs')
 155   else
 156     message('Not building documentation as gtk-doc was not found')
 157   endif
 158 endif
 159
 160 python3 = import('python3').find_python()
 161 run_command(python3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')