meson.build

   1 project('pulseaudio', 'c', 'cpp',
   2         version : run_command(find_program('git-version-gen'), join_paths(meson.current_source_dir(), '.tarball-version')).stdout().strip(),
   3         meson_version : '>= 0.50.0',
   4         default_options : [ 'c_std=gnu11', 'cpp_std=c++11' ]
   5         )
   6
   7 pa_version_str = meson.project_version()
   8 # For tarballs, the first split will do nothing, but for builds in git, we
   9 # split out suffixes when there are commits since the last tag
  10 # (e.g.: v11.99.1-3-gad14bdb24 -> v11.99.1)
  11 version_split = pa_version_str.split('-')[0].split('.')
  12 pa_version_major = version_split[0].split('v')[0]
  13 pa_version_minor = version_split[1]
  14 if version_split.length() > 2
  15   pa_version_micro = version_split[2]
  16 else
  17   pa_version_micro = '0'
  18 endif
  19 pa_version_major_minor = pa_version_major + '.' + pa_version_minor
  20
  21 pa_api_version = 12
  22 pa_protocol_version = 33
  23
  24 # The stable ABI for client applications, for the version info x:y:z
  25 # always will hold y=z
  26 libpulse_version_info = [21, 0, 21]
  27
  28 # A simplified, synchronous, ABI-stable interface for client
  29 # applications, for the version info x:y:z always will hold y=z
  30 libpulse_simple_version_info = [1, 1, 1]
  31
  32 # The ABI-stable GLib adapter for client applications, for the version
  33 # info x:y:z always will hold y=z
  34 libpulse_mainloop_glib_version_info = [0, 5, 0]
  35
  36 libpulse_version = '@0@.@1@.@2@'.format(
  37   libpulse_version_info[0] - libpulse_version_info[2],
  38   libpulse_version_info[0],
  39   libpulse_version_info[1],
  40 )
  41
  42 libpulse_simple_version = '@0@.@1@.@2@'.format(
  43   libpulse_simple_version_info[0] - libpulse_simple_version_info[2],
  44   libpulse_simple_version_info[0],
  45   libpulse_simple_version_info[1],
  46 )
  47
  48 libpulse_mainloop_glib_version = '@0@.@1@.@2@'.format(
  49   libpulse_mainloop_glib_version_info[0] - libpulse_mainloop_glib_version_info[2],
  50   libpulse_mainloop_glib_version_info[0],
  51   libpulse_mainloop_glib_version_info[1],
  52 )
  53
  54 # Paths
  55
  56 prefix = get_option('prefix')
  57 assert(prefix.startswith('/'), 'Prefix is not absolute: "@0@"'.format(prefix))
  58
  59 bindir = join_paths(prefix, get_option('bindir'))
  60 includedir = join_paths(prefix, get_option('includedir'))
  61 libdir = join_paths(prefix, get_option('libdir'))
  62 libexecdir = join_paths(prefix, get_option('libexecdir'))
  63 mandir = join_paths(prefix, get_option('mandir'))
  64 datadir = join_paths(prefix, get_option('datadir'))
  65 localedir = join_paths(prefix, get_option('localedir'))
  66 localstatedir = join_paths(prefix, get_option('localstatedir'))
  67 sysconfdir = join_paths(prefix, get_option('sysconfdir'))
  68 privlibdir = join_paths(libdir, 'pulseaudio')
  69 alsadatadir = join_paths(datadir, 'pulseaudio', 'alsa-mixer')
  70
  71 pkgconfigdir = join_paths(libdir, 'pkgconfig')
  72 pulselibexecdir = join_paths(libexecdir, 'pulse')
  73 pulsesysconfdir = join_paths(sysconfdir, 'pulse')
  74
  75 modlibexecdir = get_option('modlibexecdir')
  76 if modlibexecdir == ''
  77   modlibexecdir = join_paths(libdir, 'pulse-' + pa_version_major_minor, 'modules')
  78 endif
  79
  80 padsplibdir = get_option('padsplibdir')
  81 if padsplibdir == ''
  82   padsplibdir = privlibdir
  83 endif
  84
  85 pulsedsp_location = get_option('pulsedsp-location')
  86 if pulsedsp_location == ''
  87   pulsedsp_location = join_paths(prefix, padsplibdir)
  88 endif
  89
  90 systemduserunitdir = get_option('systemduserunitdir')
  91 # the default value is set below
  92
  93 udevrulesdir = get_option('udevrulesdir')
  94 if udevrulesdir == ''
  95   # absolute path, otherwise meson prepends the prefix
  96   udevrulesdir = '/lib/udev/rules.d'
  97 endif
  98
  99 vapidir = join_paths(datadir, 'vala', 'vapi')
 100
 101 bashcompletiondir = get_option('bashcompletiondir')
 102 if bashcompletiondir == ''
 103   bash_completion_dep = dependency('bash-completion', required : false)
 104   if bash_completion_dep.found()
 105     bashcompletiondir = bash_completion_dep.get_pkgconfig_variable('completionsdir')
 106   else
 107     bashcompletiondir = join_paths(datadir, 'bash-completion', 'completions')
 108   endif
 109 endif
 110
 111 zshcompletiondir = get_option('zshcompletiondir')
 112 if zshcompletiondir == ''
 113   zshcompletiondir = join_paths(datadir, 'zsh', 'site-functions')
 114 endif
 115
 116 # Configuration data
 117
 118 cc = meson.get_compiler('c')
 119
 120 cdata = configuration_data()
 121 cdata.set_quoted('PACKAGE', 'pulseaudio')
 122 cdata.set_quoted('PACKAGE_NAME', 'pulseaudio')
 123 cdata.set_quoted('PACKAGE_VERSION', pa_version_str)
 124 cdata.set_quoted('CANONICAL_HOST', host_machine.cpu())
 125 cdata.set('PA_MAJOR', pa_version_major)
 126 cdata.set('PA_MINOR', pa_version_minor)
 127 cdata.set('PA_API_VERSION', pa_api_version)
 128 cdata.set('PA_PROTOCOL_VERSION', pa_protocol_version)
 129 cdata.set_quoted('PA_MACHINE_ID', join_paths(sysconfdir, 'machine-id'))
 130 cdata.set_quoted('PA_MACHINE_ID_FALLBACK', join_paths(localstatedir, 'lib', 'dbus', 'machine-id'))
 131 cdata.set_quoted('PA_SRCDIR', join_paths(meson.current_source_dir(), 'src'))
 132 cdata.set_quoted('PA_BUILDDIR', meson.current_build_dir())
 133 cdata.set_quoted('PA_SOEXT', '.so')
 134 cdata.set_quoted('PA_DEFAULT_CONFIG_DIR', pulsesysconfdir)
 135 cdata.set_quoted('PA_BINARY', join_paths(bindir, 'pulseaudio'))
 136 cdata.set_quoted('PA_SYSTEM_RUNTIME_PATH', join_paths(localstatedir, 'run', 'pulse'))
 137 cdata.set_quoted('PA_SYSTEM_CONFIG_PATH', join_paths(localstatedir, 'lib', 'pulse'))
 138 cdata.set_quoted('PA_SYSTEM_STATE_PATH', join_paths(localstatedir, 'lib', 'pulse'))
 139 cdata.set_quoted('PA_DLSEARCHPATH', modlibexecdir)
 140 cdata.set_quoted('PA_SYSTEM_USER', get_option('system_user'))
 141 cdata.set_quoted('PA_SYSTEM_GROUP', get_option('system_group'))
 142 cdata.set_quoted('PA_ACCESS_GROUP', get_option('access_group'))
 143 cdata.set_quoted('PA_CFLAGS', 'Not yet supported on meson')
 144 cdata.set_quoted('PA_ALSA_PATHS_DIR', join_paths(alsadatadir, 'paths'))
 145 cdata.set_quoted('PA_ALSA_PROFILE_SETS_DIR', join_paths(alsadatadir, 'profile-sets'))
 146 cdata.set_quoted('DESKTOPFILEDIR', join_paths(datadir, 'applications'))
 147 cdata.set_quoted('PULSE_LOCALEDIR', localedir)
 148 cdata.set_quoted('GETTEXT_PACKAGE', 'pulseaudio')
 149 cdata.set('ENABLE_NLS', 1)
 150
 151 # Platform specifics
 152 # First some defaults to keep config file generation happy
 153 cdata.set('HAVE_COREAUDIO', 0)
 154 cdata.set('HAVE_WAVEOUT', 0)
 155 # FIXME: This was not tested. Maybe some flags should better be CFLAGS,
 156 # rather than ending up in the config.h file?
 157 if host_machine.system() == 'darwin'
 158   cdata.set('OS_IS_DARWIN', 1)
 159   cdata.set('_DARWIN_C_SOURCE', '200112L') # Needed to get NSIG on Mac OS
 160 elif host_machine.system() == 'windows'
 161   cdata.set('OS_IS_WIN32', 1)
 162   cdata.set('WIN32_LEAN_AND_MEAN', 1) # Needed to avoid including unnecessary headers on Windows
 163 #elif host_machine.system() == 'solaris'
 164 #  # Apparently meson has no solaris support?
 165 #  # Needed to get declarations for msg_control and msg_controllen on Solaris
 166 #  cdata.set('_XOPEN_SOURCE', 600)
 167 #  cdata.set('__EXTENSIONS__', 1)
 168 endif
 169
 170 # Headers
 171
 172 check_headers = [
 173   'arpa/inet.h',
 174   'byteswap.h',
 175   'cpuid.h',
 176   'dlfcn.h',
 177   'execinfo.h',
 178   'grp.h',
 179   'langinfo.h',
 180   'linux/sockios.h',
 181   'locale.h',
 182   'netdb.h',
 183   'netinet/in.h',
 184   'netinet/in_systm.h',
 185   'netinet/ip.h',
 186   'netinet/tcp.h',
 187   'pcreposix.h',
 188   'poll.h',
 189   'pwd.h',
 190   'regex.h',
 191   'sched.h',
 192   'sys/capability.h',
 193   'sys/dl.h',
 194   'sys/eventfd.h',
 195   'sys/filio.h',
 196   'sys/ioctl.h',
 197   'sys/mman.h',
 198   'sys/prctl.h',
 199   'sys/resource.h',
 200   'sys/select.h',
 201   'sys/socket.h',
 202   'sys/syscall.h',
 203   'sys/uio.h',
 204   'sys/un.h',
 205   'sys/wait.h',
 206   'syslog.h',
 207   'valgrind/memcheck.h',
 208   'xlocale.h',
 209 ]
 210
 211 foreach h : check_headers
 212   if cc.has_header(h)
 213     define = 'HAVE_' + h.underscorify().to_upper()
 214     cdata.set(define, 1)
 215   endif
 216 endforeach
 217
 218 # FIXME: move this to the above set
 219 if cc.has_header('pthread.h')
 220   cdata.set('HAVE_PTHREAD', 1)
 221 endif
 222
 223 # Functions
 224
 225 check_functions = [
 226   'accept4',
 227   'clock_gettime',
 228   'ctime_r',
 229   'fchmod',
 230   'fchown',
 231   'fork',
 232   'fstat',
 233   'getaddrinfo',
 234   'getgrgid_r',
 235   'getgrnam_r',
 236   'getpwnam_r',
 237   'getpwuid_r',
 238   'gettimeofday',
 239   'getuid',
 240   'lrintf',
 241   'lstat',
 242   'memfd_create',
 243   'mkfifo',
 244   'mlock',
 245   'nanosleep',
 246   'open64',
 247   'paccept',
 248   'pipe',
 249   'pipe2',
 250   'posix_fadvise',
 251   'posix_madvise',
 252   'posix_memalign',
 253   'ppoll',
 254   'readlink',
 255   'setegid',
 256   'seteuid',
 257   'setpgid',
 258   'setregid',
 259   'setresgid',
 260   'setresuid',
 261   'setreuid',
 262   'setsid',
 263   'sig2str',
 264   'sigaction',
 265   'strerror_r',
 266   'strtod_l',
 267   'strtof',
 268   'symlink',
 269   'sysconf',
 270   'uname',
 271 ]
 272
 273 foreach f : check_functions
 274   if cc.has_function(f)
 275     define = 'HAVE_' + f.underscorify().to_upper()
 276     cdata.set(define, 1)
 277   endif
 278 endforeach
 279
 280 if cc.has_function('SYS_memfd_create', prefix : '#include <sys/syscall.h>')
 281   cdata.set('HAVE_MEMFD', 1)
 282 endif
 283
 284 # Symbols
 285
 286 if cc.has_header_symbol('signal.h', 'SIGXCPU')
 287   cdata.set('HAVE_SIGXCPU', 1)
 288 endif
 289
 290 if not cc.has_header_symbol('netinet/in.h', 'INADDR_NONE')
 291   if not cc.has_header_symbol('winsock2.h', 'INADDR_NONE')
 292     # Define INADDR_NONE if not found (Solaris)
 293     cdata.set('INADDR_NONE', '0xffffffff')
 294   endif
 295 endif
 296
 297 # Types
 298
 299 # FIXME: do we ever care about gid_t not being defined / smaller than an int?
 300 cdata.set('GETGROUPS_T', 'gid_t')
 301
 302 # Include paths
 303
 304 configinc = include_directories('.')
 305 topinc = include_directories('src')
 306
 307 # CFLAGS/LDFLAGS
 308
 309 pa_c_args = ['-DHAVE_CONFIG_H', '-D_GNU_SOURCE']
 310 server_c_args = ['-D__INCLUDED_FROM_PULSE_AUDIO']
 311 cdata.set('MESON_BUILD', 1)
 312
 313 # On ELF systems we don't want the libraries to be unloaded since we don't clean them up properly,
 314 # so we request the nodelete flag to be enabled.
 315 # On other systems, we don't really know how to do that, but it's welcome if somebody can tell.
 316 nodelete_link_args = ['-Wl,-z,nodelete']
 317
 318 # Code coverage
 319
 320 if get_option('gcov')
 321   add_project_arguments('--coverage', language: ['c', 'cpp'])
 322   add_project_link_arguments('--coverage', language: ['c', 'cpp'])
 323 endif
 324
 325 # Core Dependencies
 326
 327 libm_dep = cc.find_library('m', required : true)
 328
 329 thread_dep = dependency('threads')
 330 foreach f : [
 331   'pthread_getname_np',
 332   'pthread_setaffinity_np',
 333   'pthread_setname_np',
 334 ]
 335   if cc.has_function(f, dependencies : thread_dep)
 336     define = 'HAVE_' + f.underscorify().to_upper()
 337     cdata.set(define, 1)
 338   endif
 339 endforeach
 340
 341 cap_dep = cc.find_library('cap', required : false)
 342
 343 shm_dep = cc.find_library('rt', required : false)
 344 if shm_dep.found()
 345   cdata.set('HAVE_SHM_OPEN', 1)
 346 endif
 347
 348 dl_dep = cc.find_library('dl', required : false)
 349 if dl_dep.found()
 350   cdata.set('HAVE_DLADDR', 1)
 351 endif
 352
 353 have_iconv = false
 354 if cc.has_function('iconv_open')
 355   iconv_dep = dependency('', required : false)
 356   have_iconv = true
 357 else
 358   iconv_dep = cc.find_library('iconv', required : false)
 359   have_iconv = iconv_dep.found()
 360 endif
 361 if have_iconv
 362   cdata.set('HAVE_ICONV', 1)
 363   iconvconsttest = '''#include <iconv.h>
 364 size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 365 '''
 366   if cc.compiles(iconvconsttest, dependencies : iconv_dep)
 367     cdata.set('ICONV_CONST', '')
 368   else
 369     cdata.set('ICONV_CONST', 'const')
 370   endif
 371 endif
 372
 373 atomictest = '''void func() {
 374   volatile int atomic = 2;
 375   __sync_bool_compare_and_swap (&atomic, 2, 3);
 376 }
 377 '''
 378 if cc.compiles(atomictest)
 379   newatomictest = '''void func() {
 380     int c = 0;
 381     __atomic_store_n(&c, 4, __ATOMIC_SEQ_CST);
 382   }
 383   '''
 384
 385   if(cc.compiles(newatomictest))
 386     cdata.set('HAVE_ATOMIC_BUILTINS_MEMORY_MODEL', true)
 387   endif
 388
 389   cdata.set('HAVE_ATOMIC_BUILTINS', true)
 390 else
 391   # FIXME: check if we need libatomic_ops
 392 endif
 393
 394 # FIXME: make sure it's >= 2.2
 395 ltdl_dep = cc.find_library('ltdl', required : true)
 396 # FIXME: can meson support libtool -dlopen/-dlpreopen things?
 397 #        and do we still want to support this at all?
 398 cdata.set('DISABLE_LIBTOOL_PRELOAD', 1)
 399
 400 if get_option('database') == 'tdb'
 401   database_dep = dependency('tdb')
 402 elif get_option('database') == 'gdbm'
 403   database_dep = cc.find_library('gdbm', required : true)
 404 else
 405   database_dep = dependency('', required: false)
 406 endif
 407
 408 if get_option('ipv6')
 409   cdata.set('HAVE_IPV6', 1)
 410 endif
 411
 412 if get_option('legacy-database-entry-format')
 413   cdata.set('ENABLE_LEGACY_DATABASE_ENTRY_FORMAT', 1)
 414 endif
 415
 416 if get_option('running-from-build-tree')
 417   cdata.set('HAVE_RUNNING_FROM_BUILD_TREE', 1)
 418 endif
 419
 420 alsa_dep = dependency('alsa', version : '>= 1.0.24', required : get_option('alsa'))
 421 if alsa_dep.found()
 422   cdata.set('HAVE_ALSA', 1)
 423   cdata.set('HAVE_ALSA_UCM', 1)
 424 endif
 425
 426 asyncns_dep = dependency('libasyncns', version : '>= 0.1', required : get_option('asyncns'))
 427 if asyncns_dep.found()
 428   cdata.set('HAVE_LIBASYNCNS', 1)
 429 endif
 430
 431 dbus_dep = dependency('dbus-1', version : '>= 1.4.12', required : get_option('dbus'))
 432 if dbus_dep.found()
 433   cdata.set('HAVE_DBUS', 1)
 434 endif
 435
 436 gio_dep = dependency('gio-2.0', version : '>= 2.26.0', required : get_option('gsettings'))
 437 if gio_dep.found()
 438   cdata.set('HAVE_GSETTINGS', 1)
 439 endif
 440
 441 glib_dep = dependency('glib-2.0', version : '>= 2.4.0', required: get_option('glib'))
 442 if glib_dep.found()
 443   cdata.set('HAVE_GLIB', 1)
 444 endif
 445
 446 gtk_dep = dependency('gtk+-3.0', required : get_option('gtk'))
 447 if gtk_dep.found()
 448   cdata.set('HAVE_GTK', 1)
 449 endif
 450
 451 have_orcc = false
 452 orcc_args = []
 453 orc_dep = dependency('orc-0.4', version : '>= 0.4.11', required : get_option('orc'))
 454 orcc = find_program('orcc', required : get_option('orc'))
 455 if orc_dep.found() and orcc.found()
 456   have_orcc = true
 457   orcc_args = [orcc]
 458   #orcc_args = [orcc, '--include', 'glib.h']
 459   cdata.set('HAVE_ORC', 1)
 460 else
 461   cdata.set('DISABLE_ORC', 1)
 462 endif
 463
 464 samplerate_dep = dependency('samplerate', version : '>= 0.1.0', required : get_option('samplerate'))
 465 if samplerate_dep.found()
 466   cdata.set('HAVE_LIBSAMPLERATE', 1)
 467 endif
 468
 469 sndfile_dep = dependency('sndfile', version : '>= 1.0.20')
 470
 471 soxr_dep = dependency('soxr', version : '>= 0.1.1', required : get_option('soxr'))
 472 if soxr_dep.found()
 473   cdata.set('HAVE_SOXR', 1)
 474 endif
 475
 476 libsystemd_dep = dependency('libsystemd', required : get_option('systemd'))
 477 if libsystemd_dep.found()
 478   cdata.set('HAVE_SYSTEMD_DAEMON', 1)
 479   cdata.set('HAVE_SYSTEMD_LOGIN', 1)
 480   cdata.set('HAVE_SYSTEMD_JOURNAL', 1)
 481 endif
 482 systemd_dep = dependency('systemd', required : get_option('systemd'))
 483 if systemd_dep.found() and systemduserunitdir == ''
 484   systemduserunitdir = systemd_dep.get_pkgconfig_variable('systemduserunitdir')
 485 endif
 486
 487 x11_dep = dependency('x11-xcb', required : get_option('x11'))
 488 if x11_dep.found()
 489   xcb_dep  = dependency('xcb',  required : true, version : '>= 1.6')
 490   ice_dep  = dependency('ice',  required : true)
 491   sm_dep   = dependency('sm',   required : true)
 492   xtst_dep = dependency('xtst', required : true)
 493   cdata.set('HAVE_X11', 1)
 494 endif
 495
 496 # Module dependencies
 497
 498 if cc.has_header('sys/soundcard.h')
 499   cdata.set('HAVE_OSS_OUTPUT', 1)
 500   cdata.set('HAVE_OSS_WRAPPER', 1)
 501   cdata.set('PULSEDSP_LOCATION', pulsedsp_location)
 502 endif
 503
 504 if get_option('hal-compat')
 505   cdata.set('HAVE_HAL_COMPAT', 1)
 506 endif
 507
 508 avahi_dep = dependency('avahi-client', version : '>= 0.6.0', required : get_option('avahi'), disabler : true)
 509 if avahi_dep.found()
 510   cdata.set('HAVE_AVAHI', 1)
 511 endif
 512
 513 bluez_dep = dependency('bluez', version : '>= 5.0', required : get_option('bluez5'))
 514 sbc_dep = dependency('sbc', version : '>= 1.0', required : false)
 515 if bluez_dep.found()
 516   assert(dbus_dep.found(), 'BlueZ requires D-Bus support')
 517   assert(sbc_dep.found(), 'BlueZ requires SBC support')
 518   cdata.set('HAVE_SBC', 1)
 519   cdata.set('HAVE_BLUEZ', 1)
 520   cdata.set('HAVE_BLUEZ_5', 1)
 521   if get_option('bluez5-native-headset')
 522     cdata.set('HAVE_BLUEZ_5_NATIVE_HEADSET', 1)
 523   endif
 524   if get_option('bluez5-ofono-headset')
 525     cdata.set('HAVE_BLUEZ_5_OFONO_HEADSET', 1)
 526   endif
 527 endif
 528
 529 fftw_dep = dependency('fftw3f', required : get_option('fftw'))
 530 if fftw_dep.found()
 531   cdata.set('HAVE_FFTW', 1)
 532 endif
 533
 534 jack_dep = dependency('jack', version : '>= 0.117.0', required : get_option('jack'))
 535 if jack_dep.found()
 536   cdata.set('HAVE_JACK', 1)
 537 endif
 538
 539 lirc_dep = dependency('lirc', required : get_option('lirc'))
 540 if lirc_dep.found()
 541   cdata.set('HAVE_LIRC', 1)
 542 endif
 543
 544 openssl_dep = dependency('openssl', version : '>= 0.9', required : get_option('openssl'))
 545 if openssl_dep.found()
 546   cdata.set('HAVE_OPENSSL', 1)
 547 endif
 548
 549 speex_dep = dependency('speexdsp', version : '>= 1.2', required : get_option('speex'))
 550 if speex_dep.found()
 551   cdata.set('HAVE_SPEEX', 1)
 552 endif
 553
 554 udev_dep = dependency('libudev', version : '>= 143', required : get_option('udev'))
 555 if udev_dep.found()
 556   cdata.set('HAVE_UDEV', 1)
 557 endif
 558
 559 webrtc_dep = dependency('webrtc-audio-processing', version : '>= 0.2', required : get_option('webrtc-aec'))
 560 if webrtc_dep.found()
 561   cdata.set('HAVE_WEBRTC', 1)
 562 endif
 563
 564 # These are required for the CMake file generation
 565 cdata.set('PA_LIBDIR', libdir)
 566 cdata.set('PA_INCDIR', includedir)
 567 if glib_dep.found()
 568   cdata.set('HAVE_GLIB20', 1) # to match the AM_CONDITIONAL for CMake file generation
 569 endif
 570
 571 # Test dependencies
 572
 573 check_dep = dependency('check', version : '>= 0.9.10', required : get_option('tests'))
 574
 575 # Now generate config.h from everything above
 576 configure_file(output : 'config.h', configuration : cdata)
 577
 578 # pkg-config files
 579
 580 pc_cdata = configuration_data()
 581
 582 pc_cdata.set('prefix', prefix)
 583 pc_cdata.set('exec_prefix', prefix)
 584 pc_cdata.set('libdir', libdir)
 585 pc_cdata.set('includedir', includedir)
 586 pc_cdata.set('modlibexecdir', modlibexecdir)
 587 pc_cdata.set('PACKAGE_VERSION', pa_version_str)
 588 pc_cdata.set('PA_MAJORMINOR', pa_version_major_minor)
 589 # FIXME: the line below is wrong. Currently the meson thread dep lacks documentation,
 590 # and doesn't allow introspection, ie. none of get_pkgconfig_variable() or
 591 # get_configtool_variable() work with it, so we have no way to get this flag right,
 592 # unless we do all the work ourselves. See current work in glib, also meson #553.
 593 pc_cdata.set('PTHREAD_LIBS', '-pthread')
 594
 595 pc_files = [
 596   'libpulse.pc',
 597   'libpulse-simple.pc',
 598 ]
 599
 600 if glib_dep.found()
 601   pc_files += 'libpulse-mainloop-glib.pc'
 602 endif
 603
 604 foreach file : pc_files
 605   configure_file(
 606     input : file + '.in',
 607     output : file,
 608     configuration : pc_cdata,
 609     install_dir : pkgconfigdir)
 610 endforeach
 611
 612 # CMake files
 613
 614 m4 = find_program('m4', required: true)
 615
 616 cmakedir = join_paths(libdir, 'cmake', 'PulseAudio')
 617
 618 cmake_template_file = configure_file(
 619   input : 'PulseAudioConfig.cmake.in',
 620   output : 'PulseAudioConfig.cmake.tmp',
 621   configuration: cdata,
 622 )
 623
 624 custom_target('PulseAudioConfig.cmake',
 625   input : cmake_template_file,
 626   output : 'PulseAudioConfig.cmake',
 627   capture : true,
 628   command : [m4, '@INPUT@'],
 629   build_by_default : true,
 630   install : true,
 631   install_dir : cmakedir,
 632 )
 633
 634 configure_file(
 635   input : 'PulseAudioConfigVersion.cmake.in',
 636   output : 'PulseAudioConfigVersion.cmake',
 637   configuration: cdata,
 638   install : true,
 639   install_dir : cmakedir,
 640 )
 641
 642 # Subdirs
 643
 644 subdir('po')
 645 if get_option('man')
 646   subdir('man')
 647 endif
 648 subdir('shell-completion/bash')
 649 subdir('shell-completion/zsh')
 650 subdir('src')
 651 subdir('vala')
 652
 653 ############################################################
 654
 655 # Final summary
 656
 657 summary = [
 658   '',
 659   '---{ @0@ @1@ }---'.format(meson.project_name(), meson.project_version()),
 660   '',
 661   'prefix:                        @0@'.format(prefix),
 662   'bindir:                        @0@'.format(bindir),
 663   'libdir:                        @0@'.format(libdir),
 664   'libexecdir:                    @0@'.format(libexecdir),
 665   'mandir:                        @0@'.format(mandir),
 666   'datadir:                       @0@'.format(datadir),
 667   'sysconfdir:                    @0@'.format(sysconfdir),
 668   'localstatedir:                 @0@'.format(localstatedir),
 669   'modlibexecdir:                 @0@'.format(modlibexecdir),
 670   'System Runtime Path:           @0@'.format(cdata.get_unquoted('PA_SYSTEM_RUNTIME_PATH')),
 671   'System State Path:             @0@'.format(cdata.get_unquoted('PA_SYSTEM_STATE_PATH')),
 672   'System Config Path:            @0@'.format(cdata.get_unquoted('PA_SYSTEM_CONFIG_PATH')),
 673   'Bash completions directory:    @0@'.format(bashcompletiondir),
 674   'Zsh completions directory:     @0@'.format(zshcompletiondir),
 675   'Compiler:                      @0@ @1@'.format(cc.get_id(), cc.version()),
 676 #  'CFLAGS:                        @0@'.format(${CFLAGS}),
 677 #  'CPPFLAGS:                      @0@'.format(${CPPFLAGS}),
 678 #  'LIBS:                          @0@'.format(${LIBS}),
 679   '',
 680   'Enable memfd shared memory:    @0@'.format(cdata.has('HAVE_MEMFD')),
 681   'Enable X11:                    @0@'.format(x11_dep.found()),
 682 #  'Enable OSS Output:             @0@'.format(${ENABLE_OSS_OUTPUT}),
 683 #  'Enable OSS Wrapper:            @0@'.format(${ENABLE_OSS_WRAPPER}),
 684 #  'Enable EsounD:                 @0@'.format(${ENABLE_ESOUND}),
 685   'Enable Alsa:                   @0@'.format(alsa_dep.found()),
 686 #  'Enable CoreAudio:              @0@'.format(${ENABLE_COREAUDIO}),
 687 #  'Enable Solaris:                @0@'.format(${ENABLE_SOLARIS}),
 688 #  'Enable WaveOut:                @0@'.format(${ENABLE_WAVEOUT}),
 689   'Enable GLib 2:                 @0@'.format(glib_dep.found()),
 690 #  'Enable GConf:                  @0@'.format(${ENABLE_GCONF}),
 691   'Enable GSettings:              @0@'.format(gio_dep.found()),
 692   'Enable Gtk+ 3:                 @0@'.format(gtk_dep.found()),
 693   'Enable Avahi:                  @0@'.format(avahi_dep.found()),
 694   'Enable Jack:                   @0@'.format(jack_dep.found()),
 695   'Enable Async DNS:              @0@'.format(asyncns_dep.found()),
 696   'Enable LIRC:                   @0@'.format(lirc_dep.found()),
 697   'Enable D-Bus:                  @0@'.format(dbus_dep.found()),
 698   '  Enable BlueZ 5:              @0@'.format(bluez_dep.found()),
 699   '    Enable native headsets:    @0@'.format(get_option('bluez5-native-headset')),
 700   '    Enable  ofono headsets:    @0@'.format(get_option('bluez5-ofono-headset')),
 701   'Enable udev:                   @0@'.format(udev_dep.found()),
 702   '  Enable HAL->udev compat:     @0@'.format(get_option('hal-compat')),
 703   'Enable systemd:                @0@'.format(libsystemd_dep.found()),
 704 #  'Enable TCP Wrappers:           @0@'.format(${ENABLE_TCPWRAP}),
 705   'Enable libsamplerate:          @0@'.format(samplerate_dep.found()),
 706   'Enable IPv6:                   @0@'.format(get_option('ipv6')),
 707   'Enable OpenSSL (for Airtunes): @0@'.format(openssl_dep.found()),
 708   'Enable FFTW:                   @0@'.format(fftw_dep.found()),
 709   'Enable ORC:                    @0@'.format(have_orcc),
 710   'Enable Adrian echo canceller:  @0@'.format(get_option('adrian-aec')),
 711   'Enable Speex (resampler, AEC): @0@'.format(speex_dep.found()),
 712   'Enable SoXR (resampler):       @0@'.format(soxr_dep.found()),
 713   'Enable WebRTC echo canceller:  @0@'.format(webrtc_dep.found()),
 714   'Enable Gcov coverage:          @0@'.format(get_option('gcov')),
 715   'Enable man pages:              @0@'.format(get_option('man')),
 716   'Enable unit tests:             @0@'.format(get_option('tests')),
 717   '',
 718   'Database:                      @0@'.format(get_option('database')),
 719   'Legacy Database Entry Support: @0@'.format(get_option('legacy-database-entry-format')),
 720   'Running from build tree:       @0@'.format(get_option('running-from-build-tree')),
 721   'System User:                   @0@'.format(cdata.get_unquoted('PA_SYSTEM_USER')),
 722   'System Group:                  @0@'.format(cdata.get_unquoted('PA_SYSTEM_GROUP')),
 723   'Access Group:                  @0@'.format(cdata.get_unquoted('PA_ACCESS_GROUP')),
 724 #  'Enable per-user EsounD socket: @0@'.format(${ENABLE_PER_USER_ESOUND_SOCKET}),
 725 #  'Force preopen:                 @0@'.format(${FORCE_PREOPEN}),
 726 #  'Preopened modules:             @0@'.format(${PREOPEN_MODS}),
 727 ]
 728
 729 message('\n    '.join(summary))
 730
 731 # Sanity checks
 732
 733 if not speex_dep.found() and not webrtc_dep.found() and not get_option('adrian-aec')
 734   error('At least one echo canceller implementation must be available!')
 735 endif
 736
 737 if samplerate_dep.found()
 738   warning('Support for libsamplerate is DEPRECATED')
 739 endif
 740
 741 if host_machine.system() != 'windows'
 742   if not dbus_dep.found()
 743     message = [
 744       'You do not have D-Bus support enabled. It is strongly recommended',
 745       'that you enable D-Bus support if your platform supports it.',
 746       'Many parts of PulseAudio use D-Bus, from ConsoleKit interaction',
 747       'to the Device Reservation Protocol to speak to JACK, Bluetooth',
 748       'support and even a native control protocol for communicating and',
 749       'controlling the PulseAudio daemon itself.',
 750     ]
 751     warning('\n' + '\n'.join(message))
 752   endif
 753   if not udev_dep.found()
 754     message = [
 755       'You do not have udev support enabled. It is strongly recommended',
 756       'that you enable udev support if your platform supports it as it is',
 757       'the primary method used to detect hardware audio devices (on Linux)',
 758       'and is thus a critical part of PulseAudio on that platform.',
 759     ]
 760     warning('\n' + '\n'.join(message))
 761   endif
 762   if not speex_dep.found()
 763     message = [
 764       'You do not have speex support enabled. It is strongly recommended',
 765       'that you enable speex support if your platform supports it as it is',
 766       'the primary method used for audio resampling and is thus a critical',
 767       'part of PulseAudio on that platform.',
 768     ]
 769     warning('\n' + '\n'.join(message))
 770   endif
 771 endif