meson.build

   1 project('gst-plugins-good', 'c',
   2   version : '1.13.0.1',
   3   meson_version : '>= 0.36.0',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0]
  10 gst_version_minor = version_arr[1]
  11 gst_version_micro = version_arr[2]
  12 if version_arr.length() == 4
  13   gst_version_nano = version_arr[3]
  14 else
  15   gst_version_nano = 0
  16 endif
  17
  18 glib_req = '>= 2.40.0'
  19 gst_req = '>= @0@.@1@.0'.format(gst_version_major, gst_version_minor)
  20
  21 api_version = '1.0'
  22
  23 plugins_install_dir = '@0@/gstreamer-1.0'.format(get_option('libdir'))
  24
  25 cc = meson.get_compiler('c')
  26
  27 if cc.get_id() == 'msvc'
  28   # Ignore several spurious warnings for things gstreamer does very commonly
  29   # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  30   # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  31   # NOTE: Only add warnings here if you are sure they're spurious
  32   add_project_arguments(
  33       '/wd4018', # implicit signed/unsigned conversion
  34       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  35       '/wd4244', # lossy type conversion (e.g. double -> int)
  36       '/wd4305', # truncating type conversion (e.g. double -> float)
  37       language : 'c')
  38   # Disable SAFESEH with MSVC for plugins and libs that use external deps that
  39   # are built with MinGW
  40   noseh_link_args = ['/SAFESEH:NO']
  41 else
  42   noseh_link_args = []
  43 endif
  44
  45 # Symbol visibility
  46 if cc.has_argument('-fvisibility=hidden')
  47   add_project_arguments('-fvisibility=hidden', language: 'c')
  48 endif
  49
  50 cdata = configuration_data()
  51
  52 check_headers = [
  53   ['HAVE_DLFCN_H', 'dlfcn.h'],
  54   ['HAVE_FCNTL_H', 'fcntl.h'],
  55   ['HAVE_INTTYPES_H', 'inttypes.h'],
  56   ['HAVE_MEMORY_H', 'memory.h'],
  57   ['HAVE_PROCESS_H', 'process.h'],
  58   ['HAVE_STDINT_H', 'stdint.h'],
  59   ['HAVE_STDLIB_H', 'stdlib.h'],
  60   ['HAVE_STRINGS_H', 'strings.h'],
  61   ['HAVE_STRING_H', 'string.h'],
  62   ['HAVE_SYS_IOCTL_H', 'sys/ioctl.h'],
  63   ['HAVE_SYS_PARAM_H', 'sys/param.h'],
  64   ['HAVE_SYS_SOCKET_H', 'sys/socket.h'],
  65   ['HAVE_SYS_STAT_H', 'sys/stat.h'],
  66   ['HAVE_SYS_TIME_H', 'sys/time.h'],
  67   ['HAVE_SYS_TYPES_H', 'sys/types.h'],
  68   ['HAVE_UNISTD_H', 'unistd.h'],
  69 ]
  70
  71 foreach h : check_headers
  72   if cc.has_header(h.get(1))
  73     cdata.set(h.get(0), 1)
  74   endif
  75 endforeach
  76
  77 check_functions = [
  78   ['HAVE_ASINH', 'asinh', '#include<math.h>'],
  79   ['HAVE_CLOCK_GETTIME', 'clock_gettime', '#include<time.h>'],
  80   ['HAVE_COSH', 'cosh', '#include<math.h>'],
  81 # check token HAVE_CPU_ALPHA
  82 # check token HAVE_CPU_ARM
  83 # check token HAVE_CPU_CRIS
  84 # check token HAVE_CPU_CRISV32
  85 # check token HAVE_CPU_HPPA
  86 # check token HAVE_CPU_I386
  87 # check token HAVE_CPU_IA64
  88 # check token HAVE_CPU_M68K
  89 # check token HAVE_CPU_MIPS
  90 # check token HAVE_CPU_PPC
  91 # check token HAVE_CPU_PPC64
  92 # check token HAVE_CPU_S390
  93 # check token HAVE_CPU_SPARC
  94 # check token HAVE_CPU_X86_64
  95   ['HAVE_DCGETTEXT', 'dcgettext', '#include<libintl.h>'],
  96 # check token HAVE_DIRECTSOUND
  97 # check token HAVE_EXPERIMENTAL
  98 # check token HAVE_EXTERNAL
  99 # check token HAVE_FPCLASS
 100 # check token HAVE_GCC_ASM
 101   ['HAVE_GETPAGESIZE', 'getpagesize', '#include<unistd.h>'],
 102 # check token HAVE_GETTEXT
 103 # check token HAVE_GST_V4L2
 104 # check token HAVE_IOS
 105   ['HAVE_ISINF', 'isinf', '#include<math.h>'],
 106 # check token HAVE_LIBV4L2
 107   ['HAVE_MMAP', 'mmap', '#include<sys/mman.h>'],
 108   ['HAVE_MMAP64', 'mmap64', '#include<sys/mman.h>'],
 109 # check token HAVE_OSX_AUDIO
 110 # check token HAVE_OSX_VIDEO
 111 # check token HAVE_RDTSC
 112   ['HAVE_SINH', 'sinh', '#include<math.h>'],
 113 # check token HAVE_WAVEFORM
 114 ]
 115
 116 libm = cc.find_library('m', required : false)
 117
 118 foreach f : check_functions
 119   if cc.has_function(f.get(1), prefix : f.get(2), dependencies : libm)
 120     cdata.set(f.get(0), 1)
 121   endif
 122 endforeach
 123
 124 cdata.set('SIZEOF_CHAR', cc.sizeof('char'))
 125 cdata.set('SIZEOF_INT', cc.sizeof('int'))
 126 cdata.set('SIZEOF_LONG', cc.sizeof('long'))
 127 cdata.set('SIZEOF_SHORT', cc.sizeof('short'))
 128 cdata.set('SIZEOF_VOIDP', cc.sizeof('void*'))
 129
 130 # Here be fixmes.
 131 # FIXME: check if this is correct
 132 cdata.set('HAVE_CPU_X86_64', host_machine.cpu() == 'amd64')
 133 cdata.set('HAVE_GCC_ASM', cc.get_id() != 'msvc')
 134 cdata.set('VERSION', '"@0@"'.format(gst_version))
 135 cdata.set('PACKAGE_VERSION', '"@0@"'.format(gst_version))
 136 cdata.set('GST_LICENSE', '"LGPL"')
 137 cdata.set('PACKAGE', '"gst-plugins-good"')
 138 cdata.set('GETTEXT_PACKAGE', '"gst-plugins-good-1.0"')
 139
 140 # GStreamer package name and origin url
 141 gst_package_name = get_option('with-package-name')
 142 if gst_package_name == ''
 143   if gst_version_nano == 0
 144     gst_package_name = 'GStreamer Good Plug-ins source release'
 145   elif gst_version_nano == 1
 146     gst_package_name = 'GStreamer Good Plug-ins git'
 147   else
 148     gst_package_name = 'GStreamer Good Plug-ins prerelease'
 149   endif
 150 endif
 151 cdata.set_quoted('GST_PACKAGE_NAME', gst_package_name)
 152 cdata.set_quoted('GST_PACKAGE_ORIGIN', get_option('with-package-origin'))
 153
 154 # Mandatory GST deps
 155 gst_dep = dependency('gstreamer-1.0', version : gst_req,
 156   fallback : ['gstreamer', 'gst_dep'])
 157 gstbase_dep = dependency('gstreamer-base-1.0', version : gst_req,
 158   fallback : ['gstreamer', 'gst_base_dep'])
 159 gstnet_dep = dependency('gstreamer-net-1.0', version : gst_req,
 160   fallback : ['gstreamer', 'gst_net_dep'])
 161 if host_machine.system() != 'windows'
 162   gstcheck_dep = dependency('gstreamer-check-1.0', version : gst_req,
 163     fallback : ['gstreamer', 'gst_check_dep'])
 164 endif
 165 gstcontroller_dep = dependency('gstreamer-controller-1.0', version : gst_req,
 166   fallback : ['gstreamer', 'gst_controller_dep'])
 167
 168 gstpbutils_dep = dependency('gstreamer-pbutils-1.0', version : gst_req,
 169     fallback : ['gst-plugins-base', 'pbutils_dep'])
 170 gstallocators_dep = dependency('gstreamer-allocators-1.0', version : gst_req,
 171     fallback : ['gst-plugins-base', 'allocators_dep'])
 172 gstapp_dep = dependency('gstreamer-app-1.0', version : gst_req,
 173     fallback : ['gst-plugins-base', 'app_dep'])
 174 gstaudio_dep = dependency('gstreamer-audio-1.0', version : gst_req,
 175     fallback : ['gst-plugins-base', 'audio_dep'])
 176 gstfft_dep = dependency('gstreamer-fft-1.0', version : gst_req,
 177     fallback : ['gst-plugins-base', 'fft_dep'])
 178 gstriff_dep = dependency('gstreamer-riff-1.0', version : gst_req,
 179     fallback : ['gst-plugins-base', 'riff_dep'])
 180 gstrtp_dep = dependency('gstreamer-rtp-1.0', version : gst_req,
 181     fallback : ['gst-plugins-base', 'rtp_dep'])
 182 gstrtsp_dep = dependency('gstreamer-rtsp-1.0', version : gst_req,
 183     fallback : ['gst-plugins-base', 'rtsp_dep'])
 184 gstsdp_dep = dependency('gstreamer-sdp-1.0', version : gst_req,
 185     fallback : ['gst-plugins-base', 'sdp_dep'])
 186 gsttag_dep = dependency('gstreamer-tag-1.0', version : gst_req,
 187     fallback : ['gst-plugins-base', 'tag_dep'])
 188 gstvideo_dep = dependency('gstreamer-video-1.0', version : gst_req,
 189     fallback : ['gst-plugins-base', 'video_dep'])
 190
 191 zlib_dep = dependency('zlib')
 192 bz2lib = cc.find_library('bz2', required : false)
 193 glib_deps = [dependency('glib-2.0', version : glib_req, fallback: ['glib', 'libglib_dep']),
 194              dependency('gobject-2.0', fallback: ['glib', 'libgobject_dep'])]
 195 gio_dep = dependency('gio-2.0', fallback: ['glib', 'libgio_dep'])
 196
 197 cdata.set('HAVE_ZLIB', 1)
 198 if bz2lib.found()
 199   cdata.set('HAVE_BZ2', 1)
 200 endif
 201
 202 # Check all of the things.
 203 # TODO: None of these are actually used yet because
 204 # the build files haven't been written
 205 deps = [
 206   ['gtk_dep','gtk+-3.0', '', ''],
 207   ['gtkx_dep','gtk+-x11-3.0', '', ''],
 208   ['caca_dep','caca', '', ''],
 209   ['libraw1394_dep','libraw1394', '>=2.0.0', ''],
 210   ['libiec61883_dep','libiec61883', '>=1.0.0', ''],
 211 ]
 212
 213 foreach d : deps
 214   varname = d[0]
 215   depname = d[1]
 216   version = d[2]
 217   confhname = d[3]
 218   if version == ''
 219     curdep = dependency(depname, required : false)
 220   else
 221     curdep = dependency(depname, required : false, version : version)
 222   endif
 223   set_variable(varname, curdep)
 224   if curdep.found() and confhname != ''
 225     cdata.set(confhname, 1)
 226   endif
 227 endforeach
 228
 229 gst_plugins_good_args = ['-DHAVE_CONFIG_H']
 230 configinc = include_directories('.')
 231 libsinc = include_directories('gst-libs')
 232
 233 have_orcc = false
 234 orcc_args = []
 235 if get_option('use_orc') != 'no'
 236   need_orc = get_option('use_orc') == 'yes'
 237   # Used by various libraries/elements that use Orc code
 238   orc_dep = dependency('orc-0.4', version : '>= 0.4.17', required : need_orc)
 239   orcc = find_program('orcc', required : need_orc)
 240   if orc_dep.found() and orcc.found()
 241     have_orcc = true
 242     orcc_args = [orcc, '--include', 'glib.h']
 243     cdata.set('HAVE_ORC', 1)
 244   else
 245     message('Orc Compiler not found, will use backup C code')
 246     cdata.set('DISABLE_ORC', 1)
 247   endif
 248 else
 249   cdata.set('DISABLE_ORC', 1)
 250 endif
 251
 252 if gst_dep.type_name() == 'internal'
 253     gst_proj = subproject('gstreamer')
 254
 255     if gst_proj.get_variable('disable_gst_debug')
 256         message('GStreamer debug system is disabled')
 257         add_project_arguments('-Wno-unused', language: 'c')
 258     else
 259         message('GStreamer debug system is enabled')
 260     endif
 261 else
 262     # We can't check that in the case of subprojects as we won't
 263     # be able to build against an internal dependency (which is not built yet)
 264     if not cc.compiles('''
 265 #include <gst/gstconfig.h>
 266 #ifdef GST_DISABLE_GST_DEBUG
 267 #error "debugging disabled, make compiler fail"
 268 #endif''' , dependencies: gst_dep)
 269         message('GStreamer debug system is disabled')
 270         add_project_arguments('-Wno-unused', language: 'c')
 271     else
 272         message('GStreamer debug system is enabled')
 273     endif
 274 endif
 275
 276 presetdir = join_paths(get_option('datadir'), 'gstreamer-' + api_version, 'presets')
 277
 278 subdir('gst')
 279 subdir('sys')
 280 subdir('ext')
 281 subdir('tests')
 282 subdir('po')
 283 subdir('pkgconfig')
 284
 285 configure_file(output : 'config.h', configuration : cdata)
 286
 287 python3 = import('python3').find_python()
 288 run_command(python3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')