meson.build

   1 project('at-spi2-core', 'c',
   2         version: '2.34.0',
   3         license: 'LGPLv2.1+',
   4         default_options: [
   5           'buildtype=debugoptimized',
   6           'warning_level=1',
   7           'c_std=c99',
   8         ],
   9         meson_version: '>= 0.50.0')
  10
  11 add_project_arguments([ '-D_POSIX_C_SOURCE=200809L', '-D_DEFAULT_SOURCE' ], language: 'c')
  12
  13 atspi_gir_ns = 'Atspi'
  14
  15 cc = meson.get_compiler('c')
  16 host_system = host_machine.system()
  17
  18 soversion = '0.0.1'
  19
  20 at_spi_conf = configuration_data()
  21 at_spi_conf.set('GETTEXT_PACKAGE', meson.project_name())
  22
  23 root_inc = include_directories('.')
  24 registryd_inc = include_directories('registryd')
  25
  26 atspi_prefix = get_option('prefix')
  27 atspi_datadir = join_paths(atspi_prefix, get_option('datadir'))
  28 atspi_libexecdir = join_paths(atspi_prefix, get_option('libexecdir'))
  29 atspi_sysconfdir = join_paths(atspi_prefix, get_option('sysconfdir'))
  30 atspi_libdir = join_paths(atspi_prefix, get_option('libdir'))
  31 atspi_includedir = join_paths(atspi_prefix, get_option('includedir'))
  32
  33 if get_option('dbus_services_dir') != 'default'
  34   dbus_services_dir = get_option('dbus_services_dir')
  35 else
  36   dbus_services_dir = join_paths(get_option('datadir'), 'dbus-1/services')
  37 endif
  38
  39 if get_option('systemd_user_dir') != 'default'
  40   systemd_user_dir = get_option('systemd_user_dir')
  41 else
  42   systemd_user_dir = join_paths(get_option('prefix'), 'lib/systemd/user')
  43 endif
  44
  45 # Dependencies
  46 libdbus_req_version = '>= 1.5'
  47 glib_req_version = '>= 2.32.0'
  48 gobject_req_version = '>= 2.0.0'
  49 gio_req_version = '>= 2.28.0'
  50
  51 libdbus_dep = dependency('dbus-1', version: libdbus_req_version)
  52 glib_dep = dependency('glib-2.0', version: glib_req_version)
  53 gobject_dep = dependency('gobject-2.0', version: gobject_req_version)
  54 gio_dep = dependency('gio-2.0', version: gio_req_version)
  55 if cc.has_function('dlopen')
  56   dl_dep = []
  57 elif cc.has_function('dlopen', args: '-ldl')
  58   dl_dep = cc.find_library('dl')
  59 else
  60   error('Could not find a library with the dlopen function')
  61 endif
  62
  63 x11_deps = []
  64 x11_option = get_option('x11')
  65 if x11_option != 'no'
  66   x11_dep = dependency('x11', required: false)
  67
  68   if x11_dep.found()
  69     x11_deps += x11_dep
  70     at_spi_conf.set('HAVE_X11', 1)
  71     xtest_dep = dependency('xtst')
  72     x11_deps += xtest_dep
  73
  74     if cc.has_function('XkbGetMap', dependencies: x11_deps)
  75       at_spi_conf.set('HAVE_XKB', 1)
  76     endif
  77
  78     xinput_dep = dependency('xi')
  79     x11_deps += xinput_dep
  80   endif
  81 endif
  82
  83 # Alignments
  84 at_spi_conf.set('ALIGNOF_CHAR', cc.alignment('char'))
  85 at_spi_conf.set('ALIGNOF_DOUBLE', cc.alignment('double'))
  86
  87 dbus_alignments = [
  88   'dbus_bool_t',
  89   'dbus_int16_t',
  90   'dbus_int32_t',
  91   'dbus_int64_t',
  92 ]
  93
  94 foreach a: dbus_alignments
  95   at_spi_conf.set('ALIGNOF_' + a.underscorify().to_upper(),
  96                   cc.alignment(a, prefix: '#include <dbus/dbus.h>', dependencies: libdbus_dep))
  97 endforeach
  98
  99 at_spi_conf.set('ALIGNOF_DBIND_POINTER', cc.alignment('dbind_pointer', prefix: 'typedef void *dbind_pointer;'))
 100 at_spi_conf.set('ALIGNOF_DBIND_STRUCT', cc.alignment('dbind_struct', prefix: 'typedef struct { char s1; } dbind_struct;'))
 101
 102 # introspection support
 103 have_gir = false
 104
 105 introspection_option = get_option('introspection')
 106 if introspection_option != 'no'
 107   gir_dep = dependency('gobject-introspection-1.0', version: '>= 0.6.7', required: false)
 108
 109   if gir_dep.found()
 110     have_gir = true
 111   endif
 112 endif
 113
 114 xgettext = find_program('xgettext', required : false)
 115
 116 configure_file(output: 'config.h', configuration: at_spi_conf)
 117
 118 gnome = import('gnome')
 119
 120 subdir('dbind')
 121 subdir('atspi')
 122 subdir('bus')
 123 subdir('registryd')
 124 subdir('test')
 125
 126 if get_option('docs')
 127   subdir('doc/libatspi')
 128 endif
 129
 130 if xgettext.found()
 131   subdir('po')
 132 endif