meson.build

   1 project(
   2     'libxkbcommon',
   3     'c',
   4     version: '1.2.1',
   5     default_options: [
   6         'c_std=c11',
   7         'warning_level=2',
   8         'b_lundef=true',
   9     ],
  10     meson_version : '>= 0.49.0',
  11 )
  12 pkgconfig = import('pkgconfig')
  13 cc = meson.get_compiler('c')
  14
  15 dir_libexec = get_option('prefix')/get_option('libexecdir')/'xkbcommon'
  16
  17 # Compiler flags.
  18 cflags = [
  19     '-fno-strict-aliasing',
  20     '-fsanitize-undefined-trap-on-error',
  21     '-Wno-unused-parameter',
  22     '-Wno-missing-field-initializers',
  23     '-Wpointer-arith',
  24     '-Wmissing-declarations',
  25     '-Wformat=2',
  26     '-Wstrict-prototypes',
  27     '-Wmissing-prototypes',
  28     '-Wnested-externs',
  29     '-Wbad-function-cast',
  30     '-Wshadow',
  31     '-Wlogical-op',
  32     '-Wdate-time',
  33     '-Wwrite-strings',
  34     '-Wno-documentation-deprecated-sync',
  35 ]
  36 add_project_arguments(cc.get_supported_arguments(cflags), language: 'c')
  37
  38
  39 # The XKB config root.
  40 XKBCONFIGROOT = get_option('xkb-config-root')
  41 if XKBCONFIGROOT == ''
  42     xkeyboard_config_dep = dependency('xkeyboard-config', required: false)
  43     if xkeyboard_config_dep.found()
  44         XKBCONFIGROOT = xkeyboard_config_dep.get_pkgconfig_variable('xkb_base')
  45     else
  46         XKBCONFIGROOT = get_option('prefix')/get_option('datadir')/'X11'/'xkb'
  47   endif
  48 endif
  49
  50 XKBCONFIGEXTRAPATH = get_option('xkb-config-extra-path')
  51 if XKBCONFIGEXTRAPATH == ''
  52     XKBCONFIGEXTRAPATH = get_option('prefix')/get_option('sysconfdir')/'xkb'
  53 endif
  54
  55 # The X locale directory for compose.
  56 XLOCALEDIR = get_option('x-locale-root')
  57 if XLOCALEDIR == ''
  58     XLOCALEDIR = get_option('prefix')/get_option('datadir')/'X11'/'locale'
  59 endif
  60
  61
  62 # config.h.
  63 configh_data = configuration_data()
  64 configh_data.set('EXIT_INVALID_USAGE', '2')
  65 configh_data.set_quoted('LIBXKBCOMMON_VERSION', meson.project_version())
  66 configh_data.set_quoted('LIBXKBCOMMON_TOOL_PATH', dir_libexec)
  67 # Like AC_USE_SYSTEM_EXTENSIONS, what #define to use to get extensions
  68 # beyond the base POSIX function set.
  69 if host_machine.system() == 'sunos'
  70   system_extensions = '__EXTENSIONS__'
  71 else
  72   system_extensions = '_GNU_SOURCE'
  73 endif
  74 configh_data.set(system_extensions, 1)
  75 system_ext_define = '#define ' + system_extensions
  76 configh_data.set_quoted('DFLT_XKB_CONFIG_ROOT', XKBCONFIGROOT)
  77 configh_data.set_quoted('DFLT_XKB_CONFIG_EXTRA_PATH', XKBCONFIGEXTRAPATH)
  78 configh_data.set_quoted('XLOCALEDIR', XLOCALEDIR)
  79 configh_data.set_quoted('DEFAULT_XKB_RULES', get_option('default-rules'))
  80 configh_data.set_quoted('DEFAULT_XKB_MODEL', get_option('default-model'))
  81 configh_data.set_quoted('DEFAULT_XKB_LAYOUT', get_option('default-layout'))
  82 if get_option('default-variant') != ''
  83     configh_data.set_quoted('DEFAULT_XKB_VARIANT', get_option('default-variant'))
  84 else
  85     configh_data.set('DEFAULT_XKB_VARIANT', 'NULL')
  86 endif
  87 if get_option('default-options') != ''
  88     configh_data.set_quoted('DEFAULT_XKB_OPTIONS', get_option('default-options'))
  89 else
  90     configh_data.set('DEFAULT_XKB_OPTIONS', 'NULL')
  91 endif
  92 if cc.has_header('unistd.h')
  93     configh_data.set('HAVE_UNISTD_H', 1)
  94 endif
  95 if cc.links('int main(){if(__builtin_expect(1<0,0)){}}', name: '__builtin_expect')
  96     configh_data.set('HAVE___BUILTIN_EXPECT', 1)
  97 endif
  98 if cc.has_header_symbol('unistd.h', 'eaccess', prefix: system_ext_define)
  99     configh_data.set('HAVE_EACCESS', 1)
 100 endif
 101 if cc.has_header_symbol('unistd.h', 'euidaccess', prefix: system_ext_define)
 102     configh_data.set('HAVE_EUIDACCESS', 1)
 103 endif
 104 if cc.has_header_symbol('sys/mman.h', 'mmap')
 105     configh_data.set('HAVE_MMAP', 1)
 106 endif
 107 if cc.has_header_symbol('stdlib.h', 'mkostemp', prefix: system_ext_define)
 108     configh_data.set('HAVE_MKOSTEMP', 1)
 109 endif
 110 if cc.has_header_symbol('fcntl.h', 'posix_fallocate', prefix: system_ext_define)
 111     configh_data.set('HAVE_POSIX_FALLOCATE', 1)
 112 endif
 113 if cc.has_header_symbol('string.h', 'strndup', prefix: system_ext_define)
 114     configh_data.set('HAVE_STRNDUP', 1)
 115 endif
 116 if cc.has_header_symbol('stdio.h', 'asprintf', prefix: system_ext_define)
 117     configh_data.set('HAVE_ASPRINTF', 1)
 118 elif cc.has_header_symbol('stdio.h', 'vasprintf', prefix: system_ext_define)
 119     configh_data.set('HAVE_VASPRINTF', 1)
 120 endif
 121 if cc.has_header_symbol('stdlib.h', 'secure_getenv', prefix: system_ext_define)
 122     configh_data.set('HAVE_SECURE_GETENV', 1)
 123 elif cc.has_header_symbol('stdlib.h', '__secure_getenv', prefix: system_ext_define)
 124     configh_data.set('HAVE___SECURE_GETENV', 1)
 125 else
 126     message('C library does not support secure_getenv, using getenv instead')
 127 endif
 128 have_getopt_long = cc.has_header_symbol('getopt.h', 'getopt_long',
 129                                         prefix: '#define _GNU_SOURCE')
 130 if not cc.has_header_symbol('limits.h', 'PATH_MAX', prefix: system_ext_define)
 131     if host_machine.system() == 'windows'
 132         # see https://docs.microsoft.com/en-us/windows/win32/fileio/naming-a-file#maximum-path-length-limitation
 133         configh_data.set('PATH_MAX', 260)
 134     else
 135         configh_data.set('PATH_MAX', 4096)
 136     endif
 137 endif
 138
 139 # Silence some security & deprecation warnings on MSVC
 140 # for some unix/C functions we use.
 141 # https://docs.microsoft.com/en-us/cpp/error-messages/compiler-warnings/compiler-warning-level-3-c4996?view=vs-2019
 142 configh_data.set('_CRT_SECURE_NO_WARNINGS', 1)
 143 configh_data.set('_CRT_NONSTDC_NO_WARNINGS', 1)
 144 configh_data.set('_CRT_NONSTDC_NO_DEPRECATE', 1)
 145 # Reduce unnecessary includes on MSVC.
 146 configh_data.set('WIN32_LEAN_AND_MEAN', 1)
 147
 148 # Supports -Wl,--version-script?
 149 have_version_script = cc.links(
 150     'int main(){}',
 151     args: '-Wl,--version-script=' + meson.source_root()/'xkbcommon.map',
 152     name: '-Wl,--version-script',
 153 )
 154
 155 map_to_def = find_program('scripts/map-to-def')
 156
 157 # libxkbcommon.
 158 # Note: we use some yacc extensions, which work with either GNU bison
 159 # (preferred) or byacc (with backtracking enabled).
 160 bison = find_program('bison', 'win_bison', required: false)
 161 if bison.found()
 162     yacc_gen = generator(
 163         bison,
 164         output: ['@BASENAME@.c', '@BASENAME@.h'],
 165         arguments: ['--defines=@OUTPUT1@', '-o', '@OUTPUT0@', '-p', '_xkbcommon_', '@INPUT@'],
 166     )
 167 else
 168     byacc = find_program('byacc', required: false)
 169     if byacc.found()
 170         yacc_gen = generator(
 171             byacc,
 172             output: ['@BASENAME@.c', '@BASENAME@.h'],
 173             arguments: ['-H', '@OUTPUT1@', '-o', '@OUTPUT0@', '-p', '_xkbcommon_', '@INPUT@'],
 174         )
 175     else
 176         error('Could not find a compatible YACC program (bison or byacc)')
 177     endif
 178 endif
 179 libxkbcommon_sources = [
 180     'src/compose/parser.c',
 181     'src/compose/parser.h',
 182     'src/compose/paths.c',
 183     'src/compose/paths.h',
 184     'src/compose/state.c',
 185     'src/compose/table.c',
 186     'src/compose/table.h',
 187     'src/xkbcomp/action.c',
 188     'src/xkbcomp/action.h',
 189     'src/xkbcomp/ast.h',
 190     'src/xkbcomp/ast-build.c',
 191     'src/xkbcomp/ast-build.h',
 192     'src/xkbcomp/compat.c',
 193     'src/xkbcomp/expr.c',
 194     'src/xkbcomp/expr.h',
 195     'src/xkbcomp/include.c',
 196     'src/xkbcomp/include.h',
 197     'src/xkbcomp/keycodes.c',
 198     'src/xkbcomp/keymap.c',
 199     'src/xkbcomp/keymap-dump.c',
 200     'src/xkbcomp/keywords.c',
 201     yacc_gen.process('src/xkbcomp/parser.y'),
 202     'src/xkbcomp/parser-priv.h',
 203     'src/xkbcomp/rules.c',
 204     'src/xkbcomp/rules.h',
 205     'src/xkbcomp/scanner.c',
 206     'src/xkbcomp/symbols.c',
 207     'src/xkbcomp/types.c',
 208     'src/xkbcomp/vmod.c',
 209     'src/xkbcomp/vmod.h',
 210     'src/xkbcomp/xkbcomp.c',
 211     'src/xkbcomp/xkbcomp-priv.h',
 212     'src/atom.c',
 213     'src/atom.h',
 214     'src/context.c',
 215     'src/context.h',
 216     'src/context-priv.c',
 217     'src/darray.h',
 218     'src/keysym.c',
 219     'src/keysym.h',
 220     'src/keysym-utf.c',
 221     'src/ks_tables.h',
 222     'src/keymap.c',
 223     'src/keymap.h',
 224     'src/keymap-priv.c',
 225     'src/scanner-utils.h',
 226     'src/state.c',
 227     'src/text.c',
 228     'src/text.h',
 229     'src/utf8.c',
 230     'src/utf8.h',
 231     'src/utils.c',
 232     'src/utils.h',
 233 ]
 234 libxkbcommon_link_args = []
 235 libxkbcommon_link_deps = []
 236 if have_version_script
 237     libxkbcommon_link_args += '-Wl,--version-script=' + meson.source_root()/'xkbcommon.map'
 238     libxkbcommon_link_deps += 'xkbcommon.map'
 239 elif cc.get_argument_syntax() == 'msvc'
 240     libxkbcommon_def = custom_target('xkbcommon.def',
 241         command: [map_to_def, '@INPUT@', '@OUTPUT@'],
 242         input: 'xkbcommon.map',
 243         output: 'kxbcommon.def',
 244     )
 245     libxkbcommon_link_deps += libxkbcommon_def
 246     libxkbcommon_link_args += '/DEF:' + libxkbcommon_def.full_path()
 247 endif
 248 libxkbcommon = library(
 249     'xkbcommon',
 250     'xkbcommon/xkbcommon.h',
 251     libxkbcommon_sources,
 252     link_args: libxkbcommon_link_args,
 253     link_depends: libxkbcommon_link_deps,
 254     gnu_symbol_visibility: 'hidden',
 255     version: '0.0.0',
 256     install: true,
 257     include_directories: include_directories('src'),
 258 )
 259 install_headers(
 260     'xkbcommon/xkbcommon.h',
 261     'xkbcommon/xkbcommon-compat.h',
 262     'xkbcommon/xkbcommon-compose.h',
 263     'xkbcommon/xkbcommon-keysyms.h',
 264     'xkbcommon/xkbcommon-names.h',
 265     subdir: 'xkbcommon',
 266 )
 267
 268 # This variable may be used to build as a subproject and should not be renamed.
 269 libxkbcommon_dep = declare_dependency(
 270     link_with: libxkbcommon,
 271     include_directories: include_directories('.'),
 272 )
 273 pkgconfig.generate(
 274     libxkbcommon,
 275     name: 'xkbcommon',
 276     filebase: 'xkbcommon',
 277     version: meson.project_version(),
 278     description: 'XKB API common to servers and clients',
 279 )
 280
 281
 282 # libxkbcommon-x11.
 283 if get_option('enable-x11')
 284     xcb_dep = dependency('xcb', version: '>=1.10', required: false)
 285     xcb_xkb_dep = dependency('xcb-xkb', version: '>=1.10', required: false)
 286     if not xcb_dep.found() or not xcb_xkb_dep.found()
 287         error('''X11 support requires xcb-xkb >= 1.10 which was not found.
 288 You can disable X11 support with -Denable-x11=false.''')
 289     endif
 290
 291     libxkbcommon_x11_sources = [
 292         'src/x11/keymap.c',
 293         'src/x11/state.c',
 294         'src/x11/util.c',
 295         'src/x11/x11-priv.h',
 296         'src/context.h',
 297         'src/context-priv.c',
 298         'src/keymap.h',
 299         'src/keymap-priv.c',
 300         'src/atom.h',
 301         'src/atom.c',
 302     ]
 303     libxkbcommon_x11_link_args = []
 304     libxkbcommon_x11_link_deps = []
 305     if have_version_script
 306         libxkbcommon_x11_link_args += '-Wl,--version-script=' + meson.source_root()/'xkbcommon-x11.map'
 307         libxkbcommon_x11_link_deps += 'xkbcommon-x11.map'
 308     elif cc.get_argument_syntax() == 'msvc'
 309         libxkbcommon_x11_def = custom_target('xkbcommon-x11.def',
 310             command: [map_to_def, '@INPUT@', '@OUTPUT@'],
 311             input: 'xkbcommon-x11.map',
 312             output: 'xkbcommon-x11.def',
 313         )
 314         libxkbcommon_x11_link_deps += libxkbcommon_x11_def
 315         libxkbcommon_x11_link_args += '/DEF:' + libxkbcommon_x11_def.full_path()
 316     endif
 317     libxkbcommon_x11 = library(
 318         'xkbcommon-x11',
 319         'xkbcommon/xkbcommon-x11.h',
 320         libxkbcommon_x11_sources,
 321         link_args: libxkbcommon_x11_link_args,
 322         link_depends: libxkbcommon_x11_link_deps,
 323         gnu_symbol_visibility: 'hidden',
 324         version: '0.0.0',
 325         install: true,
 326         include_directories: include_directories('src'),
 327         link_with: libxkbcommon,
 328         dependencies: [
 329             xcb_dep,
 330             xcb_xkb_dep,
 331         ],
 332     )
 333     install_headers(
 334         'xkbcommon/xkbcommon-x11.h',
 335         subdir: 'xkbcommon',
 336     )
 337     # This variable may be used to build as a subproject and should not be renamed.
 338     libxkbcommon_x11_dep = declare_dependency(
 339         link_with: libxkbcommon_x11,
 340         include_directories: include_directories('.'),
 341     )
 342     pkgconfig.generate(
 343         libxkbcommon_x11,
 344         name: 'xkbcommon-x11',
 345         filebase: 'xkbcommon-x11',
 346         version: meson.project_version(),
 347         description: 'XKB API common to servers and clients - X11 support',
 348         requires: ['xkbcommon'],
 349         requires_private: ['xcb>=1.10', 'xcb-xkb>=1.10'],
 350     )
 351 endif
 352
 353 # libxkbregistry
 354 if get_option('enable-xkbregistry')
 355     dep_libxml = dependency('libxml-2.0')
 356     deps_libxkbregistry = [dep_libxml]
 357     libxkbregistry_sources = [
 358         'src/registry.c',
 359         'src/utils.h',
 360         'src/utils.c',
 361         'src/util-list.h',
 362         'src/util-list.c',
 363     ]
 364     libxkbregistry_link_args = []
 365     libxkbregistry_link_deps = []
 366     if have_version_script
 367         libxkbregistry_link_args += '-Wl,--version-script=' + meson.source_root()/'xkbregistry.map'
 368         libxkbregistry_link_deps += 'xkbregistry.map'
 369     elif cc.get_argument_syntax() == 'msvc'
 370         libxkbregistry_def = custom_target('xkbregistry.def',
 371             command: [map_to_def, '@INPUT@', '@OUTPUT@'],
 372             input: 'xkbregistry.map',
 373             output: 'xkbregistry.def',
 374         )
 375         libxkbregistry_link_deps += libxkbregistry_def
 376         libxkbregistry_link_args += '/DEF:' + libxkbregistry_def.full_path()
 377     endif
 378     libxkbregistry = library(
 379         'xkbregistry',
 380         'xkbcommon/xkbregistry.h',
 381         libxkbregistry_sources,
 382         link_args: libxkbregistry_link_args,
 383         link_depends: libxkbregistry_link_deps,
 384         gnu_symbol_visibility: 'hidden',
 385         dependencies: deps_libxkbregistry,
 386         version: '0.0.0',
 387         install: true,
 388         include_directories: include_directories('src'),
 389     )
 390     install_headers(
 391         'xkbcommon/xkbregistry.h',
 392         subdir: 'xkbcommon',
 393     )
 394     pkgconfig.generate(
 395         libxkbregistry,
 396         name: 'xkbregistry',
 397         filebase: 'xkbregistry',
 398         version: meson.project_version(),
 399         description: 'XKB API to query available rules, models, layouts, variants and options',
 400     )
 401
 402     # This variable may be used to build as a subproject and should not be renamed.
 403     libxkbregistry_dep = declare_dependency(
 404                                 include_directories: include_directories('.'),
 405                                 link_with: libxkbregistry
 406                                 )
 407 endif
 408
 409 man_pages = []
 410
 411 # Tools
 412 build_tools = have_getopt_long
 413 if build_tools
 414     libxkbcommon_tools_internal = static_library(
 415         'tools-internal',
 416         'tools/tools-common.h',
 417         'tools/tools-common.c',
 418         dependencies: libxkbcommon_dep,
 419     )
 420     tools_dep = declare_dependency(
 421         include_directories: [include_directories('tools')],
 422         link_with: libxkbcommon_tools_internal,
 423     )
 424
 425     executable('xkbcli', 'tools/xkbcli.c',
 426                dependencies: tools_dep, install: true)
 427     install_man('tools/xkbcli.1')
 428
 429     xkbcli_compile_keymap = executable('xkbcli-compile-keymap',
 430                                        'tools/compile-keymap.c',
 431                                        dependencies: tools_dep,
 432                                        install: true,
 433                                        install_dir: dir_libexec)
 434     install_man('tools/xkbcli-compile-keymap.1')
 435     # The same tool again, but with access to some private APIs.
 436     executable('compile-keymap',
 437                'tools/compile-keymap.c',
 438                libxkbcommon_sources,
 439                dependencies: [tools_dep],
 440                c_args: ['-DENABLE_PRIVATE_APIS'],
 441                include_directories: [include_directories('src')],
 442                install: false)
 443     configh_data.set10('HAVE_XKBCLI_COMPILE_KEYMAP', true)
 444     executable('xkbcli-how-to-type',
 445                'tools/how-to-type.c',
 446                dependencies: tools_dep,
 447                install: true,
 448                install_dir: dir_libexec)
 449     install_man('tools/xkbcli-how-to-type.1')
 450     configh_data.set10('HAVE_XKBCLI_HOW_TO_TYPE', true)
 451     if cc.has_header('linux/input.h')
 452         executable('xkbcli-interactive-evdev',
 453                    'tools/interactive-evdev.c',
 454                    dependencies: tools_dep,
 455                    install: true,
 456                    install_dir: dir_libexec)
 457         configh_data.set10('HAVE_XKBCLI_INTERACTIVE_EVDEV', true)
 458         install_man('tools/xkbcli-interactive-evdev.1')
 459     endif
 460     if get_option('enable-x11')
 461         x11_tools_dep = declare_dependency(
 462             link_with: libxkbcommon_x11,
 463             dependencies: [
 464                 tools_dep,
 465                 xcb_dep,
 466                 xcb_xkb_dep,
 467             ],
 468         )
 469         executable('xkbcli-interactive-x11',
 470                    'tools/interactive-x11.c',
 471                    dependencies: x11_tools_dep,
 472                    install: true,
 473                    install_dir: dir_libexec)
 474         install_man('tools/xkbcli-interactive-x11.1')
 475         configh_data.set10('HAVE_XKBCLI_INTERACTIVE_X11', true)
 476     endif
 477     if get_option('enable-wayland')
 478         wayland_client_dep = dependency('wayland-client', version: '>=1.2.0', required: false)
 479         wayland_protocols_dep = dependency('wayland-protocols', version: '>=1.12', required: false)
 480         wayland_scanner_dep = dependency('wayland-scanner', required: false, native: true)
 481         if not wayland_client_dep.found() or not wayland_protocols_dep.found() or not wayland_scanner_dep.found()
 482             error('''The Wayland xkbcli programs require wayland-client >= 1.2.0, wayland-protocols >= 1.7 which were not found.
 483 You can disable the Wayland xkbcli programs with -Denable-wayland=false.''')
 484         endif
 485
 486         wayland_scanner = find_program(wayland_scanner_dep.get_pkgconfig_variable('wayland_scanner'))
 487         wayland_scanner_code_gen = generator(
 488             wayland_scanner,
 489             output: '@BASENAME@-protocol.c',
 490             arguments: ['code', '@INPUT@', '@OUTPUT@'],
 491         )
 492         wayland_scanner_client_header_gen = generator(
 493             wayland_scanner,
 494             output: '@BASENAME@-client-protocol.h',
 495             arguments: ['client-header', '@INPUT@', '@OUTPUT@'],
 496         )
 497         wayland_protocols_datadir = wayland_protocols_dep.get_pkgconfig_variable('pkgdatadir')
 498         xdg_shell_xml = wayland_protocols_datadir/'stable/xdg-shell/xdg-shell.xml'
 499         xdg_shell_sources = [
 500             wayland_scanner_code_gen.process(xdg_shell_xml),
 501             wayland_scanner_client_header_gen.process(xdg_shell_xml),
 502         ]
 503         executable('xkbcli-interactive-wayland',
 504                    'tools/interactive-wayland.c',
 505                    xdg_shell_sources,
 506                    dependencies: [tools_dep, wayland_client_dep],
 507                    install: true,
 508                    install_dir: dir_libexec)
 509         install_man('tools/xkbcli-interactive-wayland.1')
 510         configh_data.set10('HAVE_XKBCLI_INTERACTIVE_WAYLAND', true)
 511     endif
 512
 513     if get_option('enable-xkbregistry')
 514         configh_data.set10('HAVE_XKBCLI_LIST', true)
 515         executable('xkbcli-list',
 516                    'tools/registry-list.c',
 517                    dependencies: libxkbregistry_dep,
 518                    install: true,
 519                    install_dir: dir_libexec)
 520         install_man('tools/xkbcli-list.1')
 521     endif
 522 endif
 523
 524
 525 # xkeyboard-config "verifier"
 526 xkct_config = configuration_data()
 527 xkct_config.set('MESON_BUILD_ROOT', meson.build_root())
 528 xkct_config.set('XKB_CONFIG_ROOT', XKBCONFIGROOT)
 529 configure_file(input: 'test/xkeyboard-config-test.py.in',
 530                output: 'xkeyboard-config-test',
 531                configuration: xkct_config)
 532
 533 # Tests
 534 test_env = environment()
 535 test_env.set('XKB_LOG_LEVEL', 'debug')
 536 test_env.set('XKB_LOG_VERBOSITY', '10')
 537 test_env.set('top_srcdir', meson.source_root())
 538 test_env.set('top_builddir', meson.build_root())
 539 test_env.set('HAVE_XKBCLI_INTERACTIVE_EVDEV', configh_data.get('HAVE_XKBCLI_INTERACTIVE_EVDEV', 0).to_string())
 540 test_env.set('HAVE_XKBCLI_INTERACTIVE_WAYLAND', configh_data.get('HAVE_XKBCLI_INTERACTIVE_WAYLAND', 0).to_string())
 541 test_env.set('HAVE_XKBCLI_INTERACTIVE_X11', configh_data.get('HAVE_XKBCLI_INTERACTIVE_X11', 0).to_string())
 542 test_env.set('HAVE_XKBCLI_LIST', configh_data.get('HAVE_XKBCLI_LIST', 0).to_string())
 543
 544 test_configh_data = configuration_data()
 545 test_configh_data.set_quoted('TEST_XKB_CONFIG_ROOT', meson.source_root()/'test'/'data')
 546 configure_file(output: 'test-config.h', configuration: test_configh_data)
 547
 548 # Some tests need to use unexported symbols, so we link them against
 549 # an internal copy of libxkbcommon with all symbols exposed.
 550 libxkbcommon_test_internal = static_library(
 551     'xkbcommon-test-internal',
 552     'test/common.c',
 553     'test/test.h',
 554     'test/evdev-scancodes.h',
 555     'bench/bench.c',
 556     'bench/bench.h',
 557     libxkbcommon_sources,
 558     include_directories: include_directories('src'),
 559 )
 560 test_dep = declare_dependency(
 561     include_directories: include_directories('src'),
 562     link_with: libxkbcommon_test_internal,
 563 )
 564 if get_option('enable-x11')
 565     libxkbcommon_x11_internal = static_library(
 566         'xkbcommon-x11-internal',
 567         libxkbcommon_x11_sources,
 568         include_directories: include_directories('src'),
 569         link_with: libxkbcommon_test_internal,
 570         dependencies: [
 571             xcb_dep,
 572             xcb_xkb_dep,
 573         ],
 574     )
 575     x11_test_dep = declare_dependency(
 576         link_with: libxkbcommon_x11_internal,
 577         dependencies: [
 578             test_dep,
 579             xcb_dep,
 580             xcb_xkb_dep,
 581         ],
 582     )
 583 endif
 584 test(
 585     'keysym',
 586     executable('test-keysym', 'test/keysym.c', dependencies: test_dep),
 587     env: test_env,
 588 )
 589 test(
 590     'keymap',
 591     executable('test-keymap', 'test/keymap.c', dependencies: test_dep),
 592     env: test_env,
 593 )
 594 test(
 595     'filecomp',
 596     executable('test-filecomp', 'test/filecomp.c', dependencies: test_dep),
 597     env: test_env,
 598 )
 599 # TODO: This test currently uses some functions that don't exist on Windows.
 600 if cc.get_id() != 'msvc'
 601   test(
 602       'context',
 603       executable('test-context', 'test/context.c', dependencies: test_dep),
 604       env: test_env,
 605   )
 606 endif
 607 test(
 608     'rules-file',
 609     executable('test-rules-file', 'test/rules-file.c', dependencies: test_dep),
 610     env: test_env,
 611 )
 612 test(
 613     'rules-file-includes',
 614     executable('test-rules-file-includes', 'test/rules-file-includes.c', dependencies: test_dep),
 615     env: test_env,
 616 )
 617 test(
 618     'stringcomp',
 619     executable('test-stringcomp', 'test/stringcomp.c', dependencies: test_dep),
 620     env: test_env,
 621 )
 622 test(
 623     'buffercomp',
 624     executable('test-buffercomp', 'test/buffercomp.c', dependencies: test_dep),
 625     env: test_env,
 626 )
 627 test(
 628     'log',
 629     executable('test-log', 'test/log.c', dependencies: test_dep),
 630     env: test_env,
 631 )
 632 test(
 633     'atom',
 634     executable('test-atom', 'test/atom.c', dependencies: test_dep),
 635     env: test_env,
 636 )
 637 test(
 638     'utf8',
 639     executable('test-utf8', 'test/utf8.c', dependencies: test_dep),
 640     env: test_env,
 641 )
 642 test(
 643     'state',
 644     executable('test-state', 'test/state.c', dependencies: test_dep),
 645     env: test_env,
 646 )
 647 test(
 648     'keyseq',
 649     executable('test-keyseq', 'test/keyseq.c', dependencies: test_dep),
 650     env: test_env,
 651 )
 652 test(
 653     'rulescomp',
 654     executable('test-rulescomp', 'test/rulescomp.c', dependencies: test_dep),
 655     env: test_env,
 656 )
 657 test(
 658     'compose',
 659     executable('test-compose', 'test/compose.c', dependencies: test_dep),
 660     env: test_env,
 661 )
 662 test(
 663     'utils',
 664     executable('test-utils', 'test/utils.c', dependencies: test_dep),
 665     env: test_env,
 666 )
 667 test(
 668     'symbols-leak-test',
 669     find_program('test/symbols-leak-test.py'),
 670     env: test_env,
 671     suite: ['python-tests'],
 672 )
 673 if get_option('enable-x11')
 674     test(
 675         'x11',
 676         executable('test-x11', 'test/x11.c', dependencies: x11_test_dep),
 677         env: test_env,
 678     )
 679     # test/x11comp is meant to be run, but it is (temporarily?) disabled.
 680     # See: https://github.com/xkbcommon/libxkbcommon/issues/30
 681     executable('test-x11comp', 'test/x11comp.c', dependencies: x11_test_dep)
 682 endif
 683 if get_option('enable-xkbregistry')
 684     test(
 685         'registry',
 686         executable('test-registry', 'test/registry.c',
 687                    include_directories: include_directories('src'),
 688                    dependencies: libxkbregistry_dep),
 689         env: test_env,
 690     )
 691 endif
 692 if build_tools
 693     test('tool-option-parsing',
 694          find_program('test/tool-option-parsing.py'),
 695          env: test_env,
 696          suite: ['python-tests'])
 697
 698     # A set of keysyms to test for. Add one or two symbols to this array
 699     # whenever the xorgproto gets updated to make sure we resolve them.
 700     keysyms_to_test = [
 701         'XF86Macro23',
 702     ]
 703
 704     env = environment()
 705     env.set('XKB_CONFIG_ROOT', meson.source_root()/'test'/'data')
 706     foreach keysym: keysyms_to_test
 707         test('keysym-test-@0@'.format(keysym),
 708              find_program('test/test-keysym.py'),
 709              env: env,
 710              args: [keysym, '--tool', xkbcli_compile_keymap],
 711              suite: ['python-tests'])
 712     endforeach
 713 endif
 714
 715 valgrind = find_program('valgrind', required: false)
 716 if valgrind.found()
 717     add_test_setup('valgrind',
 718         exe_wrapper: [valgrind,
 719                        '--leak-check=full',
 720                        '--track-origins=yes',
 721                        '--gen-suppressions=all',
 722                        '--error-exitcode=99'],
 723         timeout_multiplier : 10)
 724 else
 725     message('valgrind not found, disabling valgrind test setup')
 726 endif
 727
 728
 729 # Fuzzing target programs.
 730 executable('fuzz-keymap', 'fuzz/keymap/target.c', dependencies: test_dep)
 731 executable('fuzz-compose', 'fuzz/compose/target.c', dependencies: test_dep)
 732
 733
 734 # Benchmarks.
 735 bench_env = environment()
 736 bench_env.set('top_srcdir', meson.source_root())
 737 benchmark(
 738     'key-proc',
 739     executable('bench-key-proc', 'bench/key-proc.c', dependencies: test_dep),
 740     env: bench_env,
 741 )
 742 benchmark(
 743     'rules',
 744     executable('bench-rules', 'bench/rules.c', dependencies: test_dep),
 745     env: bench_env,
 746 )
 747 benchmark(
 748     'rulescomp',
 749     executable('bench-rulescomp', 'bench/rulescomp.c', dependencies: test_dep),
 750     env: bench_env,
 751 )
 752 benchmark(
 753     'compose',
 754     executable('bench-compose', 'bench/compose.c', dependencies: test_dep),
 755     env: bench_env,
 756 )
 757 if get_option('enable-x11')
 758   benchmark(
 759       'x11',
 760       executable('bench-x11', 'bench/x11.c', dependencies: x11_test_dep),
 761       env: bench_env,
 762   )
 763 endif
 764
 765
 766 # Documentation.
 767 if get_option('enable-docs')
 768     doxygen = find_program('doxygen', required: false)
 769     if not doxygen.found()
 770         error('''Documentation requires doxygen which was not found.
 771 You can disable the documentation with -Denable-docs=false.''')
 772     endif
 773     doxygen_wrapper = find_program('scripts/doxygen-wrapper')
 774
 775     doxygen_input = [
 776         'README.md',
 777         'doc/doxygen-extra.css',
 778         'doc/quick-guide.md',
 779         'doc/compat.md',
 780         'doc/user-configuration.md',
 781         'doc/rules-format.md',
 782         'doc/keymap-format-text-v1.md',
 783         'xkbcommon/xkbcommon.h',
 784         'xkbcommon/xkbcommon-names.h',
 785         'xkbcommon/xkbcommon-x11.h',
 786         'xkbcommon/xkbcommon-compose.h',
 787         'xkbcommon/xkbregistry.h',
 788     ]
 789     doxygen_data = configuration_data()
 790     doxygen_data.set('PACKAGE_NAME', meson.project_name())
 791     doxygen_data.set('PACKAGE_VERSION', meson.project_version())
 792     doxygen_data.set('INPUT', ' '.join(doxygen_input))
 793     doxygen_data.set('OUTPUT_DIRECTORY', meson.build_root())
 794     doxyfile = configure_file(
 795         input: 'doc/Doxyfile.in',
 796         output: 'Doxyfile',
 797         configuration: doxygen_data,
 798     )
 799     # TODO: Meson should provide this.
 800     docdir = get_option('datadir')/'doc'/meson.project_name()
 801     custom_target(
 802         'doc',
 803         input: [doxyfile] + doxygen_input,
 804         output: 'html',
 805         command: [doxygen_wrapper, doxygen.path(), meson.build_root()/'Doxyfile', meson.source_root()],
 806         install: true,
 807         install_dir: docdir,
 808         build_by_default: true,
 809     )
 810 endif
 811
 812 configure_file(output: 'config.h', configuration: configh_data)