meson.build

   1 project('gst-plugins-good', 'c',
   2   version : '1.15.0.1',
   3   meson_version : '>= 0.47',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0].to_int()
  10 gst_version_minor = version_arr[1].to_int()
  11 gst_version_micro = version_arr[2].to_int()
  12  if version_arr.length() == 4
  13   gst_version_nano = version_arr[3].to_int()
  14 else
  15   gst_version_nano = 0
  16 endif
  17 gst_version_is_dev = gst_version_minor % 2 == 1 and gst_version_micro < 90
  18
  19 # FIXME: automagic
  20 have_cxx = add_languages('cpp', required : false)
  21
  22 glib_req = '>= 2.40.0'
  23 orc_req = '>= 0.4.17'
  24 gst_req = '>= @0@.@1@.0'.format(gst_version_major, gst_version_minor)
  25
  26 api_version = '1.0'
  27
  28 plugins_install_dir = '@0@/gstreamer-1.0'.format(get_option('libdir'))
  29
  30 cc = meson.get_compiler('c')
  31 host_system = host_machine.system()
  32
  33 if cc.get_id() == 'msvc'
  34   # Ignore several spurious warnings for things gstreamer does very commonly
  35   # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  36   # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  37   # NOTE: Only add warnings here if you are sure they're spurious
  38   add_project_arguments(
  39       '/wd4018', # implicit signed/unsigned conversion
  40       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  41       '/wd4244', # lossy type conversion (e.g. double -> int)
  42       '/wd4305', # truncating type conversion (e.g. double -> float)
  43       language : 'c')
  44   # Disable SAFESEH with MSVC for plugins and libs that use external deps that
  45   # are built with MinGW
  46   noseh_link_args = ['/SAFESEH:NO']
  47 else
  48   noseh_link_args = []
  49 endif
  50
  51 if cc.has_link_argument('-Wl,-Bsymbolic-functions')
  52   add_project_link_arguments('-Wl,-Bsymbolic-functions', language : 'c')
  53 endif
  54
  55 # Symbol visibility
  56 if cc.has_argument('-fvisibility=hidden')
  57   add_project_arguments('-fvisibility=hidden', language: 'c')
  58 endif
  59
  60 # Disable strict aliasing
  61 if cc.has_argument('-fno-strict-aliasing')
  62   add_project_arguments('-fno-strict-aliasing', language: 'c')
  63 endif
  64
  65 # Define G_DISABLE_DEPRECATED for development versions
  66 if gst_version_is_dev
  67   message('Disabling deprecated GLib API')
  68   add_project_arguments('-DG_DISABLE_DEPRECATED', language: 'c')
  69 endif
  70
  71 cast_checks = get_option('gobject-cast-checks')
  72 if cast_checks.disabled() or (cast_checks.auto() and not gst_version_is_dev)
  73   message('Disabling GLib cast checks')
  74   add_project_arguments('-DG_DISABLE_CAST_CHECKS', language: 'c')
  75 endif
  76
  77 glib_asserts = get_option('glib-asserts')
  78 if glib_asserts.disabled() or (glib_asserts.auto() and not gst_version_is_dev)
  79   message('Disabling GLib asserts')
  80   add_project_arguments('-DG_DISABLE_ASSERT', language: 'c')
  81 endif
  82
  83 cdata = configuration_data()
  84
  85 check_headers = [
  86   ['HAVE_DLFCN_H', 'dlfcn.h'],
  87   ['HAVE_FCNTL_H', 'fcntl.h'],
  88   ['HAVE_INTTYPES_H', 'inttypes.h'],
  89   ['HAVE_MEMORY_H', 'memory.h'],
  90   ['HAVE_PROCESS_H', 'process.h'],
  91   ['HAVE_STDINT_H', 'stdint.h'],
  92   ['HAVE_STDLIB_H', 'stdlib.h'],
  93   ['HAVE_STRINGS_H', 'strings.h'],
  94   ['HAVE_STRING_H', 'string.h'],
  95   ['HAVE_SYS_IOCTL_H', 'sys/ioctl.h'],
  96   ['HAVE_SYS_PARAM_H', 'sys/param.h'],
  97   ['HAVE_SYS_SOCKET_H', 'sys/socket.h'],
  98   ['HAVE_SYS_STAT_H', 'sys/stat.h'],
  99   ['HAVE_SYS_TIME_H', 'sys/time.h'],
 100   ['HAVE_SYS_TYPES_H', 'sys/types.h'],
 101   ['HAVE_UNISTD_H', 'unistd.h'],
 102 ]
 103
 104 foreach h : check_headers
 105   if cc.has_header(h.get(1))
 106     cdata.set(h.get(0), 1)
 107   endif
 108 endforeach
 109
 110 check_functions = [
 111   ['HAVE_ASINH', 'asinh', '#include<math.h>'],
 112   ['HAVE_CLOCK_GETTIME', 'clock_gettime', '#include<time.h>'],
 113   ['HAVE_COSH', 'cosh', '#include<math.h>'],
 114 # check token HAVE_CPU_ALPHA
 115 # check token HAVE_CPU_ARM
 116 # check token HAVE_CPU_CRIS
 117 # check token HAVE_CPU_CRISV32
 118 # check token HAVE_CPU_HPPA
 119 # check token HAVE_CPU_I386
 120 # check token HAVE_CPU_IA64
 121 # check token HAVE_CPU_M68K
 122 # check token HAVE_CPU_MIPS
 123 # check token HAVE_CPU_PPC
 124 # check token HAVE_CPU_PPC64
 125 # check token HAVE_CPU_S390
 126 # check token HAVE_CPU_SPARC
 127 # check token HAVE_CPU_X86_64
 128   ['HAVE_DCGETTEXT', 'dcgettext', '#include<libintl.h>'],
 129 # check token HAVE_DIRECTSOUND
 130 # check token HAVE_EXPERIMENTAL
 131 # check token HAVE_EXTERNAL
 132 # check token HAVE_FPCLASS
 133 # check token HAVE_GCC_ASM
 134   ['HAVE_GETPAGESIZE', 'getpagesize', '#include<unistd.h>'],
 135 # check token HAVE_GETTEXT
 136 # check token HAVE_GST_V4L2
 137   ['HAVE_ISINF', 'isinf', '#include<math.h>'],
 138 # check token HAVE_LIBV4L2
 139   ['HAVE_MMAP', 'mmap', '#include<sys/mman.h>'],
 140   ['HAVE_MMAP64', 'mmap64', '#include<sys/mman.h>'],
 141 # check token HAVE_OSX_AUDIO
 142 # check token HAVE_OSX_VIDEO
 143 # check token HAVE_RDTSC
 144   ['HAVE_SINH', 'sinh', '#include<math.h>'],
 145 # check token HAVE_WAVEFORM
 146 ]
 147
 148 libm = cc.find_library('m', required : false)
 149
 150 foreach f : check_functions
 151   if cc.has_function(f.get(1), prefix : f.get(2), dependencies : libm)
 152     cdata.set(f.get(0), 1)
 153   endif
 154 endforeach
 155
 156 cdata.set('HAVE_IOS', host_system == 'ios')
 157
 158 cdata.set('SIZEOF_CHAR', cc.sizeof('char'))
 159 cdata.set('SIZEOF_INT', cc.sizeof('int'))
 160 cdata.set('SIZEOF_LONG', cc.sizeof('long'))
 161 cdata.set('SIZEOF_SHORT', cc.sizeof('short'))
 162 cdata.set('SIZEOF_VOIDP', cc.sizeof('void*'))
 163 cdata.set('SIZEOF_OFF_T', cc.sizeof('off_t'))
 164
 165 # Here be fixmes.
 166 # FIXME: check if this is correct
 167 cdata.set('HAVE_CPU_X86_64', host_machine.cpu() == 'amd64')
 168 cdata.set('HAVE_GCC_ASM', cc.get_id() != 'msvc')
 169 cdata.set_quoted('VERSION', gst_version)
 170 cdata.set_quoted('PACKAGE_VERSION', gst_version)
 171 cdata.set_quoted('GST_LICENSE', 'LGPL')
 172 cdata.set_quoted('PACKAGE', 'gst-plugins-good')
 173 cdata.set_quoted('GETTEXT_PACKAGE', 'gst-plugins-good-1.0')
 174 cdata.set_quoted('LOCALEDIR', join_paths(get_option('prefix'), get_option('localedir')))
 175
 176 warning_flags = [
 177   '-Wmissing-declarations',
 178   '-Wredundant-decls',
 179   '-Wwrite-strings',
 180   '-Winit-self',
 181   '-Wmissing-include-dirs',
 182   '-Wno-multichar',
 183   '-Wvla',
 184   '-Wpointer-arith',
 185 ]
 186
 187 warning_c_flags = [
 188   '-Wmissing-prototypes',
 189   '-Wdeclaration-after-statement',
 190   '-Wold-style-definition',
 191   '-Waggregate-return',
 192 ]
 193
 194 if have_cxx
 195   cxx = meson.get_compiler('cpp')
 196 endif
 197
 198 foreach extra_arg : warning_flags
 199   if cc.has_argument (extra_arg)
 200     add_project_arguments([extra_arg], language: 'c')
 201   endif
 202   if have_cxx and cxx.has_argument (extra_arg)
 203     add_project_arguments([extra_arg], language: 'cpp')
 204   endif
 205 endforeach
 206
 207 foreach extra_arg : warning_c_flags
 208   if cc.has_argument (extra_arg)
 209     add_project_arguments([extra_arg], language: 'c')
 210   endif
 211 endforeach
 212
 213 # GStreamer package name and origin url
 214 gst_package_name = get_option('package-name')
 215 if gst_package_name == ''
 216   if gst_version_nano == 0
 217     gst_package_name = 'GStreamer Good Plug-ins source release'
 218   elif gst_version_nano == 1
 219     gst_package_name = 'GStreamer Good Plug-ins git'
 220   else
 221     gst_package_name = 'GStreamer Good Plug-ins prerelease'
 222   endif
 223 endif
 224 cdata.set_quoted('GST_PACKAGE_NAME', gst_package_name)
 225 cdata.set_quoted('GST_PACKAGE_ORIGIN', get_option('package-origin'))
 226
 227 # Mandatory GST deps
 228 gst_dep = dependency('gstreamer-1.0', version : gst_req,
 229   fallback : ['gstreamer', 'gst_dep'])
 230 gstbase_dep = dependency('gstreamer-base-1.0', version : gst_req,
 231   fallback : ['gstreamer', 'gst_base_dep'])
 232 gstnet_dep = dependency('gstreamer-net-1.0', version : gst_req,
 233   fallback : ['gstreamer', 'gst_net_dep'])
 234 gstcontroller_dep = dependency('gstreamer-controller-1.0', version : gst_req,
 235   fallback : ['gstreamer', 'gst_controller_dep'])
 236 if host_system != 'windows'
 237   gstcheck_dep = dependency('gstreamer-check-1.0', version : gst_req,
 238     required : get_option('tests'),
 239     fallback : ['gstreamer', 'gst_check_dep'])
 240 endif
 241
 242 gstpbutils_dep = dependency('gstreamer-pbutils-1.0', version : gst_req,
 243     fallback : ['gst-plugins-base', 'pbutils_dep'])
 244 gstallocators_dep = dependency('gstreamer-allocators-1.0', version : gst_req,
 245     fallback : ['gst-plugins-base', 'allocators_dep'])
 246 gstapp_dep = dependency('gstreamer-app-1.0', version : gst_req,
 247     fallback : ['gst-plugins-base', 'app_dep'])
 248 gstaudio_dep = dependency('gstreamer-audio-1.0', version : gst_req,
 249     fallback : ['gst-plugins-base', 'audio_dep'])
 250 gstfft_dep = dependency('gstreamer-fft-1.0', version : gst_req,
 251     fallback : ['gst-plugins-base', 'fft_dep'])
 252 gstriff_dep = dependency('gstreamer-riff-1.0', version : gst_req,
 253     fallback : ['gst-plugins-base', 'riff_dep'])
 254 gstrtp_dep = dependency('gstreamer-rtp-1.0', version : gst_req,
 255     fallback : ['gst-plugins-base', 'rtp_dep'])
 256 gstrtsp_dep = dependency('gstreamer-rtsp-1.0', version : gst_req,
 257     fallback : ['gst-plugins-base', 'rtsp_dep'])
 258 gstsdp_dep = dependency('gstreamer-sdp-1.0', version : gst_req,
 259     fallback : ['gst-plugins-base', 'sdp_dep'])
 260 gsttag_dep = dependency('gstreamer-tag-1.0', version : gst_req,
 261     fallback : ['gst-plugins-base', 'tag_dep'])
 262 gstvideo_dep = dependency('gstreamer-video-1.0', version : gst_req,
 263     fallback : ['gst-plugins-base', 'video_dep'])
 264
 265 # GStreamer OpenGL
 266 # FIXME: automagic
 267 gstgl_dep = dependency('gstreamer-gl-1.0', version : gst_req,
 268     fallback : ['gst-plugins-base', 'gstgl_dep'], required: false)
 269
 270 build_gstgl = gstgl_dep.found() # FIXME: add option?
 271
 272 if build_gstgl
 273   if gstgl_dep.type_name() == 'pkgconfig'
 274     gst_gl_apis = gstgl_dep.get_pkgconfig_variable('gl_apis').split()
 275     gst_gl_winsys = gstgl_dep.get_pkgconfig_variable('gl_winsys').split()
 276     gst_gl_platforms = gstgl_dep.get_pkgconfig_variable('gl_platforms').split()
 277   else
 278     gstbase = subproject('gst-plugins-base')
 279     gst_gl_apis = gstbase.get_variable('enabled_gl_apis')
 280     gst_gl_winsys = gstbase.get_variable('enabled_gl_winsys')
 281     gst_gl_platforms = gstbase.get_variable('enabled_gl_platforms')
 282   endif
 283
 284   message('GStreamer OpenGL window systems: @0@'.format(' '.join(gst_gl_winsys)))
 285   message('GStreamer OpenGL platforms: @0@'.format(' '.join(gst_gl_platforms)))
 286   message('GStreamer OpenGL apis: @0@'.format(' '.join(gst_gl_apis)))
 287
 288   foreach ws : ['x11', 'wayland', 'android', 'cocoa', 'eagl', 'win32', 'dispmanx', 'viv_fb']
 289     set_variable('gst_gl_have_window_@0@'.format(ws), gst_gl_winsys.contains(ws))
 290   endforeach
 291
 292   foreach p : ['glx', 'egl', 'cgl', 'eagl', 'wgl']
 293     set_variable('gst_gl_have_platform_@0@'.format(p), gst_gl_platforms.contains(p))
 294   endforeach
 295
 296   foreach api : ['opengl', 'gles2']
 297     set_variable('gst_gl_have_api_@0@'.format(api), gst_gl_apis.contains(api))
 298   endforeach
 299 endif
 300
 301 zlib_dep = dependency('zlib', fallback: ['zlib', 'zlib_dep'])
 302 glib_deps = [dependency('glib-2.0', version : glib_req, fallback: ['glib', 'libglib_dep']),
 303              dependency('gobject-2.0', fallback: ['glib', 'libgobject_dep'])]
 304 gio_dep = dependency('gio-2.0', fallback: ['glib', 'libgio_dep'])
 305
 306 cdata.set('HAVE_ZLIB', zlib_dep.found())
 307
 308 gst_plugins_good_args = ['-DHAVE_CONFIG_H']
 309 configinc = include_directories('.')
 310 libsinc = include_directories('gst-libs')
 311
 312 have_orcc = false
 313 orcc_args = []
 314 # Used by various libraries/elements that use Orc code
 315 orc_dep = dependency('orc-0.4', version : orc_req, required : get_option('orc'))
 316 orcc = find_program('orcc', required : get_option('orc'))
 317 if orc_dep.found() and orcc.found()
 318   have_orcc = true
 319   orcc_args = [orcc, '--include', 'glib.h']
 320   cdata.set('HAVE_ORC', 1)
 321 else
 322   message('Orc Compiler not found, will use backup C code')
 323   cdata.set('DISABLE_ORC', 1)
 324 endif
 325
 326 if gst_dep.type_name() == 'internal'
 327     gst_proj = subproject('gstreamer')
 328
 329     if not gst_proj.get_variable('gst_debug')
 330         message('GStreamer debug system is disabled')
 331         add_project_arguments('-Wno-unused', language: 'c')
 332     else
 333         message('GStreamer debug system is enabled')
 334     endif
 335 else
 336     # We can't check that in the case of subprojects as we won't
 337     # be able to build against an internal dependency (which is not built yet)
 338     if not cc.compiles('''
 339 #include <gst/gstconfig.h>
 340 #ifdef GST_DISABLE_GST_DEBUG
 341 #error "debugging disabled, make compiler fail"
 342 #endif''' , dependencies: gst_dep)
 343         message('GStreamer debug system is disabled')
 344         add_project_arguments('-Wno-unused', language: 'c')
 345     else
 346         message('GStreamer debug system is enabled')
 347     endif
 348 endif
 349
 350 presetdir = join_paths(get_option('datadir'), 'gstreamer-' + api_version, 'presets')
 351
 352 pkgconfig = import('pkgconfig')
 353 plugins_pkgconfig_install_dir = join_paths(plugins_install_dir, 'pkgconfig')
 354 if get_option('default_library') == 'shared'
 355   # If we don't build static plugins there is no need to generate pc files
 356   plugins_pkgconfig_install_dir = disabler()
 357 endif
 358
 359 subdir('gst')
 360 subdir('sys')
 361 subdir('ext')
 362 subdir('tests')
 363 subdir('pkgconfig')
 364
 365 # xgettext is optional (on Windows for instance)
 366 if find_program('xgettext', required : get_option('nls')).found()
 367   cdata.set('ENABLE_NLS', 1)
 368   subdir('po')
 369 endif
 370
 371 configure_file(output : 'config.h', configuration : cdata)
 372
 373 python3 = import('python3').find_python()
 374 run_command(python3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')