meson.build

   1 project('gst-plugins-good', 'c',
   2   version : '1.15.0.1',
   3   meson_version : '>= 0.47',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0].to_int()
  10 gst_version_minor = version_arr[1].to_int()
  11 gst_version_micro = version_arr[2].to_int()
  12  if version_arr.length() == 4
  13   gst_version_nano = version_arr[3].to_int()
  14 else
  15   gst_version_nano = 0
  16 endif
  17 gst_version_is_dev = gst_version_minor % 2 == 1 and gst_version_micro < 90
  18
  19 # FIXME: automagic
  20 have_cxx = add_languages('cpp', required : false)
  21
  22 glib_req = '>= 2.40.0'
  23 orc_req = '>= 0.4.17'
  24 gst_req = '>= @0@.@1@.0'.format(gst_version_major, gst_version_minor)
  25
  26 api_version = '1.0'
  27
  28 plugins_install_dir = '@0@/gstreamer-1.0'.format(get_option('libdir'))
  29
  30 cc = meson.get_compiler('c')
  31 host_system = host_machine.system()
  32
  33 if cc.get_id() == 'msvc'
  34   # Ignore several spurious warnings for things gstreamer does very commonly
  35   # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  36   # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  37   # NOTE: Only add warnings here if you are sure they're spurious
  38   add_project_arguments(
  39       '/wd4018', # implicit signed/unsigned conversion
  40       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  41       '/wd4244', # lossy type conversion (e.g. double -> int)
  42       '/wd4305', # truncating type conversion (e.g. double -> float)
  43       language : 'c')
  44   # Disable SAFESEH with MSVC for plugins and libs that use external deps that
  45   # are built with MinGW
  46   noseh_link_args = ['/SAFESEH:NO']
  47 else
  48   noseh_link_args = []
  49 endif
  50
  51 if cc.has_link_argument('-Wl,-Bsymbolic-functions')
  52   add_project_link_arguments('-Wl,-Bsymbolic-functions', language : 'c')
  53 endif
  54
  55 # Symbol visibility
  56 if cc.has_argument('-fvisibility=hidden')
  57   add_project_arguments('-fvisibility=hidden', language: 'c')
  58 endif
  59
  60 # Disable strict aliasing
  61 if cc.has_argument('-fno-strict-aliasing')
  62   add_project_arguments('-fno-strict-aliasing', language: 'c')
  63 endif
  64
  65 # Define G_DISABLE_DEPRECATED for development versions
  66 if gst_version_is_dev
  67   message('Disabling deprecated GLib API')
  68   add_project_arguments('-DG_DISABLE_DEPRECATED', language: 'c')
  69 endif
  70
  71 cast_checks = get_option('gobject-cast-checks')
  72 if cast_checks.disabled() or (cast_checks.auto() and not gst_version_is_dev)
  73   message('Disabling GLib cast checks')
  74   add_project_arguments('-DG_DISABLE_CAST_CHECKS', language: 'c')
  75 endif
  76
  77 glib_asserts = get_option('glib-asserts')
  78 if glib_asserts.disabled() or (glib_asserts.auto() and not gst_version_is_dev)
  79   message('Disabling GLib asserts')
  80   add_project_arguments('-DG_DISABLE_ASSERT', language: 'c')
  81 endif
  82
  83 glib_checks = get_option('glib-checks')
  84 if glib_checks.disabled() or (glib_checks.auto() and not gst_version_is_dev)
  85   message('Disabling GLib checks')
  86   add_project_arguments('-DG_DISABLE_CHECKS', language: 'c')
  87 endif
  88
  89 cdata = configuration_data()
  90
  91 check_headers = [
  92   ['HAVE_DLFCN_H', 'dlfcn.h'],
  93   ['HAVE_FCNTL_H', 'fcntl.h'],
  94   ['HAVE_INTTYPES_H', 'inttypes.h'],
  95   ['HAVE_MEMORY_H', 'memory.h'],
  96   ['HAVE_PROCESS_H', 'process.h'],
  97   ['HAVE_STDINT_H', 'stdint.h'],
  98   ['HAVE_STDLIB_H', 'stdlib.h'],
  99   ['HAVE_STRINGS_H', 'strings.h'],
 100   ['HAVE_STRING_H', 'string.h'],
 101   ['HAVE_SYS_IOCTL_H', 'sys/ioctl.h'],
 102   ['HAVE_SYS_PARAM_H', 'sys/param.h'],
 103   ['HAVE_SYS_SOCKET_H', 'sys/socket.h'],
 104   ['HAVE_SYS_STAT_H', 'sys/stat.h'],
 105   ['HAVE_SYS_TIME_H', 'sys/time.h'],
 106   ['HAVE_SYS_TYPES_H', 'sys/types.h'],
 107   ['HAVE_UNISTD_H', 'unistd.h'],
 108 ]
 109
 110 foreach h : check_headers
 111   if cc.has_header(h.get(1))
 112     cdata.set(h.get(0), 1)
 113   endif
 114 endforeach
 115
 116 check_functions = [
 117   ['HAVE_ASINH', 'asinh', '#include<math.h>'],
 118   ['HAVE_CLOCK_GETTIME', 'clock_gettime', '#include<time.h>'],
 119   ['HAVE_COSH', 'cosh', '#include<math.h>'],
 120 # check token HAVE_CPU_ALPHA
 121 # check token HAVE_CPU_ARM
 122 # check token HAVE_CPU_CRIS
 123 # check token HAVE_CPU_CRISV32
 124 # check token HAVE_CPU_HPPA
 125 # check token HAVE_CPU_I386
 126 # check token HAVE_CPU_IA64
 127 # check token HAVE_CPU_M68K
 128 # check token HAVE_CPU_MIPS
 129 # check token HAVE_CPU_PPC
 130 # check token HAVE_CPU_PPC64
 131 # check token HAVE_CPU_S390
 132 # check token HAVE_CPU_SPARC
 133 # check token HAVE_CPU_X86_64
 134   ['HAVE_DCGETTEXT', 'dcgettext', '#include<libintl.h>'],
 135 # check token HAVE_DIRECTSOUND
 136 # check token HAVE_EXPERIMENTAL
 137 # check token HAVE_EXTERNAL
 138 # check token HAVE_FPCLASS
 139 # check token HAVE_GCC_ASM
 140   ['HAVE_GETPAGESIZE', 'getpagesize', '#include<unistd.h>'],
 141 # check token HAVE_GETTEXT
 142 # check token HAVE_GST_V4L2
 143   ['HAVE_ISINF', 'isinf', '#include<math.h>'],
 144 # check token HAVE_LIBV4L2
 145   ['HAVE_MMAP', 'mmap', '#include<sys/mman.h>'],
 146   ['HAVE_MMAP64', 'mmap64', '#include<sys/mman.h>'],
 147 # check token HAVE_OSX_AUDIO
 148 # check token HAVE_OSX_VIDEO
 149 # check token HAVE_RDTSC
 150   ['HAVE_SINH', 'sinh', '#include<math.h>'],
 151 # check token HAVE_WAVEFORM
 152 ]
 153
 154 libm = cc.find_library('m', required : false)
 155
 156 foreach f : check_functions
 157   if cc.has_function(f.get(1), prefix : f.get(2), dependencies : libm)
 158     cdata.set(f.get(0), 1)
 159   endif
 160 endforeach
 161
 162 cdata.set('HAVE_IOS', host_system == 'ios')
 163
 164 cdata.set('SIZEOF_CHAR', cc.sizeof('char'))
 165 cdata.set('SIZEOF_INT', cc.sizeof('int'))
 166 cdata.set('SIZEOF_LONG', cc.sizeof('long'))
 167 cdata.set('SIZEOF_SHORT', cc.sizeof('short'))
 168 cdata.set('SIZEOF_VOIDP', cc.sizeof('void*'))
 169 cdata.set('SIZEOF_OFF_T', cc.sizeof('off_t'))
 170
 171 # Here be fixmes.
 172 # FIXME: check if this is correct
 173 cdata.set('HAVE_CPU_X86_64', host_machine.cpu() == 'amd64')
 174 cdata.set('HAVE_GCC_ASM', cc.get_id() != 'msvc')
 175 cdata.set_quoted('VERSION', gst_version)
 176 cdata.set_quoted('PACKAGE_VERSION', gst_version)
 177 cdata.set_quoted('GST_LICENSE', 'LGPL')
 178 cdata.set_quoted('PACKAGE', 'gst-plugins-good')
 179 cdata.set_quoted('GETTEXT_PACKAGE', 'gst-plugins-good-1.0')
 180 cdata.set_quoted('LOCALEDIR', join_paths(get_option('prefix'), get_option('localedir')))
 181
 182 warning_flags = [
 183   '-Wmissing-declarations',
 184   '-Wredundant-decls',
 185   '-Wwrite-strings',
 186   '-Winit-self',
 187   '-Wmissing-include-dirs',
 188   '-Wno-multichar',
 189   '-Wvla',
 190   '-Wpointer-arith',
 191 ]
 192
 193 warning_c_flags = [
 194   '-Wmissing-prototypes',
 195   '-Wdeclaration-after-statement',
 196   '-Wold-style-definition',
 197   '-Waggregate-return',
 198 ]
 199
 200 if have_cxx
 201   cxx = meson.get_compiler('cpp')
 202 endif
 203
 204 foreach extra_arg : warning_flags
 205   if cc.has_argument (extra_arg)
 206     add_project_arguments([extra_arg], language: 'c')
 207   endif
 208   if have_cxx and cxx.has_argument (extra_arg)
 209     add_project_arguments([extra_arg], language: 'cpp')
 210   endif
 211 endforeach
 212
 213 foreach extra_arg : warning_c_flags
 214   if cc.has_argument (extra_arg)
 215     add_project_arguments([extra_arg], language: 'c')
 216   endif
 217 endforeach
 218
 219 # GStreamer package name and origin url
 220 gst_package_name = get_option('package-name')
 221 if gst_package_name == ''
 222   if gst_version_nano == 0
 223     gst_package_name = 'GStreamer Good Plug-ins source release'
 224   elif gst_version_nano == 1
 225     gst_package_name = 'GStreamer Good Plug-ins git'
 226   else
 227     gst_package_name = 'GStreamer Good Plug-ins prerelease'
 228   endif
 229 endif
 230 cdata.set_quoted('GST_PACKAGE_NAME', gst_package_name)
 231 cdata.set_quoted('GST_PACKAGE_ORIGIN', get_option('package-origin'))
 232
 233 # Mandatory GST deps
 234 gst_dep = dependency('gstreamer-1.0', version : gst_req,
 235   fallback : ['gstreamer', 'gst_dep'])
 236 gstbase_dep = dependency('gstreamer-base-1.0', version : gst_req,
 237   fallback : ['gstreamer', 'gst_base_dep'])
 238 gstnet_dep = dependency('gstreamer-net-1.0', version : gst_req,
 239   fallback : ['gstreamer', 'gst_net_dep'])
 240 gstcontroller_dep = dependency('gstreamer-controller-1.0', version : gst_req,
 241   fallback : ['gstreamer', 'gst_controller_dep'])
 242 if host_system != 'windows'
 243   gstcheck_dep = dependency('gstreamer-check-1.0', version : gst_req,
 244     required : get_option('tests'),
 245     fallback : ['gstreamer', 'gst_check_dep'])
 246 endif
 247
 248 gstpbutils_dep = dependency('gstreamer-pbutils-1.0', version : gst_req,
 249     fallback : ['gst-plugins-base', 'pbutils_dep'])
 250 gstallocators_dep = dependency('gstreamer-allocators-1.0', version : gst_req,
 251     fallback : ['gst-plugins-base', 'allocators_dep'])
 252 gstapp_dep = dependency('gstreamer-app-1.0', version : gst_req,
 253     fallback : ['gst-plugins-base', 'app_dep'])
 254 gstaudio_dep = dependency('gstreamer-audio-1.0', version : gst_req,
 255     fallback : ['gst-plugins-base', 'audio_dep'])
 256 gstfft_dep = dependency('gstreamer-fft-1.0', version : gst_req,
 257     fallback : ['gst-plugins-base', 'fft_dep'])
 258 gstriff_dep = dependency('gstreamer-riff-1.0', version : gst_req,
 259     fallback : ['gst-plugins-base', 'riff_dep'])
 260 gstrtp_dep = dependency('gstreamer-rtp-1.0', version : gst_req,
 261     fallback : ['gst-plugins-base', 'rtp_dep'])
 262 gstrtsp_dep = dependency('gstreamer-rtsp-1.0', version : gst_req,
 263     fallback : ['gst-plugins-base', 'rtsp_dep'])
 264 gstsdp_dep = dependency('gstreamer-sdp-1.0', version : gst_req,
 265     fallback : ['gst-plugins-base', 'sdp_dep'])
 266 gsttag_dep = dependency('gstreamer-tag-1.0', version : gst_req,
 267     fallback : ['gst-plugins-base', 'tag_dep'])
 268 gstvideo_dep = dependency('gstreamer-video-1.0', version : gst_req,
 269     fallback : ['gst-plugins-base', 'video_dep'])
 270
 271 # GStreamer OpenGL
 272 # FIXME: automagic
 273 gstgl_dep = dependency('gstreamer-gl-1.0', version : gst_req,
 274     fallback : ['gst-plugins-base', 'gstgl_dep'], required: false)
 275
 276 build_gstgl = gstgl_dep.found() # FIXME: add option?
 277
 278 if build_gstgl
 279   if gstgl_dep.type_name() == 'pkgconfig'
 280     gst_gl_apis = gstgl_dep.get_pkgconfig_variable('gl_apis').split()
 281     gst_gl_winsys = gstgl_dep.get_pkgconfig_variable('gl_winsys').split()
 282     gst_gl_platforms = gstgl_dep.get_pkgconfig_variable('gl_platforms').split()
 283   else
 284     gstbase = subproject('gst-plugins-base')
 285     gst_gl_apis = gstbase.get_variable('enabled_gl_apis')
 286     gst_gl_winsys = gstbase.get_variable('enabled_gl_winsys')
 287     gst_gl_platforms = gstbase.get_variable('enabled_gl_platforms')
 288   endif
 289
 290   message('GStreamer OpenGL window systems: @0@'.format(' '.join(gst_gl_winsys)))
 291   message('GStreamer OpenGL platforms: @0@'.format(' '.join(gst_gl_platforms)))
 292   message('GStreamer OpenGL apis: @0@'.format(' '.join(gst_gl_apis)))
 293
 294   foreach ws : ['x11', 'wayland', 'android', 'cocoa', 'eagl', 'win32', 'dispmanx', 'viv_fb']
 295     set_variable('gst_gl_have_window_@0@'.format(ws), gst_gl_winsys.contains(ws))
 296   endforeach
 297
 298   foreach p : ['glx', 'egl', 'cgl', 'eagl', 'wgl']
 299     set_variable('gst_gl_have_platform_@0@'.format(p), gst_gl_platforms.contains(p))
 300   endforeach
 301
 302   foreach api : ['opengl', 'gles2']
 303     set_variable('gst_gl_have_api_@0@'.format(api), gst_gl_apis.contains(api))
 304   endforeach
 305 endif
 306
 307 zlib_dep = dependency('zlib', required : false)
 308 if not zlib_dep.found()
 309   zlib_dep = cc.find_library('z', required : false)
 310   if not zlib_dep.found() or not cc.has_header('zlib.h')
 311     zlib_dep = subproject('zlib').get_variable('zlib_dep')
 312   endif
 313 endif
 314 cdata.set('HAVE_ZLIB', true)
 315
 316 glib_deps = [dependency('glib-2.0', version : glib_req, fallback: ['glib', 'libglib_dep']),
 317              dependency('gobject-2.0', fallback: ['glib', 'libgobject_dep'])]
 318 gio_dep = dependency('gio-2.0', fallback: ['glib', 'libgio_dep'])
 319
 320 gst_plugins_good_args = ['-DHAVE_CONFIG_H']
 321 configinc = include_directories('.')
 322 libsinc = include_directories('gst-libs')
 323
 324 have_orcc = false
 325 orcc_args = []
 326 # Used by various libraries/elements that use Orc code
 327 orc_dep = dependency('orc-0.4', version : orc_req, required : get_option('orc'))
 328 orcc = find_program('orcc', required : get_option('orc'))
 329 if orc_dep.found() and orcc.found()
 330   have_orcc = true
 331   orcc_args = [orcc, '--include', 'glib.h']
 332   cdata.set('HAVE_ORC', 1)
 333 else
 334   message('Orc Compiler not found, will use backup C code')
 335   cdata.set('DISABLE_ORC', 1)
 336 endif
 337
 338 if gst_dep.type_name() == 'internal'
 339     gst_proj = subproject('gstreamer')
 340
 341     if not gst_proj.get_variable('gst_debug')
 342         message('GStreamer debug system is disabled')
 343         add_project_arguments('-Wno-unused', language: 'c')
 344     else
 345         message('GStreamer debug system is enabled')
 346     endif
 347 else
 348     # We can't check that in the case of subprojects as we won't
 349     # be able to build against an internal dependency (which is not built yet)
 350     if not cc.compiles('''
 351 #include <gst/gstconfig.h>
 352 #ifdef GST_DISABLE_GST_DEBUG
 353 #error "debugging disabled, make compiler fail"
 354 #endif''' , dependencies: gst_dep)
 355         message('GStreamer debug system is disabled')
 356         add_project_arguments('-Wno-unused', language: 'c')
 357     else
 358         message('GStreamer debug system is enabled')
 359     endif
 360 endif
 361
 362 presetdir = join_paths(get_option('datadir'), 'gstreamer-' + api_version, 'presets')
 363
 364 pkgconfig = import('pkgconfig')
 365 plugins_pkgconfig_install_dir = join_paths(plugins_install_dir, 'pkgconfig')
 366 if get_option('default_library') == 'shared'
 367   # If we don't build static plugins there is no need to generate pc files
 368   plugins_pkgconfig_install_dir = disabler()
 369 endif
 370
 371 subdir('gst')
 372 subdir('sys')
 373 subdir('ext')
 374 subdir('tests')
 375 subdir('pkgconfig')
 376
 377 # xgettext is optional (on Windows for instance)
 378 if find_program('xgettext', required : get_option('nls')).found()
 379   cdata.set('ENABLE_NLS', 1)
 380   subdir('po')
 381 endif
 382
 383 configure_file(output : 'config.h', configuration : cdata)
 384
 385 python3 = import('python').find_installation()
 386 run_command(python3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')