meson.build

   1 project('gst-plugins-base', 'c',
   2   version : '1.15.0.1',
   3   meson_version : '>= 0.47',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0].to_int()
  10 gst_version_minor = version_arr[1].to_int()
  11 gst_version_micro = version_arr[2].to_int()
  12 if version_arr.length() == 4
  13   gst_version_nano = version_arr[3].to_int()
  14 else
  15   gst_version_nano = 0
  16 endif
  17 gst_version_is_dev = gst_version_minor % 2 == 1 and gst_version_micro < 90
  18
  19 have_cxx = add_languages('cpp', required : false)
  20 have_objc = add_languages('objc', required : false)
  21
  22 glib_req = '>= 2.40.0'
  23 orc_req = '>= 0.4.24'
  24 gst_req = '>= @0@.@1@.0'.format(gst_version_major, gst_version_minor)
  25
  26 api_version = '1.0'
  27 soversion = 0
  28 # maintaining compatibility with the previous libtool versioning
  29 # current = minor * 100 + micro
  30 # FIXME: should be able to convert string to int somehow so we can just do maths
  31 libversion = '@0@.@1@.0'.format(soversion, gst_version_minor * 100 + gst_version_micro)
  32
  33 plugins_install_dir = '@0@/gstreamer-1.0'.format(get_option('libdir'))
  34
  35 cc = meson.get_compiler('c')
  36 host_system = host_machine.system()
  37
  38 if cc.get_id() == 'msvc'
  39   # Ignore several spurious warnings for things gstreamer does very commonly
  40   # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  41   # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  42   # NOTE: Only add warnings here if you are sure they're spurious
  43   add_project_arguments(
  44       '/wd4018', # implicit signed/unsigned conversion
  45       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  46       '/wd4244', # lossy type conversion (e.g. double -> int)
  47       '/wd4305', # truncating type conversion (e.g. double -> float)
  48       language : 'c')
  49   # Disable SAFESEH with MSVC for plugins and libs that use external deps that
  50   # are built with MinGW
  51   noseh_link_args = ['/SAFESEH:NO']
  52 else
  53   noseh_link_args = []
  54 endif
  55
  56 if cc.has_link_argument('-Wl,-Bsymbolic-functions')
  57   add_project_link_arguments('-Wl,-Bsymbolic-functions', language : 'c')
  58 endif
  59
  60 # Symbol visibility
  61 if cc.has_argument('-fvisibility=hidden')
  62   add_project_arguments('-fvisibility=hidden', language: 'c')
  63 endif
  64
  65 # Disable strict aliasing
  66 if cc.has_argument('-fno-strict-aliasing')
  67   add_project_arguments('-fno-strict-aliasing', language: 'c')
  68 endif
  69
  70 # Define G_DISABLE_DEPRECATED for development versions
  71 if gst_version_is_dev
  72   message('Disabling deprecated GLib API')
  73   add_project_arguments('-DG_DISABLE_DEPRECATED', language: 'c')
  74 endif
  75
  76 cast_checks = get_option('gobject-cast-checks')
  77 if cast_checks.disabled() or (cast_checks.auto() and not gst_version_is_dev)
  78   message('Disabling GLib cast checks')
  79   add_project_arguments('-DG_DISABLE_CAST_CHECKS', language: 'c')
  80 endif
  81
  82 glib_asserts = get_option('glib-asserts')
  83 if glib_asserts.disabled() or (glib_asserts.auto() and not gst_version_is_dev)
  84   message('Disabling GLib asserts')
  85   add_project_arguments('-DG_DISABLE_ASSERT', language: 'c')
  86 endif
  87
  88 core_conf = configuration_data()
  89 check_headers = [
  90   ['HAVE_DLFCN_H', 'dlfcn.h'],
  91   ['HAVE_EMMINTRIN_H', 'emmintrin.h'],
  92   ['HAVE_INTTYPES_H', 'inttypes.h'],
  93   ['HAVE_MEMORY_H', 'memory.h'],
  94   ['HAVE_PROCESS_H', 'process.h'],
  95   ['HAVE_SMMINTRIN_H', 'smmintrin.h'],
  96   ['HAVE_STDINT_H', 'stdint.h'],
  97   ['HAVE_STDLIB_H', 'stdlib.h'],
  98   ['HAVE_STRINGS_H', 'strings.h'],
  99   ['HAVE_STRING_H', 'string.h'],
 100   ['HAVE_SYS_SOCKET_H', 'sys/socket.h'],
 101   ['HAVE_SYS_STAT_H', 'sys/stat.h'],
 102   ['HAVE_SYS_TYPES_H', 'sys/types.h'],
 103   ['HAVE_SYS_WAIT_H', 'sys/wait.h'],
 104   ['HAVE_UNISTD_H', 'unistd.h'],
 105   ['HAVE_WINSOCK2_H', 'winsock2.h'],
 106   ['HAVE_XMMINTRIN_H', 'xmmintrin.h'],
 107   ['HAVE_LINUX_DMA_BUF_H', 'linux/dma-buf.h'],
 108 ]
 109 foreach h : check_headers
 110   if cc.has_header(h.get(1))
 111     core_conf.set(h.get(0), 1)
 112   endif
 113 endforeach
 114
 115 check_functions = [
 116   ['HAVE_DCGETTEXT', 'dcgettext', '#include<libintl.h>'],
 117   ['HAVE_GMTIME_R', 'gmtime_r', '#include<time.h>'],
 118   ['HAVE_LRINTF', 'lrintf', '#include<math.h>'],
 119   ['HAVE_MMAP', 'mmap', '#include<sys/mman.h>'],
 120   ['HAVE_LOG2', 'log2', '#include<math.h>'],
 121 ]
 122
 123 libm = cc.find_library('m', required : false)
 124 foreach f : check_functions
 125   if cc.has_function(f.get(1), prefix : f.get(2), dependencies : libm)
 126     core_conf.set(f.get(0), 1)
 127   endif
 128 endforeach
 129
 130 core_conf.set('SIZEOF_CHAR', cc.sizeof('char'))
 131 core_conf.set('SIZEOF_INT', cc.sizeof('int'))
 132 core_conf.set('SIZEOF_LONG', cc.sizeof('long'))
 133 core_conf.set('SIZEOF_SHORT', cc.sizeof('short'))
 134 core_conf.set('SIZEOF_VOIDP', cc.sizeof('void*'))
 135
 136 core_conf.set_quoted('GETTEXT_PACKAGE', 'gst-plugins-base-1.0')
 137 core_conf.set_quoted('LOCALEDIR', join_paths(get_option('prefix'), get_option('localedir')))
 138 core_conf.set_quoted('PACKAGE', 'gst-plugins-base')
 139 core_conf.set_quoted('VERSION', gst_version)
 140 core_conf.set_quoted('PACKAGE_VERSION', gst_version)
 141 core_conf.set_quoted('GST_API_VERSION', api_version)
 142 core_conf.set_quoted('GST_DATADIR', join_paths(get_option('prefix'), get_option('datadir')))
 143 core_conf.set_quoted('GST_LICENSE', 'LGPL')
 144
 145 install_plugins_helper = get_option('install_plugins_helper')
 146 if install_plugins_helper == ''
 147   install_plugins_helper = join_paths(get_option('prefix'),
 148                                       get_option('libexecdir'),
 149                                       'gst-install-plugins-helper')
 150 endif
 151 core_conf.set_quoted('GST_INSTALL_PLUGINS_HELPER', install_plugins_helper)
 152
 153 warning_flags = [
 154   '-Wmissing-declarations',
 155   '-Wredundant-decls',
 156   '-Wundef',
 157   '-Wwrite-strings',
 158   '-Wformat',
 159   '-Wformat-nonliteral',
 160   '-Wformat-security',
 161   '-Winit-self',
 162   '-Wmissing-include-dirs',
 163   '-Waddress',
 164   '-Wno-multichar',
 165   '-Wvla',
 166   '-Wpointer-arith',
 167 ]
 168
 169 warning_c_flags = [
 170   '-Wmissing-prototypes',
 171   '-Wdeclaration-after-statement',
 172 ]
 173
 174 warning_cxx_flags = [
 175   '-Waggregate-return',
 176 ]
 177
 178 if have_cxx
 179   cxx = meson.get_compiler('cpp')
 180   foreach extra_arg : warning_cxx_flags
 181     if cxx.has_argument (extra_arg)
 182       add_project_arguments([extra_arg], language: 'cpp')
 183     endif
 184   endforeach
 185 endif
 186
 187 foreach extra_arg : warning_flags
 188   if cc.has_argument (extra_arg)
 189     add_project_arguments([extra_arg], language: 'c')
 190   endif
 191   if have_cxx and cxx.has_argument (extra_arg)
 192     add_project_arguments([extra_arg], language: 'cpp')
 193   endif
 194 endforeach
 195
 196 foreach extra_arg : warning_c_flags
 197   if cc.has_argument (extra_arg)
 198     add_project_arguments([extra_arg], language: 'c')
 199   endif
 200 endforeach
 201
 202 # GStreamer package name and origin url
 203 gst_package_name = get_option('package-name')
 204 if gst_package_name == ''
 205   if gst_version_nano == 0
 206     gst_package_name = 'GStreamer Base Plug-ins source release'
 207   elif gst_version_nano == 1
 208     gst_package_name = 'GStreamer Base Plug-ins git'
 209   else
 210     gst_package_name = 'GStreamer Base Plug-ins prerelease'
 211   endif
 212 endif
 213 core_conf.set_quoted('GST_PACKAGE_NAME', gst_package_name)
 214 core_conf.set_quoted('GST_PACKAGE_ORIGIN', get_option('package-origin'))
 215
 216 # FIXME: These should be configure options
 217 core_conf.set_quoted('DEFAULT_VIDEOSINK', 'autovideosink')
 218 core_conf.set_quoted('DEFAULT_AUDIOSINK', 'autoaudiosink')
 219
 220 # Set whether the audioresampling method should be detected at runtime
 221 core_conf.set('AUDIORESAMPLE_FORMAT_' + get_option('audioresample_format').to_upper(), true)
 222
 223 gst_plugins_base_args = ['-DHAVE_CONFIG_H']
 224 if get_option('default_library') == 'static'
 225   gst_plugins_base_args += ['-DGST_STATIC_COMPILATION']
 226 endif
 227
 228 # X11 checks are for sys/ and tests/
 229 x11_dep = dependency('x11', required : get_option('x11'))
 230 # GLib checks are for the entire project
 231 # Almost everything that uses glib also uses gobject
 232 glib_deps = [dependency('glib-2.0', version : glib_req, fallback: ['glib', 'libglib_dep']),
 233              dependency('gobject-2.0', fallback: ['glib', 'libgobject_dep'])]
 234 # GIO is used by the GIO plugin, and by the TCP, SDP, and RTSP plugins
 235 gio_dep = dependency('gio-2.0', fallback: ['glib', 'libgio_dep'])
 236 giounix_dep = dependency('gio-unix-2.0', version : glib_req, required : host_system != 'windows',
 237                          fallback: ['glib', 'libgiounix_dep'])
 238 gmodule_dep = dependency('gmodule-no-export-2.0',
 239                          fallback: ['glib', 'libgmodule_dep'])
 240
 241 # some of the examples can use gdk-pixbuf and GTK+3
 242 gdk_pixbuf_dep = dependency('gdk-pixbuf-2.0', required : get_option('examples'))
 243 gtk_dep = dependency('gtk+-3.0', version : '>= 3.10', required : get_option('examples'))
 244 # TODO: https://github.com/mesonbuild/meson/issues/3941
 245 if not get_option('x11').disabled()
 246   gtk_x11_dep = dependency('gtk+-x11-3.0', version : '>= 3.10', required : get_option('examples'))
 247 else
 248   gtk_x11_dep = dependency('', required : false)
 249 endif
 250 # gtk+ quartz backend is only available on macOS
 251 if host_system == 'darwin'
 252   gtk_quartz_dep = dependency('gtk+-quartz-3.0', version : '>= 3.10', required : get_option('examples'))
 253 else
 254   gtk_quartz_dep = dependency('', required : false)
 255 endif
 256
 257 core_conf.set('HAVE_X', x11_dep.found())
 258 core_conf.set('HAVE_GIO_UNIX_2_0', giounix_dep.found())
 259
 260 if gio_dep.type_name() == 'pkgconfig'
 261     core_conf.set_quoted('GIO_MODULE_DIR',
 262         gio_dep.get_pkgconfig_variable('giomoduledir'))
 263     core_conf.set_quoted('GIO_LIBDIR',
 264         gio_dep.get_pkgconfig_variable('libdir'))
 265     core_conf.set_quoted('GIO_PREFIX',
 266         gio_dep.get_pkgconfig_variable('prefix'))
 267 else
 268     core_conf.set_quoted('GIO_MODULE_DIR', join_paths(get_option('prefix'),
 269       get_option('libdir'), 'gio/modules'))
 270     core_conf.set_quoted('GIO_LIBDIR', join_paths(get_option('prefix'),
 271       get_option('libdir')))
 272     core_conf.set_quoted('GIO_PREFIX', get_option('prefix'))
 273 endif
 274
 275 configinc = include_directories('.')
 276 libsinc = include_directories('gst-libs')
 277
 278 # To use the subproject make subprojects directory
 279 # and put gstreamer meson git there (symlinking is fine)
 280 gst_dep = dependency('gstreamer-1.0', version : gst_req,
 281   fallback : ['gstreamer', 'gst_dep'])
 282 gst_base_dep = dependency('gstreamer-base-1.0', version : gst_req,
 283   fallback : ['gstreamer', 'gst_base_dep'])
 284 gst_net_dep = dependency('gstreamer-net-1.0', version : gst_req,
 285   fallback : ['gstreamer', 'gst_net_dep'])
 286 if host_system != 'windows'
 287   gst_check_dep = dependency('gstreamer-check-1.0', version : gst_req,
 288     required : get_option('tests'),
 289     fallback : ['gstreamer', 'gst_check_dep'])
 290 endif
 291 gst_controller_dep = dependency('gstreamer-controller-1.0', version : gst_req,
 292   fallback : ['gstreamer', 'gst_controller_dep'])
 293
 294 have_orcc = false
 295 orcc_args = []
 296 # Used by various libraries/elements that use Orc code
 297 orc_dep = dependency('orc-0.4', version : orc_req, required : get_option('orc'))
 298 orcc = find_program('orcc', required : get_option('orc'))
 299 if orc_dep.found() and orcc.found()
 300   have_orcc = true
 301   orcc_args = [orcc, '--include', 'glib.h']
 302   core_conf.set('HAVE_ORC', 1)
 303 else
 304   message('Orc Compiler not found or disabled, will use backup C code')
 305   core_conf.set('DISABLE_ORC', 1)
 306 endif
 307
 308 # Used to build SSE* things in audio-resampler
 309 sse_args = '-msse'
 310 sse2_args = '-msse2'
 311 sse41_args = '-msse4.1'
 312
 313 have_sse = cc.has_argument(sse_args)
 314 have_sse2 = cc.has_argument(sse2_args)
 315 have_sse41 = cc.has_argument(sse41_args)
 316
 317 if gst_dep.type_name() == 'internal'
 318     gst_proj = subproject('gstreamer')
 319
 320     if not gst_proj.get_variable('gst_debug')
 321         message('GStreamer debug system is disabled')
 322         add_project_arguments('-Wno-unused', language: 'c')
 323     else
 324         message('GStreamer debug system is enabled')
 325     endif
 326 else
 327     # We can't check that in the case of subprojects as we won't
 328     # be able to build against an internal dependency (which is not built yet)
 329     if not cc.compiles('''
 330 #include <gst/gstconfig.h>
 331 #ifdef GST_DISABLE_GST_DEBUG
 332 #error "debugging disabled, make compiler fail"
 333 #endif''' , dependencies: gst_dep)
 334         message('GStreamer debug system is disabled')
 335         add_project_arguments('-Wno-unused', language: 'c')
 336     else
 337         message('GStreamer debug system is enabled')
 338     endif
 339 endif
 340
 341 gir = find_program('g-ir-scanner', required : get_option('introspection'))
 342 gnome = import('gnome')
 343 build_gir = gir.found() and not meson.is_cross_build()
 344 gir_init_section = [ '--add-init-section=extern void gst_init(gint*,gchar**);' + \
 345     'g_setenv("GST_REGISTRY_DISABLE", "yes", TRUE);' + \
 346     'g_setenv("GST_REGISTRY_1.0", "@0@", TRUE);'.format(meson.current_build_dir() + '/gir_empty_registry.reg') + \
 347     'g_setenv("GST_PLUGIN_PATH_1_0", "", TRUE);' + \
 348     'g_setenv("GST_PLUGIN_SYSTEM_PATH_1_0", "", TRUE);' + \
 349     'gst_init(NULL,NULL);' ]
 350
 351 pkgconfig = import('pkgconfig')
 352 plugins_pkgconfig_install_dir = join_paths(plugins_install_dir, 'pkgconfig')
 353 if get_option('default_library') == 'shared'
 354   # If we don't build static plugins there is no need to generate pc files
 355   plugins_pkgconfig_install_dir = disabler()
 356 endif
 357
 358 subdir('gst-libs')
 359 subdir('gst')
 360 subdir('ext')
 361 subdir('sys')
 362 if not get_option('tools').disabled()
 363   subdir('tools')
 364 endif
 365 subdir('tests')
 366 subdir('pkgconfig')
 367
 368 # xgettext is optional (on Windows for instance)
 369 if find_program('xgettext', required : get_option('nls')).found()
 370   core_conf.set('ENABLE_NLS', 1)
 371   subdir('po')
 372 endif
 373
 374 if build_machine.system() == 'windows'
 375   message('Disabling gtk-doc while building on Windows')
 376 else
 377   if find_program('gtkdoc-scan', required : get_option('gtk_doc')).found()
 378     subdir('docs')
 379   else
 380     message('Not building documentation as gtk-doc was not found')
 381   endif
 382 endif
 383
 384 # Use core_conf after all subdirs have set values
 385 configure_file(output : 'config.h', configuration : core_conf)
 386
 387 python3 = import('python3').find_python()
 388 run_command(python3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')