meson.build

   1 project('pulseaudio', 'c', 'cpp',
   2         version : run_command(find_program('git-version-gen'), join_paths(meson.current_source_dir(), '.tarball-version')).stdout().strip(),
   3         meson_version : '>= 0.50.0',
   4         default_options : [ 'c_std=gnu11', 'cpp_std=c++11' ]
   5         )
   6
   7 pa_version_str = meson.project_version()
   8 # For tarballs, the first split will do nothing, but for builds in git, we
   9 # split out suffixes when there are commits since the last tag
  10 # (e.g.: v11.99.1-3-gad14bdb24 -> v11.99.1)
  11 version_split = pa_version_str.split('-')[0].split('.')
  12 pa_version_major = version_split[0].split('v')[0]
  13 pa_version_minor = version_split[1]
  14 if version_split.length() > 2
  15   pa_version_micro = version_split[2]
  16 else
  17   pa_version_micro = '0'
  18 endif
  19 pa_version_major_minor = pa_version_major + '.' + pa_version_minor
  20
  21 pa_api_version = 12
  22 pa_protocol_version = 35
  23
  24 # The stable ABI for client applications, for the version info x:y:z
  25 # always will hold x=z
  26 libpulse_version_info = [23, 0, 23]
  27
  28 # A simplified, synchronous, ABI-stable interface for client
  29 # applications, for the version info x:y:z always will hold x=z
  30 libpulse_simple_version_info = [1, 1, 1]
  31
  32 # The ABI-stable GLib adapter for client applications, for the version
  33 # info x:y:z always will hold x=z
  34 libpulse_mainloop_glib_version_info = [0, 6, 0]
  35
  36 libpulse_version = '@0@.@1@.@2@'.format(
  37   libpulse_version_info[0] - libpulse_version_info[2],
  38   libpulse_version_info[0],
  39   libpulse_version_info[1],
  40 )
  41
  42 libpulse_simple_version = '@0@.@1@.@2@'.format(
  43   libpulse_simple_version_info[0] - libpulse_simple_version_info[2],
  44   libpulse_simple_version_info[0],
  45   libpulse_simple_version_info[1],
  46 )
  47
  48 libpulse_mainloop_glib_version = '@0@.@1@.@2@'.format(
  49   libpulse_mainloop_glib_version_info[0] - libpulse_mainloop_glib_version_info[2],
  50   libpulse_mainloop_glib_version_info[0],
  51   libpulse_mainloop_glib_version_info[1],
  52 )
  53
  54 # Paths
  55
  56 prefix = get_option('prefix')
  57 assert(prefix.startswith('/'), 'Prefix is not absolute: "@0@"'.format(prefix))
  58
  59 bindir = join_paths(prefix, get_option('bindir'))
  60 includedir = join_paths(prefix, get_option('includedir'))
  61 libdir = join_paths(prefix, get_option('libdir'))
  62 libexecdir = join_paths(prefix, get_option('libexecdir'))
  63 mandir = join_paths(prefix, get_option('mandir'))
  64 datadir = join_paths(prefix, get_option('datadir'))
  65 localedir = join_paths(prefix, get_option('localedir'))
  66 localstatedir = join_paths(prefix, get_option('localstatedir'))
  67 sysconfdir = join_paths(prefix, get_option('sysconfdir'))
  68 privlibdir = join_paths(libdir, 'pulseaudio')
  69
  70 if host_machine.system() == 'windows'
  71   # Windows only supports loading libraries from the same dir as the executable
  72   privlibdir = bindir
  73 endif
  74
  75 alsadatadir = get_option('alsadatadir')
  76 if alsadatadir == ''
  77   alsadatadir = join_paths(datadir, 'pulseaudio', 'alsa-mixer')
  78 endif
  79
  80 pkgconfigdir = join_paths(libdir, 'pkgconfig')
  81 pulselibexecdir = join_paths(libexecdir, 'pulse')
  82 pulsesysconfdir = join_paths(sysconfdir, 'pulse')
  83
  84 modlibexecdir = get_option('modlibexecdir')
  85 if modlibexecdir == ''
  86   modlibexecdir = join_paths(libdir, 'pulse-' + pa_version_major_minor, 'modules')
  87 endif
  88
  89 padsplibdir = get_option('padsplibdir')
  90 if padsplibdir == ''
  91   padsplibdir = privlibdir
  92 endif
  93
  94 pulsedsp_location = get_option('pulsedsp-location')
  95 if pulsedsp_location == ''
  96   pulsedsp_location = join_paths(prefix, padsplibdir)
  97 endif
  98
  99 systemduserunitdir = get_option('systemduserunitdir')
 100 # the default value is set below
 101
 102 udevrulesdir = get_option('udevrulesdir')
 103 if udevrulesdir == ''
 104   # absolute path, otherwise meson prepends the prefix
 105   udevrulesdir = '/lib/udev/rules.d'
 106 endif
 107
 108 vapidir = join_paths(datadir, 'vala', 'vapi')
 109
 110 bashcompletiondir = get_option('bashcompletiondir')
 111 if bashcompletiondir == ''
 112   bash_completion_dep = dependency('bash-completion', required : false)
 113   if bash_completion_dep.found()
 114     bashcompletiondir = bash_completion_dep.get_pkgconfig_variable('completionsdir')
 115   else
 116     bashcompletiondir = join_paths(datadir, 'bash-completion', 'completions')
 117   endif
 118 endif
 119
 120 zshcompletiondir = get_option('zshcompletiondir')
 121 if zshcompletiondir == ''
 122   zshcompletiondir = join_paths(datadir, 'zsh', 'site-functions')
 123 endif
 124
 125 # Configuration data
 126
 127 cc = meson.get_compiler('c')
 128
 129 cdata = configuration_data()
 130 cdata.set_quoted('PACKAGE', 'pulseaudio')
 131 cdata.set_quoted('PACKAGE_NAME', 'pulseaudio')
 132 cdata.set_quoted('PACKAGE_VERSION', pa_version_str)
 133 cdata.set('PA_MAJOR', pa_version_major)
 134 cdata.set('PA_MINOR', pa_version_minor)
 135 cdata.set('PA_API_VERSION', pa_api_version)
 136 cdata.set('PA_PROTOCOL_VERSION', pa_protocol_version)
 137 cdata.set_quoted('PA_MACHINE_ID', join_paths(sysconfdir, 'machine-id'))
 138 cdata.set_quoted('PA_MACHINE_ID_FALLBACK', join_paths(localstatedir, 'lib', 'dbus', 'machine-id'))
 139 cdata.set_quoted('PA_SRCDIR', join_paths(meson.current_source_dir(), 'src'))
 140 cdata.set_quoted('PA_BUILDDIR', meson.current_build_dir())
 141 cdata.set_quoted('PA_SOEXT', '.so')
 142 cdata.set_quoted('PA_DEFAULT_CONFIG_DIR', pulsesysconfdir)
 143 cdata.set('PA_DEFAULT_CONFIG_DIR_UNQUOTED', pulsesysconfdir)
 144 cdata.set_quoted('PA_BINARY', join_paths(bindir, 'pulseaudio'))
 145 cdata.set_quoted('PA_SYSTEM_RUNTIME_PATH', join_paths(localstatedir, 'run', 'pulse'))
 146 cdata.set_quoted('PA_SYSTEM_CONFIG_PATH', join_paths(localstatedir, 'lib', 'pulse'))
 147 cdata.set_quoted('PA_SYSTEM_STATE_PATH', join_paths(localstatedir, 'lib', 'pulse'))
 148 cdata.set_quoted('PA_DLSEARCHPATH', modlibexecdir)
 149 cdata.set_quoted('PA_SYSTEM_USER', get_option('system_user'))
 150 cdata.set_quoted('PA_SYSTEM_GROUP', get_option('system_group'))
 151 cdata.set_quoted('PA_ACCESS_GROUP', get_option('access_group'))
 152 cdata.set_quoted('PA_CFLAGS', 'Not yet supported on meson')
 153 cdata.set_quoted('PA_ALSA_PATHS_DIR', join_paths(alsadatadir, 'paths'))
 154 cdata.set_quoted('PA_ALSA_PROFILE_SETS_DIR', join_paths(alsadatadir, 'profile-sets'))
 155 cdata.set_quoted('DESKTOPFILEDIR', join_paths(datadir, 'applications'))
 156 cdata.set_quoted('PULSE_LOCALEDIR', localedir)
 157 cdata.set_quoted('GETTEXT_PACKAGE', 'pulseaudio')
 158 cdata.set('ENABLE_NLS', 1)
 159 cdata.set('top_srcdir', meson.source_root())
 160
 161 # Platform specifics
 162 # First some defaults to keep config file generation happy
 163 cdata.set('HAVE_COREAUDIO', 0)
 164 cdata.set('HAVE_WAVEOUT', 0)
 165
 166 platform_socket_dep = []
 167 platform_dep = []
 168
 169 # FIXME: This was not tested. Maybe some flags should better be CFLAGS,
 170 # rather than ending up in the config.h file?
 171 if host_machine.system() == 'darwin'
 172   cdata.set('OS_IS_DARWIN', 1)
 173   cdata.set('_DARWIN_C_SOURCE', '200112L') # Needed to get NSIG on Mac OS
 174 elif host_machine.system() == 'windows'
 175   cdata.set('OS_IS_WIN32', 1)
 176   cdata.set('HAVE_WINDOWS_H', 1)
 177   cdata.set('HAVE_WAVEOUT', 1)
 178   cdata.set('HAVE_WINSOCK2_H', 1)
 179   cdata.set('HAVE_WS2TCPIP_H', 1)
 180   cdata.set('WIN32_LEAN_AND_MEAN', 1) # Needed to avoid including unnecessary headers on Windows
 181   cdata.set('gid_t', 'int')
 182   cdata.set('uid_t', 'int')
 183   ws2_32_dep = meson.get_compiler('c').find_library('ws2_32')
 184   winsock_dep = meson.get_compiler('c').find_library('wsock32')
 185   ole32_dep = meson.get_compiler('c').find_library('ole32')
 186   ssp_dep = meson.get_compiler('c').find_library('ssp')
 187   pcreposix_dep = meson.get_compiler('c').find_library('pcreposix')
 188   platform_socket_dep = [ws2_32_dep, winsock_dep]
 189   platform_dep = [ole32_dep, ssp_dep, pcreposix_dep]
 190 #elif host_machine.system() == 'solaris'
 191 #  # Apparently meson has no solaris support?
 192 #  # Needed to get declarations for msg_control and msg_controllen on Solaris
 193 #  cdata.set('_XOPEN_SOURCE', 600)
 194 #  cdata.set('__EXTENSIONS__', 1)
 195 endif
 196
 197 if cc.has_type('_Bool')
 198   cdata.set('HAVE_STD_BOOL', 1)
 199 endif
 200
 201 if host_machine.cpu_family() == 'x86_64' or cc.sizeof('void *') >= 8
 202   cdata.set('HAVE_FAST_64BIT_OPERATIONS', 1)
 203 endif
 204
 205 # Headers
 206
 207 check_headers = [
 208   'arpa/inet.h',
 209   'byteswap.h',
 210   'cpuid.h',
 211   'dlfcn.h',
 212   'execinfo.h',
 213   'grp.h',
 214   'langinfo.h',
 215   'linux/sockios.h',
 216   'locale.h',
 217   'netdb.h',
 218   'netinet/in.h',
 219   'netinet/in_systm.h',
 220   'netinet/ip.h',
 221   'netinet/tcp.h',
 222   'pcreposix.h',
 223   'poll.h',
 224   'pwd.h',
 225   'regex.h',
 226   'sched.h',
 227   'stdint.h',
 228   'sys/atomic.h',
 229   'sys/capability.h',
 230   'sys/conf.h',
 231   'sys/dl.h',
 232   'sys/eventfd.h',
 233   'sys/filio.h',
 234   'sys/ioctl.h',
 235   'sys/mman.h',
 236   'sys/prctl.h',
 237   'sys/resource.h',
 238   'sys/select.h',
 239   'sys/socket.h',
 240   'sys/syscall.h',
 241   'sys/uio.h',
 242   'sys/un.h',
 243   'sys/wait.h',
 244   'syslog.h',
 245   'xlocale.h',
 246 ]
 247
 248 foreach h : check_headers
 249   if cc.has_header(h)
 250     define = 'HAVE_' + h.underscorify().to_upper()
 251     cdata.set(define, 1)
 252   endif
 253 endforeach
 254
 255 if cc.has_header('valgrind/memcheck.h', required: get_option('valgrind'))
 256   cdata.set('HAVE_VALGRIND_MEMCHECK_H', 1)
 257 endif
 258
 259 # FIXME: move this to the above set
 260 if host_machine.system() != 'windows'
 261   if cc.has_header('pthread.h')
 262     cdata.set('HAVE_PTHREAD', 1)
 263   endif
 264 endif
 265
 266 if cc.has_header_symbol('pthread.h', 'PTHREAD_PRIO_INHERIT')
 267   cdata.set('HAVE_PTHREAD_PRIO_INHERIT', 1)
 268 endif
 269
 270 # Functions
 271
 272 check_functions = [
 273   'accept4',
 274   'clock_gettime',
 275   'ctime_r',
 276   'fchmod',
 277   'fchown',
 278   'fork',
 279   'fstat',
 280   'getaddrinfo',
 281   'getgrgid_r',
 282   'getgrnam_r',
 283   'getpwnam_r',
 284   'getpwuid_r',
 285   'gettimeofday',
 286   'getuid',
 287   'lrintf',
 288   'lstat',
 289   'memfd_create',
 290   'mkfifo',
 291   'mlock',
 292   'nanosleep',
 293   'open64',
 294   'paccept',
 295   'pipe',
 296   'pipe2',
 297   'posix_fadvise',
 298   'posix_madvise',
 299   'posix_memalign',
 300   'ppoll',
 301   'readlink',
 302   'setegid',
 303   'seteuid',
 304   'setpgid',
 305   'setregid',
 306   'setresgid',
 307   'setresuid',
 308   'setreuid',
 309   'setsid',
 310   'sig2str',
 311   'sigaction',
 312   'strerror_r',
 313   'strtod_l',
 314   'strtof',
 315   'symlink',
 316   'sysconf',
 317   'uname',
 318 ]
 319
 320 foreach f : check_functions
 321   if cc.has_function(f)
 322     define = 'HAVE_' + f.underscorify().to_upper()
 323
 324     if f == 'posix_memalign' and host_machine.system() == 'windows'
 325       message('Win32/mingw32 does not properly define posix_memalign.')
 326     elif f == 'fork' and host_machine.system() == 'windows'
 327       # __builtin_fork is defined and compiles properly, but calling __builtin_fork() does not.
 328       # This causes Meson to think that Windows has a fork() which causes a link error...
 329       message('Win32/mingw32 does not properly define fork.')
 330     else
 331       cdata.set(define, 1)
 332     endif
 333   endif
 334 endforeach
 335
 336 if cc.has_header_symbol('sys/syscall.h', 'SYS_memfd_create')
 337   cdata.set('HAVE_MEMFD', 1)
 338 endif
 339
 340 if cc.has_function('dgettext')
 341   if host_machine.system() != 'windows'
 342     libintl_dep = []
 343   else
 344     libintl_dep = cc.find_library('intl')
 345   endif
 346 else
 347   libintl_dep = cc.find_library('intl')
 348 endif
 349
 350 # Symbols
 351
 352 if cc.has_header_symbol('signal.h', 'SIGXCPU')
 353   cdata.set('HAVE_SIGXCPU', 1)
 354 endif
 355
 356 if not cc.has_header_symbol('netinet/in.h', 'INADDR_NONE')
 357   if not cc.has_header_symbol('winsock2.h', 'INADDR_NONE')
 358     # Define INADDR_NONE if not found (Solaris)
 359     cdata.set('INADDR_NONE', '0xffffffff')
 360   endif
 361 endif
 362
 363 check_decls = [
 364   [ 'environ', 'unistd.h', '#define _GNU_SOURCE' ],
 365   [ 'SOUND_PCM_READ_RATE', 'sys/soundcard.h', '' ],
 366   [ 'SOUND_PCM_READ_CHANNELS', 'sys/soundcard.h', '' ],
 367   [ 'SOUND_PCM_READ_BITS', 'sys/soundcard.h', '' ],
 368 ]
 369
 370 foreach s : check_decls
 371   if cc.has_header_symbol(s[1], s[0], prefix : s[2])
 372     define = 'HAVE_DECL_' + s[0].to_upper()
 373     cdata.set(define, 1)
 374   endif
 375 endforeach
 376
 377 # Types
 378
 379 # FIXME: do we ever care about gid_t not being defined / smaller than an int?
 380 cdata.set('GETGROUPS_T', 'gid_t')
 381
 382 # Include paths
 383
 384 configinc = include_directories('.')
 385 topinc = include_directories('src')
 386
 387 # CFLAGS/LDFLAGS
 388
 389 pa_c_args = ['-DHAVE_CONFIG_H', '-D_GNU_SOURCE']
 390 server_c_args = ['-D__INCLUDED_FROM_PULSE_AUDIO']
 391 cdata.set('MESON_BUILD', 1)
 392
 393 # On ELF systems we don't want the libraries to be unloaded since we don't clean them up properly,
 394 # so we request the nodelete flag to be enabled.
 395 # On other systems, we don't really know how to do that, but it's welcome if somebody can tell.
 396 # Windows doesn't support this flag.
 397 if host_machine.system() != 'windows'
 398   nodelete_link_args = ['-Wl,-z,nodelete']
 399 else
 400   nodelete_link_args = []
 401 endif
 402
 403 # Code coverage
 404
 405 if get_option('gcov')
 406   add_project_arguments('--coverage', language: ['c', 'cpp'])
 407   add_project_link_arguments('--coverage', language: ['c', 'cpp'])
 408 endif
 409
 410 # Core Dependencies
 411
 412 libm_dep = cc.find_library('m', required : true)
 413
 414 thread_dep = dependency('threads')
 415 foreach f : [
 416   'pthread_getname_np',
 417   'pthread_setaffinity_np',
 418   'pthread_setname_np',
 419 ]
 420   if cc.has_function(f, dependencies : thread_dep)
 421     define = 'HAVE_' + f.underscorify().to_upper()
 422     cdata.set(define, 1)
 423   endif
 424 endforeach
 425
 426 cap_dep = cc.find_library('cap', required : false)
 427
 428 shm_dep = cc.find_library('rt', required : false)
 429 if cc.has_function('shm_open', dependencies : shm_dep)
 430   cdata.set('HAVE_SHM_OPEN', 1)
 431 endif
 432
 433 dl_dep = cc.find_library('dl', required : false)
 434 if cc.has_function('dladdr', dependencies : dl_dep)
 435   cdata.set('HAVE_DLADDR', 1)
 436 endif
 437
 438 have_iconv = false
 439 if cc.has_function('iconv_open')
 440   iconv_dep = dependency('', required : false)
 441   have_iconv = true
 442   # tell the libiconv header to pretend to be libc iconv
 443   cdata.set('LIBICONV_PLUG', 1)
 444 else
 445   iconv_dep = cc.find_library('iconv', required : false)
 446   have_iconv = iconv_dep.found()
 447 endif
 448 if have_iconv
 449   cdata.set('HAVE_ICONV', 1)
 450   iconvconsttest = '''#include <iconv.h>
 451 size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 452 '''
 453   if cc.compiles(iconvconsttest, dependencies : iconv_dep)
 454     cdata.set('ICONV_CONST', '')
 455   else
 456     cdata.set('ICONV_CONST', 'const')
 457   endif
 458 endif
 459
 460 # Atomic operations
 461
 462 if get_option('atomic-arm-memory-barrier')
 463     cdata.set('ATOMIC_ARM_MEMORY_BARRIER_ENABLED', 1)
 464 endif
 465
 466 need_libatomic_ops = false
 467
 468 atomictest = '''void func() {
 469   volatile int atomic = 2;
 470   __sync_bool_compare_and_swap (&atomic, 2, 3);
 471 }
 472 '''
 473
 474 if cc.compiles(atomictest)
 475   cdata.set('HAVE_ATOMIC_BUILTINS', 1)
 476
 477   newatomictest = '''void func() {
 478     int c = 0;
 479     __atomic_store_n(&c, 4, __ATOMIC_SEQ_CST);
 480   }
 481   '''
 482
 483   if(cc.compiles(newatomictest))
 484     cdata.set('HAVE_ATOMIC_BUILTINS_MEMORY_MODEL', 1)
 485   endif
 486
 487 elif host_machine.cpu_family() == 'arm'
 488   if host_machine.system() == 'linux' and get_option('atomic-arm-linux-helpers')
 489     cdata.set('ATOMIC_ARM_LINUX_HELPERS', 1)
 490   else
 491     armatomictest = '''int func() {
 492       volatile int a=0;
 493       int o=0, n=1, r;
 494       asm volatile (
 495               "ldrex    %0, [%1]\n"
 496               "subs  %0, %0, %2\n"
 497               "strexeq %0, %3, [%1]\n"
 498               : "=&r" (r)
 499               : "r" (&a), "Ir" (o), "r" (n)
 500       : "cc");
 501       return (a==1 ? 0 : -1);
 502     }
 503     '''
 504
 505     if cc.compiles(armatomictest)
 506       cdata.set('ATOMIC_ARM_INLINE_ASM', 1)
 507     else
 508       need_libatomic_ops = true
 509     endif
 510   endif # arm && !linux
 511
 512 elif not ['freebsd', 'netbsd'].contains(host_machine.system())
 513   need_libatomic_ops = true
 514 endif # !atomic helpers && !arm
 515
 516 if need_libatomic_ops
 517   assert(cc.has_header('atomic_ops.h'), 'Need libatomic_ops')
 518
 519   cdata.set('AO_REQUIRE_CAS', 1)
 520
 521   if host_machine.system() != 'windows'
 522     libatomic_ops_dep = cc.find_library('atomic_ops', required : true)
 523   else
 524     libatomic_ops_dep = dependency('', required: false)
 525   endif
 526 else
 527   libatomic_ops_dep = dependency('', required: false)
 528 endif
 529
 530 # ARM checks
 531 # ARMV6 instructions we need
 532 if host_machine.cpu_family() == 'arm'
 533   armv6test = '''int func() {
 534     volatile int a = -60000, b = 0xaaaabbbb, c = 0xccccdddd;
 535     asm volatile ("ldr r0, %2 \n"
 536                   "ldr r2, %3 \n"
 537                   "ldr r3, %4 \n"
 538                   "ssat r1, #8, r0 \n"
 539                   "str r1, %0 \n"
 540                   "pkhbt r1, r3, r2, LSL #8 \n"
 541                   "str r1, %1 \n"
 542                   : "=m" (a), "=m" (b)
 543                   : "m" (a), "m" (b), "m" (c)
 544                   : "r0", "r1", "r2", "r3", "cc");
 545     return (a == -128 && b == 0xaabbdddd) ? 0 : -1;
 546   }
 547   '''
 548
 549   if cc.compiles(armv6test)
 550     cdata.set('HAVE_ARMV6', 1)
 551   endif
 552 endif
 553 # NEON checks are automatically done by the unstable-simd module
 554
 555 # FIXME: make sure it's >= 2.2
 556 ltdl_dep = cc.find_library('ltdl', required : true)
 557 # FIXME: can meson support libtool -dlopen/-dlpreopen things?
 558 #        and do we still want to support this at all?
 559 cdata.set('DISABLE_LIBTOOL_PRELOAD', 1)
 560
 561 if get_option('database') == 'tdb'
 562   database_dep = dependency('tdb')
 563 elif get_option('database') == 'gdbm'
 564   database_dep = cc.find_library('gdbm', required : true)
 565 else
 566   database_dep = dependency('', required: false)
 567 endif
 568
 569 if get_option('ipv6')
 570   cdata.set('HAVE_IPV6', 1)
 571 endif
 572
 573 if get_option('legacy-database-entry-format')
 574   cdata.set('ENABLE_LEGACY_DATABASE_ENTRY_FORMAT', 1)
 575 endif
 576
 577 if get_option('stream-restore-clear-old-devices')
 578   cdata.set('STREAM_RESTORE_CLEAR_OLD_DEVICES', 1)
 579 endif
 580
 581 if get_option('running-from-build-tree')
 582   cdata.set('HAVE_RUNNING_FROM_BUILD_TREE', 1)
 583 endif
 584
 585 alsa_dep = dependency('alsa', version : '>= 1.0.24', required : get_option('alsa'))
 586 if alsa_dep.found()
 587   cdata.set('HAVE_ALSA', 1)
 588   cdata.set('HAVE_ALSA_UCM', 1)
 589 endif
 590
 591 asyncns_dep = dependency('libasyncns', version : '>= 0.1', required : get_option('asyncns'))
 592 if asyncns_dep.found()
 593   cdata.set('HAVE_LIBASYNCNS', 1)
 594 endif
 595
 596 dbus_dep = dependency('dbus-1', version : '>= 1.4.12', required : get_option('dbus'))
 597 if dbus_dep.found()
 598   cdata.set('HAVE_DBUS', 1)
 599 endif
 600
 601 gio_dep = dependency('gio-2.0', version : '>= 2.26.0', required : get_option('gsettings'))
 602 if gio_dep.found()
 603   cdata.set('HAVE_GSETTINGS', 1)
 604 endif
 605
 606 glib_dep = dependency('glib-2.0', version : '>= 2.28.0', required: get_option('glib'))
 607 if glib_dep.found()
 608   cdata.set('HAVE_GLIB', 1)
 609 endif
 610
 611 gtk_dep = dependency('gtk+-3.0', required : get_option('gtk'))
 612 if gtk_dep.found()
 613   cdata.set('HAVE_GTK', 1)
 614 endif
 615
 616 have_orcc = false
 617 orcc_args = []
 618 orc_dep = dependency('orc-0.4', version : '>= 0.4.11', required : get_option('orc'))
 619 orcc = find_program('orcc', required : get_option('orc'))
 620 if orc_dep.found() and orcc.found()
 621   have_orcc = true
 622   orcc_args = [orcc]
 623   #orcc_args = [orcc, '--include', 'glib.h']
 624   cdata.set('HAVE_ORC', 1)
 625 else
 626   cdata.set('DISABLE_ORC', 1)
 627 endif
 628
 629 samplerate_dep = dependency('samplerate', version : '>= 0.1.0', required : get_option('samplerate'))
 630 if samplerate_dep.found()
 631   cdata.set('HAVE_LIBSAMPLERATE', 1)
 632 endif
 633
 634 sndfile_dep = dependency('sndfile', version : '>= 1.0.20')
 635
 636 soxr_dep = dependency('soxr', version : '>= 0.1.1', required : get_option('soxr'))
 637 if soxr_dep.found()
 638   cdata.set('HAVE_SOXR', 1)
 639 endif
 640
 641 libsystemd_dep = dependency('libsystemd', required : get_option('systemd'))
 642 if libsystemd_dep.found()
 643   cdata.set('HAVE_SYSTEMD_DAEMON', 1)
 644   cdata.set('HAVE_SYSTEMD_LOGIN', 1)
 645   cdata.set('HAVE_SYSTEMD_JOURNAL', 1)
 646 endif
 647 systemd_dep = dependency('systemd', required : get_option('systemd'))
 648 if systemd_dep.found() and systemduserunitdir == ''
 649   systemduserunitdir = systemd_dep.get_pkgconfig_variable('systemduserunitdir')
 650 endif
 651
 652 x11_dep = dependency('x11-xcb', required : get_option('x11'))
 653 if x11_dep.found()
 654   xcb_dep  = dependency('xcb',  required : true, version : '>= 1.6')
 655   ice_dep  = dependency('ice',  required : true)
 656   sm_dep   = dependency('sm',   required : true)
 657   xtst_dep = dependency('xtst', required : true)
 658   cdata.set('HAVE_X11', 1)
 659   if cc.has_function('XSetIOErrorExitHandler', dependencies: x11_dep)
 660     cdata.set('HAVE_XSETIOERROREXITHANDLER', 1)
 661   endif
 662 endif
 663
 664 # Module dependencies
 665 if cc.has_header('sys/soundcard.h', required: get_option('oss-output'))
 666   cdata.set('HAVE_OSS_OUTPUT', 1)
 667   cdata.set('HAVE_OSS_WRAPPER', 1)
 668   cdata.set('PULSEDSP_LOCATION', pulsedsp_location)
 669 endif
 670
 671 if get_option('hal-compat')
 672   cdata.set('HAVE_HAL_COMPAT', 1)
 673 endif
 674
 675 avahi_dep = dependency('avahi-client', version : '>= 0.6.0', required : get_option('avahi'), disabler : true)
 676 if avahi_dep.found()
 677   cdata.set('HAVE_AVAHI', 1)
 678 endif
 679
 680 sbc_dep = dependency('sbc', version : '>= 1.0', required : false)
 681 if get_option('bluez5')
 682   assert(dbus_dep.found(), 'BlueZ requires D-Bus support')
 683   assert(sbc_dep.found(), 'BlueZ requires SBC support')
 684   cdata.set('HAVE_SBC', 1)
 685   cdata.set('HAVE_BLUEZ', 1)
 686   cdata.set('HAVE_BLUEZ_5', 1)
 687   if get_option('bluez5-native-headset')
 688     cdata.set('HAVE_BLUEZ_5_NATIVE_HEADSET', 1)
 689   endif
 690   if get_option('bluez5-ofono-headset')
 691     cdata.set('HAVE_BLUEZ_5_OFONO_HEADSET', 1)
 692   endif
 693 endif
 694
 695 fftw_dep = dependency('fftw3f', required : get_option('fftw'))
 696 if fftw_dep.found()
 697   cdata.set('HAVE_FFTW', 1)
 698 endif
 699
 700 jack_dep = dependency('jack', version : '>= 0.117.0', required : get_option('jack'))
 701 if jack_dep.found()
 702   cdata.set('HAVE_JACK', 1)
 703 endif
 704
 705 lirc_dep = dependency('lirc', required : get_option('lirc'))
 706 if lirc_dep.found()
 707   cdata.set('HAVE_LIRC', 1)
 708 endif
 709
 710 openssl_dep = dependency('openssl', version : '>= 0.9', required : get_option('openssl'))
 711 if openssl_dep.found()
 712   cdata.set('HAVE_OPENSSL', 1)
 713 endif
 714
 715 speex_dep = dependency('speexdsp', version : '>= 1.2', required : get_option('speex'))
 716 if speex_dep.found()
 717   cdata.set('HAVE_SPEEX', 1)
 718 endif
 719
 720 udev_dep = dependency('libudev', version : '>= 143', required : get_option('udev'))
 721 if udev_dep.found()
 722   cdata.set('HAVE_UDEV', 1)
 723 endif
 724
 725 webrtc_dep = dependency('webrtc-audio-processing', version : '>= 0.2', required : get_option('webrtc-aec'))
 726 if webrtc_dep.found()
 727   cdata.set('HAVE_WEBRTC', 1)
 728 endif
 729
 730 gst_dep = dependency('gstreamer-1.0', version : '>= 1.14', required : get_option('gstreamer'))
 731 gstapp_dep = dependency('gstreamer-app-1.0', required : get_option('gstreamer'))
 732 gstrtp_dep = dependency('gstreamer-rtp-1.0', required : get_option('gstreamer'))
 733
 734 have_gstreamer = false
 735 if gst_dep.found() and gstapp_dep.found() and gstrtp_dep.found()
 736   have_gstreamer = true
 737 endif
 738
 739 # These are required for the CMake file generation
 740 cdata.set('PA_LIBDIR', libdir)
 741 cdata.set('PA_INCDIR', includedir)
 742 if glib_dep.found()
 743   cdata.set('HAVE_GLIB20', 1) # to match the AM_CONDITIONAL for CMake file generation
 744 endif
 745
 746 # Test dependencies
 747
 748 check_dep = dependency('check', version : '>= 0.9.10', required : get_option('tests'))
 749
 750 # Subdirs
 751
 752 subdir('doxygen')
 753 subdir('po')
 754 if get_option('man')
 755   subdir('man')
 756 endif
 757 subdir('shell-completion/bash')
 758 subdir('shell-completion/zsh')
 759 subdir('src')
 760 subdir('vala')
 761
 762 # Now generate config.h from everything above
 763 configure_file(output : 'config.h', configuration : cdata)
 764
 765 # pkg-config files
 766
 767 pc_cdata = configuration_data()
 768
 769 pc_cdata.set('prefix', prefix)
 770 pc_cdata.set('exec_prefix', prefix)
 771 pc_cdata.set('libdir', libdir)
 772 pc_cdata.set('includedir', includedir)
 773 pc_cdata.set('modlibexecdir', modlibexecdir)
 774 pc_cdata.set('PACKAGE_VERSION', pa_version_str)
 775 pc_cdata.set('PA_MAJORMINOR', pa_version_major_minor)
 776 # FIXME: the line below is wrong. Currently the meson thread dep lacks documentation,
 777 # and doesn't allow introspection, ie. none of get_pkgconfig_variable() or
 778 # get_configtool_variable() work with it, so we have no way to get this flag right,
 779 # unless we do all the work ourselves. See current work in glib, also meson #553.
 780 pc_cdata.set('PTHREAD_LIBS', '-pthread')
 781
 782 pc_files = [
 783   'libpulse.pc',
 784   'libpulse-simple.pc',
 785 ]
 786
 787 if glib_dep.found()
 788   pc_files += 'libpulse-mainloop-glib.pc'
 789 endif
 790
 791 foreach file : pc_files
 792   configure_file(
 793     input : file + '.in',
 794     output : file,
 795     configuration : pc_cdata,
 796     install_dir : pkgconfigdir)
 797 endforeach
 798
 799 # CMake files
 800
 801 m4 = find_program('m4', required: true)
 802
 803 cmakedir = join_paths(libdir, 'cmake', 'PulseAudio')
 804
 805 cmake_template_file = configure_file(
 806   input : 'PulseAudioConfig.cmake.in',
 807   output : 'PulseAudioConfig.cmake.tmp',
 808   configuration: cdata,
 809 )
 810
 811 custom_target('PulseAudioConfig.cmake',
 812   input : cmake_template_file,
 813   output : 'PulseAudioConfig.cmake',
 814   capture : true,
 815   command : [m4, '@INPUT@'],
 816   build_by_default : true,
 817   install : true,
 818   install_dir : cmakedir,
 819 )
 820
 821 configure_file(
 822   input : 'PulseAudioConfigVersion.cmake.in',
 823   output : 'PulseAudioConfigVersion.cmake',
 824   configuration: cdata,
 825   install : true,
 826   install_dir : cmakedir,
 827 )
 828
 829 ############################################################
 830
 831 # Final summary
 832
 833 summary = [
 834   '',
 835   '---{ @0@ @1@ }---'.format(meson.project_name(), meson.project_version()),
 836   '',
 837   'prefix:                        @0@'.format(prefix),
 838   'bindir:                        @0@'.format(bindir),
 839   'libdir:                        @0@'.format(libdir),
 840   'libexecdir:                    @0@'.format(libexecdir),
 841   'mandir:                        @0@'.format(mandir),
 842   'datadir:                       @0@'.format(datadir),
 843   'sysconfdir:                    @0@'.format(sysconfdir),
 844   'localstatedir:                 @0@'.format(localstatedir),
 845   'modlibexecdir:                 @0@'.format(modlibexecdir),
 846   'alsadatadir:                   @0@'.format(alsadatadir),
 847   'System Runtime Path:           @0@'.format(cdata.get_unquoted('PA_SYSTEM_RUNTIME_PATH')),
 848   'System State Path:             @0@'.format(cdata.get_unquoted('PA_SYSTEM_STATE_PATH')),
 849   'System Config Path:            @0@'.format(cdata.get_unquoted('PA_SYSTEM_CONFIG_PATH')),
 850   'Bash completions directory:    @0@'.format(bashcompletiondir),
 851   'Zsh completions directory:     @0@'.format(zshcompletiondir),
 852   'Compiler:                      @0@ @1@'.format(cc.get_id(), cc.version()),
 853 #  'CFLAGS:                        @0@'.format(${CFLAGS}),
 854 #  'CPPFLAGS:                      @0@'.format(${CPPFLAGS}),
 855 #  'LIBS:                          @0@'.format(${LIBS}),
 856   '',
 857   'Enable memfd shared memory:    @0@'.format(cdata.has('HAVE_MEMFD')),
 858   'Enable X11:                    @0@'.format(x11_dep.found()),
 859   '  Safe X11 I/O errors:         @0@'.format(cdata.has('HAVE_XSETIOERROREXITHANDLER')),
 860   'Enable OSS Output:             @0@'.format(cdata.has('HAVE_OSS_OUTPUT')),
 861   'Enable OSS Wrapper:            @0@'.format(cdata.has('HAVE_OSS_WRAPPER')),
 862 #  'Enable EsounD:                 @0@'.format(${ENABLE_ESOUND}),
 863   'Enable Alsa:                   @0@'.format(alsa_dep.found()),
 864 #  'Enable CoreAudio:              @0@'.format(${ENABLE_COREAUDIO}),
 865 #  'Enable Solaris:                @0@'.format(${ENABLE_SOLARIS}),
 866 #  'Enable WaveOut:                @0@'.format(${ENABLE_WAVEOUT}),
 867   'Enable GLib 2:                 @0@'.format(glib_dep.found()),
 868 #  'Enable GConf:                  @0@'.format(${ENABLE_GCONF}),
 869   'Enable GSettings:              @0@'.format(gio_dep.found()),
 870   'Enable Gtk+ 3:                 @0@'.format(gtk_dep.found()),
 871   'Enable Avahi:                  @0@'.format(avahi_dep.found()),
 872   'Enable Jack:                   @0@'.format(jack_dep.found()),
 873   'Enable Async DNS:              @0@'.format(asyncns_dep.found()),
 874   'Enable LIRC:                   @0@'.format(lirc_dep.found()),
 875   'Enable D-Bus:                  @0@'.format(dbus_dep.found()),
 876   '  Enable BlueZ 5:              @0@'.format(get_option('bluez5')),
 877   '    Enable native headsets:    @0@'.format(get_option('bluez5-native-headset')),
 878   '    Enable  ofono headsets:    @0@'.format(get_option('bluez5-ofono-headset')),
 879   'Enable udev:                   @0@'.format(udev_dep.found()),
 880   '  Enable HAL->udev compat:     @0@'.format(get_option('hal-compat')),
 881   'Enable systemd:                @0@'.format(libsystemd_dep.found()),
 882 #  'Enable TCP Wrappers:           @0@'.format(${ENABLE_TCPWRAP}),
 883   'Enable libsamplerate:          @0@'.format(samplerate_dep.found()),
 884   'Enable IPv6:                   @0@'.format(get_option('ipv6')),
 885   'Enable OpenSSL (for Airtunes): @0@'.format(openssl_dep.found()),
 886   'Enable FFTW:                   @0@'.format(fftw_dep.found()),
 887   'Enable ORC:                    @0@'.format(have_orcc),
 888   'Enable GStreamer:              @0@'.format(have_gstreamer),
 889   'Enable Adrian echo canceller:  @0@'.format(get_option('adrian-aec')),
 890   'Enable Speex (resampler, AEC): @0@'.format(speex_dep.found()),
 891   'Enable SoXR (resampler):       @0@'.format(soxr_dep.found()),
 892   'Enable WebRTC echo canceller:  @0@'.format(webrtc_dep.found()),
 893   'Enable Gcov coverage:          @0@'.format(get_option('gcov')),
 894   'Enable Valgrind:               @0@'.format(cdata.has('HAVE_VALGRIND_MEMCHECK_H')),
 895   'Enable man pages:              @0@'.format(get_option('man')),
 896   'Enable unit tests:             @0@'.format(get_option('tests')),
 897   '',
 898   'Database:                      @0@'.format(get_option('database')),
 899   'Legacy Database Entry Support: @0@'.format(get_option('legacy-database-entry-format')),
 900   'module-stream-restore:',
 901   '  Clear old devices:           @0@'.format(get_option('stream-restore-clear-old-devices')),
 902   'Running from build tree:       @0@'.format(get_option('running-from-build-tree')),
 903   'System User:                   @0@'.format(cdata.get_unquoted('PA_SYSTEM_USER')),
 904   'System Group:                  @0@'.format(cdata.get_unquoted('PA_SYSTEM_GROUP')),
 905   'Access Group:                  @0@'.format(cdata.get_unquoted('PA_ACCESS_GROUP')),
 906 #  'Enable per-user EsounD socket: @0@'.format(${ENABLE_PER_USER_ESOUND_SOCKET}),
 907 #  'Force preopen:                 @0@'.format(${FORCE_PREOPEN}),
 908 #  'Preopened modules:             @0@'.format(${PREOPEN_MODS}),
 909 ]
 910
 911 message('\n    '.join(summary))
 912
 913 # Sanity checks
 914
 915 if not speex_dep.found() and not webrtc_dep.found() and not get_option('adrian-aec')
 916   error('At least one echo canceller implementation must be available!')
 917 endif
 918
 919 if samplerate_dep.found()
 920   warning('Support for libsamplerate is DEPRECATED')
 921 endif
 922
 923 if host_machine.system() != 'windows'
 924   if not dbus_dep.found()
 925     message = [
 926       'You do not have D-Bus support enabled. It is strongly recommended',
 927       'that you enable D-Bus support if your platform supports it.',
 928       'Many parts of PulseAudio use D-Bus, from ConsoleKit interaction',
 929       'to the Device Reservation Protocol to speak to JACK, Bluetooth',
 930       'support and even a native control protocol for communicating and',
 931       'controlling the PulseAudio daemon itself.',
 932     ]
 933     warning('\n' + '\n'.join(message))
 934   endif
 935   if not udev_dep.found()
 936     message = [
 937       'You do not have udev support enabled. It is strongly recommended',
 938       'that you enable udev support if your platform supports it as it is',
 939       'the primary method used to detect hardware audio devices (on Linux)',
 940       'and is thus a critical part of PulseAudio on that platform.',
 941     ]
 942     warning('\n' + '\n'.join(message))
 943   endif
 944   if not speex_dep.found()
 945     message = [
 946       'You do not have speex support enabled. It is strongly recommended',
 947       'that you enable speex support if your platform supports it as it is',
 948       'the primary method used for audio resampling and is thus a critical',
 949       'part of PulseAudio on that platform.',
 950     ]
 951     warning('\n' + '\n'.join(message))
 952   endif
 953 endif