meson.build

   1 project('pulseaudio', 'c', 'cpp',
   2         version : run_command(find_program('git-version-gen'), join_paths(meson.current_source_dir(), '.tarball-version')).stdout().strip(),
   3         meson_version : '>= 0.50.0',
   4         default_options : [ 'c_std=gnu11', 'cpp_std=c++11' ]
   5         )
   6
   7 pa_version_str = meson.project_version()
   8 # For tarballs, the first split will do nothing, but for builds in git, we
   9 # split out suffixes when there are commits since the last tag
  10 # (e.g.: v11.99.1-3-gad14bdb24 -> v11.99.1)
  11 version_split = pa_version_str.split('-')[0].split('.')
  12 pa_version_major = version_split[0].split('v')[0]
  13 pa_version_minor = version_split[1]
  14 if version_split.length() > 2
  15   pa_version_micro = version_split[2]
  16 else
  17   pa_version_micro = '0'
  18 endif
  19 pa_version_major_minor = pa_version_major + '.' + pa_version_minor
  20
  21 pa_api_version = 12
  22 pa_protocol_version = 35
  23
  24 # The stable ABI for client applications, for the version info x:y:z
  25 # always will hold x=z
  26 libpulse_version_info = [23, 0, 23]
  27
  28 # A simplified, synchronous, ABI-stable interface for client
  29 # applications, for the version info x:y:z always will hold x=z
  30 libpulse_simple_version_info = [1, 1, 1]
  31
  32 # The ABI-stable GLib adapter for client applications, for the version
  33 # info x:y:z always will hold x=z
  34 libpulse_mainloop_glib_version_info = [0, 6, 0]
  35
  36 libpulse_version = '@0@.@1@.@2@'.format(
  37   libpulse_version_info[0] - libpulse_version_info[2],
  38   libpulse_version_info[0],
  39   libpulse_version_info[1],
  40 )
  41
  42 libpulse_simple_version = '@0@.@1@.@2@'.format(
  43   libpulse_simple_version_info[0] - libpulse_simple_version_info[2],
  44   libpulse_simple_version_info[0],
  45   libpulse_simple_version_info[1],
  46 )
  47
  48 libpulse_mainloop_glib_version = '@0@.@1@.@2@'.format(
  49   libpulse_mainloop_glib_version_info[0] - libpulse_mainloop_glib_version_info[2],
  50   libpulse_mainloop_glib_version_info[0],
  51   libpulse_mainloop_glib_version_info[1],
  52 )
  53
  54 # Paths
  55
  56 prefix = get_option('prefix')
  57 assert(prefix.startswith('/'), 'Prefix is not absolute: "@0@"'.format(prefix))
  58
  59 bindir = join_paths(prefix, get_option('bindir'))
  60 includedir = join_paths(prefix, get_option('includedir'))
  61 libdir = join_paths(prefix, get_option('libdir'))
  62 libexecdir = join_paths(prefix, get_option('libexecdir'))
  63 mandir = join_paths(prefix, get_option('mandir'))
  64 datadir = join_paths(prefix, get_option('datadir'))
  65 localedir = join_paths(prefix, get_option('localedir'))
  66 localstatedir = join_paths(prefix, get_option('localstatedir'))
  67 sysconfdir = join_paths(prefix, get_option('sysconfdir'))
  68 privlibdir = join_paths(libdir, 'pulseaudio')
  69
  70 if host_machine.system() == 'windows'
  71   # Windows only supports loading libraries from the same dir as the executable
  72   privlibdir = bindir
  73 endif
  74
  75 alsadatadir = get_option('alsadatadir')
  76 if alsadatadir == ''
  77   alsadatadir = join_paths(datadir, 'pulseaudio', 'alsa-mixer')
  78 endif
  79
  80 pkgconfigdir = join_paths(libdir, 'pkgconfig')
  81 pulselibexecdir = join_paths(libexecdir, 'pulse')
  82 pulsesysconfdir = join_paths(sysconfdir, 'pulse')
  83
  84 modlibexecdir = get_option('modlibexecdir')
  85 if modlibexecdir == ''
  86   modlibexecdir = join_paths(libdir, 'pulse-' + pa_version_major_minor, 'modules')
  87 endif
  88
  89 padsplibdir = get_option('padsplibdir')
  90 if padsplibdir == ''
  91   padsplibdir = privlibdir
  92 endif
  93
  94 pulsedsp_location = get_option('pulsedsp-location')
  95 if pulsedsp_location == ''
  96   pulsedsp_location = join_paths(prefix, padsplibdir)
  97 endif
  98
  99 systemduserunitdir = get_option('systemduserunitdir')
 100 # the default value is set below
 101
 102 udevrulesdir = get_option('udevrulesdir')
 103 if udevrulesdir == ''
 104   # absolute path, otherwise meson prepends the prefix
 105   udevrulesdir = '/lib/udev/rules.d'
 106 endif
 107
 108 vapidir = join_paths(datadir, 'vala', 'vapi')
 109
 110 bashcompletiondir = get_option('bashcompletiondir')
 111 if bashcompletiondir == ''
 112   bash_completion_dep = dependency('bash-completion', required : false)
 113   if bash_completion_dep.found()
 114     bashcompletiondir = bash_completion_dep.get_pkgconfig_variable('completionsdir')
 115   else
 116     bashcompletiondir = join_paths(datadir, 'bash-completion', 'completions')
 117   endif
 118 endif
 119
 120 zshcompletiondir = get_option('zshcompletiondir')
 121 if zshcompletiondir == ''
 122   zshcompletiondir = join_paths(datadir, 'zsh', 'site-functions')
 123 endif
 124
 125 # Configuration data
 126
 127 cc = meson.get_compiler('c')
 128
 129 cdata = configuration_data()
 130 cdata.set_quoted('PACKAGE', 'pulseaudio')
 131 cdata.set_quoted('PACKAGE_NAME', 'pulseaudio')
 132 cdata.set_quoted('PACKAGE_VERSION', pa_version_str)
 133 cdata.set('PA_MAJOR', pa_version_major)
 134 cdata.set('PA_MINOR', pa_version_minor)
 135 cdata.set('PA_API_VERSION', pa_api_version)
 136 cdata.set('PA_PROTOCOL_VERSION', pa_protocol_version)
 137 cdata.set_quoted('PA_MACHINE_ID', join_paths(sysconfdir, 'machine-id'))
 138 cdata.set_quoted('PA_MACHINE_ID_FALLBACK', join_paths(localstatedir, 'lib', 'dbus', 'machine-id'))
 139 cdata.set_quoted('PA_SRCDIR', join_paths(meson.current_source_dir(), 'src'))
 140 cdata.set_quoted('PA_BUILDDIR', meson.current_build_dir())
 141 cdata.set_quoted('PA_SOEXT', '.so')
 142 cdata.set_quoted('PA_DEFAULT_CONFIG_DIR', pulsesysconfdir)
 143 cdata.set('PA_DEFAULT_CONFIG_DIR_UNQUOTED', pulsesysconfdir)
 144 cdata.set_quoted('PA_BINARY', join_paths(bindir, 'pulseaudio'))
 145 cdata.set_quoted('PA_SYSTEM_RUNTIME_PATH', join_paths(localstatedir, 'run', 'pulse'))
 146 cdata.set_quoted('PA_SYSTEM_CONFIG_PATH', join_paths(localstatedir, 'lib', 'pulse'))
 147 cdata.set_quoted('PA_SYSTEM_STATE_PATH', join_paths(localstatedir, 'lib', 'pulse'))
 148 cdata.set_quoted('PA_DLSEARCHPATH', modlibexecdir)
 149 cdata.set_quoted('PA_SYSTEM_USER', get_option('system_user'))
 150 cdata.set_quoted('PA_SYSTEM_GROUP', get_option('system_group'))
 151 cdata.set_quoted('PA_ACCESS_GROUP', get_option('access_group'))
 152 cdata.set_quoted('PA_CFLAGS', 'Not yet supported on meson')
 153 cdata.set_quoted('PA_ALSA_PATHS_DIR', join_paths(alsadatadir, 'paths'))
 154 cdata.set_quoted('PA_ALSA_PROFILE_SETS_DIR', join_paths(alsadatadir, 'profile-sets'))
 155 cdata.set_quoted('DESKTOPFILEDIR', join_paths(datadir, 'applications'))
 156 cdata.set_quoted('PULSE_LOCALEDIR', localedir)
 157 cdata.set_quoted('GETTEXT_PACKAGE', 'pulseaudio')
 158 cdata.set('ENABLE_NLS', 1)
 159 cdata.set('top_srcdir', meson.source_root())
 160
 161 # Platform specifics
 162 # First some defaults to keep config file generation happy
 163 cdata.set('HAVE_COREAUDIO', 0)
 164 cdata.set('HAVE_WAVEOUT', 0)
 165
 166 platform_socket_dep = []
 167 platform_dep = []
 168
 169 # FIXME: This was not tested. Maybe some flags should better be CFLAGS,
 170 # rather than ending up in the config.h file?
 171 if host_machine.system() == 'darwin'
 172   cdata.set('OS_IS_DARWIN', 1)
 173   cdata.set('_DARWIN_C_SOURCE', '200112L') # Needed to get NSIG on Mac OS
 174 elif host_machine.system() == 'windows'
 175   cdata.set('OS_IS_WIN32', 1)
 176   cdata.set('HAVE_WINDOWS_H', 1)
 177   cdata.set('HAVE_WAVEOUT', 1)
 178   cdata.set('HAVE_WINSOCK2_H', 1)
 179   cdata.set('HAVE_WS2TCPIP_H', 1)
 180   cdata.set('WIN32_LEAN_AND_MEAN', 1) # Needed to avoid including unnecessary headers on Windows
 181   cdata.set('gid_t', 'int')
 182   cdata.set('uid_t', 'int')
 183   ws2_32_dep = meson.get_compiler('c').find_library('ws2_32')
 184   winsock_dep = meson.get_compiler('c').find_library('wsock32')
 185   ole32_dep = meson.get_compiler('c').find_library('ole32')
 186   ssp_dep = meson.get_compiler('c').find_library('ssp')
 187   pcreposix_dep = meson.get_compiler('c').find_library('pcreposix')
 188   platform_socket_dep = [ws2_32_dep, winsock_dep]
 189   platform_dep = [ole32_dep, ssp_dep, pcreposix_dep]
 190 #elif host_machine.system() == 'solaris'
 191 #  # Apparently meson has no solaris support?
 192 #  # Needed to get declarations for msg_control and msg_controllen on Solaris
 193 #  cdata.set('_XOPEN_SOURCE', 600)
 194 #  cdata.set('__EXTENSIONS__', 1)
 195 endif
 196
 197 if cc.has_type('_Bool')
 198   cdata.set('HAVE_STD_BOOL', 1)
 199 endif
 200
 201 if host_machine.cpu_family() == 'x86_64' or cc.sizeof('void *') >= 8
 202   cdata.set('HAVE_FAST_64BIT_OPERATIONS', 1)
 203 endif
 204
 205 # Headers
 206
 207 check_headers = [
 208   'arpa/inet.h',
 209   'byteswap.h',
 210   'cpuid.h',
 211   'dlfcn.h',
 212   'execinfo.h',
 213   'grp.h',
 214   'langinfo.h',
 215   'linux/sockios.h',
 216   'locale.h',
 217   'netdb.h',
 218   'netinet/in.h',
 219   'netinet/in_systm.h',
 220   'netinet/ip.h',
 221   'netinet/tcp.h',
 222   'pcreposix.h',
 223   'poll.h',
 224   'pwd.h',
 225   'regex.h',
 226   'sched.h',
 227   'stdint.h',
 228   'sys/atomic.h',
 229   'sys/capability.h',
 230   'sys/conf.h',
 231   'sys/dl.h',
 232   'sys/eventfd.h',
 233   'sys/filio.h',
 234   'sys/ioctl.h',
 235   'sys/mman.h',
 236   'sys/prctl.h',
 237   'sys/resource.h',
 238   'sys/select.h',
 239   'sys/socket.h',
 240   'sys/syscall.h',
 241   'sys/uio.h',
 242   'sys/un.h',
 243   'sys/wait.h',
 244   'syslog.h',
 245   'xlocale.h',
 246 ]
 247
 248 foreach h : check_headers
 249   if cc.has_header(h)
 250     define = 'HAVE_' + h.underscorify().to_upper()
 251     cdata.set(define, 1)
 252   endif
 253 endforeach
 254
 255 if cc.has_header('valgrind/memcheck.h', required: get_option('valgrind'))
 256   cdata.set('HAVE_VALGRIND_MEMCHECK_H', 1)
 257 endif
 258
 259 # FIXME: move this to the above set
 260 if host_machine.system() != 'windows'
 261   if cc.has_header('pthread.h')
 262     cdata.set('HAVE_PTHREAD', 1)
 263   endif
 264 endif
 265
 266 if cc.has_header_symbol('pthread.h', 'PTHREAD_PRIO_INHERIT')
 267   cdata.set('HAVE_PTHREAD_PRIO_INHERIT', 1)
 268 endif
 269
 270 # Functions
 271
 272 check_functions = [
 273   'accept4',
 274   'clock_gettime',
 275   'ctime_r',
 276   'fchmod',
 277   'fchown',
 278   'fork',
 279   'fstat',
 280   'getaddrinfo',
 281   'getgrgid_r',
 282   'getgrnam_r',
 283   'getpwnam_r',
 284   'getpwuid_r',
 285   'gettimeofday',
 286   'getuid',
 287   'lrintf',
 288   'lstat',
 289   'memfd_create',
 290   'mkfifo',
 291   'mlock',
 292   'nanosleep',
 293   'open64',
 294   'paccept',
 295   'pipe',
 296   'pipe2',
 297   'posix_fadvise',
 298   'posix_madvise',
 299   'posix_memalign',
 300   'ppoll',
 301   'readlink',
 302   'setegid',
 303   'seteuid',
 304   'setpgid',
 305   'setregid',
 306   'setresgid',
 307   'setresuid',
 308   'setreuid',
 309   'setsid',
 310   'sig2str',
 311   'sigaction',
 312   'strerror_r',
 313   'strtod_l',
 314   'strtof',
 315   'symlink',
 316   'sysconf',
 317   'uname',
 318 ]
 319
 320 foreach f : check_functions
 321   if cc.has_function(f)
 322     define = 'HAVE_' + f.underscorify().to_upper()
 323
 324     if f == 'posix_memalign' and host_machine.system() == 'windows'
 325       message('Win32/mingw32 does not properly define posix_memalign.')
 326     elif f == 'fork' and host_machine.system() == 'windows'
 327       # __builtin_fork is defined and compiles properly, but calling __builtin_fork() does not.
 328       # This causes Meson to think that Windows has a fork() which causes a link error...
 329       message('Win32/mingw32 does not properly define fork.')
 330     else
 331       cdata.set(define, 1)
 332     endif
 333   endif
 334 endforeach
 335
 336 if cc.has_header_symbol('sys/syscall.h', 'SYS_memfd_create')
 337   cdata.set('HAVE_MEMFD', 1)
 338 endif
 339
 340 if cc.has_function('dgettext')
 341   if host_machine.system() != 'windows'
 342     libintl_dep = []
 343   else
 344     libintl_dep = cc.find_library('intl')
 345   endif
 346 else
 347   libintl_dep = cc.find_library('intl')
 348 endif
 349
 350 # Symbols
 351
 352 if cc.has_header_symbol('signal.h', 'SIGXCPU')
 353   cdata.set('HAVE_SIGXCPU', 1)
 354 endif
 355
 356 if not cc.has_header_symbol('netinet/in.h', 'INADDR_NONE')
 357   if not cc.has_header_symbol('winsock2.h', 'INADDR_NONE')
 358     # Define INADDR_NONE if not found (Solaris)
 359     cdata.set('INADDR_NONE', '0xffffffff')
 360   endif
 361 endif
 362
 363 check_decls = [
 364   [ 'environ', 'unistd.h', '#define _GNU_SOURCE' ],
 365   [ 'SOUND_PCM_READ_RATE', 'sys/soundcard.h', '' ],
 366   [ 'SOUND_PCM_READ_CHANNELS', 'sys/soundcard.h', '' ],
 367   [ 'SOUND_PCM_READ_BITS', 'sys/soundcard.h', '' ],
 368 ]
 369
 370 foreach s : check_decls
 371   if cc.has_header_symbol(s[1], s[0], prefix : s[2])
 372     define = 'HAVE_DECL_' + s[0].to_upper()
 373     cdata.set(define, 1)
 374   endif
 375 endforeach
 376
 377 # Types
 378
 379 # FIXME: do we ever care about gid_t not being defined / smaller than an int?
 380 cdata.set('GETGROUPS_T', 'gid_t')
 381
 382 # Include paths
 383
 384 configinc = include_directories('.')
 385 topinc = include_directories('src')
 386
 387 # CFLAGS/LDFLAGS
 388
 389 pa_c_args = ['-DHAVE_CONFIG_H', '-D_GNU_SOURCE']
 390 server_c_args = ['-D__INCLUDED_FROM_PULSE_AUDIO']
 391 cdata.set('MESON_BUILD', 1)
 392
 393 # On ELF systems we don't want the libraries to be unloaded since we don't clean them up properly,
 394 # so we request the nodelete flag to be enabled.
 395 # On other systems, we don't really know how to do that, but it's welcome if somebody can tell.
 396 # Windows doesn't support this flag.
 397 if host_machine.system() != 'windows'
 398   nodelete_link_args = ['-Wl,-z,nodelete']
 399 else
 400   nodelete_link_args = []
 401 endif
 402
 403 # Code coverage
 404
 405 if get_option('gcov')
 406   add_project_arguments('--coverage', language: ['c', 'cpp'])
 407   add_project_link_arguments('--coverage', language: ['c', 'cpp'])
 408 endif
 409
 410 # Core Dependencies
 411
 412 libm_dep = cc.find_library('m', required : true)
 413
 414 thread_dep = dependency('threads')
 415 foreach f : [
 416   'pthread_getname_np',
 417   'pthread_setaffinity_np',
 418   'pthread_setname_np',
 419 ]
 420   if cc.has_function(f, dependencies : thread_dep)
 421     define = 'HAVE_' + f.underscorify().to_upper()
 422     cdata.set(define, 1)
 423   endif
 424 endforeach
 425
 426 cap_dep = cc.find_library('cap', required : false)
 427
 428 shm_dep = cc.find_library('rt', required : false)
 429 if shm_dep.found()
 430   cdata.set('HAVE_SHM_OPEN', 1)
 431 endif
 432
 433 dl_dep = cc.find_library('dl', required : false)
 434 if dl_dep.found()
 435   cdata.set('HAVE_DLADDR', 1)
 436 endif
 437
 438 have_iconv = false
 439 if cc.has_function('iconv_open')
 440   iconv_dep = dependency('', required : false)
 441   have_iconv = true
 442 else
 443   iconv_dep = cc.find_library('iconv', required : false)
 444   have_iconv = iconv_dep.found()
 445 endif
 446 if have_iconv
 447   cdata.set('HAVE_ICONV', 1)
 448   iconvconsttest = '''#include <iconv.h>
 449 size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 450 '''
 451   if cc.compiles(iconvconsttest, dependencies : iconv_dep)
 452     cdata.set('ICONV_CONST', '')
 453   else
 454     cdata.set('ICONV_CONST', 'const')
 455   endif
 456 endif
 457
 458 # Atomic operations
 459
 460 if get_option('atomic-arm-memory-barrier')
 461     cdata.set('ATOMIC_ARM_MEMORY_BARRIER_ENABLED', 1)
 462 endif
 463
 464 need_libatomic_ops = false
 465
 466 atomictest = '''void func() {
 467   volatile int atomic = 2;
 468   __sync_bool_compare_and_swap (&atomic, 2, 3);
 469 }
 470 '''
 471
 472 if cc.compiles(atomictest)
 473   cdata.set('HAVE_ATOMIC_BUILTINS', 1)
 474
 475   newatomictest = '''void func() {
 476     int c = 0;
 477     __atomic_store_n(&c, 4, __ATOMIC_SEQ_CST);
 478   }
 479   '''
 480
 481   if(cc.compiles(newatomictest))
 482     cdata.set('HAVE_ATOMIC_BUILTINS_MEMORY_MODEL', 1)
 483   endif
 484
 485 elif host_machine.cpu_family() == 'arm'
 486   if host_machine.system() == 'linux' and get_option('atomic-arm-linux-helpers')
 487     cdata.set('ATOMIC_ARM_LINUX_HELPERS', 1)
 488   else
 489     armatomictest = '''int func() {
 490       volatile int a=0;
 491       int o=0, n=1, r;
 492       asm volatile (
 493               "ldrex    %0, [%1]\n"
 494               "subs  %0, %0, %2\n"
 495               "strexeq %0, %3, [%1]\n"
 496               : "=&r" (r)
 497               : "r" (&a), "Ir" (o), "r" (n)
 498       : "cc");
 499       return (a==1 ? 0 : -1);
 500     }
 501     '''
 502
 503     if cc.compiles(armatomictest)
 504       cdata.set('ATOMIC_ARM_INLINE_ASM', 1)
 505     else
 506       need_libatomic_ops = true
 507     endif
 508   endif # arm && !linux
 509
 510 elif not ['freebsd', 'netbsd'].contains(host_machine.system())
 511   need_libatomic_ops = true
 512 endif # !atomic helpers && !arm
 513
 514 if need_libatomic_ops
 515   assert(cc.has_header('atomic_ops.h'), 'Need libatomic_ops')
 516
 517   cdata.set('AO_REQUIRE_CAS', 1)
 518
 519   if host_machine.system() != 'windows'
 520     libatomic_ops_dep = cc.find_library('atomic_ops', required : true)
 521   else
 522     libatomic_ops_dep = dependency('', required: false)
 523   endif
 524 else
 525   libatomic_ops_dep = dependency('', required: false)
 526 endif
 527
 528 # ARM checks
 529 # ARMV6 instructions we need
 530 if host_machine.cpu_family() == 'arm'
 531   armv6test = '''int func() {
 532     volatile int a = -60000, b = 0xaaaabbbb, c = 0xccccdddd;
 533     asm volatile ("ldr r0, %2 \n"
 534                   "ldr r2, %3 \n"
 535                   "ldr r3, %4 \n"
 536                   "ssat r1, #8, r0 \n"
 537                   "str r1, %0 \n"
 538                   "pkhbt r1, r3, r2, LSL #8 \n"
 539                   "str r1, %1 \n"
 540                   : "=m" (a), "=m" (b)
 541                   : "m" (a), "m" (b), "m" (c)
 542                   : "r0", "r1", "r2", "r3", "cc");
 543     return (a == -128 && b == 0xaabbdddd) ? 0 : -1;
 544   }
 545   '''
 546
 547   if cc.compiles(armv6test)
 548     cdata.set('HAVE_ARMV6', 1)
 549   endif
 550 endif
 551 # NEON checks are automatically done by the unstable-simd module
 552
 553 # FIXME: make sure it's >= 2.2
 554 ltdl_dep = cc.find_library('ltdl', required : true)
 555 # FIXME: can meson support libtool -dlopen/-dlpreopen things?
 556 #        and do we still want to support this at all?
 557 cdata.set('DISABLE_LIBTOOL_PRELOAD', 1)
 558
 559 if get_option('database') == 'tdb'
 560   database_dep = dependency('tdb')
 561 elif get_option('database') == 'gdbm'
 562   database_dep = cc.find_library('gdbm', required : true)
 563 else
 564   database_dep = dependency('', required: false)
 565 endif
 566
 567 if get_option('ipv6')
 568   cdata.set('HAVE_IPV6', 1)
 569 endif
 570
 571 if get_option('legacy-database-entry-format')
 572   cdata.set('ENABLE_LEGACY_DATABASE_ENTRY_FORMAT', 1)
 573 endif
 574
 575 if get_option('stream-restore-clear-old-devices')
 576   cdata.set('STREAM_RESTORE_CLEAR_OLD_DEVICES', 1)
 577 endif
 578
 579 if get_option('running-from-build-tree')
 580   cdata.set('HAVE_RUNNING_FROM_BUILD_TREE', 1)
 581 endif
 582
 583 alsa_dep = dependency('alsa', version : '>= 1.0.24', required : get_option('alsa'))
 584 if alsa_dep.found()
 585   cdata.set('HAVE_ALSA', 1)
 586   cdata.set('HAVE_ALSA_UCM', 1)
 587 endif
 588
 589 asyncns_dep = dependency('libasyncns', version : '>= 0.1', required : get_option('asyncns'))
 590 if asyncns_dep.found()
 591   cdata.set('HAVE_LIBASYNCNS', 1)
 592 endif
 593
 594 dbus_dep = dependency('dbus-1', version : '>= 1.4.12', required : get_option('dbus'))
 595 if dbus_dep.found()
 596   cdata.set('HAVE_DBUS', 1)
 597 endif
 598
 599 gio_dep = dependency('gio-2.0', version : '>= 2.26.0', required : get_option('gsettings'))
 600 if gio_dep.found()
 601   cdata.set('HAVE_GSETTINGS', 1)
 602 endif
 603
 604 glib_dep = dependency('glib-2.0', version : '>= 2.28.0', required: get_option('glib'))
 605 if glib_dep.found()
 606   cdata.set('HAVE_GLIB', 1)
 607 endif
 608
 609 gtk_dep = dependency('gtk+-3.0', required : get_option('gtk'))
 610 if gtk_dep.found()
 611   cdata.set('HAVE_GTK', 1)
 612 endif
 613
 614 have_orcc = false
 615 orcc_args = []
 616 orc_dep = dependency('orc-0.4', version : '>= 0.4.11', required : get_option('orc'))
 617 orcc = find_program('orcc', required : get_option('orc'))
 618 if orc_dep.found() and orcc.found()
 619   have_orcc = true
 620   orcc_args = [orcc]
 621   #orcc_args = [orcc, '--include', 'glib.h']
 622   cdata.set('HAVE_ORC', 1)
 623 else
 624   cdata.set('DISABLE_ORC', 1)
 625 endif
 626
 627 samplerate_dep = dependency('samplerate', version : '>= 0.1.0', required : get_option('samplerate'))
 628 if samplerate_dep.found()
 629   cdata.set('HAVE_LIBSAMPLERATE', 1)
 630 endif
 631
 632 sndfile_dep = dependency('sndfile', version : '>= 1.0.20')
 633
 634 soxr_dep = dependency('soxr', version : '>= 0.1.1', required : get_option('soxr'))
 635 if soxr_dep.found()
 636   cdata.set('HAVE_SOXR', 1)
 637 endif
 638
 639 libsystemd_dep = dependency('libsystemd', required : get_option('systemd'))
 640 if libsystemd_dep.found()
 641   cdata.set('HAVE_SYSTEMD_DAEMON', 1)
 642   cdata.set('HAVE_SYSTEMD_LOGIN', 1)
 643   cdata.set('HAVE_SYSTEMD_JOURNAL', 1)
 644 endif
 645 systemd_dep = dependency('systemd', required : get_option('systemd'))
 646 if systemd_dep.found() and systemduserunitdir == ''
 647   systemduserunitdir = systemd_dep.get_pkgconfig_variable('systemduserunitdir')
 648 endif
 649
 650 x11_dep = dependency('x11-xcb', required : get_option('x11'))
 651 if x11_dep.found()
 652   xcb_dep  = dependency('xcb',  required : true, version : '>= 1.6')
 653   ice_dep  = dependency('ice',  required : true)
 654   sm_dep   = dependency('sm',   required : true)
 655   xtst_dep = dependency('xtst', required : true)
 656   cdata.set('HAVE_X11', 1)
 657   if cc.has_function('XSetIOErrorExitHandler', dependencies: x11_dep)
 658     cdata.set('HAVE_XSETIOERROREXITHANDLER', 1)
 659   endif
 660 endif
 661
 662 # Module dependencies
 663 if cc.has_header('sys/soundcard.h', required: get_option('oss-output'))
 664   cdata.set('HAVE_OSS_OUTPUT', 1)
 665   cdata.set('HAVE_OSS_WRAPPER', 1)
 666   cdata.set('PULSEDSP_LOCATION', pulsedsp_location)
 667 endif
 668
 669 if get_option('hal-compat')
 670   cdata.set('HAVE_HAL_COMPAT', 1)
 671 endif
 672
 673 avahi_dep = dependency('avahi-client', version : '>= 0.6.0', required : get_option('avahi'), disabler : true)
 674 if avahi_dep.found()
 675   cdata.set('HAVE_AVAHI', 1)
 676 endif
 677
 678 sbc_dep = dependency('sbc', version : '>= 1.0', required : false)
 679 if get_option('bluez5')
 680   assert(dbus_dep.found(), 'BlueZ requires D-Bus support')
 681   assert(sbc_dep.found(), 'BlueZ requires SBC support')
 682   cdata.set('HAVE_SBC', 1)
 683   cdata.set('HAVE_BLUEZ', 1)
 684   cdata.set('HAVE_BLUEZ_5', 1)
 685   if get_option('bluez5-native-headset')
 686     cdata.set('HAVE_BLUEZ_5_NATIVE_HEADSET', 1)
 687   endif
 688   if get_option('bluez5-ofono-headset')
 689     cdata.set('HAVE_BLUEZ_5_OFONO_HEADSET', 1)
 690   endif
 691 endif
 692
 693 fftw_dep = dependency('fftw3f', required : get_option('fftw'))
 694 if fftw_dep.found()
 695   cdata.set('HAVE_FFTW', 1)
 696 endif
 697
 698 jack_dep = dependency('jack', version : '>= 0.117.0', required : get_option('jack'))
 699 if jack_dep.found()
 700   cdata.set('HAVE_JACK', 1)
 701 endif
 702
 703 lirc_dep = dependency('lirc', required : get_option('lirc'))
 704 if lirc_dep.found()
 705   cdata.set('HAVE_LIRC', 1)
 706 endif
 707
 708 openssl_dep = dependency('openssl', version : '>= 0.9', required : get_option('openssl'))
 709 if openssl_dep.found()
 710   cdata.set('HAVE_OPENSSL', 1)
 711 endif
 712
 713 speex_dep = dependency('speexdsp', version : '>= 1.2', required : get_option('speex'))
 714 if speex_dep.found()
 715   cdata.set('HAVE_SPEEX', 1)
 716 endif
 717
 718 udev_dep = dependency('libudev', version : '>= 143', required : get_option('udev'))
 719 if udev_dep.found()
 720   cdata.set('HAVE_UDEV', 1)
 721 endif
 722
 723 webrtc_dep = dependency('webrtc-audio-processing', version : '>= 0.2', required : get_option('webrtc-aec'))
 724 if webrtc_dep.found()
 725   cdata.set('HAVE_WEBRTC', 1)
 726 endif
 727
 728 gst_dep = dependency('gstreamer-1.0', version : '>= 1.14', required : get_option('gstreamer'))
 729 gstapp_dep = dependency('gstreamer-app-1.0', required : get_option('gstreamer'))
 730 gstrtp_dep = dependency('gstreamer-rtp-1.0', required : get_option('gstreamer'))
 731
 732 have_gstreamer = false
 733 if gst_dep.found() and gstapp_dep.found() and gstrtp_dep.found()
 734   have_gstreamer = true
 735 endif
 736
 737 # These are required for the CMake file generation
 738 cdata.set('PA_LIBDIR', libdir)
 739 cdata.set('PA_INCDIR', includedir)
 740 if glib_dep.found()
 741   cdata.set('HAVE_GLIB20', 1) # to match the AM_CONDITIONAL for CMake file generation
 742 endif
 743
 744 # Test dependencies
 745
 746 check_dep = dependency('check', version : '>= 0.9.10', required : get_option('tests'))
 747
 748 # Subdirs
 749
 750 subdir('doxygen')
 751 subdir('po')
 752 if get_option('man')
 753   subdir('man')
 754 endif
 755 subdir('shell-completion/bash')
 756 subdir('shell-completion/zsh')
 757 subdir('src')
 758 subdir('vala')
 759
 760 # Now generate config.h from everything above
 761 configure_file(output : 'config.h', configuration : cdata)
 762
 763 # pkg-config files
 764
 765 pc_cdata = configuration_data()
 766
 767 pc_cdata.set('prefix', prefix)
 768 pc_cdata.set('exec_prefix', prefix)
 769 pc_cdata.set('libdir', libdir)
 770 pc_cdata.set('includedir', includedir)
 771 pc_cdata.set('modlibexecdir', modlibexecdir)
 772 pc_cdata.set('PACKAGE_VERSION', pa_version_str)
 773 pc_cdata.set('PA_MAJORMINOR', pa_version_major_minor)
 774 # FIXME: the line below is wrong. Currently the meson thread dep lacks documentation,
 775 # and doesn't allow introspection, ie. none of get_pkgconfig_variable() or
 776 # get_configtool_variable() work with it, so we have no way to get this flag right,
 777 # unless we do all the work ourselves. See current work in glib, also meson #553.
 778 pc_cdata.set('PTHREAD_LIBS', '-pthread')
 779
 780 pc_files = [
 781   'libpulse.pc',
 782   'libpulse-simple.pc',
 783 ]
 784
 785 if glib_dep.found()
 786   pc_files += 'libpulse-mainloop-glib.pc'
 787 endif
 788
 789 foreach file : pc_files
 790   configure_file(
 791     input : file + '.in',
 792     output : file,
 793     configuration : pc_cdata,
 794     install_dir : pkgconfigdir)
 795 endforeach
 796
 797 # CMake files
 798
 799 m4 = find_program('m4', required: true)
 800
 801 cmakedir = join_paths(libdir, 'cmake', 'PulseAudio')
 802
 803 cmake_template_file = configure_file(
 804   input : 'PulseAudioConfig.cmake.in',
 805   output : 'PulseAudioConfig.cmake.tmp',
 806   configuration: cdata,
 807 )
 808
 809 custom_target('PulseAudioConfig.cmake',
 810   input : cmake_template_file,
 811   output : 'PulseAudioConfig.cmake',
 812   capture : true,
 813   command : [m4, '@INPUT@'],
 814   build_by_default : true,
 815   install : true,
 816   install_dir : cmakedir,
 817 )
 818
 819 configure_file(
 820   input : 'PulseAudioConfigVersion.cmake.in',
 821   output : 'PulseAudioConfigVersion.cmake',
 822   configuration: cdata,
 823   install : true,
 824   install_dir : cmakedir,
 825 )
 826
 827 ############################################################
 828
 829 # Final summary
 830
 831 summary = [
 832   '',
 833   '---{ @0@ @1@ }---'.format(meson.project_name(), meson.project_version()),
 834   '',
 835   'prefix:                        @0@'.format(prefix),
 836   'bindir:                        @0@'.format(bindir),
 837   'libdir:                        @0@'.format(libdir),
 838   'libexecdir:                    @0@'.format(libexecdir),
 839   'mandir:                        @0@'.format(mandir),
 840   'datadir:                       @0@'.format(datadir),
 841   'sysconfdir:                    @0@'.format(sysconfdir),
 842   'localstatedir:                 @0@'.format(localstatedir),
 843   'modlibexecdir:                 @0@'.format(modlibexecdir),
 844   'alsadatadir:                   @0@'.format(alsadatadir),
 845   'System Runtime Path:           @0@'.format(cdata.get_unquoted('PA_SYSTEM_RUNTIME_PATH')),
 846   'System State Path:             @0@'.format(cdata.get_unquoted('PA_SYSTEM_STATE_PATH')),
 847   'System Config Path:            @0@'.format(cdata.get_unquoted('PA_SYSTEM_CONFIG_PATH')),
 848   'Bash completions directory:    @0@'.format(bashcompletiondir),
 849   'Zsh completions directory:     @0@'.format(zshcompletiondir),
 850   'Compiler:                      @0@ @1@'.format(cc.get_id(), cc.version()),
 851 #  'CFLAGS:                        @0@'.format(${CFLAGS}),
 852 #  'CPPFLAGS:                      @0@'.format(${CPPFLAGS}),
 853 #  'LIBS:                          @0@'.format(${LIBS}),
 854   '',
 855   'Enable memfd shared memory:    @0@'.format(cdata.has('HAVE_MEMFD')),
 856   'Enable X11:                    @0@'.format(x11_dep.found()),
 857   '  Safe X11 I/O errors:         @0@'.format(cdata.has('HAVE_XSETIOERROREXITHANDLER')),
 858   'Enable OSS Output:             @0@'.format(cdata.has('HAVE_OSS_OUTPUT')),
 859   'Enable OSS Wrapper:            @0@'.format(cdata.has('HAVE_OSS_WRAPPER')),
 860 #  'Enable EsounD:                 @0@'.format(${ENABLE_ESOUND}),
 861   'Enable Alsa:                   @0@'.format(alsa_dep.found()),
 862 #  'Enable CoreAudio:              @0@'.format(${ENABLE_COREAUDIO}),
 863 #  'Enable Solaris:                @0@'.format(${ENABLE_SOLARIS}),
 864 #  'Enable WaveOut:                @0@'.format(${ENABLE_WAVEOUT}),
 865   'Enable GLib 2:                 @0@'.format(glib_dep.found()),
 866 #  'Enable GConf:                  @0@'.format(${ENABLE_GCONF}),
 867   'Enable GSettings:              @0@'.format(gio_dep.found()),
 868   'Enable Gtk+ 3:                 @0@'.format(gtk_dep.found()),
 869   'Enable Avahi:                  @0@'.format(avahi_dep.found()),
 870   'Enable Jack:                   @0@'.format(jack_dep.found()),
 871   'Enable Async DNS:              @0@'.format(asyncns_dep.found()),
 872   'Enable LIRC:                   @0@'.format(lirc_dep.found()),
 873   'Enable D-Bus:                  @0@'.format(dbus_dep.found()),
 874   '  Enable BlueZ 5:              @0@'.format(get_option('bluez5')),
 875   '    Enable native headsets:    @0@'.format(get_option('bluez5-native-headset')),
 876   '    Enable  ofono headsets:    @0@'.format(get_option('bluez5-ofono-headset')),
 877   'Enable udev:                   @0@'.format(udev_dep.found()),
 878   '  Enable HAL->udev compat:     @0@'.format(get_option('hal-compat')),
 879   'Enable systemd:                @0@'.format(libsystemd_dep.found()),
 880 #  'Enable TCP Wrappers:           @0@'.format(${ENABLE_TCPWRAP}),
 881   'Enable libsamplerate:          @0@'.format(samplerate_dep.found()),
 882   'Enable IPv6:                   @0@'.format(get_option('ipv6')),
 883   'Enable OpenSSL (for Airtunes): @0@'.format(openssl_dep.found()),
 884   'Enable FFTW:                   @0@'.format(fftw_dep.found()),
 885   'Enable ORC:                    @0@'.format(have_orcc),
 886   'Enable GStreamer:              @0@'.format(have_gstreamer),
 887   'Enable Adrian echo canceller:  @0@'.format(get_option('adrian-aec')),
 888   'Enable Speex (resampler, AEC): @0@'.format(speex_dep.found()),
 889   'Enable SoXR (resampler):       @0@'.format(soxr_dep.found()),
 890   'Enable WebRTC echo canceller:  @0@'.format(webrtc_dep.found()),
 891   'Enable Gcov coverage:          @0@'.format(get_option('gcov')),
 892   'Enable Valgrind:               @0@'.format(cdata.has('HAVE_VALGRIND_MEMCHECK_H')),
 893   'Enable man pages:              @0@'.format(get_option('man')),
 894   'Enable unit tests:             @0@'.format(get_option('tests')),
 895   '',
 896   'Database:                      @0@'.format(get_option('database')),
 897   'Legacy Database Entry Support: @0@'.format(get_option('legacy-database-entry-format')),
 898   'module-stream-restore:',
 899   '  Clear old devices:           @0@'.format(get_option('stream-restore-clear-old-devices')),
 900   'Running from build tree:       @0@'.format(get_option('running-from-build-tree')),
 901   'System User:                   @0@'.format(cdata.get_unquoted('PA_SYSTEM_USER')),
 902   'System Group:                  @0@'.format(cdata.get_unquoted('PA_SYSTEM_GROUP')),
 903   'Access Group:                  @0@'.format(cdata.get_unquoted('PA_ACCESS_GROUP')),
 904 #  'Enable per-user EsounD socket: @0@'.format(${ENABLE_PER_USER_ESOUND_SOCKET}),
 905 #  'Force preopen:                 @0@'.format(${FORCE_PREOPEN}),
 906 #  'Preopened modules:             @0@'.format(${PREOPEN_MODS}),
 907 ]
 908
 909 message('\n    '.join(summary))
 910
 911 # Sanity checks
 912
 913 if not speex_dep.found() and not webrtc_dep.found() and not get_option('adrian-aec')
 914   error('At least one echo canceller implementation must be available!')
 915 endif
 916
 917 if samplerate_dep.found()
 918   warning('Support for libsamplerate is DEPRECATED')
 919 endif
 920
 921 if host_machine.system() != 'windows'
 922   if not dbus_dep.found()
 923     message = [
 924       'You do not have D-Bus support enabled. It is strongly recommended',
 925       'that you enable D-Bus support if your platform supports it.',
 926       'Many parts of PulseAudio use D-Bus, from ConsoleKit interaction',
 927       'to the Device Reservation Protocol to speak to JACK, Bluetooth',
 928       'support and even a native control protocol for communicating and',
 929       'controlling the PulseAudio daemon itself.',
 930     ]
 931     warning('\n' + '\n'.join(message))
 932   endif
 933   if not udev_dep.found()
 934     message = [
 935       'You do not have udev support enabled. It is strongly recommended',
 936       'that you enable udev support if your platform supports it as it is',
 937       'the primary method used to detect hardware audio devices (on Linux)',
 938       'and is thus a critical part of PulseAudio on that platform.',
 939     ]
 940     warning('\n' + '\n'.join(message))
 941   endif
 942   if not speex_dep.found()
 943     message = [
 944       'You do not have speex support enabled. It is strongly recommended',
 945       'that you enable speex support if your platform supports it as it is',
 946       'the primary method used for audio resampling and is thus a critical',
 947       'part of PulseAudio on that platform.',
 948     ]
 949     warning('\n' + '\n'.join(message))
 950   endif
 951 endif