meson.build

   1 project('gst-plugins-base', 'c',
   2   version : '1.15.0.1',
   3   meson_version : '>= 0.46.0',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0].to_int()
  10 gst_version_minor = version_arr[1].to_int()
  11 gst_version_micro = version_arr[2].to_int()
  12 if version_arr.length() == 4
  13   gst_version_nano = version_arr[3].to_int()
  14 else
  15   gst_version_nano = 0
  16 endif
  17
  18 have_cxx = add_languages('cpp', required : false)
  19
  20 glib_req = '>= 2.40.0'
  21 orc_req = '>= 0.4.24'
  22 gst_req = '>= @0@.@1@.0'.format(gst_version_major, gst_version_minor)
  23
  24 api_version = '1.0'
  25 soversion = 0
  26 # maintaining compatibility with the previous libtool versioning
  27 # current = minor * 100 + micro
  28 # FIXME: should be able to convert string to int somehow so we can just do maths
  29 libversion = '@0@.@1@.0'.format(soversion, gst_version_minor * 100 + gst_version_micro)
  30
  31 plugins_install_dir = '@0@/gstreamer-1.0'.format(get_option('libdir'))
  32
  33 cc = meson.get_compiler('c')
  34
  35 if cc.get_id() == 'msvc'
  36   # Ignore several spurious warnings for things gstreamer does very commonly
  37   # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  38   # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  39   # NOTE: Only add warnings here if you are sure they're spurious
  40   add_project_arguments(
  41       '/wd4018', # implicit signed/unsigned conversion
  42       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  43       '/wd4244', # lossy type conversion (e.g. double -> int)
  44       '/wd4305', # truncating type conversion (e.g. double -> float)
  45       language : 'c')
  46   # Disable SAFESEH with MSVC for plugins and libs that use external deps that
  47   # are built with MinGW
  48   noseh_link_args = ['/SAFESEH:NO']
  49 else
  50   noseh_link_args = []
  51 endif
  52
  53 if cc.has_link_argument('-Wl,-Bsymbolic-functions')
  54   add_project_link_arguments('-Wl,-Bsymbolic-functions', language : 'c')
  55 endif
  56
  57 # Symbol visibility
  58 if cc.has_argument('-fvisibility=hidden')
  59   add_project_arguments('-fvisibility=hidden', language: 'c')
  60 endif
  61
  62 # Disable strict aliasing
  63 if cc.has_argument('-fno-strict-aliasing')
  64   add_project_arguments('-fno-strict-aliasing', language: 'c')
  65 endif
  66
  67 core_conf = configuration_data()
  68 check_headers = [
  69   ['HAVE_DLFCN_H', 'dlfcn.h'],
  70   ['HAVE_EMMINTRIN_H', 'emmintrin.h'],
  71   ['HAVE_INTTYPES_H', 'inttypes.h'],
  72   ['HAVE_MEMORY_H', 'memory.h'],
  73   ['HAVE_PROCESS_H', 'process.h'],
  74   ['HAVE_SMMINTRIN_H', 'smmintrin.h'],
  75   ['HAVE_STDINT_H', 'stdint.h'],
  76   ['HAVE_STDLIB_H', 'stdlib.h'],
  77   ['HAVE_STRINGS_H', 'strings.h'],
  78   ['HAVE_STRING_H', 'string.h'],
  79   ['HAVE_SYS_SOCKET_H', 'sys/socket.h'],
  80   ['HAVE_SYS_STAT_H', 'sys/stat.h'],
  81   ['HAVE_SYS_TYPES_H', 'sys/types.h'],
  82   ['HAVE_SYS_WAIT_H', 'sys/wait.h'],
  83   ['HAVE_UNISTD_H', 'unistd.h'],
  84   ['HAVE_WINSOCK2_H', 'winsock2.h'],
  85   ['HAVE_XMMINTRIN_H', 'xmmintrin.h'],
  86   ['HAVE_LINUX_DMA_BUF_H', 'linux/dma-buf.h'],
  87 ]
  88 foreach h : check_headers
  89   if cc.has_header(h.get(1))
  90     core_conf.set(h.get(0), 1)
  91   endif
  92 endforeach
  93
  94 check_functions = [
  95   ['HAVE_DCGETTEXT', 'dcgettext', '#include<libintl.h>'],
  96   ['HAVE_GMTIME_R', 'gmtime_r', '#include<time.h>'],
  97   ['HAVE_LRINTF', 'lrintf', '#include<math.h>'],
  98   ['HAVE_MMAP', 'mmap', '#include<sys/mman.h>'],
  99   ['HAVE_LOG2', 'log2', '#include<math.h>'],
 100 ]
 101
 102 libm = cc.find_library('m', required : false)
 103 foreach f : check_functions
 104   if cc.has_function(f.get(1), prefix : f.get(2), dependencies : libm)
 105     core_conf.set(f.get(0), 1)
 106   endif
 107 endforeach
 108
 109 core_conf.set('SIZEOF_CHAR', cc.sizeof('char'))
 110 core_conf.set('SIZEOF_INT', cc.sizeof('int'))
 111 core_conf.set('SIZEOF_LONG', cc.sizeof('long'))
 112 core_conf.set('SIZEOF_SHORT', cc.sizeof('short'))
 113 core_conf.set('SIZEOF_VOIDP', cc.sizeof('void*'))
 114
 115 core_conf.set('GETTEXT_PACKAGE', '"gst-plugins-base-1.0"')
 116 core_conf.set('PACKAGE', '"gst-plugins-base"')
 117 core_conf.set('VERSION', '"@0@"'.format(gst_version))
 118 core_conf.set('PACKAGE_VERSION', '"@0@"'.format(gst_version))
 119 core_conf.set('GST_API_VERSION', '"@0@"'.format(api_version))
 120 core_conf.set('GST_INSTALL_PLUGINS_HELPER', '"/FIXME"')
 121 core_conf.set('GST_DATADIR', '"/FIXME"')
 122 core_conf.set('GST_LICENSE', '"LGPL"')
 123
 124 warning_flags = [
 125   '-Wmissing-declarations',
 126   '-Wredundant-decls',
 127   '-Wundef',
 128   '-Wwrite-strings',
 129   '-Wformat',
 130   '-Wformat-nonliteral',
 131   '-Wformat-security',
 132   '-Winit-self',
 133   '-Wmissing-include-dirs',
 134   '-Waddress',
 135   '-Wno-multichar',
 136   '-Wvla',
 137   '-Wpointer-arith',
 138 ]
 139
 140 warning_c_flags = [
 141   '-Wmissing-prototypes',
 142   '-Wdeclaration-after-statement',
 143 ]
 144
 145 warning_cxx_flags = [
 146   '-Waggregate-return',
 147 ]
 148
 149 if have_cxx
 150   cxx = meson.get_compiler('cpp')
 151   foreach extra_arg : warning_cxx_flags
 152     if cxx.has_argument (extra_arg)
 153       add_project_arguments([extra_arg], language: 'cpp')
 154     endif
 155   endforeach
 156 endif
 157
 158 foreach extra_arg : warning_flags
 159   if cc.has_argument (extra_arg)
 160     add_project_arguments([extra_arg], language: 'c')
 161   endif
 162   if have_cxx and cxx.has_argument (extra_arg)
 163     add_project_arguments([extra_arg], language: 'cpp')
 164   endif
 165 endforeach
 166
 167 foreach extra_arg : warning_c_flags
 168   if cc.has_argument (extra_arg)
 169     add_project_arguments([extra_arg], language: 'c')
 170   endif
 171 endforeach
 172
 173 # GStreamer package name and origin url
 174 gst_package_name = get_option('with-package-name')
 175 if gst_package_name == ''
 176   if gst_version_nano == 0
 177     gst_package_name = 'GStreamer Base Plug-ins source release'
 178   elif gst_version_nano == 1
 179     gst_package_name = 'GStreamer Base Plug-ins git'
 180   else
 181     gst_package_name = 'GStreamer Base Plug-ins prerelease'
 182   endif
 183 endif
 184 core_conf.set_quoted('GST_PACKAGE_NAME', gst_package_name)
 185 core_conf.set_quoted('GST_PACKAGE_ORIGIN', get_option('with-package-origin'))
 186
 187 # FIXME: These should be configure options
 188 core_conf.set('DEFAULT_VIDEOSINK', '"autovideosink"')
 189 core_conf.set('DEFAULT_AUDIOSINK', '"autoaudiosink"')
 190
 191 # Set whether the audioresampling method should be detected at runtime
 192 core_conf.set('AUDIORESAMPLE_FORMAT_' + get_option('audioresample_format').to_upper(), true)
 193
 194 gst_plugins_base_args = ['-DHAVE_CONFIG_H']
 195 if get_option('default_library') == 'static'
 196   gst_plugins_base_args += ['-DGST_STATIC_COMPILATION']
 197 endif
 198
 199 # X11 checks are for sys/ and tests/
 200 x11_dep = dependency('x11', required : false)
 201 # GLib checks are for the entire project
 202 giounix_dep = dependency('gio-unix-2.0', version : glib_req, required : false)
 203 # Almost everything that uses glib also uses gobject
 204 glib_deps = [dependency('glib-2.0', version : glib_req, fallback: ['glib', 'libglib_dep']),
 205              dependency('gobject-2.0', fallback: ['glib', 'libgobject_dep'])]
 206 gio_dep = dependency('gio-2.0', fallback: ['glib', 'libgio_dep'])
 207
 208 # some of the examples want GTK+
 209 gtk_dep = dependency('gtk+-3.0', version : '>= 3.10', required : false)
 210 gtk_x11_dep = dependency('gtk+-x11-3.0', version : '>= 3.10', required : false)
 211 gtk_quartz_dep = dependency('gtk+-quartz-3.0', version : '>= 3.10', required : false)
 212 gdk_pixbuf_dep = dependency('gdk-pixbuf-2.0', required : false)
 213
 214 core_conf.set('HAVE_X', x11_dep.found())
 215 core_conf.set('HAVE_GIO_UNIX_2_0',
 216     (gio_dep.type_name() != 'pkgconfig' and host_machine.system() != 'windows')
 217     or giounix_dep.found())
 218
 219 if gio_dep.type_name() == 'pkgconfig'
 220     core_conf.set_quoted('GIO_MODULE_DIR',
 221         gio_dep.get_pkgconfig_variable('giomoduledir'))
 222     core_conf.set_quoted('GIO_LIBDIR',
 223         gio_dep.get_pkgconfig_variable('libdir'))
 224     core_conf.set_quoted('GIO_PREFIX',
 225         gio_dep.get_pkgconfig_variable('prefix'))
 226 else
 227     core_conf.set_quoted('GIO_MODULE_DIR', join_paths(get_option('prefix'),
 228       get_option('libdir'), 'gio/modules'))
 229     core_conf.set_quoted('GIO_LIBDIR', join_paths(get_option('prefix'),
 230       get_option('libdir')))
 231     core_conf.set_quoted('GIO_PREFIX', get_option('prefix'))
 232 endif
 233
 234 configinc = include_directories('.')
 235 libsinc = include_directories('gst-libs')
 236
 237 # To use the subproject make subprojects directory
 238 # and put gstreamer meson git there (symlinking is fine)
 239 gst_dep = dependency('gstreamer-1.0', version : gst_req,
 240   fallback : ['gstreamer', 'gst_dep'])
 241 gst_base_dep = dependency('gstreamer-base-1.0', version : gst_req,
 242   fallback : ['gstreamer', 'gst_base_dep'])
 243 gst_net_dep = dependency('gstreamer-net-1.0', version : gst_req,
 244   fallback : ['gstreamer', 'gst_net_dep'])
 245 if host_machine.system() != 'windows'
 246   gst_check_dep = dependency('gstreamer-check-1.0', version : gst_req,
 247     fallback : ['gstreamer', 'gst_check_dep'])
 248 endif
 249 gst_controller_dep = dependency('gstreamer-controller-1.0', version : gst_req,
 250   fallback : ['gstreamer', 'gst_controller_dep'])
 251
 252 have_orcc = false
 253 orcc_args = []
 254 if get_option('use_orc') != 'no'
 255   need_orc = get_option('use_orc') == 'yes'
 256   # Used by various libraries/elements that use Orc code
 257   orc_dep = dependency('orc-0.4', version : orc_req, required : need_orc)
 258   orcc = find_program('orcc', required : need_orc)
 259   if orc_dep.found() and orcc.found()
 260     have_orcc = true
 261     orcc_args = [orcc, '--include', 'glib.h']
 262     core_conf.set('HAVE_ORC', 1)
 263   else
 264     message('Orc Compiler not found, will use backup C code')
 265     core_conf.set('DISABLE_ORC', 1)
 266   endif
 267 else
 268   core_conf.set('DISABLE_ORC', 1)
 269 endif
 270
 271 # Used to build SSE* things in audio-resampler
 272 sse_args = '-msse'
 273 sse2_args = '-msse2'
 274 sse41_args = '-msse4.1'
 275
 276 have_sse = cc.has_argument(sse_args)
 277 have_sse2 = cc.has_argument(sse2_args)
 278 have_sse41 = cc.has_argument(sse41_args)
 279
 280 if gst_dep.type_name() == 'internal'
 281     gst_proj = subproject('gstreamer')
 282
 283     if gst_proj.get_variable('disable_gst_debug')
 284         message('GStreamer debug system is disabled')
 285         add_project_arguments('-Wno-unused', language: 'c')
 286     else
 287         message('GStreamer debug system is enabled')
 288     endif
 289 else
 290     # We can't check that in the case of subprojects as we won't
 291     # be able to build against an internal dependency (which is not built yet)
 292     if not cc.compiles('''
 293 #include <gst/gstconfig.h>
 294 #ifdef GST_DISABLE_GST_DEBUG
 295 #error "debugging disabled, make compiler fail"
 296 #endif''' , dependencies: gst_dep)
 297         message('GStreamer debug system is disabled')
 298         add_project_arguments('-Wno-unused', language: 'c')
 299     else
 300         message('GStreamer debug system is enabled')
 301     endif
 302 endif
 303
 304 gir = find_program('g-ir-scanner', required : false)
 305 gnome = import('gnome')
 306 build_gir = gir.found() and not meson.is_cross_build() and not get_option('disable_introspection')
 307 gir_init_section = [ '--add-init-section=extern void gst_init(gint*,gchar**);' + \
 308     'g_setenv("GST_REGISTRY_DISABLE", "yes", TRUE);' + \
 309     'g_setenv("GST_REGISTRY_1.0", "@0@", TRUE);'.format(meson.current_build_dir() + '/gir_empty_registry.reg') + \
 310     'g_setenv("GST_PLUGIN_PATH_1_0", "", TRUE);' + \
 311     'g_setenv("GST_PLUGIN_SYSTEM_PATH_1_0", "", TRUE);' + \
 312     'gst_init(NULL,NULL);' ]
 313
 314 subdir('gst-libs')
 315 subdir('gst')
 316 subdir('ext')
 317 subdir('sys')
 318 subdir('tools')
 319 subdir('tests')
 320 subdir('pkgconfig')
 321
 322 # xgettext is optional (on Windows for instance)
 323 if find_program('xgettext', required : false).found()
 324   subdir('po')
 325 endif
 326
 327 if build_machine.system() == 'windows'
 328   message('Disabling gtk-doc while building on Windows')
 329 elif get_option('disable_gtkdoc')
 330   message('gtk-doc is disabled via options')
 331 else
 332   if find_program('gtkdoc-scan', required : false).found()
 333     subdir('docs')
 334   else
 335     message('Not building documentation as gtk-doc was not found')
 336   endif
 337 endif
 338
 339 # Use core_conf after all subdirs have set values
 340 configure_file(output : 'config.h', configuration : core_conf)
 341
 342 python3 = import('python3').find_python()
 343 run_command(python3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')