meson.build

   1 project('pulseaudio', 'c', 'cpp',
   2         version : run_command(find_program('git-version-gen'), join_paths(meson.current_source_dir(), '.tarball-version')).stdout().strip(),
   3         meson_version : '>= 0.50.0',
   4         default_options : [ 'c_std=gnu11', 'cpp_std=c++11' ]
   5         )
   6
   7 meson.add_dist_script('scripts/save-tarball-version.sh', meson.project_version())
   8
   9 pa_version_str = meson.project_version()
  10 # For tarballs, the first split will do nothing, but for builds in git, we
  11 # split out suffixes when there are commits since the last tag
  12 # (e.g.: v11.99.1-3-gad14bdb24 -> v11.99.1)
  13 version_split = pa_version_str.split('-')[0].split('.')
  14 pa_version_major = version_split[0].split('v')[0]
  15 pa_version_minor = version_split[1]
  16 if version_split.length() > 2
  17   pa_version_micro = version_split[2]
  18 else
  19   pa_version_micro = '0'
  20 endif
  21 pa_version_major_minor = pa_version_major + '.' + pa_version_minor
  22
  23 pa_api_version = 12
  24 pa_protocol_version = 35
  25
  26 # The stable ABI for client applications, for the version info x:y:z
  27 # always will hold x=z
  28 libpulse_version_info = [24, 0, 24]
  29
  30 # A simplified, synchronous, ABI-stable interface for client
  31 # applications, for the version info x:y:z always will hold x=z
  32 libpulse_simple_version_info = [1, 1, 1]
  33
  34 # The ABI-stable GLib adapter for client applications, for the version
  35 # info x:y:z always will hold x=z
  36 libpulse_mainloop_glib_version_info = [0, 6, 0]
  37
  38 libpulse_version = '@0@.@1@.@2@'.format(
  39   libpulse_version_info[0] - libpulse_version_info[2],
  40   libpulse_version_info[0],
  41   libpulse_version_info[1],
  42 )
  43
  44 libpulse_simple_version = '@0@.@1@.@2@'.format(
  45   libpulse_simple_version_info[0] - libpulse_simple_version_info[2],
  46   libpulse_simple_version_info[0],
  47   libpulse_simple_version_info[1],
  48 )
  49
  50 libpulse_mainloop_glib_version = '@0@.@1@.@2@'.format(
  51   libpulse_mainloop_glib_version_info[0] - libpulse_mainloop_glib_version_info[2],
  52   libpulse_mainloop_glib_version_info[0],
  53   libpulse_mainloop_glib_version_info[1],
  54 )
  55
  56 # Paths
  57
  58 prefix = get_option('prefix')
  59 assert(prefix.startswith('/'), 'Prefix is not absolute: "@0@"'.format(prefix))
  60
  61 bindir = join_paths(prefix, get_option('bindir'))
  62 includedir = join_paths(prefix, get_option('includedir'))
  63 libdir = join_paths(prefix, get_option('libdir'))
  64 libexecdir = join_paths(prefix, get_option('libexecdir'))
  65 mandir = join_paths(prefix, get_option('mandir'))
  66 datadir = join_paths(prefix, get_option('datadir'))
  67 localedir = join_paths(prefix, get_option('localedir'))
  68 localstatedir = join_paths(prefix, get_option('localstatedir'))
  69 sysconfdir = join_paths(prefix, get_option('sysconfdir'))
  70 privlibdir = join_paths(libdir, 'pulseaudio')
  71
  72 if host_machine.system() == 'windows'
  73   # Windows only supports loading libraries from the same dir as the executable
  74   privlibdir = bindir
  75 endif
  76
  77 alsadatadir = get_option('alsadatadir')
  78 if alsadatadir == ''
  79   alsadatadir = join_paths(datadir, 'pulseaudio', 'alsa-mixer')
  80 endif
  81
  82 pkgconfigdir = join_paths(libdir, 'pkgconfig')
  83 pulselibexecdir = join_paths(libexecdir, 'pulse')
  84 pulsesysconfdir = join_paths(sysconfdir, 'pulse')
  85
  86 modlibexecdir = get_option('modlibexecdir')
  87 if modlibexecdir == ''
  88   modlibexecdir = join_paths(libdir, 'pulse-' + pa_version_major_minor, 'modules')
  89 endif
  90
  91 padsplibdir = get_option('padsplibdir')
  92 if padsplibdir == ''
  93   padsplibdir = privlibdir
  94 endif
  95
  96 pulsedsp_location = get_option('pulsedsp-location')
  97 if pulsedsp_location == ''
  98   pulsedsp_location = join_paths(prefix, padsplibdir)
  99 endif
 100
 101 systemduserunitdir = get_option('systemduserunitdir')
 102 # the default value is set below
 103
 104 udevrulesdir = get_option('udevrulesdir')
 105 if udevrulesdir == ''
 106   # absolute path, otherwise meson prepends the prefix
 107   udevrulesdir = '/lib/udev/rules.d'
 108 endif
 109
 110 vapidir = join_paths(datadir, 'vala', 'vapi')
 111
 112 bashcompletiondir = get_option('bashcompletiondir')
 113 if bashcompletiondir == ''
 114   bash_completion_dep = dependency('bash-completion', required : false)
 115   if bash_completion_dep.found()
 116     bashcompletiondir = bash_completion_dep.get_pkgconfig_variable('completionsdir')
 117   else
 118     bashcompletiondir = join_paths(datadir, 'bash-completion', 'completions')
 119   endif
 120 endif
 121
 122 zshcompletiondir = get_option('zshcompletiondir')
 123 if zshcompletiondir == ''
 124   zshcompletiondir = join_paths(datadir, 'zsh', 'site-functions')
 125 endif
 126
 127 # Configuration data
 128
 129 cc = meson.get_compiler('c')
 130
 131 cdata = configuration_data()
 132 cdata.set_quoted('PACKAGE', 'pulseaudio')
 133 cdata.set_quoted('PACKAGE_NAME', 'pulseaudio')
 134 cdata.set_quoted('PACKAGE_VERSION', pa_version_str)
 135 cdata.set('PA_MAJOR', pa_version_major)
 136 cdata.set('PA_MINOR', pa_version_minor)
 137 cdata.set('PA_API_VERSION', pa_api_version)
 138 cdata.set('PA_PROTOCOL_VERSION', pa_protocol_version)
 139 cdata.set_quoted('PA_MACHINE_ID', join_paths(sysconfdir, 'machine-id'))
 140 cdata.set_quoted('PA_MACHINE_ID_FALLBACK', join_paths(localstatedir, 'lib', 'dbus', 'machine-id'))
 141 cdata.set_quoted('PA_SRCDIR', join_paths(meson.current_source_dir(), 'src'))
 142 cdata.set_quoted('PA_BUILDDIR', meson.current_build_dir())
 143 cdata.set_quoted('PA_SOEXT', '.so')
 144 cdata.set_quoted('PA_DEFAULT_CONFIG_DIR', pulsesysconfdir)
 145 cdata.set('PA_DEFAULT_CONFIG_DIR_UNQUOTED', pulsesysconfdir)
 146 cdata.set_quoted('PA_BINARY', join_paths(bindir, 'pulseaudio'))
 147 cdata.set_quoted('PA_SYSTEM_RUNTIME_PATH', join_paths(localstatedir, 'run', 'pulse'))
 148 cdata.set_quoted('PA_SYSTEM_CONFIG_PATH', join_paths(localstatedir, 'lib', 'pulse'))
 149 cdata.set_quoted('PA_SYSTEM_STATE_PATH', join_paths(localstatedir, 'lib', 'pulse'))
 150 cdata.set_quoted('PA_DLSEARCHPATH', modlibexecdir)
 151 cdata.set_quoted('PA_SYSTEM_USER', get_option('system_user'))
 152 cdata.set_quoted('PA_SYSTEM_GROUP', get_option('system_group'))
 153 cdata.set_quoted('PA_ACCESS_GROUP', get_option('access_group'))
 154 cdata.set_quoted('PA_CFLAGS', 'Not yet supported on meson')
 155 cdata.set_quoted('PA_ALSA_PATHS_DIR', join_paths(alsadatadir, 'paths'))
 156 cdata.set_quoted('PA_ALSA_PROFILE_SETS_DIR', join_paths(alsadatadir, 'profile-sets'))
 157 cdata.set_quoted('DESKTOPFILEDIR', join_paths(datadir, 'applications'))
 158 cdata.set_quoted('PULSE_LOCALEDIR', localedir)
 159 cdata.set_quoted('GETTEXT_PACKAGE', 'pulseaudio')
 160 cdata.set('ENABLE_NLS', 1)
 161 cdata.set('top_srcdir', meson.source_root())
 162
 163 # Platform specifics
 164 # First some defaults to keep config file generation happy
 165 cdata.set('HAVE_COREAUDIO', 0)
 166 cdata.set('HAVE_WAVEOUT', 0)
 167 cdata.set('OS_IS_FREEBSD', 0)
 168
 169 platform_socket_dep = []
 170 platform_dep = []
 171
 172 if host_machine.endian() == 'big'
 173   cdata.set('WORDS_BIGENDIAN', 1)
 174 endif
 175
 176 # FIXME: This was not tested. Maybe some flags should better be CFLAGS,
 177 # rather than ending up in the config.h file?
 178 if host_machine.system() == 'darwin'
 179   cdata.set('OS_IS_DARWIN', 1)
 180   cdata.set('_DARWIN_C_SOURCE', '200112L') # Needed to get NSIG on Mac OS
 181 elif host_machine.system() == 'windows'
 182   cdata.set('OS_IS_WIN32', 1)
 183   cdata.set('HAVE_WINDOWS_H', 1)
 184   cdata.set('HAVE_WAVEOUT', 1)
 185   cdata.set('HAVE_WINSOCK2_H', 1)
 186   cdata.set('HAVE_WS2TCPIP_H', 1)
 187   cdata.set('WIN32_LEAN_AND_MEAN', 1) # Needed to avoid including unnecessary headers on Windows
 188   cdata.set('gid_t', 'int')
 189   cdata.set('uid_t', 'int')
 190   ws2_32_dep = meson.get_compiler('c').find_library('ws2_32')
 191   winsock_dep = meson.get_compiler('c').find_library('wsock32')
 192   ole32_dep = meson.get_compiler('c').find_library('ole32')
 193   ssp_dep = meson.get_compiler('c').find_library('ssp')
 194   pcreposix_dep = meson.get_compiler('c').find_library('pcreposix')
 195   platform_socket_dep = [ws2_32_dep, winsock_dep]
 196   platform_dep = [ole32_dep, ssp_dep, pcreposix_dep]
 197 elif host_machine.system() == 'freebsd'
 198   cdata.set('OS_IS_FREEBSD', 1)
 199 #elif host_machine.system() == 'solaris'
 200 #  # Apparently meson has no solaris support?
 201 #  # Needed to get declarations for msg_control and msg_controllen on Solaris
 202 #  cdata.set('_XOPEN_SOURCE', 600)
 203 #  cdata.set('__EXTENSIONS__', 1)
 204 endif
 205
 206 if cc.has_type('_Bool')
 207   cdata.set('HAVE_STD_BOOL', 1)
 208 endif
 209
 210 if host_machine.cpu_family() == 'x86_64' or cc.sizeof('void *') >= 8
 211   cdata.set('HAVE_FAST_64BIT_OPERATIONS', 1)
 212 endif
 213
 214 # Headers
 215
 216 check_headers = [
 217   'arpa/inet.h',
 218   'byteswap.h',
 219   'cpuid.h',
 220   'dlfcn.h',
 221   'execinfo.h',
 222   'grp.h',
 223   'langinfo.h',
 224   'linux/sockios.h',
 225   'locale.h',
 226   'netdb.h',
 227   'netinet/in.h',
 228   'netinet/in_systm.h',
 229   'netinet/ip.h',
 230   'netinet/tcp.h',
 231   'pcreposix.h',
 232   'poll.h',
 233   'pwd.h',
 234   'regex.h',
 235   'sched.h',
 236   'stdint.h',
 237   'sys/atomic.h',
 238   'sys/capability.h',
 239   'sys/conf.h',
 240   'sys/dl.h',
 241   'sys/eventfd.h',
 242   'sys/filio.h',
 243   'sys/ioctl.h',
 244   'sys/mman.h',
 245   'sys/prctl.h',
 246   'sys/resource.h',
 247   'sys/select.h',
 248   'sys/socket.h',
 249   'sys/syscall.h',
 250   'sys/uio.h',
 251   'sys/un.h',
 252   'sys/wait.h',
 253   'syslog.h',
 254   'xlocale.h',
 255 ]
 256
 257 foreach h : check_headers
 258   if cc.has_header(h)
 259     define = 'HAVE_' + h.underscorify().to_upper()
 260     cdata.set(define, 1)
 261   endif
 262 endforeach
 263
 264 if cc.has_header('valgrind/memcheck.h', required: get_option('valgrind'))
 265   cdata.set('HAVE_VALGRIND_MEMCHECK_H', 1)
 266 endif
 267
 268 # FIXME: move this to the above set
 269 if host_machine.system() != 'windows'
 270   if cc.has_header('pthread.h')
 271     cdata.set('HAVE_PTHREAD', 1)
 272   endif
 273 endif
 274
 275 if cc.has_header_symbol('pthread.h', 'PTHREAD_PRIO_INHERIT')
 276   cdata.set('HAVE_PTHREAD_PRIO_INHERIT', 1)
 277 endif
 278
 279 # Functions
 280
 281 check_functions = [
 282   'accept4',
 283   'clock_gettime',
 284   'ctime_r',
 285   'fchmod',
 286   'fchown',
 287   'fork',
 288   'fstat',
 289   'getaddrinfo',
 290   'getgrgid_r',
 291   'getgrnam_r',
 292   'getpwnam_r',
 293   'getpwuid_r',
 294   'gettimeofday',
 295   'getuid',
 296   'lrintf',
 297   'lstat',
 298   'memfd_create',
 299   'mkfifo',
 300   'mlock',
 301   'nanosleep',
 302   'open64',
 303   'paccept',
 304   'pipe',
 305   'pipe2',
 306   'posix_fadvise',
 307   'posix_madvise',
 308   'posix_memalign',
 309   'ppoll',
 310   'readlink',
 311   'setegid',
 312   'seteuid',
 313   'setpgid',
 314   'setregid',
 315   'setresgid',
 316   'setresuid',
 317   'setreuid',
 318   'setsid',
 319   'sig2str',
 320   'sigaction',
 321   'strerror_r',
 322   'strtod_l',
 323   'strtof',
 324   'symlink',
 325   'sysconf',
 326   'uname',
 327 ]
 328
 329 foreach f : check_functions
 330   if cc.has_function(f)
 331     define = 'HAVE_' + f.underscorify().to_upper()
 332
 333     if f == 'posix_memalign' and host_machine.system() == 'windows'
 334       message('Win32/mingw32 does not properly define posix_memalign.')
 335     elif f == 'fork' and host_machine.system() == 'windows'
 336       # __builtin_fork is defined and compiles properly, but calling __builtin_fork() does not.
 337       # This causes Meson to think that Windows has a fork() which causes a link error...
 338       message('Win32/mingw32 does not properly define fork.')
 339     else
 340       cdata.set(define, 1)
 341     endif
 342   endif
 343 endforeach
 344
 345 if cc.has_header_symbol('sys/syscall.h', 'SYS_memfd_create') \
 346   or cc.has_function('memfd_create')
 347   cdata.set('HAVE_MEMFD', 1)
 348 endif
 349
 350 if cc.has_function('dgettext')
 351   if host_machine.system() != 'windows'
 352     libintl_dep = []
 353   else
 354     libintl_dep = cc.find_library('intl')
 355   endif
 356 else
 357   libintl_dep = cc.find_library('intl')
 358 endif
 359
 360 # Symbols
 361
 362 if cc.has_header_symbol('signal.h', 'SIGXCPU')
 363   cdata.set('HAVE_SIGXCPU', 1)
 364 endif
 365
 366 if not cc.has_header_symbol('netinet/in.h', 'INADDR_NONE')
 367   if not cc.has_header_symbol('winsock2.h', 'INADDR_NONE')
 368     # Define INADDR_NONE if not found (Solaris)
 369     cdata.set('INADDR_NONE', '0xffffffff')
 370   endif
 371 endif
 372
 373 check_decls = [
 374   [ 'environ', 'unistd.h', '#define _GNU_SOURCE' ],
 375   [ 'SOUND_PCM_READ_RATE', 'sys/soundcard.h', '' ],
 376   [ 'SOUND_PCM_READ_CHANNELS', 'sys/soundcard.h', '' ],
 377   [ 'SOUND_PCM_READ_BITS', 'sys/soundcard.h', '' ],
 378 ]
 379
 380 foreach s : check_decls
 381   if cc.has_header_symbol(s[1], s[0], prefix : s[2])
 382     define = 'HAVE_DECL_' + s[0].to_upper()
 383     cdata.set(define, 1)
 384   endif
 385 endforeach
 386
 387 # Types
 388
 389 # FIXME: do we ever care about gid_t not being defined / smaller than an int?
 390 cdata.set('GETGROUPS_T', 'gid_t')
 391
 392 # Include paths
 393
 394 configinc = include_directories('.')
 395 topinc = include_directories('src')
 396
 397 # CFLAGS/LDFLAGS
 398
 399 pa_c_args = ['-DHAVE_CONFIG_H', '-D_GNU_SOURCE']
 400 server_c_args = ['-D__INCLUDED_FROM_PULSE_AUDIO']
 401 cdata.set('MESON_BUILD', 1)
 402
 403 # On ELF systems we don't want the libraries to be unloaded since we don't clean them up properly,
 404 # so we request the nodelete flag to be enabled.
 405 # On other systems, we don't really know how to do that, but it's welcome if somebody can tell.
 406 # Windows doesn't support this flag.
 407 if host_machine.system() != 'windows'
 408   nodelete_link_args = ['-Wl,-z,nodelete']
 409 else
 410   nodelete_link_args = []
 411 endif
 412
 413 # Code coverage
 414
 415 if get_option('gcov')
 416   add_project_arguments('--coverage', language: ['c', 'cpp'])
 417   add_project_link_arguments('--coverage', language: ['c', 'cpp'])
 418 endif
 419
 420 # Core Dependencies
 421
 422 libm_dep = cc.find_library('m', required : true)
 423
 424 thread_dep = dependency('threads')
 425 foreach f : [
 426   'pthread_getname_np',
 427   'pthread_setaffinity_np',
 428   'pthread_setname_np',
 429 ]
 430   if cc.has_function(f, dependencies : thread_dep)
 431     define = 'HAVE_' + f.underscorify().to_upper()
 432     cdata.set(define, 1)
 433   endif
 434 endforeach
 435
 436 cap_dep = cc.find_library('cap', required : false)
 437
 438 shm_dep = cc.find_library('rt', required : false)
 439 if cc.has_function('shm_open', dependencies : shm_dep)
 440   cdata.set('HAVE_SHM_OPEN', 1)
 441 endif
 442
 443 dl_dep = cc.find_library('dl', required : false)
 444 if cc.has_function('dladdr', dependencies : dl_dep)
 445   cdata.set('HAVE_DLADDR', 1)
 446 endif
 447
 448 have_iconv = false
 449 if cc.has_function('iconv_open')
 450   iconv_dep = dependency('', required : false)
 451   have_iconv = true
 452   # tell the libiconv header to pretend to be libc iconv
 453   cdata.set('LIBICONV_PLUG', 1)
 454 else
 455   iconv_dep = cc.find_library('iconv', required : false)
 456   have_iconv = iconv_dep.found()
 457 endif
 458 if have_iconv
 459   cdata.set('HAVE_ICONV', 1)
 460   iconvconsttest = '''#include <iconv.h>
 461 size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 462 '''
 463   if cc.compiles(iconvconsttest, dependencies : iconv_dep)
 464     cdata.set('ICONV_CONST', '')
 465   else
 466     cdata.set('ICONV_CONST', 'const')
 467   endif
 468 endif
 469
 470 # Used for backtraces on BSD
 471 execinfo_dep = cc.find_library('execinfo', required : false)
 472
 473 # Atomic operations
 474
 475 if get_option('atomic-arm-memory-barrier')
 476     cdata.set('ATOMIC_ARM_MEMORY_BARRIER_ENABLED', 1)
 477 endif
 478
 479 need_libatomic_ops = false
 480
 481 atomictest = '''void func() {
 482   volatile int atomic = 2;
 483   __sync_bool_compare_and_swap (&atomic, 2, 3);
 484 }
 485 '''
 486
 487 if cc.compiles(atomictest)
 488   cdata.set('HAVE_ATOMIC_BUILTINS', 1)
 489
 490   newatomictest = '''void func() {
 491     int c = 0;
 492     __atomic_store_n(&c, 4, __ATOMIC_SEQ_CST);
 493   }
 494   '''
 495
 496   if(cc.compiles(newatomictest))
 497     cdata.set('HAVE_ATOMIC_BUILTINS_MEMORY_MODEL', 1)
 498   endif
 499
 500 elif host_machine.cpu_family() == 'arm'
 501   if host_machine.system() == 'linux' and get_option('atomic-arm-linux-helpers')
 502     cdata.set('ATOMIC_ARM_LINUX_HELPERS', 1)
 503   else
 504     armatomictest = '''int func() {
 505       volatile int a=0;
 506       int o=0, n=1, r;
 507       asm volatile (
 508               "ldrex    %0, [%1]\n"
 509               "subs  %0, %0, %2\n"
 510               "strexeq %0, %3, [%1]\n"
 511               : "=&r" (r)
 512               : "r" (&a), "Ir" (o), "r" (n)
 513       : "cc");
 514       return (a==1 ? 0 : -1);
 515     }
 516     '''
 517
 518     if cc.compiles(armatomictest)
 519       cdata.set('ATOMIC_ARM_INLINE_ASM', 1)
 520     else
 521       need_libatomic_ops = true
 522     endif
 523   endif # arm && !linux
 524
 525 elif not ['freebsd', 'netbsd'].contains(host_machine.system())
 526   need_libatomic_ops = true
 527 endif # !atomic helpers && !arm
 528
 529 if need_libatomic_ops
 530   assert(cc.has_header('atomic_ops.h'), 'Need libatomic_ops')
 531
 532   cdata.set('AO_REQUIRE_CAS', 1)
 533
 534   if host_machine.system() != 'windows'
 535     libatomic_ops_dep = cc.find_library('atomic_ops', required : true)
 536   else
 537     libatomic_ops_dep = dependency('', required: false)
 538   endif
 539 else
 540   libatomic_ops_dep = dependency('', required: false)
 541 endif
 542
 543 # ARM checks
 544 # ARMV6 instructions we need
 545 if host_machine.cpu_family() == 'arm'
 546   armv6test = '''int func() {
 547     volatile int a = -60000, b = 0xaaaabbbb, c = 0xccccdddd;
 548     asm volatile ("ldr r0, %2 \n"
 549                   "ldr r2, %3 \n"
 550                   "ldr r3, %4 \n"
 551                   "ssat r1, #8, r0 \n"
 552                   "str r1, %0 \n"
 553                   "pkhbt r1, r3, r2, LSL #8 \n"
 554                   "str r1, %1 \n"
 555                   : "=m" (a), "=m" (b)
 556                   : "m" (a), "m" (b), "m" (c)
 557                   : "r0", "r1", "r2", "r3", "cc");
 558     return (a == -128 && b == 0xaabbdddd) ? 0 : -1;
 559   }
 560   '''
 561
 562   if cc.compiles(armv6test)
 563     cdata.set('HAVE_ARMV6', 1)
 564   endif
 565 endif
 566 # NEON checks are automatically done by the unstable-simd module
 567
 568 if get_option('daemon')
 569   # FIXME: make sure it's >= 2.2
 570   ltdl_dep = cc.find_library('ltdl', required : true)
 571 endif
 572
 573 # FIXME: can meson support libtool -dlopen/-dlpreopen things?
 574 #        and do we still want to support this at all?
 575 cdata.set('DISABLE_LIBTOOL_PRELOAD', 1)
 576
 577 if get_option('database') == 'tdb'
 578   database_dep = dependency('tdb')
 579 elif get_option('database') == 'gdbm'
 580   database_dep = cc.find_library('gdbm', required : true)
 581 else
 582   database_dep = dependency('', required: false)
 583 endif
 584
 585 if get_option('ipv6')
 586   cdata.set('HAVE_IPV6', 1)
 587 endif
 588
 589 if get_option('legacy-database-entry-format')
 590   cdata.set('ENABLE_LEGACY_DATABASE_ENTRY_FORMAT', 1)
 591 endif
 592
 593 if get_option('stream-restore-clear-old-devices')
 594   cdata.set('STREAM_RESTORE_CLEAR_OLD_DEVICES', 1)
 595 endif
 596
 597 if get_option('running-from-build-tree')
 598   cdata.set('HAVE_RUNNING_FROM_BUILD_TREE', 1)
 599 endif
 600
 601 alsa_dep = dependency('alsa', version : '>= 1.0.24', required : get_option('alsa'))
 602 if alsa_dep.found()
 603   cdata.set('HAVE_ALSA', 1)
 604   cdata.set('HAVE_ALSA_UCM', 1)
 605 endif
 606
 607 asyncns_dep = dependency('libasyncns', version : '>= 0.1', required : get_option('asyncns'))
 608 if asyncns_dep.found()
 609   cdata.set('HAVE_LIBASYNCNS', 1)
 610 endif
 611
 612 dbus_dep = dependency('dbus-1', version : '>= 1.4.12', required : get_option('dbus'))
 613 if dbus_dep.found()
 614   cdata.set('HAVE_DBUS', 1)
 615 endif
 616
 617 gio_dep = dependency('gio-2.0', version : '>= 2.26.0')
 618 if get_option('gsettings').enabled()
 619   assert(gio_dep.found(), 'GSettings support needs glib I/O library (GIO)')
 620   cdata.set('HAVE_GSETTINGS', 1)
 621 else
 622   cdata.set('HAVE_GSETTINGS', 0)
 623 endif
 624
 625 glib_dep = dependency('glib-2.0', version : '>= 2.28.0', required: get_option('glib'))
 626 if glib_dep.found()
 627   cdata.set('HAVE_GLIB', 1)
 628 endif
 629
 630 gtk_dep = dependency('gtk+-3.0', required : get_option('gtk'))
 631 if gtk_dep.found()
 632   cdata.set('HAVE_GTK', 1)
 633 endif
 634
 635 have_orcc = false
 636 orcc_args = []
 637 orc_dep = dependency('orc-0.4', version : '>= 0.4.11', required : get_option('orc'))
 638 orcc = find_program('orcc', required : get_option('orc'))
 639 if orc_dep.found() and orcc.found()
 640   have_orcc = true
 641   orcc_args = [orcc]
 642   #orcc_args = [orcc, '--include', 'glib.h']
 643   cdata.set('HAVE_ORC', 1)
 644 else
 645   cdata.set('DISABLE_ORC', 1)
 646 endif
 647
 648 samplerate_dep = dependency('samplerate', version : '>= 0.1.0', required : get_option('samplerate'))
 649 if samplerate_dep.found()
 650   cdata.set('HAVE_LIBSAMPLERATE', 1)
 651 endif
 652
 653 sndfile_dep = dependency('sndfile', version : '>= 1.0.20')
 654
 655 soxr_dep = dependency('soxr', version : '>= 0.1.1', required : get_option('soxr'))
 656 if soxr_dep.found()
 657   cdata.set('HAVE_SOXR', 1)
 658 endif
 659
 660 libsystemd_dep = dependency('libsystemd', required : get_option('systemd'))
 661 if libsystemd_dep.found()
 662   cdata.set('HAVE_SYSTEMD_DAEMON', 1)
 663   cdata.set('HAVE_SYSTEMD_LOGIN', 1)
 664   cdata.set('HAVE_SYSTEMD_JOURNAL', 1)
 665 endif
 666 systemd_dep = dependency('systemd', required : get_option('systemd'))
 667 if systemd_dep.found() and systemduserunitdir == ''
 668   systemduserunitdir = systemd_dep.get_pkgconfig_variable('systemduserunitdir')
 669 endif
 670
 671 libelogind_dep = dependency('libelogind', required : get_option('elogind'))
 672 if libelogind_dep.found()
 673   cdata.set('HAVE_SYSTEMD_LOGIN', 1)
 674 endif
 675
 676 tcpwrap_dep = cc.find_library('wrap', required: get_option('tcpwrap'))
 677 if cc.has_header('tcpd.h') and cc.has_function('hosts_access', dependencies : tcpwrap_dep)
 678   cdata.set('HAVE_LIBWRAP', 1)
 679 endif
 680
 681 x11_dep = dependency('x11-xcb', required : get_option('x11'))
 682 if x11_dep.found()
 683   xcb_dep  = dependency('xcb',  required : true, version : '>= 1.6')
 684   ice_dep  = dependency('ice',  required : true)
 685   sm_dep   = dependency('sm',   required : true)
 686   xtst_dep = dependency('xtst', required : true)
 687   cdata.set('HAVE_X11', 1)
 688   if cc.has_function('XSetIOErrorExitHandler', dependencies: x11_dep)
 689     cdata.set('HAVE_XSETIOERROREXITHANDLER', 1)
 690   endif
 691 endif
 692
 693 # Module dependencies
 694 if cc.has_header('sys/soundcard.h', required: get_option('oss-output'))
 695   cdata.set('HAVE_OSS_OUTPUT', 1)
 696   cdata.set('HAVE_OSS_WRAPPER', 1)
 697   cdata.set('PULSEDSP_LOCATION', pulsedsp_location)
 698 endif
 699
 700 if get_option('hal-compat')
 701   cdata.set('HAVE_HAL_COMPAT', 1)
 702 endif
 703
 704 avahi_dep = dependency('avahi-client', version : '>= 0.6.0', required : get_option('avahi'), disabler : true)
 705 if avahi_dep.found()
 706   cdata.set('HAVE_AVAHI', 1)
 707 else
 708   cdata.set('HAVE_AVAHI', 0)
 709 endif
 710
 711 sbc_dep = dependency('sbc', version : '>= 1.0', required : false)
 712
 713 bluez_dep = dependency('bluez', required : get_option('bluez5'))
 714
 715 if bluez_dep.found()
 716   assert(dbus_dep.found(), 'BlueZ requires D-Bus support')
 717   assert(sbc_dep.found(), 'BlueZ requires SBC support')
 718   cdata.set('HAVE_SBC', 1)
 719   cdata.set('HAVE_BLUEZ', 1)
 720   cdata.set('HAVE_BLUEZ_5', 1)
 721   if get_option('bluez5-native-headset')
 722     cdata.set('HAVE_BLUEZ_5_NATIVE_HEADSET', 1)
 723   endif
 724   if get_option('bluez5-ofono-headset')
 725     cdata.set('HAVE_BLUEZ_5_OFONO_HEADSET', 1)
 726   endif
 727 endif
 728
 729 fftw_dep = dependency('fftw3f', required : get_option('fftw'))
 730 if fftw_dep.found()
 731   cdata.set('HAVE_FFTW', 1)
 732 endif
 733
 734 jack_dep = dependency('jack', version : '>= 0.117.0', required : get_option('jack'))
 735 if jack_dep.found()
 736   cdata.set('HAVE_JACK', 1)
 737 endif
 738
 739 lirc_dep = dependency('lirc', required : get_option('lirc'))
 740 if lirc_dep.found()
 741   cdata.set('HAVE_LIRC', 1)
 742 endif
 743
 744 openssl_dep = dependency('openssl', version : '>= 0.9', required : get_option('openssl'))
 745 if openssl_dep.found()
 746   cdata.set('HAVE_OPENSSL', 1)
 747 endif
 748
 749 speex_dep = dependency('speexdsp', version : '>= 1.2', required : get_option('speex'))
 750 if speex_dep.found()
 751   cdata.set('HAVE_SPEEX', 1)
 752 endif
 753
 754 udev_dep = dependency('libudev', version : '>= 143', required : get_option('udev'))
 755 if udev_dep.found()
 756   cdata.set('HAVE_UDEV', 1)
 757 endif
 758
 759 webrtc_dep = dependency('webrtc-audio-processing', version : '>= 0.2', required : get_option('webrtc-aec'))
 760 if webrtc_dep.found()
 761   cdata.set('HAVE_WEBRTC', 1)
 762 endif
 763
 764 gst_dep = dependency('gstreamer-1.0', version : '>= 1.14', required : get_option('gstreamer'))
 765 gstapp_dep = dependency('gstreamer-app-1.0', required : get_option('gstreamer'))
 766 gstrtp_dep = dependency('gstreamer-rtp-1.0', required : get_option('gstreamer'))
 767
 768 have_gstreamer = false
 769 if gst_dep.found() and gstapp_dep.found() and gstrtp_dep.found()
 770   assert(gio_dep.found(), 'GStreamer-based RTP needs glib I/O library (GIO)')
 771   have_gstreamer = true
 772 endif
 773
 774 bluez5_gst_dep = dependency('gstreamer-1.0', version : '>= 1.14', required : get_option('bluez5-gstreamer'))
 775 bluez5_gstapp_dep = dependency('gstreamer-app-1.0', required : get_option('bluez5-gstreamer'))
 776 have_bluez5_gstreamer = false
 777 if bluez5_gst_dep.found() and bluez5_gstapp_dep.found()
 778   have_bluez5_gstreamer = true
 779   cdata.set('HAVE_GSTLDAC', 1)
 780   cdata.set('HAVE_GSTAPTX', 1)
 781 endif
 782
 783 # These are required for the CMake file generation
 784 cdata.set('PA_LIBDIR', libdir)
 785 cdata.set('PA_INCDIR', includedir)
 786 if glib_dep.found()
 787   cdata.set('HAVE_GLIB20', 1) # to match the AM_CONDITIONAL for CMake file generation
 788 endif
 789
 790 # Test dependencies
 791
 792 check_dep = dependency('check', version : '>= 0.9.10', required : get_option('tests'))
 793
 794 # Subdirs
 795
 796 if get_option('doxygen')
 797   subdir('doxygen')
 798 endif
 799 subdir('po')
 800 if get_option('man')
 801   subdir('man')
 802 endif
 803 subdir('shell-completion/bash')
 804 subdir('shell-completion/zsh')
 805 subdir('src')
 806 subdir('vala')
 807
 808 # Now generate config.h from everything above
 809 configure_file(output : 'config.h', configuration : cdata)
 810
 811 # pkg-config files
 812
 813 pc_cdata = configuration_data()
 814
 815 pc_cdata.set('prefix', prefix)
 816 pc_cdata.set('exec_prefix', prefix)
 817 pc_cdata.set('libdir', libdir)
 818 pc_cdata.set('includedir', includedir)
 819 pc_cdata.set('modlibexecdir', modlibexecdir)
 820 pc_cdata.set('PACKAGE_VERSION', pa_version_str)
 821 pc_cdata.set('PA_MAJORMINOR', pa_version_major_minor)
 822 # FIXME: the line below is wrong. Currently the meson thread dep lacks documentation,
 823 # and doesn't allow introspection, ie. none of get_pkgconfig_variable() or
 824 # get_configtool_variable() work with it, so we have no way to get this flag right,
 825 # unless we do all the work ourselves. See current work in glib, also meson #553.
 826 pc_cdata.set('PTHREAD_LIBS', '-pthread')
 827
 828 pc_files = [
 829   'libpulse.pc',
 830   'libpulse-simple.pc',
 831 ]
 832
 833 if glib_dep.found()
 834   pc_files += 'libpulse-mainloop-glib.pc'
 835 endif
 836
 837 foreach file : pc_files
 838   configure_file(
 839     input : file + '.in',
 840     output : file,
 841     configuration : pc_cdata,
 842     install_dir : pkgconfigdir)
 843 endforeach
 844
 845 # CMake files
 846
 847 m4 = find_program('m4', required: true)
 848
 849 cmakedir = join_paths(libdir, 'cmake', 'PulseAudio')
 850
 851 cmake_template_file = configure_file(
 852   input : 'PulseAudioConfig.cmake.in',
 853   output : 'PulseAudioConfig.cmake.tmp',
 854   configuration: cdata,
 855 )
 856
 857 custom_target('PulseAudioConfig.cmake',
 858   input : cmake_template_file,
 859   output : 'PulseAudioConfig.cmake',
 860   capture : true,
 861   command : [m4, '@INPUT@'],
 862   build_by_default : true,
 863   install : true,
 864   install_dir : cmakedir,
 865 )
 866
 867 configure_file(
 868   input : 'PulseAudioConfigVersion.cmake.in',
 869   output : 'PulseAudioConfigVersion.cmake',
 870   configuration: cdata,
 871   install : true,
 872   install_dir : cmakedir,
 873 )
 874
 875 ############################################################
 876
 877 # Final summary
 878
 879 summary = [
 880   '',
 881   '---{ @0@ @1@ }---'.format(meson.project_name(), meson.project_version()),
 882   '',
 883   'prefix:                        @0@'.format(prefix),
 884   'bindir:                        @0@'.format(bindir),
 885   'libdir:                        @0@'.format(libdir),
 886   'libexecdir:                    @0@'.format(libexecdir),
 887   'mandir:                        @0@'.format(mandir),
 888   'datadir:                       @0@'.format(datadir),
 889   'sysconfdir:                    @0@'.format(sysconfdir),
 890   'localstatedir:                 @0@'.format(localstatedir),
 891   'modlibexecdir:                 @0@'.format(modlibexecdir),
 892   'alsadatadir:                   @0@'.format(alsadatadir),
 893   'System Runtime Path:           @0@'.format(cdata.get_unquoted('PA_SYSTEM_RUNTIME_PATH')),
 894   'System State Path:             @0@'.format(cdata.get_unquoted('PA_SYSTEM_STATE_PATH')),
 895   'System Config Path:            @0@'.format(cdata.get_unquoted('PA_SYSTEM_CONFIG_PATH')),
 896   'Bash completions directory:    @0@'.format(bashcompletiondir),
 897   'Zsh completions directory:     @0@'.format(zshcompletiondir),
 898   'Compiler:                      @0@ @1@'.format(cc.get_id(), cc.version()),
 899 #  'CFLAGS:                        @0@'.format(${CFLAGS}),
 900 #  'CPPFLAGS:                      @0@'.format(${CPPFLAGS}),
 901 #  'LIBS:                          @0@'.format(${LIBS}),
 902   '',
 903   'Enable pulseaudio daemon:      @0@'.format(get_option('daemon')),
 904   '',
 905   'Enable memfd shared memory:    @0@'.format(cdata.has('HAVE_MEMFD')),
 906   'Enable X11:                    @0@'.format(x11_dep.found()),
 907   '  Safe X11 I/O errors:         @0@'.format(cdata.has('HAVE_XSETIOERROREXITHANDLER')),
 908   'Enable OSS Output:             @0@'.format(cdata.has('HAVE_OSS_OUTPUT')),
 909   'Enable OSS Wrapper:            @0@'.format(cdata.has('HAVE_OSS_WRAPPER')),
 910 #  'Enable EsounD:                 @0@'.format(${ENABLE_ESOUND}),
 911   'Enable Alsa:                   @0@'.format(alsa_dep.found()),
 912 #  'Enable CoreAudio:              @0@'.format(${ENABLE_COREAUDIO}),
 913 #  'Enable Solaris:                @0@'.format(${ENABLE_SOLARIS}),
 914 #  'Enable WaveOut:                @0@'.format(${ENABLE_WAVEOUT}),
 915   'Enable GLib 2:                 @0@'.format(glib_dep.found()),
 916   'Enable GSettings:              @0@'.format(gio_dep.found()),
 917   'Enable Gtk+ 3:                 @0@'.format(gtk_dep.found()),
 918   'Enable Avahi:                  @0@'.format(avahi_dep.found()),
 919   'Enable Jack:                   @0@'.format(jack_dep.found()),
 920   'Enable Async DNS:              @0@'.format(asyncns_dep.found()),
 921   'Enable LIRC:                   @0@'.format(lirc_dep.found()),
 922   'Enable D-Bus:                  @0@'.format(dbus_dep.found()),
 923   '  Enable BlueZ 5:              @0@'.format(cdata.has('HAVE_BLUEZ_5')),
 924   '    Enable native headsets:    @0@'.format(cdata.has('HAVE_BLUEZ_5_NATIVE_HEADSET')),
 925   '    Enable  ofono headsets:    @0@'.format(cdata.has('HAVE_BLUEZ_5_OFONO_HEADSET')),
 926   '    Enable GStreamer based codecs: @0@'.format(have_bluez5_gstreamer),
 927   'Enable udev:                   @0@'.format(udev_dep.found()),
 928   '  Enable HAL->udev compat:     @0@'.format(get_option('hal-compat')),
 929   'Enable systemd:                @0@'.format(libsystemd_dep.found()),
 930   'Enable elogind:                @0@'.format(libelogind_dep.found()),
 931   'Enable TCP Wrappers:           @0@'.format(tcpwrap_dep.found()),
 932   'Enable libsamplerate:          @0@'.format(samplerate_dep.found()),
 933   'Enable IPv6:                   @0@'.format(get_option('ipv6')),
 934   'Enable OpenSSL (for Airtunes): @0@'.format(openssl_dep.found()),
 935   'Enable FFTW:                   @0@'.format(fftw_dep.found()),
 936   'Enable ORC:                    @0@'.format(have_orcc),
 937   'Enable GStreamer:              @0@'.format(have_gstreamer),
 938   'Enable Adrian echo canceller:  @0@'.format(get_option('adrian-aec')),
 939   'Enable Speex (resampler, AEC): @0@'.format(speex_dep.found()),
 940   'Enable SoXR (resampler):       @0@'.format(soxr_dep.found()),
 941   'Enable WebRTC echo canceller:  @0@'.format(webrtc_dep.found()),
 942   'Enable Gcov coverage:          @0@'.format(get_option('gcov')),
 943   'Enable Valgrind:               @0@'.format(cdata.has('HAVE_VALGRIND_MEMCHECK_H')),
 944   'Enable man pages:              @0@'.format(get_option('man')),
 945   'Enable unit tests:             @0@'.format(get_option('tests')),
 946   '',
 947   'Database:                      @0@'.format(get_option('database')),
 948   'Legacy Database Entry Support: @0@'.format(get_option('legacy-database-entry-format')),
 949   'module-stream-restore:',
 950   '  Clear old devices:           @0@'.format(get_option('stream-restore-clear-old-devices')),
 951   'Running from build tree:       @0@'.format(get_option('running-from-build-tree')),
 952   'System User:                   @0@'.format(cdata.get_unquoted('PA_SYSTEM_USER')),
 953   'System Group:                  @0@'.format(cdata.get_unquoted('PA_SYSTEM_GROUP')),
 954   'Access Group:                  @0@'.format(cdata.get_unquoted('PA_ACCESS_GROUP')),
 955 #  'Enable per-user EsounD socket: @0@'.format(${ENABLE_PER_USER_ESOUND_SOCKET}),
 956 #  'Force preopen:                 @0@'.format(${FORCE_PREOPEN}),
 957 #  'Preopened modules:             @0@'.format(${PREOPEN_MODS}),
 958 ]
 959
 960 message('\n    '.join(summary))
 961
 962 # Sanity checks
 963
 964 if not speex_dep.found() and not webrtc_dep.found() and not get_option('adrian-aec')
 965   error('At least one echo canceller implementation must be available!')
 966 endif
 967
 968 if samplerate_dep.found()
 969   warning('Support for libsamplerate is DEPRECATED')
 970 endif
 971
 972 if host_machine.system() != 'windows'
 973   if not dbus_dep.found()
 974     message = [
 975       'You do not have D-Bus support enabled. It is strongly recommended',
 976       'that you enable D-Bus support if your platform supports it.',
 977       'Many parts of PulseAudio use D-Bus, from ConsoleKit interaction',
 978       'to the Device Reservation Protocol to speak to JACK, Bluetooth',
 979       'support and even a native control protocol for communicating and',
 980       'controlling the PulseAudio daemon itself.',
 981     ]
 982     warning('\n' + '\n'.join(message))
 983   endif
 984   if host_machine.system() == 'linux' and not udev_dep.found()
 985     message = [
 986       'You do not have udev support enabled. It is strongly recommended',
 987       'that you enable udev support if your platform supports it as it is',
 988       'the primary method used to detect hardware audio devices (on Linux)',
 989       'and is thus a critical part of PulseAudio on that platform.',
 990     ]
 991     warning('\n' + '\n'.join(message))
 992   endif
 993   if not speex_dep.found()
 994     message = [
 995       'You do not have speex support enabled. It is strongly recommended',
 996       'that you enable speex support if your platform supports it as it is',
 997       'the primary method used for audio resampling and is thus a critical',
 998       'part of PulseAudio on that platform.',
 999     ]
1000     warning('\n' + '\n'.join(message))
1001   endif
1002 endif