meson.build

   1 project('pulseaudio', 'c', 'cpp',
   2         version : run_command(find_program('git-version-gen'), join_paths(meson.current_source_dir(), '.tarball-version')).stdout().strip(),
   3         meson_version : '>= 0.50.0',
   4         default_options : [ 'c_std=gnu11', 'cpp_std=c++11' ]
   5         )
   6
   7 pa_version_str = meson.project_version()
   8 # For tarballs, the first split will do nothing, but for builds in git, we
   9 # split out suffixes when there are commits since the last tag
  10 # (e.g.: v11.99.1-3-gad14bdb24 -> v11.99.1)
  11 version_split = pa_version_str.split('-')[0].split('.')
  12 pa_version_major = version_split[0].split('v')[0]
  13 pa_version_minor = version_split[1]
  14 if version_split.length() > 2
  15   pa_version_micro = version_split[2]
  16 else
  17   pa_version_micro = '0'
  18 endif
  19 pa_version_major_minor = pa_version_major + '.' + pa_version_minor
  20
  21 pa_api_version = 12
  22 pa_protocol_version = 33
  23
  24 apiversion = '1.0'
  25 soversion = 0
  26 # FIXME: this doesn't actually do what we want it to
  27 # maintaining compatibility with the previous libtool versioning
  28 # current = minor * 100 + micro
  29 libversion = '@0@.@1@.0'.format(soversion, pa_version_minor.to_int() * 100 + pa_version_micro.to_int())
  30
  31 # A simplified, synchronous, ABI-stable interface for client applications.
  32 # For the version x:y:z always will hold y=z.
  33 libpulse_simple_version = '1.1.1'
  34
  35 # The ABI-stable GLib adapter for client applications.
  36 # For the version x:y:z always will hold y=z.
  37 libpulse_mainloop_glib_version = '0.5.0'
  38
  39 # Paths
  40
  41 prefix = get_option('prefix')
  42 assert(prefix.startswith('/'), 'Prefix is not absolute: "@0@"'.format(prefix))
  43
  44 bindir = join_paths(prefix, get_option('bindir'))
  45 includedir = join_paths(prefix, get_option('includedir'))
  46 libdir = join_paths(prefix, get_option('libdir'))
  47 libexecdir = join_paths(prefix, get_option('libexecdir'))
  48 mandir = join_paths(prefix, get_option('mandir'))
  49 datadir = join_paths(prefix, get_option('datadir'))
  50 localstatedir = join_paths(prefix, get_option('localstatedir'))
  51 sysconfdir = join_paths(prefix, get_option('sysconfdir'))
  52 privlibdir = join_paths(get_option('libdir'), 'pulseaudio')
  53 alsadatadir = join_paths(datadir, 'pulseaudio', 'alsa-mixer')
  54
  55 pkgconfigdir = join_paths(libdir, 'pkgconfig')
  56 pulselibexecdir = join_paths(libexecdir, 'pulse')
  57 pulsesysconfdir = join_paths(sysconfdir, 'pulse')
  58
  59 modlibexecdir = get_option('modlibexecdir')
  60 if modlibexecdir == ''
  61   modlibexecdir = join_paths(libdir, 'pulse-' + pa_version_major_minor, 'modules')
  62 endif
  63
  64 pulsedspdir = get_option('pulsedspdir')
  65 if pulsedspdir == ''
  66   pulsedspdir = join_paths(libdir, 'pulseaudio')
  67 endif
  68
  69 systemduserunitdir = get_option('systemduserunitdir')
  70 # the default value is set below
  71
  72 udevrulesdir = get_option('udevrulesdir')
  73 if udevrulesdir == ''
  74   udevrulesdir = join_paths('lib', 'udev', 'rules.d')
  75 endif
  76
  77 vapidir = join_paths(datadir, 'vala', 'vapi')
  78
  79 bashcompletiondir = get_option('bashcompletiondir')
  80 if bashcompletiondir == ''
  81   bash_completion_dep = dependency('bash-completion', required : false)
  82   if bash_completion_dep.found()
  83     bashcompletiondir = bash_completion_dep.get_pkgconfig_variable('completionsdir')
  84   else
  85     bashcompletiondir = join_paths(datadir, 'bash-completion', 'completions')
  86   endif
  87 endif
  88
  89 zshcompletiondir = get_option('zshcompletiondir')
  90 if zshcompletiondir == ''
  91   zshcompletiondir = join_paths(datadir, 'zsh', 'site-functions')
  92 endif
  93
  94 # Configuration data
  95
  96 cc = meson.get_compiler('c')
  97
  98 cdata = configuration_data()
  99 cdata.set_quoted('PACKAGE', 'pulseaudio')
 100 cdata.set_quoted('PACKAGE_NAME', 'pulseaudio')
 101 cdata.set_quoted('PACKAGE_VERSION', pa_version_str)
 102 cdata.set_quoted('CANONICAL_HOST', host_machine.cpu())
 103 cdata.set('PA_MAJOR', pa_version_major)
 104 cdata.set('PA_MINOR', pa_version_minor)
 105 cdata.set('PA_API_VERSION', pa_api_version)
 106 cdata.set('PA_PROTOCOL_VERSION', pa_protocol_version)
 107 cdata.set_quoted('PA_MACHINE_ID', join_paths(sysconfdir, 'machine-id'))
 108 cdata.set_quoted('PA_MACHINE_ID_FALLBACK', join_paths(localstatedir, 'lib', 'dbus', 'machine-id'))
 109 cdata.set_quoted('PA_SRCDIR', join_paths(meson.current_source_dir(), 'src'))
 110 cdata.set_quoted('PA_BUILDDIR', meson.current_build_dir())
 111 cdata.set_quoted('PA_SOEXT', '.so')
 112 cdata.set_quoted('PA_DEFAULT_CONFIG_DIR', pulsesysconfdir)
 113 cdata.set_quoted('PA_BINARY', join_paths(bindir, 'pulseaudio'))
 114 cdata.set_quoted('PA_SYSTEM_RUNTIME_PATH', join_paths(localstatedir, 'run', 'pulse'))
 115 cdata.set_quoted('PA_SYSTEM_CONFIG_PATH', join_paths(localstatedir, 'lib', 'pulse'))
 116 cdata.set_quoted('PA_SYSTEM_STATE_PATH', join_paths(localstatedir, 'lib', 'pulse'))
 117 cdata.set_quoted('PA_DLSEARCHPATH', modlibexecdir)
 118 cdata.set_quoted('PA_SYSTEM_USER', get_option('system_user'))
 119 cdata.set_quoted('PA_SYSTEM_GROUP', get_option('system_group'))
 120 cdata.set_quoted('PA_ACCESS_GROUP', get_option('access_group'))
 121 cdata.set_quoted('PA_CFLAGS', 'Not yet supported on meson')
 122 cdata.set_quoted('PA_ALSA_PATHS_DIR', join_paths(alsadatadir, 'paths'))
 123 cdata.set_quoted('PA_ALSA_PROFILE_SETS_DIR', join_paths(alsadatadir, 'profile-sets'))
 124 cdata.set_quoted('DESKTOPFILEDIR', join_paths(datadir, 'applications'))
 125
 126 # Platform specifics
 127 # First some defaults to keep config file generation happy
 128 cdata.set('HAVE_COREAUDIO', 0)
 129 cdata.set('HAVE_WAVEOUT', 0)
 130 # FIXME: This was not tested. Maybe some flags should better be CFLAGS,
 131 # rather than ending up in the config.h file?
 132 if host_machine.system() == 'darwin'
 133   cdata.set('OS_IS_DARWIN', 1)
 134   cdata.set('_DARWIN_C_SOURCE', '200112L') # Needed to get NSIG on Mac OS
 135 elif host_machine.system() == 'windows'
 136   cdata.set('OS_IS_WIN32', 1)
 137   cdata.set('WIN32_LEAN_AND_MEAN', 1) # Needed to avoid including unnecessary headers on Windows
 138 #elif host_machine.system() == 'solaris'
 139 #  # Apparently meson has no solaris support?
 140 #  # Needed to get declarations for msg_control and msg_controllen on Solaris
 141 #  cdata.set('_XOPEN_SOURCE', 600)
 142 #  cdata.set('__EXTENSIONS__', 1)
 143 endif
 144
 145 # Headers
 146
 147 check_headers = [
 148   'arpa/inet.h',
 149   'cpuid.h',
 150   'execinfo.h',
 151   'grp.h',
 152   'langinfo.h',
 153   'locale.h',
 154   'netdb.h',
 155   'netinet/in.h',
 156   'netinet/in_systm.h',
 157   'netinet/ip.h',
 158   'netinet/tcp.h',
 159   'pcreposix.h',
 160   'poll.h',
 161   'pwd.h',
 162   'regex.h',
 163   'sched.h',
 164   'sys/capability.h',
 165   'sys/eventfd.h',
 166   'sys/ioctl.h',
 167   'sys/mman.h',
 168   'sys/prctl.h',
 169   'sys/resource.h',
 170   'sys/select.h',
 171   'sys/socket.h',
 172   'sys/un.h',
 173   'sys/wait.h',
 174   'valgrind/memcheck.h',
 175   'xlocale.h',
 176 ]
 177
 178 foreach h : check_headers
 179   if cc.has_header(h)
 180     define = 'HAVE_' + h.underscorify().to_upper()
 181     cdata.set(define, 1)
 182   endif
 183 endforeach
 184
 185 # FIXME: move this to the above set
 186 if cc.has_header('pthread.h')
 187   cdata.set('HAVE_PTHREAD', 1)
 188 endif
 189
 190 # Functions
 191
 192 check_functions = [
 193   'accept4',
 194   'clock_gettime',
 195   'fchmod',
 196   'fchown',
 197   'fork',
 198   'fstat',
 199   'getaddrinfo',
 200   'getgrgid_r',
 201   'getpwnam_r',
 202   'gettimeofday',
 203   'getuid',
 204   'lstat',
 205   'memfd_create',
 206   'mkfifo',
 207   'mlock',
 208   'nanosleep',
 209   'paccept',
 210   'pipe',
 211   'pipe2',
 212   'posix_madvise',
 213   'readlink',
 214   'setegid',
 215   'seteuid',
 216   'setregid',
 217   'setreuid',
 218   'setresgid',
 219   'setresuid',
 220   'setsid',
 221   'sig2str',
 222   'sigaction',
 223   'strtod_l',
 224   'symlink',
 225   'sysconf',
 226   'uname',
 227 ]
 228
 229 foreach f : check_functions
 230   if cc.has_function(f)
 231     define = 'HAVE_' + f.underscorify().to_upper()
 232     cdata.set(define, 1)
 233   endif
 234 endforeach
 235
 236 if cc.has_function('SYS_memfd_create', prefix : '#include <sys/syscall.h>')
 237   cdata.set('HAVE_MEMFD', 1)
 238 endif
 239
 240 # Symbols
 241
 242 if cc.has_header_symbol('signal.h', 'SIGXCPU')
 243   cdata.set('HAVE_SIGXCPU', 1)
 244 endif
 245
 246 if not cc.has_header_symbol('netinet/in.h', 'INADDR_NONE')
 247   if not cc.has_header_symbol('winsock2.h', 'INADDR_NONE')
 248     # Define INADDR_NONE if not found (Solaris)
 249     cdata.set('INADDR_NONE', '0xffffffff')
 250   endif
 251 endif
 252
 253 # Types
 254
 255 # FIXME: do we ever care about gid_t not being defined / smaller than an int?
 256 cdata.set('GETGROUPS_T', 'gid_t')
 257
 258 # Include paths
 259
 260 configinc = include_directories('.')
 261 topinc = include_directories('src')
 262
 263 # CFLAGS
 264
 265 pa_c_args = ['-DHAVE_CONFIG_H', '-D_GNU_SOURCE']
 266 server_c_args = ['-D__INCLUDED_FROM_PULSE_AUDIO']
 267 cdata.set('MESON_BUILD', 1)
 268
 269 # Core Dependencies
 270
 271 libm_dep = cc.find_library('m', required : true)
 272 thread_dep = dependency('threads')
 273 cap_dep = cc.find_library('cap', required : false)
 274
 275 shm_dep = cc.find_library('rt', required : false)
 276 if shm_dep.found()
 277   cdata.set('HAVE_SHM_OPEN', 1)
 278 endif
 279
 280 atomictest = '''void func() {
 281   volatile int atomic = 2;
 282   __sync_bool_compare_and_swap (&atomic, 2, 3);
 283 }
 284 '''
 285 if cc.compiles(atomictest)
 286   cdata.set('HAVE_ATOMIC_BUILTINS', true)
 287 else
 288   # FIXME: check if we need libatomic_ops
 289 endif
 290
 291 # FIXME: make sure it's >= 2.2
 292 ltdl_dep = cc.find_library('ltdl', required : true)
 293 # FIXME: can meson support libtool -dlopen/-dlpreopen things?
 294 #        and do we still want to support this at all?
 295 cdata.set('DISABLE_LIBTOOL_PRELOAD', 1)
 296
 297 if get_option('database') == 'tdb'
 298   database_dep = dependency('tdb')
 299 elif get_option('database') == 'gdbm'
 300   database_dep = cc.find_library('gdbm', required : true)
 301 else
 302   database_dep = dependency('', required: false)
 303 endif
 304
 305 if get_option('ipv6')
 306   cdata.set('HAVE_IPV6', 1)
 307 endif
 308
 309 if get_option('legacy-database-entry-format')
 310   cdata.set('ENABLE_LEGACY_DATABASE_ENTRY_FORMAT', 1)
 311 endif
 312
 313 alsa_dep = dependency('alsa', version : '>= 1.0.24', required : get_option('alsa'))
 314 if alsa_dep.found()
 315   cdata.set('HAVE_ALSA', 1)
 316   cdata.set('HAVE_ALSA_UCM', 1)
 317 endif
 318
 319 asyncns_dep = dependency('libasyncns', version : '>= 0.1', required : get_option('asyncns'))
 320 if asyncns_dep.found()
 321   cdata.set('HAVE_LIBASYNCNS', 1)
 322 endif
 323
 324 dbus_dep = dependency('dbus-1', version : '>= 1.4.12', required : get_option('dbus'))
 325 if dbus_dep.found()
 326   cdata.set('HAVE_DBUS', 1)
 327 endif
 328
 329 gio_dep = dependency('gio-2.0', version : '>= 2.26.0', required : get_option('gsettings'))
 330 if gio_dep.found()
 331   cdata.set('HAVE_GSETTINGS', 1)
 332 endif
 333
 334 glib_dep = dependency('glib-2.0', version : '>= 2.4.0', required: get_option('glib'))
 335 if glib_dep.found()
 336   cdata.set('HAVE_GLIB', 1)
 337 endif
 338
 339 gtk_dep = dependency('gtk+-3.0', required : get_option('gtk'))
 340 if gtk_dep.found()
 341   cdata.set('HAVE_GTK', 1)
 342 endif
 343
 344 samplerate_dep = dependency('samplerate', version : '>= 0.1.0', required : get_option('samplerate'))
 345 if samplerate_dep.found()
 346   cdata.set('HAVE_LIBSAMPLERATE', 1)
 347 endif
 348
 349 sndfile_dep = dependency('sndfile', version : '>= 1.0.20')
 350
 351 soxr_dep = dependency('soxr', version : '>= 0.1.1', required : get_option('soxr'))
 352 if soxr_dep.found()
 353   cdata.set('HAVE_SOXR', 1)
 354 endif
 355
 356 libsystemd_dep = dependency('libsystemd', required : get_option('systemd'))
 357 if libsystemd_dep.found()
 358   cdata.set('HAVE_SYSTEMD_DAEMON', 1)
 359   cdata.set('HAVE_SYSTEMD_LOGIN', 1)
 360   cdata.set('HAVE_SYSTEMD_JOURNAL', 1)
 361   systemd_dep = dependency('systemd', required : get_option('systemd'))
 362   if systemd_dep.found() and systemduserunitdir == ''
 363     systemduserunitdir = systemd_dep.get_pkgconfig_variable('systemduserunitdir')
 364   endif
 365 endif
 366
 367 x11_dep = dependency('x11-xcb', required : get_option('x11'))
 368 if x11_dep.found()
 369   xcb_dep  = dependency('xcb',  required : true, version : '>= 1.6')
 370   ice_dep  = dependency('ice',  required : true)
 371   sm_dep   = dependency('sm',   required : true)
 372   xtst_dep = dependency('xtst', required : true)
 373   cdata.set('HAVE_X11', 1)
 374 endif
 375
 376 # FIXME: support ORC
 377 cdata.set('DISABLE_ORC', 1)
 378
 379 # Module dependencies
 380
 381 if cc.has_header('sys/soundcard.h')
 382   cdata.set('HAVE_OSS_OUTPUT', 1)
 383   cdata.set('HAVE_OSS_WRAPPER', 1)
 384   cdata.set_quoted('PULSEDSP_LOCATION', pulsedspdir)
 385 endif
 386
 387 if get_option('hal-compat')
 388   cdata.set('HAVE_HAL_COMPAT', 1)
 389 endif
 390
 391 avahi_dep = dependency('avahi-client', version : '>= 0.6.0', required : get_option('avahi'), disabler : true)
 392 if avahi_dep.found()
 393   cdata.set('HAVE_AVAHI', 1)
 394 endif
 395
 396 bluez_dep = dependency('bluez', version : '>= 5.0', required : get_option('bluez5'))
 397 sbc_dep = dependency('sbc', version : '>= 1.0', required : false)
 398 if bluez_dep.found()
 399   assert(dbus_dep.found(), 'BlueZ requires D-Bus support')
 400   assert(sbc_dep.found(), 'BlueZ requires SBC support')
 401   cdata.set('HAVE_SBC', 1)
 402   cdata.set('HAVE_BLUEZ', 1)
 403   cdata.set('HAVE_BLUEZ_5', 1)
 404   if get_option('bluez5-native-headset')
 405     cdata.set('HAVE_BLUEZ_5_NATIVE_HEADSET', 1)
 406   endif
 407   if get_option('bluez5-ofono-headset')
 408     cdata.set('HAVE_BLUEZ_5_OFONO_HEADSET', 1)
 409   endif
 410 endif
 411
 412 fftw_dep = dependency('fftw3f', required : get_option('fftw'))
 413 if fftw_dep.found()
 414   cdata.set('HAVE_FFTW', 1)
 415 endif
 416
 417 jack_dep = dependency('jack', version : '>= 0.117.0', required : get_option('jack'))
 418 if jack_dep.found()
 419   cdata.set('HAVE_JACK', 1)
 420 endif
 421
 422 lirc_dep = dependency('lirc', required : get_option('lirc'))
 423 if lirc_dep.found()
 424   cdata.set('HAVE_LIRC', 1)
 425 endif
 426
 427 openssl_dep = dependency('openssl', version : '>= 0.9', required : get_option('openssl'))
 428 if openssl_dep.found()
 429   cdata.set('HAVE_OPENSSL', 1)
 430 endif
 431
 432 speex_dep = dependency('speexdsp', version : '>= 1.2', required : get_option('speex'))
 433 if speex_dep.found()
 434   cdata.set('HAVE_SPEEX', 1)
 435 endif
 436
 437 udev_dep = dependency('libudev', version : '>= 143', required : get_option('udev'))
 438 if udev_dep.found()
 439   cdata.set('HAVE_UDEV', 1)
 440 endif
 441
 442 webrtc_dep = dependency('webrtc-audio-processing', version : '>= 0.2', required : get_option('webrtc-aec'))
 443 if webrtc_dep.found()
 444   cdata.set('HAVE_WEBRTC', 1)
 445 endif
 446
 447 # Test dependencies
 448
 449 check_dep = dependency('check', version : '>= 0.9.10', required : get_option('tests'))
 450
 451 # Now generate config.h from everything above
 452 configure_file(output : 'config.h', configuration : cdata)
 453
 454 # pkg-config files
 455
 456 pc_cdata = configuration_data()
 457
 458 pc_cdata.set('prefix', prefix)
 459 pc_cdata.set('exec_prefix', prefix)
 460 pc_cdata.set('libdir', libdir)
 461 pc_cdata.set('includedir', includedir)
 462 pc_cdata.set('modlibexecdir', modlibexecdir)
 463 pc_cdata.set('PACKAGE_VERSION', pa_version_str)
 464 pc_cdata.set('PA_MAJORMINOR', pa_version_major_minor)
 465 # FIXME: the line below is wrong. Currently the meson thread dep lacks documentation,
 466 # and doesn't allow introspection, ie. none of get_pkgconfig_variable() or
 467 # get_configtool_variable() work with it, so we have no way to get this flag right,
 468 # unless we do all the work ourselves. See current work in glib, also meson #553.
 469 pc_cdata.set('PTHREAD_LIBS', '-pthread')
 470
 471 pc_files = [
 472   'libpulse.pc',
 473   'libpulse-simple.pc',
 474 ]
 475
 476 if glib_dep.found()
 477   pc_files += 'libpulse-mainloop-glib.pc'
 478 endif
 479
 480 foreach file : pc_files
 481   configure_file(
 482     input : file + '.in',
 483     output : file,
 484     configuration : pc_cdata,
 485     install_dir : pkgconfigdir)
 486 endforeach
 487
 488 # Subdirs
 489
 490 subdir('po')
 491 if get_option('man')
 492   subdir('man')
 493 endif
 494 subdir('shell-completion/bash')
 495 subdir('shell-completion/zsh')
 496 subdir('src')
 497 subdir('vala')
 498
 499 ############################################################
 500
 501 # Final summary
 502
 503 summary = [
 504   '',
 505   '---{ @0@ @1@ }---'.format(meson.project_name(), meson.project_version()),
 506   '',
 507   'prefix:                        @0@'.format(prefix),
 508   'bindir:                        @0@'.format(bindir),
 509   'libdir:                        @0@'.format(libdir),
 510   'libexecdir:                    @0@'.format(libexecdir),
 511   'mandir:                        @0@'.format(mandir),
 512   'datadir:                       @0@'.format(datadir),
 513   'sysconfdir:                    @0@'.format(sysconfdir),
 514   'localstatedir:                 @0@'.format(localstatedir),
 515   'modlibexecdir:                 @0@'.format(modlibexecdir),
 516   'System Runtime Path:           @0@'.format(cdata.get_unquoted('PA_SYSTEM_RUNTIME_PATH')),
 517   'System State Path:             @0@'.format(cdata.get_unquoted('PA_SYSTEM_STATE_PATH')),
 518   'System Config Path:            @0@'.format(cdata.get_unquoted('PA_SYSTEM_CONFIG_PATH')),
 519   'Bash completions directory:    @0@'.format(bashcompletiondir),
 520   'Zsh completions directory:     @0@'.format(zshcompletiondir),
 521   'Compiler:                      @0@ @1@'.format(cc.get_id(), cc.version()),
 522 #  'CFLAGS:                        @0@'.format(${CFLAGS}),
 523 #  'CPPFLAGS:                      @0@'.format(${CPPFLAGS}),
 524 #  'LIBS:                          @0@'.format(${LIBS}),
 525   '',
 526   'Enable memfd shared memory:    @0@'.format(cdata.has('HAVE_MEMFD')),
 527   'Enable X11:                    @0@'.format(x11_dep.found()),
 528 #  'Enable OSS Output:             @0@'.format(${ENABLE_OSS_OUTPUT}),
 529 #  'Enable OSS Wrapper:            @0@'.format(${ENABLE_OSS_WRAPPER}),
 530 #  'Enable EsounD:                 @0@'.format(${ENABLE_ESOUND}),
 531   'Enable Alsa:                   @0@'.format(alsa_dep.found()),
 532 #  'Enable CoreAudio:              @0@'.format(${ENABLE_COREAUDIO}),
 533 #  'Enable Solaris:                @0@'.format(${ENABLE_SOLARIS}),
 534 #  'Enable WaveOut:                @0@'.format(${ENABLE_WAVEOUT}),
 535   'Enable GLib 2:                 @0@'.format(glib_dep.found()),
 536 #  'Enable GConf:                  @0@'.format(${ENABLE_GCONF}),
 537   'Enable GSettings:              @0@'.format(gio_dep.found()),
 538   'Enable Gtk+ 3:                 @0@'.format(gtk_dep.found()),
 539   'Enable Avahi:                  @0@'.format(avahi_dep.found()),
 540   'Enable Jack:                   @0@'.format(jack_dep.found()),
 541   'Enable Async DNS:              @0@'.format(asyncns_dep.found()),
 542   'Enable LIRC:                   @0@'.format(lirc_dep.found()),
 543   'Enable D-Bus:                  @0@'.format(dbus_dep.found()),
 544   '  Enable BlueZ 5:              @0@'.format(bluez_dep.found()),
 545   '    Enable native headsets:    @0@'.format(get_option('bluez5-native-headset')),
 546   '    Enable  ofono headsets:    @0@'.format(get_option('bluez5-ofono-headset')),
 547   'Enable udev:                   @0@'.format(udev_dep.found()),
 548   '  Enable HAL->udev compat:     @0@'.format(get_option('hal-compat')),
 549   'Enable systemd:                @0@'.format(libsystemd_dep.found()),
 550 #  'Enable TCP Wrappers:           @0@'.format(${ENABLE_TCPWRAP}),
 551   'Enable libsamplerate:          @0@'.format(samplerate_dep.found()),
 552   'Enable IPv6:                   @0@'.format(get_option('ipv6')),
 553   'Enable OpenSSL (for Airtunes): @0@'.format(openssl_dep.found()),
 554   'Enable FFTW:                   @0@'.format(fftw_dep.found()),
 555 #  'Enable orc:                    @0@'.format(${ENABLE_ORC}),
 556   'Enable Adrian echo canceller:  @0@'.format(get_option('adrian-aec')),
 557   'Enable Speex (resampler, AEC): @0@'.format(speex_dep.found()),
 558   'Enable SoXR (resampler):       @0@'.format(soxr_dep.found()),
 559   'Enable WebRTC echo canceller:  @0@'.format(webrtc_dep.found()),
 560 #  'Enable gcov coverage:          @0@'.format(${ENABLE_GCOV}),
 561   'Enable man pages:              @0@'.format(get_option('man')),
 562   'Enable unit tests:             @0@'.format(get_option('tests')),
 563   '',
 564   'Database:                      @0@'.format(get_option('database')),
 565   'Legacy Database Entry Support: @0@'.format(get_option('legacy-database-entry-format')),
 566   'System User:                   @0@'.format(cdata.get_unquoted('PA_SYSTEM_USER')),
 567   'System Group:                  @0@'.format(cdata.get_unquoted('PA_SYSTEM_GROUP')),
 568   'Access Group:                  @0@'.format(cdata.get_unquoted('PA_ACCESS_GROUP')),
 569 #  'Enable per-user EsounD socket: @0@'.format(${ENABLE_PER_USER_ESOUND_SOCKET}),
 570 #  'Force preopen:                 @0@'.format(${FORCE_PREOPEN}),
 571 #  'Preopened modules:             @0@'.format(${PREOPEN_MODS}),
 572 ]
 573
 574 message('\n    '.join(summary))
 575
 576 # Sanity checks
 577
 578 if not speex_dep.found() and not webrtc_dep.found() and not get_option('adrian-aec')
 579   error('At least one echo canceller implementation must be available!')
 580 endif
 581
 582 if samplerate_dep.found()
 583   warning('Support for libsamplerate is DEPRECATED')
 584 endif
 585
 586 if host_machine.system() != 'windows'
 587   if not dbus_dep.found()
 588     message = [
 589       'You do not have D-Bus support enabled. It is strongly recommended',
 590       'that you enable D-Bus support if your platform supports it.',
 591       'Many parts of PulseAudio use D-Bus, from ConsoleKit interaction',
 592       'to the Device Reservation Protocol to speak to JACK, Bluetooth',
 593       'support and even a native control protocol for communicating and',
 594       'controlling the PulseAudio daemon itself.',
 595     ]
 596     warning('\n' + '\n'.join(message))
 597   endif
 598   if not udev_dep.found()
 599     message = [
 600       'You do not have udev support enabled. It is strongly recommended',
 601       'that you enable udev support if your platform supports it as it is',
 602       'the primary method used to detect hardware audio devices (on Linux)',
 603       'and is thus a critical part of PulseAudio on that platform.',
 604     ]
 605     warning('\n' + '\n'.join(message))
 606   endif
 607   if not speex_dep.found()
 608     message = [
 609       'You do not have speex support enabled. It is strongly recommended',
 610       'that you enable speex support if your platform supports it as it is',
 611       'the primary method used for audio resampling and is thus a critical',
 612       'part of PulseAudio on that platform.',
 613     ]
 614     warning('\n' + '\n'.join(message))
 615   endif
 616 endif