meson.build

   1 project('gst-plugins-good', 'c',
   2   version : '1.13.0.1',
   3   meson_version : '>= 0.36.0',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0]
  10 gst_version_minor = version_arr[1]
  11 gst_version_micro = version_arr[2]
  12 if version_arr.length() == 4
  13   gst_version_nano = version_arr[3]
  14 else
  15   gst_version_nano = 0
  16 endif
  17
  18 glib_req = '>= 2.40.0'
  19 gst_req = '>= @0@.@1@.0'.format(gst_version_major, gst_version_minor)
  20
  21 api_version = '1.0'
  22
  23 plugins_install_dir = '@0@/gstreamer-1.0'.format(get_option('libdir'))
  24
  25 cc = meson.get_compiler('c')
  26
  27 if cc.get_id() == 'msvc'
  28   # Ignore several spurious warnings for things gstreamer does very commonly
  29   # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  30   # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  31   # NOTE: Only add warnings here if you are sure they're spurious
  32   add_project_arguments(
  33       '/wd4018', # implicit signed/unsigned conversion
  34       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  35       '/wd4244', # lossy type conversion (e.g. double -> int)
  36       '/wd4305', # truncating type conversion (e.g. double -> float)
  37       language : 'c')
  38   # Disable SAFESEH with MSVC for plugins and libs that use external deps that
  39   # are built with MinGW
  40   noseh_link_args = ['/SAFESEH:NO']
  41 else
  42   noseh_link_args = []
  43 endif
  44
  45 # Symbol visibility
  46 if cc.has_argument('-fvisibility=hidden')
  47   add_project_arguments('-fvisibility=hidden', language: 'c')
  48 endif
  49
  50 cdata = configuration_data()
  51
  52 check_headers = [
  53   ['HAVE_DLFCN_H', 'dlfcn.h'],
  54   ['HAVE_FCNTL_H', 'fcntl.h'],
  55   ['HAVE_INTTYPES_H', 'inttypes.h'],
  56   ['HAVE_MEMORY_H', 'memory.h'],
  57   ['HAVE_PROCESS_H', 'process.h'],
  58   ['HAVE_STDINT_H', 'stdint.h'],
  59   ['HAVE_STDLIB_H', 'stdlib.h'],
  60   ['HAVE_STRINGS_H', 'strings.h'],
  61   ['HAVE_STRING_H', 'string.h'],
  62   ['HAVE_SYS_IOCTL_H', 'sys/ioctl.h'],
  63   ['HAVE_SYS_PARAM_H', 'sys/param.h'],
  64   ['HAVE_SYS_SOCKET_H', 'sys/socket.h'],
  65   ['HAVE_SYS_STAT_H', 'sys/stat.h'],
  66   ['HAVE_SYS_TIME_H', 'sys/time.h'],
  67   ['HAVE_SYS_TYPES_H', 'sys/types.h'],
  68   ['HAVE_UNISTD_H', 'unistd.h'],
  69 ]
  70
  71 foreach h : check_headers
  72   if cc.has_header(h.get(1))
  73     cdata.set(h.get(0), 1)
  74   endif
  75 endforeach
  76
  77 check_functions = [
  78   ['HAVE_ASINH', 'asinh', '#include<math.h>'],
  79   ['HAVE_CLOCK_GETTIME', 'clock_gettime', '#include<time.h>'],
  80   ['HAVE_COSH', 'cosh', '#include<math.h>'],
  81 # check token HAVE_CPU_ALPHA
  82 # check token HAVE_CPU_ARM
  83 # check token HAVE_CPU_CRIS
  84 # check token HAVE_CPU_CRISV32
  85 # check token HAVE_CPU_HPPA
  86 # check token HAVE_CPU_I386
  87 # check token HAVE_CPU_IA64
  88 # check token HAVE_CPU_M68K
  89 # check token HAVE_CPU_MIPS
  90 # check token HAVE_CPU_PPC
  91 # check token HAVE_CPU_PPC64
  92 # check token HAVE_CPU_S390
  93 # check token HAVE_CPU_SPARC
  94 # check token HAVE_CPU_X86_64
  95   ['HAVE_DCGETTEXT', 'dcgettext', '#include<libintl.h>'],
  96 # check token HAVE_DIRECTSOUND
  97 # check token HAVE_EXPERIMENTAL
  98 # check token HAVE_EXTERNAL
  99 # check token HAVE_FPCLASS
 100 # check token HAVE_GCC_ASM
 101   ['HAVE_GETPAGESIZE', 'getpagesize', '#include<unistd.h>'],
 102 # check token HAVE_GETTEXT
 103 # check token HAVE_GST_V4L2
 104 # check token HAVE_IOS
 105   ['HAVE_ISINF', 'isinf', '#include<math.h>'],
 106 # check token HAVE_LIBV4L2
 107   ['HAVE_MMAP', 'mmap', '#include<sys/mman.h>'],
 108   ['HAVE_MMAP64', 'mmap64', '#include<sys/mman.h>'],
 109 # check token HAVE_OSX_AUDIO
 110 # check token HAVE_OSX_VIDEO
 111 # check token HAVE_RDTSC
 112   ['HAVE_SINH', 'sinh', '#include<math.h>'],
 113 # check token HAVE_WAVEFORM
 114 ]
 115
 116 libm = cc.find_library('m', required : false)
 117
 118 foreach f : check_functions
 119   if cc.has_function(f.get(1), prefix : f.get(2), dependencies : libm)
 120     cdata.set(f.get(0), 1)
 121   endif
 122 endforeach
 123
 124 cdata.set('SIZEOF_CHAR', cc.sizeof('char'))
 125 cdata.set('SIZEOF_INT', cc.sizeof('int'))
 126 cdata.set('SIZEOF_LONG', cc.sizeof('long'))
 127 cdata.set('SIZEOF_SHORT', cc.sizeof('short'))
 128 cdata.set('SIZEOF_VOIDP', cc.sizeof('void*'))
 129 cdata.set('SIZEOF_OFF_T', cc.sizeof('off_t'))
 130
 131 # Here be fixmes.
 132 # FIXME: check if this is correct
 133 cdata.set('HAVE_CPU_X86_64', host_machine.cpu() == 'amd64')
 134 cdata.set('HAVE_GCC_ASM', cc.get_id() != 'msvc')
 135 cdata.set('VERSION', '"@0@"'.format(gst_version))
 136 cdata.set('PACKAGE_VERSION', '"@0@"'.format(gst_version))
 137 cdata.set('GST_LICENSE', '"LGPL"')
 138 cdata.set('PACKAGE', '"gst-plugins-good"')
 139 cdata.set('GETTEXT_PACKAGE', '"gst-plugins-good-1.0"')
 140
 141 # GStreamer package name and origin url
 142 gst_package_name = get_option('with-package-name')
 143 if gst_package_name == ''
 144   if gst_version_nano == 0
 145     gst_package_name = 'GStreamer Good Plug-ins source release'
 146   elif gst_version_nano == 1
 147     gst_package_name = 'GStreamer Good Plug-ins git'
 148   else
 149     gst_package_name = 'GStreamer Good Plug-ins prerelease'
 150   endif
 151 endif
 152 cdata.set_quoted('GST_PACKAGE_NAME', gst_package_name)
 153 cdata.set_quoted('GST_PACKAGE_ORIGIN', get_option('with-package-origin'))
 154
 155 # Mandatory GST deps
 156 gst_dep = dependency('gstreamer-1.0', version : gst_req,
 157   fallback : ['gstreamer', 'gst_dep'])
 158 gstbase_dep = dependency('gstreamer-base-1.0', version : gst_req,
 159   fallback : ['gstreamer', 'gst_base_dep'])
 160 gstnet_dep = dependency('gstreamer-net-1.0', version : gst_req,
 161   fallback : ['gstreamer', 'gst_net_dep'])
 162 if host_machine.system() != 'windows'
 163   gstcheck_dep = dependency('gstreamer-check-1.0', version : gst_req,
 164     fallback : ['gstreamer', 'gst_check_dep'])
 165 endif
 166 gstcontroller_dep = dependency('gstreamer-controller-1.0', version : gst_req,
 167   fallback : ['gstreamer', 'gst_controller_dep'])
 168
 169 gstpbutils_dep = dependency('gstreamer-pbutils-1.0', version : gst_req,
 170     fallback : ['gst-plugins-base', 'pbutils_dep'])
 171 gstallocators_dep = dependency('gstreamer-allocators-1.0', version : gst_req,
 172     fallback : ['gst-plugins-base', 'allocators_dep'])
 173 gstapp_dep = dependency('gstreamer-app-1.0', version : gst_req,
 174     fallback : ['gst-plugins-base', 'app_dep'])
 175 gstaudio_dep = dependency('gstreamer-audio-1.0', version : gst_req,
 176     fallback : ['gst-plugins-base', 'audio_dep'])
 177 gstfft_dep = dependency('gstreamer-fft-1.0', version : gst_req,
 178     fallback : ['gst-plugins-base', 'fft_dep'])
 179 gstriff_dep = dependency('gstreamer-riff-1.0', version : gst_req,
 180     fallback : ['gst-plugins-base', 'riff_dep'])
 181 gstrtp_dep = dependency('gstreamer-rtp-1.0', version : gst_req,
 182     fallback : ['gst-plugins-base', 'rtp_dep'])
 183 gstrtsp_dep = dependency('gstreamer-rtsp-1.0', version : gst_req,
 184     fallback : ['gst-plugins-base', 'rtsp_dep'])
 185 gstsdp_dep = dependency('gstreamer-sdp-1.0', version : gst_req,
 186     fallback : ['gst-plugins-base', 'sdp_dep'])
 187 gsttag_dep = dependency('gstreamer-tag-1.0', version : gst_req,
 188     fallback : ['gst-plugins-base', 'tag_dep'])
 189 gstvideo_dep = dependency('gstreamer-video-1.0', version : gst_req,
 190     fallback : ['gst-plugins-base', 'video_dep'])
 191
 192 zlib_dep = dependency('zlib')
 193 bz2lib = cc.find_library('bz2', required : false)
 194 glib_deps = [dependency('glib-2.0', version : glib_req, fallback: ['glib', 'libglib_dep']),
 195              dependency('gobject-2.0', fallback: ['glib', 'libgobject_dep'])]
 196 gio_dep = dependency('gio-2.0', fallback: ['glib', 'libgio_dep'])
 197
 198 cdata.set('HAVE_ZLIB', 1)
 199 if bz2lib.found()
 200   cdata.set('HAVE_BZ2', 1)
 201 endif
 202
 203 # Check all of the things.
 204 # TODO: None of these are actually used yet because
 205 # the build files haven't been written
 206 deps = [
 207   ['gtk_dep','gtk+-3.0', '', ''],
 208   ['gtkx_dep','gtk+-x11-3.0', '', ''],
 209   ['caca_dep','caca', '', ''],
 210   ['libraw1394_dep','libraw1394', '>=2.0.0', ''],
 211   ['libiec61883_dep','libiec61883', '>=1.0.0', ''],
 212 ]
 213
 214 foreach d : deps
 215   varname = d[0]
 216   depname = d[1]
 217   version = d[2]
 218   confhname = d[3]
 219   if version == ''
 220     curdep = dependency(depname, required : false)
 221   else
 222     curdep = dependency(depname, required : false, version : version)
 223   endif
 224   set_variable(varname, curdep)
 225   if curdep.found() and confhname != ''
 226     cdata.set(confhname, 1)
 227   endif
 228 endforeach
 229
 230 gst_plugins_good_args = ['-DHAVE_CONFIG_H']
 231 configinc = include_directories('.')
 232 libsinc = include_directories('gst-libs')
 233
 234 have_orcc = false
 235 orcc_args = []
 236 if get_option('use_orc') != 'no'
 237   need_orc = get_option('use_orc') == 'yes'
 238   # Used by various libraries/elements that use Orc code
 239   orc_dep = dependency('orc-0.4', version : '>= 0.4.17', required : need_orc)
 240   orcc = find_program('orcc', required : need_orc)
 241   if orc_dep.found() and orcc.found()
 242     have_orcc = true
 243     orcc_args = [orcc, '--include', 'glib.h']
 244     cdata.set('HAVE_ORC', 1)
 245   else
 246     message('Orc Compiler not found, will use backup C code')
 247     cdata.set('DISABLE_ORC', 1)
 248   endif
 249 else
 250   cdata.set('DISABLE_ORC', 1)
 251 endif
 252
 253 if gst_dep.type_name() == 'internal'
 254     gst_proj = subproject('gstreamer')
 255
 256     if gst_proj.get_variable('disable_gst_debug')
 257         message('GStreamer debug system is disabled')
 258         add_project_arguments('-Wno-unused', language: 'c')
 259     else
 260         message('GStreamer debug system is enabled')
 261     endif
 262 else
 263     # We can't check that in the case of subprojects as we won't
 264     # be able to build against an internal dependency (which is not built yet)
 265     if not cc.compiles('''
 266 #include <gst/gstconfig.h>
 267 #ifdef GST_DISABLE_GST_DEBUG
 268 #error "debugging disabled, make compiler fail"
 269 #endif''' , dependencies: gst_dep)
 270         message('GStreamer debug system is disabled')
 271         add_project_arguments('-Wno-unused', language: 'c')
 272     else
 273         message('GStreamer debug system is enabled')
 274     endif
 275 endif
 276
 277 presetdir = join_paths(get_option('datadir'), 'gstreamer-' + api_version, 'presets')
 278
 279 subdir('gst')
 280 subdir('sys')
 281 subdir('ext')
 282 subdir('tests')
 283 subdir('po')
 284 subdir('pkgconfig')
 285
 286 configure_file(output : 'config.h', configuration : cdata)
 287
 288 python3 = import('python3').find_python()
 289 run_command(python3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')