meson.build

   1 project('gst-editing-services', 'c',
   2   version : '1.15.0.1',
   3   meson_version : '>= 0.47',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version = meson.project_version()
  10 version_arr = gst_version.split('.')
  11 gst_version_major = version_arr[0].to_int()
  12 gst_version_minor = version_arr[1].to_int()
  13 gst_version_micro = version_arr[2].to_int()
  14  if version_arr.length() == 4
  15   gst_version_nano = version_arr[3].to_int()
  16 else
  17   gst_version_nano = 0
  18 endif
  19
  20 apiversion = '1.0'
  21 soversion = 0
  22 # maintaining compatibility with the previous libtool versioning
  23 # current = minor * 100 + micro
  24 curversion = gst_version_minor * 100 + gst_version_micro
  25 libversion = '@0@.@1@.0'.format(soversion, curversion)
  26 osxversion = curversion + 1
  27
  28 glib_req = '>= 2.40.0'
  29 gst_req = '>= @0@.@1@.0'.format(gst_version_major, gst_version_minor)
  30
  31 cc = meson.get_compiler('c')
  32 # Ignore several spurious warnings for things gstreamer does very commonly
  33 # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  34 # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  35 # NOTE: Only add warnings here if you are sure they're spurious
  36 if cc.get_id() == 'msvc'
  37   add_project_arguments(
  38       '/wd4018', # implicit signed/unsigned conversion
  39       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  40       '/wd4244', # lossy type conversion (e.g. double -> int)
  41       '/wd4305', # truncating type conversion (e.g. double -> float)
  42       language : 'c')
  43 endif
  44
  45 if cc.has_link_argument('-Wl,-Bsymbolic-functions')
  46   add_project_link_arguments('-Wl,-Bsymbolic-functions', language : 'c')
  47 endif
  48
  49 # Symbol visibility
  50 if cc.has_argument('-fvisibility=hidden')
  51   add_project_arguments('-fvisibility=hidden', language: 'c')
  52 endif
  53
  54 # Disable strict aliasing
  55 if cc.has_argument('-fno-strict-aliasing')
  56   add_project_arguments('-fno-strict-aliasing', language: 'c')
  57 endif
  58
  59 cdata = configuration_data()
  60 cdata.set('VERSION', '"@0@"'.format(gst_version))
  61 cdata.set('PACKAGE', '"gst-editing-services"')
  62 cdata.set('PACKAGE_VERSION', '"@0@"'.format(gst_version))
  63 cdata.set('PACKAGE_BUGREPORT', '"http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer"')
  64 cdata.set('PACKAGE_NAME', '"GStreamer Editing Services"')
  65 cdata.set('GST_PACKAGE_NAME', '"GStreamer Editing Services"')
  66 cdata.set('GST_PACKAGE_ORIGIN', '"Unknown package origin"')
  67 cdata.set('GST_LICENSE', '"LGPL"')
  68
  69 # Mandatory GST deps
  70 gst_dep = dependency('gstreamer-' + apiversion, version : gst_req,
  71     fallback : ['gstreamer', 'gst_dep'])
  72 gstpbutils_dep = dependency('gstreamer-pbutils-' + apiversion, version : gst_req,
  73     fallback : ['gst-plugins-base', 'pbutils_dep'])
  74 gstvideo_dep = dependency('gstreamer-video-' + apiversion, version : gst_req,
  75     fallback : ['gst-plugins-base', 'video_dep'])
  76 gstbase_dep = dependency('gstreamer-base-1.0', version : gst_req,
  77     fallback : ['gstreamer', 'gst_base_dep'])
  78 if host_machine.system() != 'windows'
  79   gstcheck_dep = dependency('gstreamer-check-1.0', version : gst_req,
  80     required : get_option('tests'),
  81     fallback : ['gstreamer', 'gst_check_dep'])
  82 endif
  83 gstcontroller_dep = dependency('gstreamer-controller-1.0', version : gst_req,
  84   fallback : ['gstreamer', 'gst_controller_dep'])
  85 gstvalidate_dep = dependency('gst-validate-1.0', version : gst_req, required : false,
  86   fallback : ['gst-devtools', 'validate_dep'])
  87
  88 gio_dep = dependency('gio-2.0', fallback: ['glib', 'libgio_dep'])
  89 libxml_dep = dependency('libxml-2.0', fallback: ['libxml2', 'xml2lib_dep'])
  90
  91 # TODO Properly port to Gtk 3
  92 # gtk_dep = dependency('gtk+-3.0', required : false)
  93
  94 libges_deps = [gst_dep, gstbase_dep, gstvideo_dep, gstpbutils_dep,
  95                gstcontroller_dep, gio_dep, libxml_dep]
  96
  97 if gstvalidate_dep.found()
  98     libges_deps = libges_deps + [gstvalidate_dep]
  99     cdata.set('HAVE_GST_VALIDATE', 1)
 100 endif
 101
 102 configure_file(output : 'config.h', configuration : cdata)
 103
 104
 105 gir = find_program('g-ir-scanner', required : get_option('introspection'))
 106 gnome = import('gnome')
 107
 108 # Fixme, not very elegant.
 109 build_gir = gir.found() and not meson.is_cross_build()
 110 gir_init_section = [ '--add-init-section=' + \
 111     'extern void gst_init(gint*,gchar**);' + \
 112     'extern void ges_init(void);' + \
 113     'g_setenv("GST_REGISTRY_1.0", "/no/way/this/exists.reg", TRUE);' + \
 114     'g_setenv("GST_PLUGIN_PATH_1_0", "", TRUE);' + \
 115     'g_setenv("GST_PLUGIN_SYSTEM_PATH_1_0", "", TRUE);' + \
 116     'g_setenv("GST_DEBUG", "0", TRUE);' + \
 117     'gst_init(NULL,NULL);' + \
 118     'ges_init();' ]
 119
 120 ges_c_args = ['-DHAVE_CONFIG_H', '-DG_LOG_DOMAIN="GES"']
 121 plugins_install_dir = '@0@/gstreamer-1.0'.format(get_option('libdir'))
 122
 123 pkgconfig = import('pkgconfig')
 124 plugins_pkgconfig_install_dir = join_paths(plugins_install_dir, 'pkgconfig')
 125 if get_option('default_library') == 'shared'
 126   # If we don't build static plugins there is no need to generate pc files
 127   plugins_pkgconfig_install_dir = disabler()
 128 endif
 129
 130 if gst_dep.type_name() == 'internal'
 131   gst_debug_disabled = not subproject('gstreamer').get_variable('gst_debug')
 132 else
 133   # We can't check that in the case of subprojects as we won't
 134   # be able to build against an internal dependency (which is not built yet)
 135   gst_debug_disabled = cc.has_header_symbol('gst/gstconfig.h', 'GST_DISABLE_GST_DEBUG', dependencies: gst_dep)
 136 endif
 137
 138 if gst_debug_disabled and cc.has_argument('-Wno-unused')
 139   add_project_arguments('-Wno-unused', language: 'c')
 140 endif
 141
 142 warning_flags = [
 143   '-Wmissing-declarations',
 144   '-Wmissing-prototypes',
 145   '-Wredundant-decls',
 146   '-Wundef',
 147   '-Wwrite-strings',
 148   '-Wformat',
 149   '-Wformat-security',
 150   '-Winit-self',
 151   '-Wmissing-include-dirs',
 152   '-Waddress',
 153   '-Wno-multichar',
 154   '-Wdeclaration-after-statement',
 155   '-Wvla',
 156   '-Wpointer-arith',
 157 ]
 158
 159 foreach extra_arg : warning_flags
 160   if cc.has_argument (extra_arg)
 161     add_project_arguments([extra_arg], language: 'c')
 162   endif
 163 endforeach
 164
 165 configinc = include_directories('.')
 166 subdir('ges')
 167 subdir('plugins')
 168 subdir('tools')
 169 subdir('pkgconfig')
 170 subdir('tests')
 171 subdir('examples')
 172
 173 override_detector = '''
 174 import sys
 175 import os
 176
 177 prefix = sys.argv[1]
 178 version = sys.version_info
 179
 180 # If we are installing in the same prefix as PyGobject
 181 # make sure to install in the right place.
 182 import gi.overrides
 183
 184 overrides_path = os.path.dirname(gi.overrides.__file__)
 185 if os.path.commonprefix([overrides_path, prefix]) == prefix:
 186     print(overrides_path)
 187     exit(0)
 188
 189 # Otherwise follow python's way of install site packages inside
 190 # the provided prefix
 191 if os.name == 'posix':
 192     print(os.path.join(
 193         prefix, 'lib', 'python%d.%d' % (version.major, version.minor),
 194         'site-packages', 'gi', 'overrides'))
 195 else:
 196     print(os.path.join(
 197         prefix, 'Lib', 'Python%d%d' % (version.major, version.minor),
 198         'site-packages', 'gi', 'overrides'))
 199 '''
 200 python3 = import('python').find_installation()
 201 pygi_override_dir = get_option('pygi-overrides-dir')
 202 if pygi_override_dir == ''
 203     cres = run_command(python3, '-c', override_detector, get_option('prefix'))
 204     if cres.returncode() == 0
 205       pygi_override_dir = cres.stdout().strip()
 206     endif
 207     if cres.stderr() != ''
 208         message(cres.stderr())
 209     endif
 210 endif
 211
 212 if pygi_override_dir != ''
 213   message('pygobject overrides directory ' + pygi_override_dir)
 214   subdir('bindings/python')
 215 endif
 216
 217 if build_machine.system() == 'windows'
 218   message('Disabling gtk-doc while building on Windows')
 219 else
 220   if find_program('gtkdoc-scan', required : get_option('gtk_doc')).found()
 221     subdir('docs')
 222   else
 223     message('Not building documentation as gtk-doc was not found')
 224   endif
 225 endif
 226
 227 run_command(python3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')