meson.build

   1 project('pulseaudio', 'c', 'cpp',
   2         version : run_command(find_program('git-version-gen'), join_paths(meson.current_source_dir(), '.tarball-version')).stdout().strip(),
   3         meson_version : '>= 0.50.0',
   4         default_options : [ 'c_std=gnu11', 'cpp_std=c++11' ]
   5         )
   6
   7 pa_version_str = meson.project_version()
   8 # For tarballs, the first split will do nothing, but for builds in git, we
   9 # split out suffixes when there are commits since the last tag
  10 # (e.g.: v11.99.1-3-gad14bdb24 -> v11.99.1)
  11 version_split = pa_version_str.split('-')[0].split('.')
  12 pa_version_major = version_split[0].split('v')[0]
  13 pa_version_minor = version_split[1]
  14 if version_split.length() > 2
  15   pa_version_micro = version_split[2]
  16 else
  17   pa_version_micro = '0'
  18 endif
  19 pa_version_major_minor = pa_version_major + '.' + pa_version_minor
  20
  21 pa_api_version = 12
  22 pa_protocol_version = 35
  23
  24 # The stable ABI for client applications, for the version info x:y:z
  25 # always will hold x=z
  26 libpulse_version_info = [23, 0, 23]
  27
  28 # A simplified, synchronous, ABI-stable interface for client
  29 # applications, for the version info x:y:z always will hold x=z
  30 libpulse_simple_version_info = [1, 1, 1]
  31
  32 # The ABI-stable GLib adapter for client applications, for the version
  33 # info x:y:z always will hold x=z
  34 libpulse_mainloop_glib_version_info = [0, 6, 0]
  35
  36 libpulse_version = '@0@.@1@.@2@'.format(
  37   libpulse_version_info[0] - libpulse_version_info[2],
  38   libpulse_version_info[0],
  39   libpulse_version_info[1],
  40 )
  41
  42 libpulse_simple_version = '@0@.@1@.@2@'.format(
  43   libpulse_simple_version_info[0] - libpulse_simple_version_info[2],
  44   libpulse_simple_version_info[0],
  45   libpulse_simple_version_info[1],
  46 )
  47
  48 libpulse_mainloop_glib_version = '@0@.@1@.@2@'.format(
  49   libpulse_mainloop_glib_version_info[0] - libpulse_mainloop_glib_version_info[2],
  50   libpulse_mainloop_glib_version_info[0],
  51   libpulse_mainloop_glib_version_info[1],
  52 )
  53
  54 # Paths
  55
  56 prefix = get_option('prefix')
  57 assert(prefix.startswith('/'), 'Prefix is not absolute: "@0@"'.format(prefix))
  58
  59 bindir = join_paths(prefix, get_option('bindir'))
  60 includedir = join_paths(prefix, get_option('includedir'))
  61 libdir = join_paths(prefix, get_option('libdir'))
  62 libexecdir = join_paths(prefix, get_option('libexecdir'))
  63 mandir = join_paths(prefix, get_option('mandir'))
  64 datadir = join_paths(prefix, get_option('datadir'))
  65 localedir = join_paths(prefix, get_option('localedir'))
  66 localstatedir = join_paths(prefix, get_option('localstatedir'))
  67 sysconfdir = join_paths(prefix, get_option('sysconfdir'))
  68 privlibdir = join_paths(libdir, 'pulseaudio')
  69
  70 if host_machine.system() == 'windows'
  71   # Windows only supports loading libraries from the same dir as the executable
  72   privlibdir = bindir
  73 endif
  74
  75 alsadatadir = get_option('alsadatadir')
  76 if alsadatadir == ''
  77   alsadatadir = join_paths(datadir, 'pulseaudio', 'alsa-mixer')
  78 endif
  79
  80 pkgconfigdir = join_paths(libdir, 'pkgconfig')
  81 pulselibexecdir = join_paths(libexecdir, 'pulse')
  82 pulsesysconfdir = join_paths(sysconfdir, 'pulse')
  83
  84 modlibexecdir = get_option('modlibexecdir')
  85 if modlibexecdir == ''
  86   modlibexecdir = join_paths(libdir, 'pulse-' + pa_version_major_minor, 'modules')
  87 endif
  88
  89 padsplibdir = get_option('padsplibdir')
  90 if padsplibdir == ''
  91   padsplibdir = privlibdir
  92 endif
  93
  94 pulsedsp_location = get_option('pulsedsp-location')
  95 if pulsedsp_location == ''
  96   pulsedsp_location = join_paths(prefix, padsplibdir)
  97 endif
  98
  99 systemduserunitdir = get_option('systemduserunitdir')
 100 # the default value is set below
 101
 102 udevrulesdir = get_option('udevrulesdir')
 103 if udevrulesdir == ''
 104   # absolute path, otherwise meson prepends the prefix
 105   udevrulesdir = '/lib/udev/rules.d'
 106 endif
 107
 108 vapidir = join_paths(datadir, 'vala', 'vapi')
 109
 110 bashcompletiondir = get_option('bashcompletiondir')
 111 if bashcompletiondir == ''
 112   bash_completion_dep = dependency('bash-completion', required : false)
 113   if bash_completion_dep.found()
 114     bashcompletiondir = bash_completion_dep.get_pkgconfig_variable('completionsdir')
 115   else
 116     bashcompletiondir = join_paths(datadir, 'bash-completion', 'completions')
 117   endif
 118 endif
 119
 120 zshcompletiondir = get_option('zshcompletiondir')
 121 if zshcompletiondir == ''
 122   zshcompletiondir = join_paths(datadir, 'zsh', 'site-functions')
 123 endif
 124
 125 # Configuration data
 126
 127 cc = meson.get_compiler('c')
 128
 129 cdata = configuration_data()
 130 cdata.set_quoted('PACKAGE', 'pulseaudio')
 131 cdata.set_quoted('PACKAGE_NAME', 'pulseaudio')
 132 cdata.set_quoted('PACKAGE_VERSION', pa_version_str)
 133 cdata.set('PA_MAJOR', pa_version_major)
 134 cdata.set('PA_MINOR', pa_version_minor)
 135 cdata.set('PA_API_VERSION', pa_api_version)
 136 cdata.set('PA_PROTOCOL_VERSION', pa_protocol_version)
 137 cdata.set_quoted('PA_MACHINE_ID', join_paths(sysconfdir, 'machine-id'))
 138 cdata.set_quoted('PA_MACHINE_ID_FALLBACK', join_paths(localstatedir, 'lib', 'dbus', 'machine-id'))
 139 cdata.set_quoted('PA_SRCDIR', join_paths(meson.current_source_dir(), 'src'))
 140 cdata.set_quoted('PA_BUILDDIR', meson.current_build_dir())
 141 cdata.set_quoted('PA_SOEXT', '.so')
 142 cdata.set_quoted('PA_DEFAULT_CONFIG_DIR', pulsesysconfdir)
 143 cdata.set('PA_DEFAULT_CONFIG_DIR_UNQUOTED', pulsesysconfdir)
 144 cdata.set_quoted('PA_BINARY', join_paths(bindir, 'pulseaudio'))
 145 cdata.set_quoted('PA_SYSTEM_RUNTIME_PATH', join_paths(localstatedir, 'run', 'pulse'))
 146 cdata.set_quoted('PA_SYSTEM_CONFIG_PATH', join_paths(localstatedir, 'lib', 'pulse'))
 147 cdata.set_quoted('PA_SYSTEM_STATE_PATH', join_paths(localstatedir, 'lib', 'pulse'))
 148 cdata.set_quoted('PA_DLSEARCHPATH', modlibexecdir)
 149 cdata.set_quoted('PA_SYSTEM_USER', get_option('system_user'))
 150 cdata.set_quoted('PA_SYSTEM_GROUP', get_option('system_group'))
 151 cdata.set_quoted('PA_ACCESS_GROUP', get_option('access_group'))
 152 cdata.set_quoted('PA_CFLAGS', 'Not yet supported on meson')
 153 cdata.set_quoted('PA_ALSA_PATHS_DIR', join_paths(alsadatadir, 'paths'))
 154 cdata.set_quoted('PA_ALSA_PROFILE_SETS_DIR', join_paths(alsadatadir, 'profile-sets'))
 155 cdata.set_quoted('DESKTOPFILEDIR', join_paths(datadir, 'applications'))
 156 cdata.set_quoted('PULSE_LOCALEDIR', localedir)
 157 cdata.set_quoted('GETTEXT_PACKAGE', 'pulseaudio')
 158 cdata.set('ENABLE_NLS', 1)
 159 cdata.set('top_srcdir', meson.source_root())
 160
 161 # Platform specifics
 162 # First some defaults to keep config file generation happy
 163 cdata.set('HAVE_COREAUDIO', 0)
 164 cdata.set('HAVE_WAVEOUT', 0)
 165
 166 platform_socket_dep = []
 167 platform_dep = []
 168
 169 # FIXME: This was not tested. Maybe some flags should better be CFLAGS,
 170 # rather than ending up in the config.h file?
 171 if host_machine.system() == 'darwin'
 172   cdata.set('OS_IS_DARWIN', 1)
 173   cdata.set('_DARWIN_C_SOURCE', '200112L') # Needed to get NSIG on Mac OS
 174 elif host_machine.system() == 'windows'
 175   cdata.set('OS_IS_WIN32', 1)
 176   cdata.set('HAVE_WINDOWS_H', 1)
 177   cdata.set('HAVE_WAVEOUT', 1)
 178   cdata.set('HAVE_WINSOCK2_H', 1)
 179   cdata.set('HAVE_WS2TCPIP_H', 1)
 180   cdata.set('WIN32_LEAN_AND_MEAN', 1) # Needed to avoid including unnecessary headers on Windows
 181   cdata.set('gid_t', 'int')
 182   cdata.set('uid_t', 'int')
 183   ws2_32_dep = meson.get_compiler('c').find_library('ws2_32')
 184   winsock_dep = meson.get_compiler('c').find_library('wsock32')
 185   ole32_dep = meson.get_compiler('c').find_library('ole32')
 186   ssp_dep = meson.get_compiler('c').find_library('ssp')
 187   pcreposix_dep = meson.get_compiler('c').find_library('pcreposix')
 188   platform_socket_dep = [ws2_32_dep, winsock_dep]
 189   platform_dep = [ole32_dep, ssp_dep, pcreposix_dep]
 190 #elif host_machine.system() == 'solaris'
 191 #  # Apparently meson has no solaris support?
 192 #  # Needed to get declarations for msg_control and msg_controllen on Solaris
 193 #  cdata.set('_XOPEN_SOURCE', 600)
 194 #  cdata.set('__EXTENSIONS__', 1)
 195 endif
 196
 197 if cc.has_type('_Bool')
 198   cdata.set('HAVE_STD_BOOL', 1)
 199 endif
 200
 201 if host_machine.cpu_family() == 'x86_64' or cc.sizeof('void *') >= 8
 202   cdata.set('HAVE_FAST_64BIT_OPERATIONS', 1)
 203 endif
 204
 205 # Headers
 206
 207 check_headers = [
 208   'arpa/inet.h',
 209   'byteswap.h',
 210   'cpuid.h',
 211   'dlfcn.h',
 212   'execinfo.h',
 213   'grp.h',
 214   'langinfo.h',
 215   'linux/sockios.h',
 216   'locale.h',
 217   'netdb.h',
 218   'netinet/in.h',
 219   'netinet/in_systm.h',
 220   'netinet/ip.h',
 221   'netinet/tcp.h',
 222   'pcreposix.h',
 223   'poll.h',
 224   'pwd.h',
 225   'regex.h',
 226   'sched.h',
 227   'stdint.h',
 228   'sys/atomic.h',
 229   'sys/capability.h',
 230   'sys/conf.h',
 231   'sys/dl.h',
 232   'sys/eventfd.h',
 233   'sys/filio.h',
 234   'sys/ioctl.h',
 235   'sys/mman.h',
 236   'sys/prctl.h',
 237   'sys/resource.h',
 238   'sys/select.h',
 239   'sys/socket.h',
 240   'sys/syscall.h',
 241   'sys/uio.h',
 242   'sys/un.h',
 243   'sys/wait.h',
 244   'syslog.h',
 245   'xlocale.h',
 246 ]
 247
 248 foreach h : check_headers
 249   if cc.has_header(h)
 250     define = 'HAVE_' + h.underscorify().to_upper()
 251     cdata.set(define, 1)
 252   endif
 253 endforeach
 254
 255 if cc.has_header('valgrind/memcheck.h', required: get_option('valgrind'))
 256   cdata.set('HAVE_VALGRIND_MEMCHECK_H', 1)
 257 endif
 258
 259 # FIXME: move this to the above set
 260 if host_machine.system() != 'windows'
 261   if cc.has_header('pthread.h')
 262     cdata.set('HAVE_PTHREAD', 1)
 263   endif
 264 endif
 265
 266 if cc.has_header_symbol('pthread.h', 'PTHREAD_PRIO_INHERIT')
 267   cdata.set('HAVE_PTHREAD_PRIO_INHERIT', 1)
 268 endif
 269
 270 # Functions
 271
 272 check_functions = [
 273   'accept4',
 274   'clock_gettime',
 275   'ctime_r',
 276   'fchmod',
 277   'fchown',
 278   'fork',
 279   'fstat',
 280   'getaddrinfo',
 281   'getgrgid_r',
 282   'getgrnam_r',
 283   'getpwnam_r',
 284   'getpwuid_r',
 285   'gettimeofday',
 286   'getuid',
 287   'lrintf',
 288   'lstat',
 289   'memfd_create',
 290   'mkfifo',
 291   'mlock',
 292   'nanosleep',
 293   'open64',
 294   'paccept',
 295   'pipe',
 296   'pipe2',
 297   'posix_fadvise',
 298   'posix_madvise',
 299   'posix_memalign',
 300   'ppoll',
 301   'readlink',
 302   'setegid',
 303   'seteuid',
 304   'setpgid',
 305   'setregid',
 306   'setresgid',
 307   'setresuid',
 308   'setreuid',
 309   'setsid',
 310   'sig2str',
 311   'sigaction',
 312   'strerror_r',
 313   'strtod_l',
 314   'strtof',
 315   'symlink',
 316   'sysconf',
 317   'uname',
 318 ]
 319
 320 foreach f : check_functions
 321   if cc.has_function(f)
 322     define = 'HAVE_' + f.underscorify().to_upper()
 323
 324     if f == 'posix_memalign' and host_machine.system() == 'windows'
 325       message('Win32/mingw32 does not properly define posix_memalign.')
 326     elif f == 'fork' and host_machine.system() == 'windows'
 327       # __builtin_fork is defined and compiles properly, but calling __builtin_fork() does not.
 328       # This causes Meson to think that Windows has a fork() which causes a link error...
 329       message('Win32/mingw32 does not properly define fork.')
 330     else
 331       cdata.set(define, 1)
 332     endif
 333   endif
 334 endforeach
 335
 336 if cc.has_header_symbol('sys/syscall.h', 'SYS_memfd_create')
 337   cdata.set('HAVE_MEMFD', 1)
 338 endif
 339
 340 if cc.has_function('dgettext')
 341   if host_machine.system() != 'windows'
 342     libintl_dep = []
 343   else
 344     libintl_dep = cc.find_library('intl')
 345   endif
 346 else
 347   libintl_dep = cc.find_library('intl')
 348 endif
 349
 350 # Symbols
 351
 352 if cc.has_header_symbol('signal.h', 'SIGXCPU')
 353   cdata.set('HAVE_SIGXCPU', 1)
 354 endif
 355
 356 if not cc.has_header_symbol('netinet/in.h', 'INADDR_NONE')
 357   if not cc.has_header_symbol('winsock2.h', 'INADDR_NONE')
 358     # Define INADDR_NONE if not found (Solaris)
 359     cdata.set('INADDR_NONE', '0xffffffff')
 360   endif
 361 endif
 362
 363 check_decls = [
 364   [ 'environ', 'unistd.h', '#define _GNU_SOURCE' ],
 365   [ 'SOUND_PCM_READ_RATE', 'sys/soundcard.h', '' ],
 366   [ 'SOUND_PCM_READ_CHANNELS', 'sys/soundcard.h', '' ],
 367   [ 'SOUND_PCM_READ_BITS', 'sys/soundcard.h', '' ],
 368 ]
 369
 370 foreach s : check_decls
 371   if cc.has_header_symbol(s[1], s[0], prefix : s[2])
 372     define = 'HAVE_DECL_' + s[0].to_upper()
 373     cdata.set(define, 1)
 374   endif
 375 endforeach
 376
 377 # Types
 378
 379 # FIXME: do we ever care about gid_t not being defined / smaller than an int?
 380 cdata.set('GETGROUPS_T', 'gid_t')
 381
 382 # Include paths
 383
 384 configinc = include_directories('.')
 385 topinc = include_directories('src')
 386
 387 # CFLAGS/LDFLAGS
 388
 389 pa_c_args = ['-DHAVE_CONFIG_H', '-D_GNU_SOURCE']
 390 server_c_args = ['-D__INCLUDED_FROM_PULSE_AUDIO']
 391 cdata.set('MESON_BUILD', 1)
 392
 393 # On ELF systems we don't want the libraries to be unloaded since we don't clean them up properly,
 394 # so we request the nodelete flag to be enabled.
 395 # On other systems, we don't really know how to do that, but it's welcome if somebody can tell.
 396 # Windows doesn't support this flag.
 397 if host_machine.system() != 'windows'
 398   nodelete_link_args = ['-Wl,-z,nodelete']
 399 else
 400   nodelete_link_args = []
 401 endif
 402
 403 # Code coverage
 404
 405 if get_option('gcov')
 406   add_project_arguments('--coverage', language: ['c', 'cpp'])
 407   add_project_link_arguments('--coverage', language: ['c', 'cpp'])
 408 endif
 409
 410 # Core Dependencies
 411
 412 libm_dep = cc.find_library('m', required : true)
 413
 414 thread_dep = dependency('threads')
 415 foreach f : [
 416   'pthread_getname_np',
 417   'pthread_setaffinity_np',
 418   'pthread_setname_np',
 419 ]
 420   if cc.has_function(f, dependencies : thread_dep)
 421     define = 'HAVE_' + f.underscorify().to_upper()
 422     cdata.set(define, 1)
 423   endif
 424 endforeach
 425
 426 cap_dep = cc.find_library('cap', required : false)
 427
 428 shm_dep = cc.find_library('rt', required : false)
 429 if cc.has_function('shm_open', dependencies : shm_dep)
 430   cdata.set('HAVE_SHM_OPEN', 1)
 431 endif
 432
 433 dl_dep = cc.find_library('dl', required : false)
 434 if cc.has_function('dladdr', dependencies : dl_dep)
 435   cdata.set('HAVE_DLADDR', 1)
 436 endif
 437
 438 have_iconv = false
 439 if cc.has_function('iconv_open')
 440   iconv_dep = dependency('', required : false)
 441   have_iconv = true
 442   # tell the libiconv header to pretend to be libc iconv
 443   cdata.set('LIBICONV_PLUG', 1)
 444 else
 445   iconv_dep = cc.find_library('iconv', required : false)
 446   have_iconv = iconv_dep.found()
 447 endif
 448 if have_iconv
 449   cdata.set('HAVE_ICONV', 1)
 450   iconvconsttest = '''#include <iconv.h>
 451 size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 452 '''
 453   if cc.compiles(iconvconsttest, dependencies : iconv_dep)
 454     cdata.set('ICONV_CONST', '')
 455   else
 456     cdata.set('ICONV_CONST', 'const')
 457   endif
 458 endif
 459
 460 # Used for backtraces on BSD
 461 execinfo_dep = cc.find_library('execinfo', required : false)
 462
 463 # Atomic operations
 464
 465 if get_option('atomic-arm-memory-barrier')
 466     cdata.set('ATOMIC_ARM_MEMORY_BARRIER_ENABLED', 1)
 467 endif
 468
 469 need_libatomic_ops = false
 470
 471 atomictest = '''void func() {
 472   volatile int atomic = 2;
 473   __sync_bool_compare_and_swap (&atomic, 2, 3);
 474 }
 475 '''
 476
 477 if cc.compiles(atomictest)
 478   cdata.set('HAVE_ATOMIC_BUILTINS', 1)
 479
 480   newatomictest = '''void func() {
 481     int c = 0;
 482     __atomic_store_n(&c, 4, __ATOMIC_SEQ_CST);
 483   }
 484   '''
 485
 486   if(cc.compiles(newatomictest))
 487     cdata.set('HAVE_ATOMIC_BUILTINS_MEMORY_MODEL', 1)
 488   endif
 489
 490 elif host_machine.cpu_family() == 'arm'
 491   if host_machine.system() == 'linux' and get_option('atomic-arm-linux-helpers')
 492     cdata.set('ATOMIC_ARM_LINUX_HELPERS', 1)
 493   else
 494     armatomictest = '''int func() {
 495       volatile int a=0;
 496       int o=0, n=1, r;
 497       asm volatile (
 498               "ldrex    %0, [%1]\n"
 499               "subs  %0, %0, %2\n"
 500               "strexeq %0, %3, [%1]\n"
 501               : "=&r" (r)
 502               : "r" (&a), "Ir" (o), "r" (n)
 503       : "cc");
 504       return (a==1 ? 0 : -1);
 505     }
 506     '''
 507
 508     if cc.compiles(armatomictest)
 509       cdata.set('ATOMIC_ARM_INLINE_ASM', 1)
 510     else
 511       need_libatomic_ops = true
 512     endif
 513   endif # arm && !linux
 514
 515 elif not ['freebsd', 'netbsd'].contains(host_machine.system())
 516   need_libatomic_ops = true
 517 endif # !atomic helpers && !arm
 518
 519 if need_libatomic_ops
 520   assert(cc.has_header('atomic_ops.h'), 'Need libatomic_ops')
 521
 522   cdata.set('AO_REQUIRE_CAS', 1)
 523
 524   if host_machine.system() != 'windows'
 525     libatomic_ops_dep = cc.find_library('atomic_ops', required : true)
 526   else
 527     libatomic_ops_dep = dependency('', required: false)
 528   endif
 529 else
 530   libatomic_ops_dep = dependency('', required: false)
 531 endif
 532
 533 # ARM checks
 534 # ARMV6 instructions we need
 535 if host_machine.cpu_family() == 'arm'
 536   armv6test = '''int func() {
 537     volatile int a = -60000, b = 0xaaaabbbb, c = 0xccccdddd;
 538     asm volatile ("ldr r0, %2 \n"
 539                   "ldr r2, %3 \n"
 540                   "ldr r3, %4 \n"
 541                   "ssat r1, #8, r0 \n"
 542                   "str r1, %0 \n"
 543                   "pkhbt r1, r3, r2, LSL #8 \n"
 544                   "str r1, %1 \n"
 545                   : "=m" (a), "=m" (b)
 546                   : "m" (a), "m" (b), "m" (c)
 547                   : "r0", "r1", "r2", "r3", "cc");
 548     return (a == -128 && b == 0xaabbdddd) ? 0 : -1;
 549   }
 550   '''
 551
 552   if cc.compiles(armv6test)
 553     cdata.set('HAVE_ARMV6', 1)
 554   endif
 555 endif
 556 # NEON checks are automatically done by the unstable-simd module
 557
 558 # FIXME: make sure it's >= 2.2
 559 ltdl_dep = cc.find_library('ltdl', required : true)
 560 # FIXME: can meson support libtool -dlopen/-dlpreopen things?
 561 #        and do we still want to support this at all?
 562 cdata.set('DISABLE_LIBTOOL_PRELOAD', 1)
 563
 564 if get_option('database') == 'tdb'
 565   database_dep = dependency('tdb')
 566 elif get_option('database') == 'gdbm'
 567   database_dep = cc.find_library('gdbm', required : true)
 568 else
 569   database_dep = dependency('', required: false)
 570 endif
 571
 572 if get_option('ipv6')
 573   cdata.set('HAVE_IPV6', 1)
 574 endif
 575
 576 if get_option('legacy-database-entry-format')
 577   cdata.set('ENABLE_LEGACY_DATABASE_ENTRY_FORMAT', 1)
 578 endif
 579
 580 if get_option('stream-restore-clear-old-devices')
 581   cdata.set('STREAM_RESTORE_CLEAR_OLD_DEVICES', 1)
 582 endif
 583
 584 if get_option('running-from-build-tree')
 585   cdata.set('HAVE_RUNNING_FROM_BUILD_TREE', 1)
 586 endif
 587
 588 alsa_dep = dependency('alsa', version : '>= 1.0.24', required : get_option('alsa'))
 589 if alsa_dep.found()
 590   cdata.set('HAVE_ALSA', 1)
 591   cdata.set('HAVE_ALSA_UCM', 1)
 592 endif
 593
 594 asyncns_dep = dependency('libasyncns', version : '>= 0.1', required : get_option('asyncns'))
 595 if asyncns_dep.found()
 596   cdata.set('HAVE_LIBASYNCNS', 1)
 597 endif
 598
 599 dbus_dep = dependency('dbus-1', version : '>= 1.4.12', required : get_option('dbus'))
 600 if dbus_dep.found()
 601   cdata.set('HAVE_DBUS', 1)
 602 endif
 603
 604 gio_dep = dependency('gio-2.0', version : '>= 2.26.0', required : get_option('gsettings'))
 605 if gio_dep.found()
 606   cdata.set('HAVE_GSETTINGS', 1)
 607 endif
 608
 609 glib_dep = dependency('glib-2.0', version : '>= 2.28.0', required: get_option('glib'))
 610 if glib_dep.found()
 611   cdata.set('HAVE_GLIB', 1)
 612 endif
 613
 614 gtk_dep = dependency('gtk+-3.0', required : get_option('gtk'))
 615 if gtk_dep.found()
 616   cdata.set('HAVE_GTK', 1)
 617 endif
 618
 619 have_orcc = false
 620 orcc_args = []
 621 orc_dep = dependency('orc-0.4', version : '>= 0.4.11', required : get_option('orc'))
 622 orcc = find_program('orcc', required : get_option('orc'))
 623 if orc_dep.found() and orcc.found()
 624   have_orcc = true
 625   orcc_args = [orcc]
 626   #orcc_args = [orcc, '--include', 'glib.h']
 627   cdata.set('HAVE_ORC', 1)
 628 else
 629   cdata.set('DISABLE_ORC', 1)
 630 endif
 631
 632 samplerate_dep = dependency('samplerate', version : '>= 0.1.0', required : get_option('samplerate'))
 633 if samplerate_dep.found()
 634   cdata.set('HAVE_LIBSAMPLERATE', 1)
 635 endif
 636
 637 sndfile_dep = dependency('sndfile', version : '>= 1.0.20')
 638
 639 soxr_dep = dependency('soxr', version : '>= 0.1.1', required : get_option('soxr'))
 640 if soxr_dep.found()
 641   cdata.set('HAVE_SOXR', 1)
 642 endif
 643
 644 libsystemd_dep = dependency('libsystemd', required : get_option('systemd'))
 645 if libsystemd_dep.found()
 646   cdata.set('HAVE_SYSTEMD_DAEMON', 1)
 647   cdata.set('HAVE_SYSTEMD_LOGIN', 1)
 648   cdata.set('HAVE_SYSTEMD_JOURNAL', 1)
 649 endif
 650 systemd_dep = dependency('systemd', required : get_option('systemd'))
 651 if systemd_dep.found() and systemduserunitdir == ''
 652   systemduserunitdir = systemd_dep.get_pkgconfig_variable('systemduserunitdir')
 653 endif
 654
 655 x11_dep = dependency('x11-xcb', required : get_option('x11'))
 656 if x11_dep.found()
 657   xcb_dep  = dependency('xcb',  required : true, version : '>= 1.6')
 658   ice_dep  = dependency('ice',  required : true)
 659   sm_dep   = dependency('sm',   required : true)
 660   xtst_dep = dependency('xtst', required : true)
 661   cdata.set('HAVE_X11', 1)
 662   if cc.has_function('XSetIOErrorExitHandler', dependencies: x11_dep)
 663     cdata.set('HAVE_XSETIOERROREXITHANDLER', 1)
 664   endif
 665 endif
 666
 667 # Module dependencies
 668 if cc.has_header('sys/soundcard.h', required: get_option('oss-output'))
 669   cdata.set('HAVE_OSS_OUTPUT', 1)
 670   cdata.set('HAVE_OSS_WRAPPER', 1)
 671   cdata.set('PULSEDSP_LOCATION', pulsedsp_location)
 672 endif
 673
 674 if get_option('hal-compat')
 675   cdata.set('HAVE_HAL_COMPAT', 1)
 676 endif
 677
 678 avahi_dep = dependency('avahi-client', version : '>= 0.6.0', required : get_option('avahi'), disabler : true)
 679 if avahi_dep.found()
 680   cdata.set('HAVE_AVAHI', 1)
 681 endif
 682
 683 sbc_dep = dependency('sbc', version : '>= 1.0', required : false)
 684 if get_option('bluez5')
 685   assert(dbus_dep.found(), 'BlueZ requires D-Bus support')
 686   assert(sbc_dep.found(), 'BlueZ requires SBC support')
 687   cdata.set('HAVE_SBC', 1)
 688   cdata.set('HAVE_BLUEZ', 1)
 689   cdata.set('HAVE_BLUEZ_5', 1)
 690   if get_option('bluez5-native-headset')
 691     cdata.set('HAVE_BLUEZ_5_NATIVE_HEADSET', 1)
 692   endif
 693   if get_option('bluez5-ofono-headset')
 694     cdata.set('HAVE_BLUEZ_5_OFONO_HEADSET', 1)
 695   endif
 696 endif
 697
 698 fftw_dep = dependency('fftw3f', required : get_option('fftw'))
 699 if fftw_dep.found()
 700   cdata.set('HAVE_FFTW', 1)
 701 endif
 702
 703 jack_dep = dependency('jack', version : '>= 0.117.0', required : get_option('jack'))
 704 if jack_dep.found()
 705   cdata.set('HAVE_JACK', 1)
 706 endif
 707
 708 lirc_dep = dependency('lirc', required : get_option('lirc'))
 709 if lirc_dep.found()
 710   cdata.set('HAVE_LIRC', 1)
 711 endif
 712
 713 openssl_dep = dependency('openssl', version : '>= 0.9', required : get_option('openssl'))
 714 if openssl_dep.found()
 715   cdata.set('HAVE_OPENSSL', 1)
 716 endif
 717
 718 speex_dep = dependency('speexdsp', version : '>= 1.2', required : get_option('speex'))
 719 if speex_dep.found()
 720   cdata.set('HAVE_SPEEX', 1)
 721 endif
 722
 723 udev_dep = dependency('libudev', version : '>= 143', required : get_option('udev'))
 724 if udev_dep.found()
 725   cdata.set('HAVE_UDEV', 1)
 726 endif
 727
 728 webrtc_dep = dependency('webrtc-audio-processing', version : '>= 0.2', required : get_option('webrtc-aec'))
 729 if webrtc_dep.found()
 730   cdata.set('HAVE_WEBRTC', 1)
 731 endif
 732
 733 gst_dep = dependency('gstreamer-1.0', version : '>= 1.14', required : get_option('gstreamer'))
 734 gstapp_dep = dependency('gstreamer-app-1.0', required : get_option('gstreamer'))
 735 gstrtp_dep = dependency('gstreamer-rtp-1.0', required : get_option('gstreamer'))
 736
 737 have_gstreamer = false
 738 if gst_dep.found() and gstapp_dep.found() and gstrtp_dep.found()
 739   have_gstreamer = true
 740 endif
 741
 742 # These are required for the CMake file generation
 743 cdata.set('PA_LIBDIR', libdir)
 744 cdata.set('PA_INCDIR', includedir)
 745 if glib_dep.found()
 746   cdata.set('HAVE_GLIB20', 1) # to match the AM_CONDITIONAL for CMake file generation
 747 endif
 748
 749 # Test dependencies
 750
 751 check_dep = dependency('check', version : '>= 0.9.10', required : get_option('tests'))
 752
 753 # Subdirs
 754
 755 subdir('doxygen')
 756 subdir('po')
 757 if get_option('man')
 758   subdir('man')
 759 endif
 760 subdir('shell-completion/bash')
 761 subdir('shell-completion/zsh')
 762 subdir('src')
 763 subdir('vala')
 764
 765 # Now generate config.h from everything above
 766 configure_file(output : 'config.h', configuration : cdata)
 767
 768 # pkg-config files
 769
 770 pc_cdata = configuration_data()
 771
 772 pc_cdata.set('prefix', prefix)
 773 pc_cdata.set('exec_prefix', prefix)
 774 pc_cdata.set('libdir', libdir)
 775 pc_cdata.set('includedir', includedir)
 776 pc_cdata.set('modlibexecdir', modlibexecdir)
 777 pc_cdata.set('PACKAGE_VERSION', pa_version_str)
 778 pc_cdata.set('PA_MAJORMINOR', pa_version_major_minor)
 779 # FIXME: the line below is wrong. Currently the meson thread dep lacks documentation,
 780 # and doesn't allow introspection, ie. none of get_pkgconfig_variable() or
 781 # get_configtool_variable() work with it, so we have no way to get this flag right,
 782 # unless we do all the work ourselves. See current work in glib, also meson #553.
 783 pc_cdata.set('PTHREAD_LIBS', '-pthread')
 784
 785 pc_files = [
 786   'libpulse.pc',
 787   'libpulse-simple.pc',
 788 ]
 789
 790 if glib_dep.found()
 791   pc_files += 'libpulse-mainloop-glib.pc'
 792 endif
 793
 794 foreach file : pc_files
 795   configure_file(
 796     input : file + '.in',
 797     output : file,
 798     configuration : pc_cdata,
 799     install_dir : pkgconfigdir)
 800 endforeach
 801
 802 # CMake files
 803
 804 m4 = find_program('m4', required: true)
 805
 806 cmakedir = join_paths(libdir, 'cmake', 'PulseAudio')
 807
 808 cmake_template_file = configure_file(
 809   input : 'PulseAudioConfig.cmake.in',
 810   output : 'PulseAudioConfig.cmake.tmp',
 811   configuration: cdata,
 812 )
 813
 814 custom_target('PulseAudioConfig.cmake',
 815   input : cmake_template_file,
 816   output : 'PulseAudioConfig.cmake',
 817   capture : true,
 818   command : [m4, '@INPUT@'],
 819   build_by_default : true,
 820   install : true,
 821   install_dir : cmakedir,
 822 )
 823
 824 configure_file(
 825   input : 'PulseAudioConfigVersion.cmake.in',
 826   output : 'PulseAudioConfigVersion.cmake',
 827   configuration: cdata,
 828   install : true,
 829   install_dir : cmakedir,
 830 )
 831
 832 ############################################################
 833
 834 # Final summary
 835
 836 summary = [
 837   '',
 838   '---{ @0@ @1@ }---'.format(meson.project_name(), meson.project_version()),
 839   '',
 840   'prefix:                        @0@'.format(prefix),
 841   'bindir:                        @0@'.format(bindir),
 842   'libdir:                        @0@'.format(libdir),
 843   'libexecdir:                    @0@'.format(libexecdir),
 844   'mandir:                        @0@'.format(mandir),
 845   'datadir:                       @0@'.format(datadir),
 846   'sysconfdir:                    @0@'.format(sysconfdir),
 847   'localstatedir:                 @0@'.format(localstatedir),
 848   'modlibexecdir:                 @0@'.format(modlibexecdir),
 849   'alsadatadir:                   @0@'.format(alsadatadir),
 850   'System Runtime Path:           @0@'.format(cdata.get_unquoted('PA_SYSTEM_RUNTIME_PATH')),
 851   'System State Path:             @0@'.format(cdata.get_unquoted('PA_SYSTEM_STATE_PATH')),
 852   'System Config Path:            @0@'.format(cdata.get_unquoted('PA_SYSTEM_CONFIG_PATH')),
 853   'Bash completions directory:    @0@'.format(bashcompletiondir),
 854   'Zsh completions directory:     @0@'.format(zshcompletiondir),
 855   'Compiler:                      @0@ @1@'.format(cc.get_id(), cc.version()),
 856 #  'CFLAGS:                        @0@'.format(${CFLAGS}),
 857 #  'CPPFLAGS:                      @0@'.format(${CPPFLAGS}),
 858 #  'LIBS:                          @0@'.format(${LIBS}),
 859   '',
 860   'Enable memfd shared memory:    @0@'.format(cdata.has('HAVE_MEMFD')),
 861   'Enable X11:                    @0@'.format(x11_dep.found()),
 862   '  Safe X11 I/O errors:         @0@'.format(cdata.has('HAVE_XSETIOERROREXITHANDLER')),
 863   'Enable OSS Output:             @0@'.format(cdata.has('HAVE_OSS_OUTPUT')),
 864   'Enable OSS Wrapper:            @0@'.format(cdata.has('HAVE_OSS_WRAPPER')),
 865 #  'Enable EsounD:                 @0@'.format(${ENABLE_ESOUND}),
 866   'Enable Alsa:                   @0@'.format(alsa_dep.found()),
 867 #  'Enable CoreAudio:              @0@'.format(${ENABLE_COREAUDIO}),
 868 #  'Enable Solaris:                @0@'.format(${ENABLE_SOLARIS}),
 869 #  'Enable WaveOut:                @0@'.format(${ENABLE_WAVEOUT}),
 870   'Enable GLib 2:                 @0@'.format(glib_dep.found()),
 871 #  'Enable GConf:                  @0@'.format(${ENABLE_GCONF}),
 872   'Enable GSettings:              @0@'.format(gio_dep.found()),
 873   'Enable Gtk+ 3:                 @0@'.format(gtk_dep.found()),
 874   'Enable Avahi:                  @0@'.format(avahi_dep.found()),
 875   'Enable Jack:                   @0@'.format(jack_dep.found()),
 876   'Enable Async DNS:              @0@'.format(asyncns_dep.found()),
 877   'Enable LIRC:                   @0@'.format(lirc_dep.found()),
 878   'Enable D-Bus:                  @0@'.format(dbus_dep.found()),
 879   '  Enable BlueZ 5:              @0@'.format(get_option('bluez5')),
 880   '    Enable native headsets:    @0@'.format(get_option('bluez5-native-headset')),
 881   '    Enable  ofono headsets:    @0@'.format(get_option('bluez5-ofono-headset')),
 882   'Enable udev:                   @0@'.format(udev_dep.found()),
 883   '  Enable HAL->udev compat:     @0@'.format(get_option('hal-compat')),
 884   'Enable systemd:                @0@'.format(libsystemd_dep.found()),
 885 #  'Enable TCP Wrappers:           @0@'.format(${ENABLE_TCPWRAP}),
 886   'Enable libsamplerate:          @0@'.format(samplerate_dep.found()),
 887   'Enable IPv6:                   @0@'.format(get_option('ipv6')),
 888   'Enable OpenSSL (for Airtunes): @0@'.format(openssl_dep.found()),
 889   'Enable FFTW:                   @0@'.format(fftw_dep.found()),
 890   'Enable ORC:                    @0@'.format(have_orcc),
 891   'Enable GStreamer:              @0@'.format(have_gstreamer),
 892   'Enable Adrian echo canceller:  @0@'.format(get_option('adrian-aec')),
 893   'Enable Speex (resampler, AEC): @0@'.format(speex_dep.found()),
 894   'Enable SoXR (resampler):       @0@'.format(soxr_dep.found()),
 895   'Enable WebRTC echo canceller:  @0@'.format(webrtc_dep.found()),
 896   'Enable Gcov coverage:          @0@'.format(get_option('gcov')),
 897   'Enable Valgrind:               @0@'.format(cdata.has('HAVE_VALGRIND_MEMCHECK_H')),
 898   'Enable man pages:              @0@'.format(get_option('man')),
 899   'Enable unit tests:             @0@'.format(get_option('tests')),
 900   '',
 901   'Database:                      @0@'.format(get_option('database')),
 902   'Legacy Database Entry Support: @0@'.format(get_option('legacy-database-entry-format')),
 903   'module-stream-restore:',
 904   '  Clear old devices:           @0@'.format(get_option('stream-restore-clear-old-devices')),
 905   'Running from build tree:       @0@'.format(get_option('running-from-build-tree')),
 906   'System User:                   @0@'.format(cdata.get_unquoted('PA_SYSTEM_USER')),
 907   'System Group:                  @0@'.format(cdata.get_unquoted('PA_SYSTEM_GROUP')),
 908   'Access Group:                  @0@'.format(cdata.get_unquoted('PA_ACCESS_GROUP')),
 909 #  'Enable per-user EsounD socket: @0@'.format(${ENABLE_PER_USER_ESOUND_SOCKET}),
 910 #  'Force preopen:                 @0@'.format(${FORCE_PREOPEN}),
 911 #  'Preopened modules:             @0@'.format(${PREOPEN_MODS}),
 912 ]
 913
 914 message('\n    '.join(summary))
 915
 916 # Sanity checks
 917
 918 if not speex_dep.found() and not webrtc_dep.found() and not get_option('adrian-aec')
 919   error('At least one echo canceller implementation must be available!')
 920 endif
 921
 922 if samplerate_dep.found()
 923   warning('Support for libsamplerate is DEPRECATED')
 924 endif
 925
 926 if host_machine.system() != 'windows'
 927   if not dbus_dep.found()
 928     message = [
 929       'You do not have D-Bus support enabled. It is strongly recommended',
 930       'that you enable D-Bus support if your platform supports it.',
 931       'Many parts of PulseAudio use D-Bus, from ConsoleKit interaction',
 932       'to the Device Reservation Protocol to speak to JACK, Bluetooth',
 933       'support and even a native control protocol for communicating and',
 934       'controlling the PulseAudio daemon itself.',
 935     ]
 936     warning('\n' + '\n'.join(message))
 937   endif
 938   if not udev_dep.found()
 939     message = [
 940       'You do not have udev support enabled. It is strongly recommended',
 941       'that you enable udev support if your platform supports it as it is',
 942       'the primary method used to detect hardware audio devices (on Linux)',
 943       'and is thus a critical part of PulseAudio on that platform.',
 944     ]
 945     warning('\n' + '\n'.join(message))
 946   endif
 947   if not speex_dep.found()
 948     message = [
 949       'You do not have speex support enabled. It is strongly recommended',
 950       'that you enable speex support if your platform supports it as it is',
 951       'the primary method used for audio resampling and is thus a critical',
 952       'part of PulseAudio on that platform.',
 953     ]
 954     warning('\n' + '\n'.join(message))
 955   endif
 956 endif