meson.build

   1 project('gst-plugins-base', 'c',
   2   version : '1.17.0.1',
   3   meson_version : '>= 0.48',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0].to_int()
  10 gst_version_minor = version_arr[1].to_int()
  11 gst_version_micro = version_arr[2].to_int()
  12 if version_arr.length() == 4
  13   gst_version_nano = version_arr[3].to_int()
  14 else
  15   gst_version_nano = 0
  16 endif
  17 gst_version_is_dev = gst_version_minor % 2 == 1 and gst_version_micro < 90
  18
  19 have_cxx = add_languages('cpp', required : false)
  20 have_objc = add_languages('objc', required : false)
  21
  22 glib_req = '>= 2.44.0'
  23 orc_req = '>= 0.4.24'
  24 gst_req = '>= @0@.@1@.0'.format(gst_version_major, gst_version_minor)
  25
  26 api_version = '1.0'
  27 soversion = 0
  28 # maintaining compatibility with the previous libtool versioning
  29 # current = minor * 100 + micro
  30 curversion = gst_version_minor * 100 + gst_version_micro
  31 libversion = '@0@.@1@.0'.format(soversion, curversion)
  32 osxversion = curversion + 1
  33
  34 plugins_install_dir = join_paths(get_option('libdir'), 'gstreamer-1.0')
  35 plugins = []
  36
  37 cc = meson.get_compiler('c')
  38 host_system = host_machine.system()
  39
  40 if cc.get_id() == 'msvc'
  41   # Ignore several spurious warnings for things gstreamer does very commonly
  42   # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  43   # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  44   # NOTE: Only add warnings here if you are sure they're spurious
  45   add_project_arguments(
  46       '/wd4018', # implicit signed/unsigned conversion
  47       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  48       '/wd4244', # lossy type conversion (e.g. double -> int)
  49       '/wd4305', # truncating type conversion (e.g. double -> float)
  50       cc.get_supported_arguments(['/utf-8']), # set the input encoding to utf-8
  51       language : 'c')
  52   # Disable SAFESEH with MSVC for plugins and libs that use external deps that
  53   # are built with MinGW
  54   noseh_link_args = ['/SAFESEH:NO']
  55 else
  56   noseh_link_args = []
  57 endif
  58
  59 if cc.has_link_argument('-Wl,-Bsymbolic-functions')
  60   add_project_link_arguments('-Wl,-Bsymbolic-functions', language : 'c')
  61 endif
  62
  63 core_conf = configuration_data()
  64
  65 # Symbol visibility
  66 if cc.get_id() == 'msvc'
  67   export_define = '__declspec(dllexport) extern'
  68 elif cc.has_argument('-fvisibility=hidden')
  69   add_project_arguments('-fvisibility=hidden', language: 'c')
  70   if have_objc
  71     add_project_arguments('-fvisibility=hidden', language: 'objc')
  72   endif
  73   export_define = 'extern __attribute__ ((visibility ("default")))'
  74 else
  75   export_define = 'extern'
  76 endif
  77
  78 # Passing this through the command line would be too messy
  79 core_conf.set('GST_API_EXPORT', export_define)
  80
  81 # Disable strict aliasing
  82 if cc.has_argument('-fno-strict-aliasing')
  83   add_project_arguments('-fno-strict-aliasing', language: 'c')
  84 endif
  85
  86 # Define G_DISABLE_DEPRECATED for development versions
  87 if gst_version_is_dev
  88   message('Disabling deprecated GLib API')
  89   add_project_arguments('-DG_DISABLE_DEPRECATED', language: 'c')
  90 endif
  91
  92 cast_checks = get_option('gobject-cast-checks')
  93 if cast_checks.disabled() or (cast_checks.auto() and not gst_version_is_dev)
  94   message('Disabling GLib cast checks')
  95   add_project_arguments('-DG_DISABLE_CAST_CHECKS', language: 'c')
  96 endif
  97
  98 glib_asserts = get_option('glib-asserts')
  99 if glib_asserts.disabled() or (glib_asserts.auto() and not gst_version_is_dev)
 100   message('Disabling GLib asserts')
 101   add_project_arguments('-DG_DISABLE_ASSERT', language: 'c')
 102 endif
 103
 104 glib_checks = get_option('glib-checks')
 105 if glib_checks.disabled() or (glib_checks.auto() and not gst_version_is_dev)
 106   message('Disabling GLib checks')
 107   add_project_arguments('-DG_DISABLE_CHECKS', language: 'c')
 108 endif
 109
 110 check_headers = [
 111   ['HAVE_DLFCN_H', 'dlfcn.h'],
 112   ['HAVE_EMMINTRIN_H', 'emmintrin.h'],
 113   ['HAVE_INTTYPES_H', 'inttypes.h'],
 114   ['HAVE_MEMORY_H', 'memory.h'],
 115   ['HAVE_PROCESS_H', 'process.h'],
 116   ['HAVE_SMMINTRIN_H', 'smmintrin.h'],
 117   ['HAVE_STDINT_H', 'stdint.h'],
 118   ['HAVE_STDLIB_H', 'stdlib.h'],
 119   ['HAVE_STRINGS_H', 'strings.h'],
 120   ['HAVE_STRING_H', 'string.h'],
 121   ['HAVE_SYS_SOCKET_H', 'sys/socket.h'],
 122   ['HAVE_SYS_STAT_H', 'sys/stat.h'],
 123   ['HAVE_SYS_TYPES_H', 'sys/types.h'],
 124   ['HAVE_SYS_WAIT_H', 'sys/wait.h'],
 125   ['HAVE_UNISTD_H', 'unistd.h'],
 126   ['HAVE_WINSOCK2_H', 'winsock2.h'],
 127   ['HAVE_XMMINTRIN_H', 'xmmintrin.h'],
 128   ['HAVE_LINUX_DMA_BUF_H', 'linux/dma-buf.h'],
 129 ]
 130 foreach h : check_headers
 131   if cc.has_header(h.get(1))
 132     core_conf.set(h.get(0), 1)
 133   endif
 134 endforeach
 135
 136 check_functions = [
 137   ['HAVE_DCGETTEXT', 'dcgettext', '#include<libintl.h>'],
 138   ['HAVE_GMTIME_R', 'gmtime_r', '#include<time.h>'],
 139   ['HAVE_LRINTF', 'lrintf', '#include<math.h>'],
 140   ['HAVE_MMAP', 'mmap', '#include<sys/mman.h>'],
 141   ['HAVE_LOG2', 'log2', '#include<math.h>'],
 142 ]
 143
 144 libm = cc.find_library('m', required : false)
 145 foreach f : check_functions
 146   if cc.has_function(f.get(1), prefix : f.get(2), dependencies : libm)
 147     core_conf.set(f.get(0), 1)
 148   endif
 149 endforeach
 150
 151 core_conf.set('SIZEOF_CHAR', cc.sizeof('char'))
 152 core_conf.set('SIZEOF_INT', cc.sizeof('int'))
 153 core_conf.set('SIZEOF_LONG', cc.sizeof('long'))
 154 core_conf.set('SIZEOF_SHORT', cc.sizeof('short'))
 155 core_conf.set('SIZEOF_VOIDP', cc.sizeof('void*'))
 156
 157 core_conf.set_quoted('GETTEXT_PACKAGE', 'gst-plugins-base-1.0')
 158 core_conf.set_quoted('LOCALEDIR', join_paths(get_option('prefix'), get_option('localedir')))
 159 core_conf.set_quoted('PACKAGE', 'gst-plugins-base')
 160 core_conf.set_quoted('VERSION', gst_version)
 161 core_conf.set_quoted('PACKAGE_VERSION', gst_version)
 162 core_conf.set_quoted('GST_API_VERSION', api_version)
 163 core_conf.set_quoted('GST_DATADIR', join_paths(get_option('prefix'), get_option('datadir')))
 164 core_conf.set_quoted('GST_LICENSE', 'LGPL')
 165
 166 install_plugins_helper = get_option('install_plugins_helper')
 167 if install_plugins_helper == ''
 168   install_plugins_helper = join_paths(get_option('prefix'),
 169                                       get_option('libexecdir'),
 170                                       'gst-install-plugins-helper')
 171 endif
 172 core_conf.set_quoted('GST_INSTALL_PLUGINS_HELPER', install_plugins_helper)
 173
 174 warning_flags = [
 175   '-Wmissing-declarations',
 176   '-Wredundant-decls',
 177   '-Wundef',
 178   '-Wwrite-strings',
 179   '-Wformat',
 180   '-Wformat-nonliteral',
 181   '-Wformat-security',
 182   '-Winit-self',
 183   '-Wmissing-include-dirs',
 184   '-Waddress',
 185   '-Wno-multichar',
 186   '-Wvla',
 187   '-Wpointer-arith',
 188 ]
 189
 190 warning_c_flags = [
 191   '-Wmissing-prototypes',
 192   '-Wdeclaration-after-statement',
 193 ]
 194
 195 warning_cxx_flags = [
 196   '-Waggregate-return',
 197 ]
 198
 199 if have_cxx
 200   cxx = meson.get_compiler('cpp')
 201   foreach extra_arg : warning_cxx_flags
 202     if cxx.has_argument (extra_arg)
 203       add_project_arguments([extra_arg], language: 'cpp')
 204     endif
 205   endforeach
 206 endif
 207
 208 foreach extra_arg : warning_flags
 209   if cc.has_argument (extra_arg)
 210     add_project_arguments([extra_arg], language: 'c')
 211   endif
 212   if have_cxx and cxx.has_argument (extra_arg)
 213     add_project_arguments([extra_arg], language: 'cpp')
 214   endif
 215 endforeach
 216
 217 foreach extra_arg : warning_c_flags
 218   if cc.has_argument (extra_arg)
 219     add_project_arguments([extra_arg], language: 'c')
 220   endif
 221 endforeach
 222
 223 # GStreamer package name and origin url
 224 gst_package_name = get_option('package-name')
 225 if gst_package_name == ''
 226   if gst_version_nano == 0
 227     gst_package_name = 'GStreamer Base Plug-ins source release'
 228   elif gst_version_nano == 1
 229     gst_package_name = 'GStreamer Base Plug-ins git'
 230   else
 231     gst_package_name = 'GStreamer Base Plug-ins prerelease'
 232   endif
 233 endif
 234 core_conf.set_quoted('GST_PACKAGE_NAME', gst_package_name)
 235 core_conf.set_quoted('GST_PACKAGE_ORIGIN', get_option('package-origin'))
 236
 237 # FIXME: These should be configure options
 238 core_conf.set_quoted('DEFAULT_VIDEOSINK', 'autovideosink')
 239 core_conf.set_quoted('DEFAULT_AUDIOSINK', 'autoaudiosink')
 240
 241 # Set whether the audioresampling method should be detected at runtime
 242 core_conf.set('AUDIORESAMPLE_FORMAT_' + get_option('audioresample_format').to_upper(), true)
 243
 244 gst_plugins_base_args = ['-DHAVE_CONFIG_H']
 245 if get_option('default_library') == 'static'
 246   gst_plugins_base_args += ['-DGST_STATIC_COMPILATION']
 247 endif
 248
 249 # X11 checks are for sys/ and tests/
 250 x11_dep = dependency('x11', required : get_option('x11'))
 251 # GLib checks are for the entire project
 252 # Almost everything that uses glib also uses gobject
 253 glib_deps = [dependency('glib-2.0', version : glib_req, fallback: ['glib', 'libglib_dep']),
 254              dependency('gobject-2.0', fallback: ['glib', 'libgobject_dep'])]
 255 # GIO is used by the GIO plugin, and by the TCP, SDP, and RTSP plugins
 256 gio_dep = dependency('gio-2.0', fallback: ['glib', 'libgio_dep'])
 257 giounix_dep = dependency('', required: false)
 258 if host_system != 'windows'
 259   giounix_dep = dependency('gio-unix-2.0', version : glib_req,
 260                            fallback: ['glib', 'libgiounix_dep'])
 261 endif
 262 gmodule_dep = dependency('gmodule-no-export-2.0',
 263                          fallback: ['glib', 'libgmodule_dep'])
 264
 265 # some of the examples can use gdk-pixbuf and GTK+3
 266 gdk_pixbuf_dep = dependency('gdk-pixbuf-2.0', required : get_option('examples'))
 267 gtk_dep = dependency('gtk+-3.0', version : '>= 3.10', required : get_option('examples'))
 268 # TODO: https://github.com/mesonbuild/meson/issues/3941
 269 if not get_option('x11').disabled()
 270   gtk_x11_dep = dependency('gtk+-x11-3.0', version : '>= 3.10', required : get_option('examples'))
 271 else
 272   gtk_x11_dep = dependency('', required : false)
 273 endif
 274 # gtk+ quartz backend is only available on macOS
 275 if host_system == 'darwin'
 276   gtk_quartz_dep = dependency('gtk+-quartz-3.0', version : '>= 3.10', required : get_option('examples'))
 277 else
 278   gtk_quartz_dep = dependency('', required : false)
 279 endif
 280
 281 core_conf.set('HAVE_X', x11_dep.found())
 282 core_conf.set('HAVE_GIO_UNIX_2_0', giounix_dep.found())
 283
 284 if gio_dep.type_name() == 'pkgconfig'
 285     core_conf.set_quoted('GIO_MODULE_DIR',
 286         gio_dep.get_pkgconfig_variable('giomoduledir'))
 287     core_conf.set_quoted('GIO_LIBDIR',
 288         gio_dep.get_pkgconfig_variable('libdir'))
 289     core_conf.set_quoted('GIO_PREFIX',
 290         gio_dep.get_pkgconfig_variable('prefix'))
 291 else
 292     core_conf.set_quoted('GIO_MODULE_DIR', join_paths(get_option('prefix'),
 293       get_option('libdir'), 'gio/modules'))
 294     core_conf.set_quoted('GIO_LIBDIR', join_paths(get_option('prefix'),
 295       get_option('libdir')))
 296     core_conf.set_quoted('GIO_PREFIX', get_option('prefix'))
 297 endif
 298
 299 configinc = include_directories('.')
 300 libsinc = include_directories('gst-libs')
 301
 302 # To use the subproject make subprojects directory
 303 # and put gstreamer meson git there (symlinking is fine)
 304 gst_dep = dependency('gstreamer-1.0', version : gst_req,
 305   fallback : ['gstreamer', 'gst_dep'])
 306 gst_base_dep = dependency('gstreamer-base-1.0', version : gst_req,
 307   fallback : ['gstreamer', 'gst_base_dep'])
 308 gst_net_dep = dependency('gstreamer-net-1.0', version : gst_req,
 309   fallback : ['gstreamer', 'gst_net_dep'])
 310 gst_check_dep = dependency('gstreamer-check-1.0', version : gst_req,
 311   required : get_option('tests'),
 312   fallback : ['gstreamer', 'gst_check_dep'])
 313 gst_controller_dep = dependency('gstreamer-controller-1.0', version : gst_req,
 314   fallback : ['gstreamer', 'gst_controller_dep'])
 315
 316 have_orcc = false
 317 orcc_args = []
 318 # Used by various libraries/elements that use Orc code
 319 orc_dep = dependency('orc-0.4', version : orc_req, required : get_option('orc'),
 320     fallback : ['orc', 'orc_dep'])
 321 orcc = find_program('orcc', required : get_option('orc'))
 322 if orc_dep.found() and orcc.found()
 323   have_orcc = true
 324   orcc_args = [orcc, '--include', 'glib.h']
 325   core_conf.set('HAVE_ORC', 1)
 326 else
 327   message('Orc Compiler not found or disabled, will use backup C code')
 328   core_conf.set('DISABLE_ORC', 1)
 329 endif
 330
 331 # Used to build SSE* things in audio-resampler
 332 sse_args = '-msse'
 333 sse2_args = '-msse2'
 334 sse41_args = '-msse4.1'
 335
 336 have_sse = cc.has_argument(sse_args)
 337 have_sse2 = cc.has_argument(sse2_args)
 338 have_sse41 = cc.has_argument(sse41_args)
 339
 340 if host_machine.cpu_family() == 'arm'
 341   if cc.compiles('''
 342 #include <arm_neon.h>
 343 int32x4_t testfunc(int16_t *a, int16_t *b) {
 344   asm volatile ("vmull.s16 q0, d0, d0" : : : "q0");
 345   return vmull_s16(vld1_s16(a), vld1_s16(b));
 346 }
 347 ''', name : 'NEON support')
 348     core_conf.set('HAVE_ARM_NEON', true)
 349   endif
 350 endif
 351
 352 if gst_dep.type_name() == 'internal'
 353     gst_proj = subproject('gstreamer')
 354
 355     if not gst_proj.get_variable('gst_debug')
 356         message('GStreamer debug system is disabled')
 357         add_project_arguments('-Wno-unused', language: 'c')
 358     else
 359         message('GStreamer debug system is enabled')
 360     endif
 361 else
 362     # We can't check that in the case of subprojects as we won't
 363     # be able to build against an internal dependency (which is not built yet)
 364     if not cc.compiles('''
 365 #include <gst/gstconfig.h>
 366 #ifdef GST_DISABLE_GST_DEBUG
 367 #error "debugging disabled, make compiler fail"
 368 #endif''' , dependencies: gst_dep)
 369         message('GStreamer debug system is disabled')
 370         add_project_arguments('-Wno-unused', language: 'c')
 371     else
 372         message('GStreamer debug system is enabled')
 373     endif
 374 endif
 375
 376 gir = find_program('g-ir-scanner', required : get_option('introspection'))
 377 gnome = import('gnome')
 378 build_gir = gir.found() and (not meson.is_cross_build() or get_option('introspection').enabled())
 379 gir_init_section = [ '--add-init-section=extern void gst_init(gint*,gchar**);' + \
 380     'g_setenv("GST_REGISTRY_DISABLE", "yes", TRUE);' + \
 381     'g_setenv("GST_REGISTRY_1.0", "@0@", TRUE);'.format(meson.current_build_dir() + '/gir_empty_registry.reg') + \
 382     'g_setenv("GST_PLUGIN_PATH_1_0", "", TRUE);' + \
 383     'g_setenv("GST_PLUGIN_SYSTEM_PATH_1_0", "", TRUE);' + \
 384     'gst_init(NULL,NULL);', '--quiet']
 385
 386 pkgconfig = import('pkgconfig')
 387 plugins_pkgconfig_install_dir = join_paths(plugins_install_dir, 'pkgconfig')
 388 if get_option('default_library') == 'shared'
 389   # If we don't build static plugins there is no need to generate pc files
 390   plugins_pkgconfig_install_dir = disabler()
 391 endif
 392
 393 python3 = import('python').find_installation()
 394 subdir('gst-libs')
 395 subdir('gst')
 396 subdir('ext')
 397 subdir('sys')
 398 if not get_option('tools').disabled()
 399   subdir('tools')
 400 endif
 401 subdir('tests')
 402 subdir('pkgconfig')
 403 # xgettext is optional (on Windows for instance)
 404 if find_program('xgettext', required : get_option('nls')).found()
 405   core_conf.set('ENABLE_NLS', 1)
 406   subdir('po')
 407 endif
 408 subdir('docs')
 409
 410 # Use core_conf after all subdirs have set values
 411 configure_file(output : 'config.h', configuration : core_conf)
 412
 413 run_command(python3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')