meson.build

   1 project('gst-plugins-good', 'c',
   2   version : '1.13.0.1',
   3   meson_version : '>= 0.36.0',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0]
  10 gst_version_minor = version_arr[1]
  11 gst_version_micro = version_arr[2]
  12 if version_arr.length() == 4
  13   gst_version_nano = version_arr[3]
  14 else
  15   gst_version_nano = 0
  16 endif
  17
  18 glib_req = '>= 2.40.0'
  19 gst_req = '>= @0@.@1@.0'.format(gst_version_major, gst_version_minor)
  20
  21 api_version = '1.0'
  22
  23 plugins_install_dir = '@0@/gstreamer-1.0'.format(get_option('libdir'))
  24
  25 cc = meson.get_compiler('c')
  26
  27 if cc.get_id() == 'msvc'
  28   # Ignore several spurious warnings for things gstreamer does very commonly
  29   # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  30   # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  31   # NOTE: Only add warnings here if you are sure they're spurious
  32   add_project_arguments(
  33       '/wd4018', # implicit signed/unsigned conversion
  34       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  35       '/wd4244', # lossy type conversion (e.g. double -> int)
  36       '/wd4305', # truncating type conversion (e.g. double -> float)
  37       language : 'c')
  38   # Disable SAFESEH with MSVC for plugins and libs that use external deps that
  39   # are built with MinGW
  40   noseh_link_args = ['/SAFESEH:NO']
  41 else
  42   noseh_link_args = []
  43 endif
  44
  45 cdata = configuration_data()
  46
  47 check_headers = [
  48   ['HAVE_DLFCN_H', 'dlfcn.h'],
  49   ['HAVE_FCNTL_H', 'fcntl.h'],
  50   ['HAVE_INTTYPES_H', 'inttypes.h'],
  51   ['HAVE_MEMORY_H', 'memory.h'],
  52   ['HAVE_PROCESS_H', 'process.h'],
  53   ['HAVE_STDINT_H', 'stdint.h'],
  54   ['HAVE_STDLIB_H', 'stdlib.h'],
  55   ['HAVE_STRINGS_H', 'strings.h'],
  56   ['HAVE_STRING_H', 'string.h'],
  57   ['HAVE_SYS_IOCTL_H', 'sys/ioctl.h'],
  58   ['HAVE_SYS_PARAM_H', 'sys/param.h'],
  59   ['HAVE_SYS_SOCKET_H', 'sys/socket.h'],
  60   ['HAVE_SYS_STAT_H', 'sys/stat.h'],
  61   ['HAVE_SYS_TIME_H', 'sys/time.h'],
  62   ['HAVE_SYS_TYPES_H', 'sys/types.h'],
  63   ['HAVE_UNISTD_H', 'unistd.h'],
  64 ]
  65
  66 foreach h : check_headers
  67   if cc.has_header(h.get(1))
  68     cdata.set(h.get(0), 1)
  69   endif
  70 endforeach
  71
  72 check_functions = [
  73   ['HAVE_ASINH', 'asinh', '#include<math.h>'],
  74   ['HAVE_CLOCK_GETTIME', 'clock_gettime', '#include<time.h>'],
  75   ['HAVE_COSH', 'cosh', '#include<math.h>'],
  76 # check token HAVE_CPU_ALPHA
  77 # check token HAVE_CPU_ARM
  78 # check token HAVE_CPU_CRIS
  79 # check token HAVE_CPU_CRISV32
  80 # check token HAVE_CPU_HPPA
  81 # check token HAVE_CPU_I386
  82 # check token HAVE_CPU_IA64
  83 # check token HAVE_CPU_M68K
  84 # check token HAVE_CPU_MIPS
  85 # check token HAVE_CPU_PPC
  86 # check token HAVE_CPU_PPC64
  87 # check token HAVE_CPU_S390
  88 # check token HAVE_CPU_SPARC
  89 # check token HAVE_CPU_X86_64
  90   ['HAVE_DCGETTEXT', 'dcgettext', '#include<libintl.h>'],
  91 # check token HAVE_DIRECTSOUND
  92 # check token HAVE_EXPERIMENTAL
  93 # check token HAVE_EXTERNAL
  94 # check token HAVE_FPCLASS
  95 # check token HAVE_GCC_ASM
  96   ['HAVE_GETPAGESIZE', 'getpagesize', '#include<unistd.h>'],
  97 # check token HAVE_GETTEXT
  98 # check token HAVE_GST_V4L2
  99 # check token HAVE_IOS
 100   ['HAVE_ISINF', 'isinf', '#include<math.h>'],
 101 # check token HAVE_LIBV4L2
 102   ['HAVE_MMAP', 'mmap', '#include<sys/mman.h>'],
 103 # check token HAVE_OSX_AUDIO
 104 # check token HAVE_OSX_VIDEO
 105 # check token HAVE_RDTSC
 106   ['HAVE_SINH', 'sinh', '#include<math.h>'],
 107 # check token HAVE_WAVEFORM
 108 ]
 109
 110 libm = cc.find_library('m', required : false)
 111
 112 foreach f : check_functions
 113   if cc.has_function(f.get(1), prefix : f.get(2), dependencies : libm)
 114     cdata.set(f.get(0), 1)
 115   endif
 116 endforeach
 117
 118 cdata.set('SIZEOF_CHAR', cc.sizeof('char'))
 119 cdata.set('SIZEOF_INT', cc.sizeof('int'))
 120 cdata.set('SIZEOF_LONG', cc.sizeof('long'))
 121 cdata.set('SIZEOF_SHORT', cc.sizeof('short'))
 122 cdata.set('SIZEOF_VOIDP', cc.sizeof('void*'))
 123
 124 # Here be fixmes.
 125 # FIXME: check if this is correct
 126 cdata.set('HAVE_CPU_X86_64', host_machine.cpu() == 'amd64')
 127 cdata.set('HAVE_GCC_ASM', cc.get_id() != 'msvc')
 128 cdata.set('VERSION', '"@0@"'.format(gst_version))
 129 cdata.set('PACKAGE_VERSION', '"@0@"'.format(gst_version))
 130 cdata.set('GST_LICENSE', '"LGPL"')
 131 cdata.set('PACKAGE', '"gst-plugins-good"')
 132 cdata.set('GETTEXT_PACKAGE', '"gst-plugins-good-1.0"')
 133
 134 # GStreamer package name and origin url
 135 gst_package_name = get_option('with-package-name')
 136 if gst_package_name == ''
 137   if gst_version_nano == 0
 138     gst_package_name = 'GStreamer Good Plug-ins source release'
 139   elif gst_version_nano == 1
 140     gst_package_name = 'GStreamer Good Plug-ins git'
 141   else
 142     gst_package_name = 'GStreamer Good Plug-ins prerelease'
 143   endif
 144 endif
 145 cdata.set_quoted('GST_PACKAGE_NAME', gst_package_name)
 146 cdata.set_quoted('GST_PACKAGE_ORIGIN', get_option('with-package-origin'))
 147
 148 # Mandatory GST deps
 149 gst_dep = dependency('gstreamer-1.0', version : gst_req,
 150   fallback : ['gstreamer', 'gst_dep'])
 151 gstbase_dep = dependency('gstreamer-base-1.0', version : gst_req,
 152   fallback : ['gstreamer', 'gst_base_dep'])
 153 gstnet_dep = dependency('gstreamer-net-1.0', version : gst_req,
 154   fallback : ['gstreamer', 'gst_net_dep'])
 155 if host_machine.system() != 'windows'
 156   gstcheck_dep = dependency('gstreamer-check-1.0', version : gst_req,
 157     fallback : ['gstreamer', 'gst_check_dep'])
 158 endif
 159 gstcontroller_dep = dependency('gstreamer-controller-1.0', version : gst_req,
 160   fallback : ['gstreamer', 'gst_controller_dep'])
 161
 162 gstpbutils_dep = dependency('gstreamer-pbutils-1.0', version : gst_req,
 163     fallback : ['gst-plugins-base', 'pbutils_dep'])
 164 gstallocators_dep = dependency('gstreamer-allocators-1.0', version : gst_req,
 165     fallback : ['gst-plugins-base', 'allocators_dep'])
 166 gstapp_dep = dependency('gstreamer-app-1.0', version : gst_req,
 167     fallback : ['gst-plugins-base', 'app_dep'])
 168 gstaudio_dep = dependency('gstreamer-audio-1.0', version : gst_req,
 169     fallback : ['gst-plugins-base', 'audio_dep'])
 170 gstfft_dep = dependency('gstreamer-fft-1.0', version : gst_req,
 171     fallback : ['gst-plugins-base', 'fft_dep'])
 172 gstriff_dep = dependency('gstreamer-riff-1.0', version : gst_req,
 173     fallback : ['gst-plugins-base', 'riff_dep'])
 174 gstrtp_dep = dependency('gstreamer-rtp-1.0', version : gst_req,
 175     fallback : ['gst-plugins-base', 'rtp_dep'])
 176 gstrtsp_dep = dependency('gstreamer-rtsp-1.0', version : gst_req,
 177     fallback : ['gst-plugins-base', 'rtsp_dep'])
 178 gstsdp_dep = dependency('gstreamer-sdp-1.0', version : gst_req,
 179     fallback : ['gst-plugins-base', 'sdp_dep'])
 180 gsttag_dep = dependency('gstreamer-tag-1.0', version : gst_req,
 181     fallback : ['gst-plugins-base', 'tag_dep'])
 182 gstvideo_dep = dependency('gstreamer-video-1.0', version : gst_req,
 183     fallback : ['gst-plugins-base', 'video_dep'])
 184
 185 zlib_dep = dependency('zlib')
 186 bz2lib = cc.find_library('bz2', required : false)
 187 glib_deps = [dependency('glib-2.0', version : glib_req, fallback: ['glib', 'libglib_dep']),
 188              dependency('gobject-2.0', fallback: ['glib', 'libgobject_dep'])]
 189 gio_dep = dependency('gio-2.0', fallback: ['glib', 'libgio_dep'])
 190
 191 cdata.set('HAVE_ZLIB', 1)
 192 if bz2lib.found()
 193   cdata.set('HAVE_BZ2', 1)
 194 endif
 195
 196 # Check all of the things.
 197 # TODO: None of these are actually used yet because
 198 # the build files haven't been written
 199 deps = [
 200   ['gtk_dep','gtk+-3.0', '', ''],
 201   ['gtkx_dep','gtk+-x11-3.0', '', ''],
 202   ['caca_dep','caca', '', ''],
 203   ['libraw1394_dep','libraw1394', '>=2.0.0', ''],
 204   ['libiec61883_dep','libiec61883', '>=1.0.0', ''],
 205 ]
 206
 207 foreach d : deps
 208   varname = d[0]
 209   depname = d[1]
 210   version = d[2]
 211   confhname = d[3]
 212   if version == ''
 213     curdep = dependency(depname, required : false)
 214   else
 215     curdep = dependency(depname, required : false, version : version)
 216   endif
 217   set_variable(varname, curdep)
 218   if curdep.found() and confhname != ''
 219     cdata.set(confhname, 1)
 220   endif
 221 endforeach
 222
 223 gst_plugins_good_args = ['-DHAVE_CONFIG_H']
 224 configinc = include_directories('.')
 225 libsinc = include_directories('gst-libs')
 226
 227 have_orcc = false
 228 orcc_args = []
 229 if get_option('use_orc') != 'no'
 230   need_orc = get_option('use_orc') == 'yes'
 231   # Used by various libraries/elements that use Orc code
 232   orc_dep = dependency('orc-0.4', version : '>= 0.4.17', required : need_orc)
 233   orcc = find_program('orcc', required : need_orc)
 234   if orc_dep.found() and orcc.found()
 235     have_orcc = true
 236     orcc_args = [orcc, '--include', 'glib.h']
 237     cdata.set('HAVE_ORC', 1)
 238   else
 239     message('Orc Compiler not found, will use backup C code')
 240     cdata.set('DISABLE_ORC', 1)
 241   endif
 242 else
 243   cdata.set('DISABLE_ORC', 1)
 244 endif
 245
 246 if gst_dep.type_name() == 'internal'
 247     gst_proj = subproject('gstreamer')
 248
 249     if gst_proj.get_variable('disable_gst_debug')
 250         message('GStreamer debug system is disabled')
 251         add_project_arguments('-Wno-unused', language: 'c')
 252     else
 253         message('GStreamer debug system is enabled')
 254     endif
 255 else
 256     # We can't check that in the case of subprojects as we won't
 257     # be able to build against an internal dependency (which is not built yet)
 258     if not cc.compiles('''
 259 #include <gst/gstconfig.h>
 260 #ifdef GST_DISABLE_GST_DEBUG
 261 #error "debugging disabled, make compiler fail"
 262 #endif''' , dependencies: gst_dep)
 263         message('GStreamer debug system is disabled')
 264         add_project_arguments('-Wno-unused', language: 'c')
 265     else
 266         message('GStreamer debug system is enabled')
 267     endif
 268 endif
 269
 270 presetdir = join_paths(get_option('datadir'), 'gstreamer-' + api_version, 'presets')
 271
 272 subdir('gst')
 273 subdir('sys')
 274 subdir('ext')
 275 subdir('tests')
 276 subdir('po')
 277 subdir('pkgconfig')
 278
 279 configure_file(output : 'config.h', configuration : cdata)
 280
 281 python3 = find_program('python3')
 282 run_command(python3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')